Dalam tutorial ini, anda akan mempelajari apa itu formula tatasusunan Excel, cara memasukkannya dengan betul dalam lembaran kerja anda dan cara menggunakan pemalar tatasusunan dan fungsi tatasusunan.

Rumus tatasusunan dalam Excel adalah alat yang sangat berkuasa dan salah satu yang paling sukar untuk dikuasai. Formula tatasusunan tunggal boleh melakukan berbilang pengiraan dan menggantikan beribu-ribu formula biasa. Namun begitu, 90% pengguna tidak pernah menggunakan fungsi tatasusunan dalam lembaran kerja mereka semata-mata kerana mereka takut untuk mula mempelajarinya.

Sememangnya, formula tatasusunan salah satu ciri Excel yang paling mengelirukan untuk dipelajari. Matlamat tutorial ini adalah untuk menjadikan lengkung pembelajaran semudah dan lancar yang mungkin.

Apakah tatasusunan dalam Excel?

Sebelum kita memulakan fungsi tatasusunan dan formula, mari kita fikirkan maksud istilah "array". Pada asasnya, tatasusunan ialah koleksi item. Item tersebut boleh berupa teks atau nombor dan ia boleh berada dalam satu baris atau lajur, atau dalam berbilang baris dan lajur.

Sebagai contoh, jika anda meletakkan senarai runcit mingguan anda ke dalam format tatasusunan Excel, ia akan kelihatan seperti:

{"Susu", "Telur", "Mentega", "Kepingan jagung"}

Kemudian, jika anda memilih sel A1 hingga D1, masukkan tatasusunan di atas didahului dengan yang sama tanda (=) dalam bar formula dan tekan CTRL + SHIFT + ENTER , anda akan mendapat hasil berikut:

Apa yang baru anda lakukan ialah mencipta mendatar satu dimensi tatasusunan. tiada apapemalar

Pemalar tatasusunan boleh mengandungi nombor, nilai teks, Boolean (BENAR dan SALAH) dan nilai ralat, dipisahkan dengan koma atau koma bernoktah.

