ट्युटोरियलले एक्सेल VLOOKUP केस-सेन्सेटिभ कसरी बनाउने भनेर बताउँछ, पाठ केस छुट्याउन सक्ने केही अन्य सूत्रहरू देखाउँछ, र प्रत्येक प्रकार्यको शक्ति र सीमितताहरू औंल्याउँछ।

म हरेक एक्सेल प्रयोगकर्तालाई थाहा छ कुन प्रकार्यले एक्सेलमा ठाडो लुकअप गर्छ। ठीक छ, यो VLOOKUP हो। यद्यपि, धेरै थोरै मानिसहरूलाई थाहा छ कि एक्सेलको VLOOKUP केस-संवेदनशील छ, यसको मतलब यसले सानो अक्षर र UPPERCASE अक्षरहरूलाई एउटै क्यारेक्टरको रूपमा व्यवहार गर्दछ।

यहाँ एउटा द्रुत उदाहरण हो जसले पाठ केस छुट्याउन VLOOKUP को असक्षमता देखाउँछ। मान्नुहोस् यदि तपाईंसँग सेल A2 मा "बिल" र A4 मा "बिल" छ। तलको सूत्रले "बिल" समात्नेछ किनभने यो लुकअप एरेमा पहिलो आउँछ र B2 बाट मिल्दो मान फर्काउँछ।

=VLOOKUP("Bill", A2:B4, 2, FALSE)

4>

यसमा थप लेख, म तपाईंलाई VLOOKUP केस-संवेदनशील बनाउने तरिका देखाउनेछु। हामी एक्सेलमा केस-संवेदनशील मिलान गर्न सक्ने केही अन्य प्रकार्यहरू पनि अन्वेषण गर्नेछौं।

केस-संवेदनशील VLOOKUP सूत्र

माथि उल्लेख गरिए अनुसार, एक सामान्य VLOOKUP सूत्र लेटर केस पहिचान गर्दैन। यद्यपि, तलको उदाहरणमा देखाइए अनुसार Excel VLOOKUP केस-सेन्सेटिभ बनाउने एउटा तरिका छ।

मान्नुहोस् तपाईंसँग स्तम्भ A मा वस्तु IDs छ र वस्तुको मूल्य र टिप्पणी तान्न चाहनुहुन्छ। स्तम्भहरू B र C बाट। समस्या यो हो कि ID हरूले सानो र ठूलो अक्षरहरू समावेश गर्दछ। उदाहरणका लागि, A4 (001Tvci3u) र A5 (001Tvci3U) मा मानहरू मात्र फरक हुन्छन्।अन्तिम वर्ण, "u" र "U", क्रमशः।

"001Tvci3 U " हेर्दा, मानक VLOOKUP सूत्र $90 आउटपुट गर्दछ जुन "001Tvci3 u सँग सम्बन्धित छ। " किनभने यो लुकअप एरेमा "001Tvci3 U " अघि आउँछ। तर यो तपाईले चाहनु भएको होइन, हैन?

=VLOOKUP(F2, A2:C7, 2, FALSE)

एक्सेलमा केस-सेन्सेटिभ लुकअप गर्न, हामी VLOOKUP, CHOOSE र EXACT लाई संयोजन गर्छौं। प्रकार्यहरू:

यो सामान्य सूत्र सबै परिस्थितिहरूमा पूर्ण रूपमा काम गर्दछ। तपाईंले दायाँ देखि बाँया माथि पनि हेर्न सक्नुहुन्छ, जुन नियमित VLOOKUP सूत्रले गर्न असक्षम छ। यो सरल र सुरुचिपूर्ण समाधान सुझाव दिनुभएकोमा पौरियालाई धन्यवाद!

हाम्रो अवस्थामा, वास्तविक सूत्रहरू निम्नानुसार छन्।

F3 मा मूल्य तान्नको लागि:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

टिप्पणी ल्याउन F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

नोट। Excel 365 बाहेक सबै एक्सेल संस्करणहरूमा, यसले एरे सूत्रको रूपमा मात्र काम गर्दछ, त्यसैले यसलाई सही रूपमा पूरा गर्न Ctrl + Shift + Enter थिच्न नबिर्सनुहोस्। एक्सेल 365 मा, गतिशील एरेहरूको लागि समर्थनको कारण, यसले नियमित सूत्रको रूपमा पनि काम गर्दछ।

यस सूत्रले कसरी काम गर्छ:

मुख्य भाग जसले ट्रिक गर्छ नेस्टेड EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