Anda boleh memasukkan nilai berangka sebagai integer, perpuluhan , atau dalam tatatanda saintifik. Jika anda menggunakan nilai teks, nilai tersebut hendaklah dikelilingi dalam petikan berganda (") seperti dalam mana-mana formula Excel.

Pemalar tatasusunan tidak boleh termasuk tatasusunan lain, rujukan sel, julat, tarikh, nama yang ditentukan, formula atau fungsi .

Menggunakan pemalar tatasusunan dalam formula Excel

Sekarang anda sudah biasa dengan konsep pemalar tatasusunan, mari lihat cara anda boleh menggunakan informula tatasusunan untuk menyelesaikan tugasan praktikal anda.

Contoh 1. Jumlah N nombor terbesar / terkecil dalam julat

Anda bermula dengan mencipta tatasusunan menegak pemalar yang mengandungi seberapa banyak nombor yang anda mahu jumlahkan. Contohnya, jika anda ingin menambah 3 nombor terkecil atau terbesar dalam julat, pemalar tatasusunan ialah {1,2,3}.

Kemudian, anda mengambil fungsi BESAR atau KECIL, tentukan keseluruhan julat sel dalam parameter pertama dan masukkan pemalar tatasusunan dalam yang kedua. Akhir sekali, benamkannya dalam fungsi SUM, seperti ini:

Jumlah 3 nombor terbesar: =SUM(LARGE(range, {1,2,3}))

Jumlah 3 nombor terkecil: =SUM(SMALL(range, {1,2,3}))

Jangan lupa tekan Ctrl + Shift + Enter kerana anda memasukkan formula tatasusunan, dan anda akan mendapat hasil berikut:

Dengan cara yang sama, anda boleh mengira purata N terkecil atau nilai terbesar dalam julat:

Purata 3 nombor teratas: =AVERAGE(LARGE(range, {1,2,3}))

Purata daripada3 nombor terbawah: =AVERAGE(SMALL(range, {1,2,3}))

Contoh 2. Formula tatasusunan untuk mengira sel dengan berbilang syarat

Andaikan, anda mempunyai senarai pesanan dan anda ingin tahu berapa kali penjual tertentu telah menjual diberikan produk.

Cara paling mudah ialah menggunakan formula COUNTIFS dengan berbilang syarat. Walau bagaimanapun, jika anda ingin memasukkan banyak produk, formula COUNTIFS anda mungkin membesar dalam saiz terlalu besar. Untuk menjadikannya lebih padat, anda boleh menggunakan COUNTIFS bersama-sama dengan SUM dan memasukkan pemalar tatasusunan dalam satu atau beberapa argumen, contohnya:

=SUM(COUNTIFS(range1, "criteria1", range2, {"criteria1", "criteria2"}))

Formula sebenar mungkin kelihatan seperti berikut:

=SUM(COUNTIFS(B2:B9, "sally", C2:C9, {"apples", "lemons"}))

Tatasusunan sampel kami hanya terdiri daripada dua elemen kerana matlamatnya adalah untuk menunjukkan pendekatan. Dalam formula tatasusunan sebenar anda, anda boleh memasukkan seberapa banyak elemen yang diperlukan oleh logik perniagaan anda, dengan syarat jumlah panjang formula tidak melebihi 8,192 aksara dalam Excel 2019 - 2007 (1,024 aksara dalam Excel 2003 dan lebih rendah) dan komputer anda berkuasa cukup untuk memproses tatasusunan yang besar. Sila lihat pengehadan formula tatasusunan untuk mendapatkan butiran lanjut.

Dan berikut ialah contoh formula tatasusunan lanjutan yang mencari jumlah semua nilai padanan dalam jadual: SUM dan VLOOKUP dengan pemalar tatasusunan.

AND dan OR operator dalam formula tatasusunan Excel

Pengendali tatasusunan memberitahu formula cara anda mahu memproses tatasusunan - menggunakan logik DAN atau ATAU.

• Pengendali DAN ialah asterisk ( *) yangialah simbol pendaraban. Ia mengarahkan Excel untuk mengembalikan TRUE jika SEMUA syarat dinilai kepada TRUE.
• OR operator ialah tanda tambah (+). Ia mengembalikan BENAR jika MANA-MANA ​​syarat dalam ungkapan yang diberikan dinilai kepada BENAR.

Formula tatasusunan dengan operator DAN

Dalam contoh ini, kami mendapati jumlah jualan di mana jualan orang ialah Mike DAN produknya ialah Epal :

=SUM((A2:A9="Mike") * (B2:B9="Apples") * (C2:C9))

Atau

=SUM(IF(((A2:A9="Mike") * (B2:B9="Apples")), (C2:C9)))

Secara teknikal, formula ini mendarabkan elemen tiga tatasusunan dalam kedudukan yang sama. Dua tatasusunan pertama diwakili oleh nilai BENAR dan SALAH yang merupakan hasil perbandingan A2:A9 kepada Mike" dan B2:B9 kepada "Epal". Tatasusunan ketiga mengandungi nombor jualan daripada julat C2:C9. Seperti mana-mana operasi matematik , pendaraban menukar TRUE dan FALSE masing-masing kepada 1 dan 0. Dan kerana mendarab dengan 0 sentiasa memberikan sifar, tatasusunan yang terhasil mempunyai 0 apabila salah satu atau kedua-dua syarat tidak dipenuhi. Jika kedua-dua syarat dipenuhi, elemen yang sepadan daripada tatasusunan ketiga mendapat ke dalam tatasusunan akhir (cth. 1*1*C2 = 10). Jadi, hasil pendaraban ialah tatasusunan ini: {10;0;0;30;0;0;0;0}. Akhirnya, fungsi SUM menjumlahkan elemen tatasusunan dan mengembalikan hasil 40.

Formula tatasusunan Excel dengan pengendali ATAU

Formula tatasusunan berikut dengan pengendali ATAU (+) menjumlahkan semua jualan yang mana jurujualnya ialah Mike ATAU produk adalah Epal:

=SUM(IF(((A2:A9="Mike") + (B2:B9="Apples")), (C2:C9)))

Dalam formula ini, anda menambah elemen dua tatasusunan pertama (iaitu syarat yang anda ingin menguji), dan dapatkan BENAR (>0) jika sekurang-kurangnya satu syarat bernilai BENAR; FALSE (0) apabila semua syarat dinilai kepada FALSE. Kemudian, IF menyemak sama ada hasil penambahan adalah lebih besar daripada 0, dan jika ia, SUM menambah elemen sepadan bagi tatasusunan ketiga (C2:C9).

Petua. Dalam versi moden Excel, tidak perlu menggunakan formula tatasusunan untuk tugasan seperti ini - formula SUMIFS mudah mengendalikannya dengan sempurna. Namun begitu, pengendali DAN dan ATAU dalam formula tatasusunan mungkin terbukti membantu dalam senario yang lebih kompleks, apatah lagi gimnastik minda yang sangat baik : )

Operator dua unari dalam formula tatasusunan Excel

Jika anda pernah bekerja dengan formula tatasusunan dalam Excel, kemungkinan besar anda menjumpai beberapa formula yang mengandungi sempang berganda (--) dan anda mungkin tertanya-tanya untuk apa ia digunakan.

Sempang berganda, yang secara teknikal dipanggil double unary operator, digunakan untuk menukar nilai Boolean bukan angka (BENAR / SALAH) yang dikembalikan oleh beberapa ungkapan kepada 1 dan 0 yang boleh difahami oleh fungsi tatasusunan.

Contoh berikut diharapkan dapat membantu lebih mudah difahami. Katakan anda mempunyai senarai tarikh dalam lajur A dan anda ingin mengetahui bilangan tarikh yang berlaku pada bulan Januari, tanpa mengira tahun.

Formula berikut akan berfungsimerawat:

=SUM(--(MONTH(A2:A10)=1))

Memandangkan ini ialah formula tatasusunan Excel, ingat untuk menekan Ctrl + Shift + Enter untuk melengkapkannya.

Jika anda berminat pada bulan lain, gantikan 1 dengan nombor yang sepadan. Contohnya, 2 bermaksud Februari, 3 bermaksud Mac, dan seterusnya. Untuk menjadikan formula lebih fleksibel, anda boleh menentukan nombor bulan dalam sesetengah sel, seperti ditunjukkan dalam tangkapan skrin:

Dan sekarang, mari kita analisa cara formula tatasusunan ini berfungsi. Fungsi MONTH mengembalikan bulan setiap tarikh dalam sel A2 hingga A10 yang diwakili oleh nombor siri, yang menghasilkan tatasusunan {2;1;4;2;12;1;2;12;1}.

Selepas itu, setiap elemen tatasusunan dibandingkan dengan nilai dalam sel D1, iaitu nombor 1 dalam contoh ini. Hasil daripada perbandingan ini ialah tatasusunan nilai Boolean TRUE dan FALSE. Seperti yang anda ingat, anda boleh memilih bahagian tertentu formula tatasusunan dan tekan F9 untuk melihat bahagian itu bersamaan dengan:

Akhir sekali, anda perlu menukar nilai Boolean ini kepada 1 dan 0 yang boleh difahami oleh fungsi SUM. Dan inilah yang diperlukan oleh pengendali double unary. Unari pertama memaksa TRUE/FALSE kepada -1/0, masing-masing. Unari kedua menafikan nilai, iaitu membalikkan tanda, mengubahnya menjadi +1 dan 0, yang kebanyakan fungsi Excel boleh memahami dan berfungsi. Jika anda mengalih keluar double unary daripada formula di atas, ia tidak akan berfungsi.

Saya berharap pendek initutorial telah terbukti membantu dalam perjalanan anda untuk menguasai formula tatasusunan Excel. Minggu depan, kami akan meneruskan tatasusunan Excel dengan memfokuskan pada contoh formula lanjutan. Sila nantikan dan terima kasih kerana membaca!

Apakah formula tatasusunan dalam Excel?

Perbezaan antara formula tatasusunan dan formula biasa ialah formula tatasusunan memproses beberapa nilai dan bukannya satu sahaja. Dalam erti kata lain, formula tatasusunan dalam Excel menilai semua nilai individu dalam tatasusunan dan melakukan berbilang pengiraan pada satu atau beberapa item mengikut syarat yang dinyatakan dalam formula.

Bukan sahaja formula tatasusunan boleh berurusan dengan beberapa nilai serentak, ia juga boleh mengembalikan beberapa nilai pada satu masa. Jadi, hasil yang dikembalikan oleh formula tatasusunan juga merupakan tatasusunan.

Formula tatasusunan tersedia dalam semua versi Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 dan lebih rendah.

Dan kini, nampaknya masa yang sesuai untuk anda mencipta formula tatasusunan pertama anda.

Contoh ringkas formula tatasusunan Excel

Andaikan anda mempunyai beberapa item dalam lajur B, harganya dalam lajur C dan anda ingin mengira jumlah besar semua jualan.

Sudah tentu, tiada apa yang menghalang anda daripada mengira subjumlah dalam setiap baris terlebih dahulu dengan sesuatu yang semudah =B2*C2 dan kemudian jumlah nilai tersebut:

Walau bagaimanapun, formula tatasusunan boleh menyelamatkan anda daripada pukulan kekunci tambahan kerana ia mendapat Excel untuk menyimpan hasil perantaraan dalam ingatan dan bukannya dalam lajur tambahan. Jadi, yang diperlukan hanyalah formula tatasusunan tunggal dan 2 langkah pantas:

1. Pilih sel kosong dan masukkanformula berikut di dalamnya:

   =SUM(B2:B6*C2:C6)

2. Tekan pintasan papan kekunci CTRL + SHIFT + ENTER untuk melengkapkan formula tatasusunan.

   Sebaik sahaja anda melakukan ini, Microsoft Excel mengelilingi formula dengan {curly braces}, yang merupakan petunjuk visual formula tatasusunan.

   Apa yang dilakukan oleh formula ialah mendarabkan nilai dalam setiap baris individu bagi yang ditentukan tatasusunan (sel B2 hingga C6), tambahkan subjumlah bersama-sama dan keluarkan jumlah besar:

   

Contoh mudah ini menunjukkan betapa kuatnya tatasusunan formula boleh. Apabila bekerja dengan ratusan dan beribu-ribu baris data, fikirkan berapa banyak masa yang anda boleh jimatkan dengan memasukkan satu formula tatasusunan dalam satu sel.

Mengapa menggunakan formula tatasusunan dalam Excel?

Anasusunan Excel formula adalah alat yang paling berguna untuk melakukan pengiraan yang canggih dan melakukan tugas yang rumit. Formula tatasusunan tunggal boleh menggantikan beratus-ratus formula biasa. Formula tatasusunan sangat bagus untuk tugasan seperti:

• Jumlah nombor yang memenuhi syarat tertentu, contohnya jumlah N nilai terbesar atau terkecil dalam julat.
• Jumlah setiap baris lain, atau setiap baris atau lajur ke-N, seperti yang ditunjukkan dalam contoh ini.
• Kira bilangan semua atau aksara tertentu dalam julat yang ditentukan. Berikut ialah formula tatasusunan yang mengira semua aksara, dan satu lagi yang mengira mana-mana aksara tertentu.

Cara memasukkan formula tatasusunan dalam Excel (Ctrl + Shift + Enter)

Seperti yang anda sedia maklum,gabungan 3 kekunci CTRL + SHIFT + ENTER ialah sentuhan ajaib yang menukar formula biasa kepada formula tatasusunan.

Apabila memasukkan formula tatasusunan dalam Excel, terdapat 4 perkara penting yang perlu diingat:

1. Setelah anda selesai menaip formula dan menekan kekunci CTRL SHIFT ENTER secara serentak, Excel secara automatik menyertakan formula antara {curly braces}. Apabila anda memilih sel sedemikian, anda boleh melihat pendakap dalam bar formula, yang memberi anda petunjuk bahawa formula tatasusunan ada di sana.
2. Menaip pendakap di sekeliling formula tidak akan berfungsi secara manual . Anda mesti menekan pintasan Ctrl+Shift+Enter untuk melengkapkan formula tatasusunan.
3. Setiap kali anda mengedit formula tatasusunan, pendakap hilang dan anda mesti menekan Ctrl+Shift+Enter sekali lagi untuk menyimpan perubahan.
4. Jika anda terlupa untuk menekan Ctrl+Shift+Enter, formula anda akan berkelakuan seperti formula biasa dan memproses hanya nilai pertama dalam tatasusunan yang ditentukan.

Kerana semua formula tatasusunan Excel memerlukan menekan Ctrl + Shift + Enter, kadangkala ia dipanggil formula CSE .

Gunakan kekunci F9 untuk menilai bahagian formula tatasusunan

Apabila bekerja dengan formula tatasusunan dalam Excel, anda boleh melihat cara mereka mengira dan menyimpan item mereka (tatasusunan dalaman) untuk memaparkan hasil akhir anda lihat dalam sel. Untuk melakukan ini, pilih satu atau beberapa argumen dalam kurungan fungsi, dan kemudian tekan kekunci F9. Kepadakeluar dari mod penilaian formula, tekan kekunci Esc.

Dalam contoh di atas, untuk melihat subjumlah semua produk, anda pilih B2:B6*C2:C6, tekan F9 dan dapatkan hasil berikut.