यहाँ, EXACT प्रकार्यले F2 मा भएको मानलाई A2:A7 मा भएको प्रत्येक मानसँग तुलना गर्छ र अक्षर केस सहित ठ्याक्कै उस्तै भएमा TRUE फर्काउँछ,FALSE अन्यथा:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE को index_num तर्कको लागि, हामी array constant {1,2} प्रयोग गर्छौं। नतिजाको रूपमा, प्रकार्यले माथिको एरेबाट तार्किक मानहरू र C2:C7 बाट मानहरूलाई यसरी दुई-आयामी एरेमा संयोजन गर्दछ:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP प्रकार्यले यसलाई त्यहाँबाट लिन्छ। र २-आयामी एरेको पहिलो स्तम्भमा लुकअप मान (जुन TRUE हो) खोज्छ (तार्किक मानहरूद्वारा प्रतिनिधित्व गरिएको) र दोस्रो स्तम्भबाट मिलान फर्काउँछ, जुन हामीले खोजिरहेको मूल्य हो:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

केस-संवेदनशील XLOOKUP सूत्र

Microsoft 365 सदस्यहरूले Excel मा केस-संवेदनशील लुकअप अझ सरल सूत्रको साथ गर्न सक्छन्। तपाईले अनुमान लगाउन सक्नुहुन्छ, म VLOOKUP को अधिक शक्तिशाली उत्तराधिकारीको बारेमा कुरा गर्दैछु - XLOOKUP प्रकार्य।

किनकि XLOOKUP ले लुकअप र रिटर्न एरेहरू अलग-अलग सञ्चालन गर्दछ, हामीलाई अघिल्लोबाट दुई-आयामी एरे ट्रिकको आवश्यकता पर्दैन। उदाहरण। सरल रूपमा, lookup_array तर्कको लागि EXACT प्रयोग गर्नुहोस्:

अन्तिम तर्क ("फेला परेन") वैकल्पिक छ। यदि कुनै मिल्दो फेला परेन भने कुन मान फर्काउने भनेर यसले मात्र परिभाषित गर्दछ। यदि तपाईंले यसलाई छोड्नुभयो भने, सूत्रले केही फेला पारेन भने मानक #N/A त्रुटि फर्काइनेछ।

हाम्रो नमूना तालिकाको लागि, यी प्रयोग गर्नका लागि केस-संवेदनशील XLOOKUP सूत्रहरू हुन्।

F3 मा मूल्य प्राप्त गर्न:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

निकाल्नटिप्पणी F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

यो सूत्र कसरी काम गर्दछ:

अघिल्लो उदाहरणमा जस्तै, EXACT फर्काउँछ TRUE र FALSE मानहरूको एर्रे, जहाँ TRUE ले केस-संवेदनशील मिलानहरूलाई प्रतिनिधित्व गर्दछ। XLOOKUP ले TRUE मानको लागि माथिको array खोज्छ र return_array बाट मिलान फर्काउँछ। कृपया ध्यान दिनुहोस्, यदि लुकअप स्तम्भमा (अक्षर केस सहित) मा दुई वा बढी समान मानहरू छन् भने, सूत्रले पहिलो फेला पारेको मिल्दो फिर्ता गर्नेछ।

XLOOKUP सीमा : मात्र उपलब्ध Excel 365 र Excel 2021 मा।

SUMPRODUCT - मिल्दो नम्बरहरू फर्काउन केस-सेन्सेटिभ लुकअप

तपाईंले हेडिङबाट बुझ्नुभएको रूपमा, SUMPRODUCT अर्को एक्सेल प्रकार्य हो जसले केस-सेन्सेटिभ लुकअप गर्न सक्छ। , तर यसले संख्यात्मक मान मात्र फर्काउन सक्छ। यदि यो तपाइँको मामला होइन भने, त्यसपछि INDEX MATCH उदाहरणमा जानुहोस् जसले सबै डेटा प्रकारहरूको समाधान प्रदान गर्दछ।

तपाईलाई थाहा छ, Excel को SUMPRODUCT ले निर्दिष्ट एरेहरूमा कम्पोनेन्टहरू गुणा गर्छ र उत्पादनहरूको योगफल फर्काउँछ। हामी केस सेन्सेटिभ लुकअप चाहने भएकोले, हामी पहिलो एरे प्राप्त गर्न EXACT प्रकार्य प्रयोग गर्छौं:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

अफसोसको कुरा, SUMPRODUCT प्रकार्यले पाठ मिलानहरू फर्काउन सक्दैन किनभने पाठ मानहरू गुणन गर्न सकिँदैन। यस अवस्थामा, तपाईंले #VALUE प्राप्त गर्नुहुनेछ! तलको स्क्रिनसटमा सेल F4 मा जस्तै त्रुटि:

यस सूत्रले कसरी काम गर्छ:

VLOOKUP उदाहरणमा जस्तै, EXACT प्रकार्य जाँचहरूA2:A7 मा भएका सबै मानहरू विरुद्ध F2 मा मान र केस-संवेदनशील मिलानहरूको लागि TRUE फर्काउँछ, अन्यथा FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

धेरै सूत्रहरूमा, एक्सेलले TRUE लाई 1 र FALSE लाई 0 मा मूल्याङ्कन गर्छ। त्यसोभए, जब SUMPRODUCT ले एउटै स्थानमा दुई एरेका तत्वहरूलाई गुणन गर्छ, सबै नमिल्ने (FALSE) शून्य हुन्छन्:

SUMPRODUCT({0;0;0;54;0;0})

परिणामको रूपमा, सूत्रले बाट संख्या फर्काउँछ। स्तम्भ B जुन स्तम्भ A मा ठ्याक्कै केस-संवेदनशील मिलानसँग मेल खान्छ।

SUMPRODUCT सीमा : संख्यात्मक मानहरू मात्र फर्काउन सक्छ।

INDEX MATCH - केस-संवेदनशील लुकअप सबै डेटा प्रकारहरू

अन्तमा, हामी सबै एक्सेल संस्करणहरूमा र सबै डेटा सेटहरूमा काम गर्ने सीमितता-रहित केस-सेन्सेटिभ लुकअप सूत्र प्राप्त गर्न नजिक छौं।

यो उदाहरण अन्तिममा आउँछ किनभने मात्र होइन। सबै भन्दा राम्रो अन्तिमको लागि बचत गरिएको छ, तर यो पनि कि तपाईंले अघिल्लो उदाहरणहरूमा प्राप्त गर्नुभएको ज्ञानले तपाईंलाई केस-संवेदनशील MATCH INDEX सूत्र राम्रोसँग बुझ्न मद्दत गर्न सक्छ।

INDEX र MATCH प्रकार्यहरूको संयोजन अक्सर प्रयोग गरिन्छ। पूर्व मा cel VLOOKUP को लागि थप लचिलो र बहुमुखी विकल्पको रूपमा। निम्न लेखले राम्रो काम गर्छ (आशा छ :) यी दुई कार्यहरू कसरी सँगै काम गर्दछ भनेर व्याख्या गर्दै - VLOOKUP को सट्टा INDEX MATCH प्रयोग गर्दै।

यहाँ, म तपाईंलाई मुख्य बुँदाहरू सम्झाउनेछु:

• MATCH प्रकार्यले निर्दिष्ट लुकअप एरेमा लुकअप मान खोज्छ र यसको सापेक्ष स्थिति फर्काउँछ।
• सापेक्षलुकअप मानको स्थिति सिधै row_num INDEX प्रकार्यको तर्कमा जान्छ जसले यसलाई पङ्क्तिबाट मान फर्काउन निर्देशन दिन्छ।

टेक्स्ट केस पहिचान गर्न सूत्रको लागि, तपाईंले मात्र क्लासिक INDEX MATCH संयोजनमा थप एउटा प्रकार्य थप्न आवश्यक छ। जाहिर छ, तपाईलाई फेरि EXACT प्रकार्य चाहिन्छ:

F3 मा वास्तविक सूत्र हो:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 मा, हामीले यो प्रयोग गरिरहेका छौं:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

कृपया याद गर्नुहोस् कि यसले मात्र काम गर्दछ Excel 365 बाहेक सबै संस्करणहरूमा एरे सूत्र, त्यसैले Ctrl + Shift + Enter कुञ्जीहरू सँगै थिचेर यसलाई प्रविष्ट गर्न निश्चित हुनुहोस्। यदि सही तरिकाले गरियो भने, सूत्र तलको स्क्रिनसटमा देखाइएको जस्तै घुमाउरो कोष्ठकहरूमा संलग्न हुनेछ:

यस सूत्रले कसरी काम गर्दछ:

अघिल्ला सबै उदाहरणहरूमा जस्तै, EXACT ले A2:A7 मा प्रत्येक मानको लागि TRUE फर्काउँछ जुन F2 मा भएको मानसँग ठ्याक्कै मेल खान्छ। हामीले MATCH को lookup_value को लागि TRUE प्रयोग गर्ने भएकोले, यसले सटीक केस-संवेदनशील मिलानको सापेक्ष स्थिति फर्काउँछ, जुन INDEX ले B2:B7 बाट मिलान फिर्ता गर्न आवश्यक छ।