Nota. Sila ambil perhatian bahawa anda mesti memilih beberapa bahagian formula sebelum menekan F9, jika tidak kekunci F9 hanya akan menggantikan formula anda dengan nilai yang dikira.

Formula tatasusunan sel tunggal dan berbilang sel dalam Excel

Formula tatasusunan Excel boleh mengembalikan hasil dalam sel tunggal atau dalam berbilang sel. Formula tatasusunan yang dimasukkan dalam julat sel dipanggil formula berbilang sel . Formula tatasusunan yang berada dalam sel tunggal dipanggil formula sel tunggal .

Terdapat beberapa fungsi tatasusunan Excel yang direka untuk mengembalikan tatasusunan berbilang sel, contohnya TRANSPOSE, TREND , FREKUENSI, LINEST, dsb.

Fungsi lain, seperti SUM, PURATA, AGREGATE, MAX, MIN, boleh mengira ungkapan tatasusunan apabila dimasukkan ke dalam sel tunggal dengan menggunakan Ctrl + Shift + Enter .

Contoh berikut menunjukkan cara menggunakan formula tatasusunan sel tunggal dan berbilang sel.

Contoh 1. Formula tatasusunan sel tunggal

Andaikan anda mempunyai dua lajur yang menyenaraikan bilangan item yang dijual dalam 2 bulan berbeza, sebut lajur B dan C, dan anda ingin mencari peningkatan jualan maksimum.

Biasanya, anda akan menambah lajur tambahan, katakan lajur D, yang mengira perubahan jualan bagi setiapproduk menggunakan formula seperti =C2-B2 , dan kemudian cari nilai maksimum dalam lajur tambahan =MAX(D:D) itu.

Formula tatasusunan tidak memerlukan lajur tambahan kerana ia menyimpan hasil perantaraan dalam memori dengan sempurna. Jadi, anda hanya masukkan formula berikut dan tekan Ctrl + Shift + Enter :

=MAX(C2:C6-B2:B6)

Contoh 2. Formula tatasusunan berbilang sel dalam Excel

Dalam contoh SUM sebelumnya, katakan anda perlu membayar cukai 10% daripada setiap jualan dan anda ingin mengira jumlah cukai untuk setiap produk dengan satu formula.

Pilih julat sel kosong, sebut D2:D6, dan masukkan formula berikut dalam bar formula:

=B2:B6 * C2:C6 * 0.1

Sebaik sahaja anda menekan Ctrl + Shift + Enter , Excel akan meletakkan contoh formula tatasusunan anda dalam setiap sel julat yang dipilih dan anda akan mendapat hasil berikut:

Contoh 3. Menggunakan fungsi tatasusunan Excel untuk mengembalikan tatasusunan berbilang sel

Seperti yang sudah disebutkan, Microsoft Excel menyediakan beberapa yang dipanggil "fungsi tatasusunan" yang direka khas untuk berfungsi dengan tatasusunan berbilang sel. TRANSPOSE ialah salah satu daripada fungsi sedemikian dan kami akan menggunakannya untuk menukar jadual di atas, iaitu menukar baris kepada lajur.

1. Pilih julat sel kosong yang anda mahu keluarkan jadual alih. Memandangkan kami sedang menukar baris kepada lajur, pastikan anda memilih bilangan baris dan lajur yang sama kerana jadual sumber anda mempunyai lajur dan baris, masing-masing. Dalamcontoh ini, kami memilih 6 lajur dan 4 baris.
2. Tekan F2 untuk memasuki mod edit.
3. Masukkan formula dan tekan Ctrl + Shift + Enter .

Dalam contoh kami, formulanya ialah:

=TRANSPOSE($A$1:$D$6)

Hasilnya akan kelihatan serupa dengan ini:

Beginilah cara anda menggunakan TRANSPOSE sebagai formula tatasusunan CSE dalam Excel 2019 dan lebih awal. Dalam Dynamic Array Excel, ini juga berfungsi sebagai formula biasa. Untuk mengetahui cara lain untuk menukar dalam Excel, sila lihat tutorial ini: Cara menukar lajur dan baris dalam Excel.

Cara bekerja dengan formula tatasusunan berbilang sel

Apabila bekerja dengan berbilang- formula tatasusunan sel dalam Excel, pastikan anda mengikuti peraturan ini untuk mendapatkan hasil yang betul:

1. Pilih julat sel yang anda mahu keluarkan hasil sebelum memasukkan formula.
2. Untuk memadam formula tatasusunan berbilang sel, sama ada pilih semua sel yang mengandunginya dan tekan DELETE , atau pilih keseluruhan formula dalam bar formula, tekan DELETE , dan kemudian tekan Ctrl + Shift + Enter .
3. Anda tidak boleh mengedit atau mengalihkan kandungan sel individu dalam formula tatasusunan, anda juga tidak boleh memasukkan sel baharu ke dalam atau memadam sel sedia ada daripada formula tatasusunan berbilang sel. Setiap kali anda cuba melakukan ini, Microsoft Excel akan memberikan amaran " Anda tidak boleh menukar sebahagian daripada tatasusunan ".
4. Untuk mengecilkan formula tatasusunan, iaitu untuk menggunakannya kepada lebih sedikit sel, anda perlu padamkanformula sedia ada dahulu dan kemudian masukkan yang baharu.
5. Untuk mengembangkan formula tatasusunan, iaitu gunakannya pada lebih banyak sel, pilih semua sel yang mengandungi formula semasa serta sel kosong yang anda mahu milikinya, tekan F2 untuk bertukar kepada mod edit, laraskan rujukan dalam formula dan tekan Ctrl + Shift + Enter untuk mengemas kininya.
6. Anda tidak boleh menggunakan formula tatasusunan berbilang sel dalam jadual Excel.
7. Anda harus memasukkan formula tatasusunan berbilang sel dalam julat sel yang sama saiz dengan tatasusunan yang terhasil yang dikembalikan oleh formula. Jika formula tatasusunan Excel anda menghasilkan tatasusunan yang lebih besar daripada julat yang dipilih, nilai lebihan tidak akan muncul pada lembaran kerja. Jika tatasusunan yang dikembalikan oleh formula adalah lebih kecil daripada julat yang dipilih, ralat #N/A akan muncul dalam sel tambahan.

Jika formula anda boleh mengembalikan tatasusunan dengan bilangan elemen yang berubah-ubah, masukkannya dalam julat yang sama atau lebih besar daripada tatasusunan maksimum yang dikembalikan oleh formula dan bungkus formula anda dalam fungsi IFERROR, seperti yang ditunjukkan dalam contoh ini.

Pemalar tatasusunan Excel

Dalam Microsoft Excel, pemalar tatasusunan hanyalah satu set nilai statik. Nilai ini tidak pernah berubah apabila anda menyalin formula ke sel atau nilai lain.

Anda sudah melihat contoh pemalar tatasusunan yang dibuat daripada senarai runcit pada awal tutorial ini. Sekarang, mari lihat jenis tatasusunan lain yang wujud dan cara anda menciptamereka.

Terdapat 3 jenis pemalar tatasusunan:

1. Pemalar tatasusunan mendatar

Pemalar tatasusunan mendatar berada dalam satu baris. Untuk mencipta pemalar tatasusunan baris, taipkan nilai yang dipisahkan dengan koma dan sertakan kemudian dalam pendakap, contohnya {1,2,3,4}.

Nota. Apabila mencipta pemalar tatasusunan, anda harus menaip pendakap pembukaan dan penutup secara manual.

Untuk memasukkan tatasusunan mendatar dalam hamparan, pilih bilangan sel kosong yang sepadan dalam satu baris, taip formula ={1,2,3,4} dalam bar formula dan tekan Ctrl + Shift + Enter . Hasilnya akan serupa dengan ini:

Seperti yang anda lihat dalam tangkapan skrin, Excel membalut pemalar tatasusunan dalam set pendakap yang lain, sama seperti semasa anda memasukkan formula tatasusunan.

2. Pemalar tatasusunan menegak

Pemalar tatasusunan menegak berada dalam lajur. Anda menciptanya dengan cara yang sama seperti tatasusunan mendatar dengan satu-satunya perbezaan iaitu anda mengehadkan item dengan koma bernoktah, contohnya:

={11; 22; 33; 44}

3. Pemalar tatasusunan dua dimensi

Untuk mencipta tatasusunan dua dimensi, anda memisahkan setiap baris dengan koma bertitik dan setiap lajur data dengan koma.

={"a", "b", "c"; 1, 2, 3}

Bekerja dengan pemalar tatasusunan Excel

Pemalar tatasusunan ialah salah satu asas formula tatasusunan Excel. Maklumat dan petua berikut mungkin membantu anda menggunakannya dengan cara yang paling cekap.

1. Elemen tatasusunan