उन्नत केस-संवेदनशील लुकअप सूत्र

माथि उल्लिखित INDEX MATCH सूत्र सही देखिन्छ, हैन? तर वास्तवमा, यो छैन। म तपाईंलाई किन देखाउँछु।

मान्नुहोस् लुकअप मानसँग सम्बन्धित रिटर्न स्तम्भमा सेल खाली छ। सूत्रले के फर्काउँछ? केही छैन।र अब, यसले वास्तवमा के फर्काउँछ हेरौं:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

ओहो, सूत्रले शून्य फर्काउँछ! हुनसक्छ, पाठ मानहरूसँग मात्र व्यवहार गर्दा यो वास्तवमै महत्त्वपूर्ण छैन। यद्यपि, यदि तपाईंको कार्यपत्रमा संख्याहरू छन् र तिनीहरूमध्ये केही वास्तविक शून्यहरू छन् भने, यो समस्या हो।

वास्तवमा, पहिले छलफल गरिएका अन्य सबै लुकअप सूत्रहरू समान रूपमा व्यवहार गर्छन्। तर अब तपाईलाई त्रुटिपूर्ण सूत्र चाहियो, हैन?

केस-सेन्सेटिभ INDEX MATCH सूत्रलाई पूर्णतया सिद्ध बनाउनको लागि, तपाईले यसलाई IF प्रकार्यमा बेर्नुहोस् जसले रिटर्न सेल खाली छ वा छैन भनेर जाँच गर्दछ र यसमा केहि फर्काउँदैन। यो केस:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

माथिको सूत्रमा:

• "C" फिर्ता स्तम्भ हो।
• "1" नम्बर हो। जसले MATCH प्रकार्यद्वारा फर्काइएको कक्षको सापेक्ष स्थिति लाई वास्तविक सेल ठेगाना मा परिणत गर्दछ।

उदाहरणका लागि, हाम्रो MATCH प्रकार्यमा लुकअप एरे A2:A7 हो, जसको अर्थ सेल A2 को सापेक्षिक स्थिति "1" हो, किनभने यो array मा पहिलो सेल हो। तर वास्तवमा, लुकअप एरे पङ्क्ति 2 मा सुरु हुन्छ। भिन्नतालाई क्षतिपूर्ति गर्न, हामी 1 थप्छौं, त्यसैले INDIRECT प्रकार्यले दायाँ कक्षबाट मान फर्काउनेछ।

तलका स्क्रिनसटहरूले सुधारिएको केस-संवेदनशील INDEX देखाउँछन्। MATCH सूत्र कार्यमा छ।

यदि रिटर्न सेल खाली छ भने, सूत्रले केही पनि आउटपुट गर्दैन (खाली स्ट्रिङ):

21>

यदि फिर्ता कक्षमा शून्य छ , सूत्रले ० फर्काउँछ:

यदि तपाईं चाहनुहुन्छ भनेरिटर्न सेल खाली हुँदा केही सन्देश देखाउनुहोस्, IF को अन्तिम तर्कमा खाली स्ट्रिङ ("") लाई केही पाठसँग बदल्नुहोस्:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

केस-सेन्सेटिभ VLOOKUP लाई सजिलो तरिकाले गर्नुहोस्

हाम्रो Ultimate Suite for Excel का प्रयोगकर्ताहरूसँग एउटा विशेष उपकरण छ जसले ठूला र जटिल तालिकाहरूमा हेर्न सजिलो र तनावमुक्त बनाउँछ। सबै भन्दा राम्रो कुरा यो हो कि मर्ज टु टेबलमा केस-संवेदनशील विकल्प छ, र तलको उदाहरणले यसलाई कार्यमा देखाउँदछ।

मान्नुहोस् कि तपाइँ Qty तान्न चाहनुहुन्छ। लुकअप तालिकाबाट मुख्य तालिकामा अद्वितीय वस्तु आईडीको आधारमा:

तपाईले के गर्नुहुन्छ मर्ज तालिकाहरू चलाउनु हो। विजार्ड र यी चरणहरू प्रदर्शन गर्नुहोस्:

1. नयाँ डाटा तान्नको लागि मुख्य तालिका चयन गर्नुहोस्।
2. नयाँ डाटा खोज्ने लुकअप तालिका चयन गर्नुहोस्।
3. एक वा बढी कुञ्जी स्तम्भहरू छान्नुहोस् (हाम्रो मामलामा वस्तु आईडी)। र केस-संवेदनशील मिलान बाकस जाँच गर्न निश्चित हुनुहोस्।