„Concatenate“ þýðir venjulega að tengja eitthvað saman í röð eða keðju. Þessi aðgerð er notuð þegar þú þarft að sameina texta úr mörgum Google Sheets hólfum. Þessi grein safnar saman vinsælustu og auðveldustu lausnunum til að hjálpa þér að leysa samtengingargátuna.

Hversu stórt gagnasafnið þitt er gætirðu rekist á það verkefni að sameina margar frumur í Google Sheets saman. Og ég efast ekki um að þú viljir ekki aðeins koma í veg fyrir að öll gildi tapist, heldur einnig bæta við komum, bilum eða öðrum stöfum, eða jafnvel aðgreina þessar færslur með öðrum texta.

Jæja, töflureiknar bjóða upp á nokkur verkfæri fyrir þetta verkefni.

Google Sheets CONCAT aðgerð

CONCAT aðgerðin er einfölduð útgáfa af Google Sheets CONCATENATE:

Til að sameina frumur með þessari aðgerð þarftu að skrá nauðsynleg gildi:

• gildi1 – skrá sem gildi2 ætti að bæta við.
• gildi2 – gildið sem á að sameina.

Til að fá einn streng úr 2 texta- eða talnaeiningum mun formúlan líta út eins og hér að neðan, með hverri skrá í tvöföldum gæsalöppum:

=CONCAT("2019:","The Lion King")

Í raun og veru eru gögnin þín líklega þegar í frumum. Þú getur vísað beint í þessar frumur í stað þess að setja niður hverja tölu eða texta sem rök. Þannig að raungagnaformúlan verður svona:

=CONCAT(A2,B2)

Ábending. Til að afrita formúluna þína í allan dálkinn skaltu velja reitinnmeð formúlunni og tvísmelltu á litla ferninginn neðst í hægra horni reitsins. Allur dálkurinn verður sjálfkrafa fylltur með formúlunni, alveg til loka töflunnar.

Eins og þú sérð er aðgerðin ofureinföld en hún hefur stóra veika punkta :

• það sameinar aðeins tvær hólf í Google Sheets í einu.
• það getur ekki sameinað dálka, raðir eða önnur stór gagnasvið, það tekur aðeins stakar frumur. Ef þú reynir að sameina margar frumur færðu annað hvort villu eða aðeins fyrstu tvö gildin verða sameinuð, svona:

  =CONCAT(A2:A11,B2:B11)

  

CONCAT valkostur: samtengingartæki og tákn (&)

Það eru fullt af mismunandi aðgerðum í ýmsum tilgangi í formúlum. Samtenging er engin undantekning. Með því að nota og-merki (&) í formúlum í stað CONCAT fallsins færðu sömu niðurstöðu:

=A2&B2

En lítið veist þú að þessi samtengingaraðili sé sveigjanlegri. Hér er það sem það getur gert:

1. Sameina fleiri en tvö gildi í einu:

   =A2&B2&C2

   

2. Ekki bara sameina frumur í Google Sheets, en aðskilið þau einnig með ýmsum stöfum:

   =A2&" "&B2&"; "&C2

   

Ef þú færð samt ekki þá niðurstöðu sem þú vilt með þessum valkostum , það er ein aðgerð í viðbót til að prófa.

Hvernig á að nota CONCATENATE í Google Sheets

Ég tel að Google Sheets CONCATENATE aðgerðin sé sú fyrsta sem notarþegar kemur að því að bæta nokkrum færslum saman.

CONCATENATE textastrengi og tölur í Google Sheets

Formúlumynstrið samanstendur af eftirfarandi rökum:

• streng1 er fyrsti strengurinn sem þú vilt bæta öðrum gildum við. Þessi rök eru nauðsynleg.
• string2, … stendur fyrir alla aðra strengi sem þú gætir viljað bæta við. Þessi rök eru valfrjáls.

Athugið. Niðurstöðuskráin mun samanstanda af strengjunum í þeirri röð sem þeir birtast í formúlunni.

Ef ég laga formúluna að gögnunum mínum fæ ég þetta:

=CONCATENATE(A2,B2,C2)

Eða þar sem fallið samþykkir svið:

=CONCATENATE(A2:D2)

Þú getur strax tekið eftir fyrsta kostinum við Google Sheets CONCATENATE: það tengist auðveldlega yfir tvo hólfa með bæði texta og tölum.

Google Sheets: sameina strengi með skiljum

Það er hálf vinnan að sameina frumur í Google Sheets. En til að útkoman líti fallega út og læsileg, ættirðu að bæta við nokkrum aukastöfum.

Ef þú heldur formúlunni eins og hún er, mun hún bara líma allt saman: BonnieJacksonCA , BonnieJacksonIN , o.s.frv. En Google Sheets CONCATENATE tekur líka stafi sem rök.

Þannig, til að bæta við nokkrum skiljum til að auðvelda læsileika, getið þá í tvöföldum gæsalöppum í formúlunni:

=CONCATENATE(A2," ",B2,", ",C2)

Hér vil ég sameina A2 & B2 með bili og aðskilið B2 frá C2 með kommu ogbil:

Þér er frjálst að nota næstum hvaða staf sem er í fallinu eins og þessu, en samt sem áður þarf línuskil aðra nálgun.

Ábending. Ef það eru tómar reiti í sumum dálkunum sem þú ert að sameina, þá er ein aðgerð í viðbót sem þú gætir haft áhuga á. TEXTJOIN sameinar ekki bara reiti í Google Sheets heldur hunsar eyður:

=TEXTJOIN(" ",TRUE,A2:C2)

Svona virkar þetta:

1. Tilgreindu æskilega afmörkun sem fyrstu röksemd – bil (" ") fyrir mig.
2. Settu TRUE sem önnur rök til að sleppa auðum hólfum eða FALSE til að hafa þær með í niðurstöðunni.
3. Sláðu inn svið til að sameinast.

Tengdu línuskil í Google Sheets

Þó að það sé augljóst hvernig á að slá inn flest afmörkun í fallinu, geturðu ekki slegið línuskil á sama hátt þar. En sem betur fer gerir Google þér kleift að spila mörg mismunandi spil.

Það er aðgerð sem hjálpar til við að fá sérstafi – hún heitir CHAR. Þú sérð, hver stafur hefur stað í Unicode töflunni. Þú þarft bara að gefa raðtölu stafsins úr þeirri töflu yfir í fallið og það síðarnefnda mun skila stafnum sjálfum.

Hér er formúla til að fá línuskil:

=CHAR(10)

Bættu því við formúluna til að sameinast línuskilunum í Google Sheets:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

Samana dagsetningu og tíma í Google Sheets

Ef þú reynir að sameina dagsetningu og tíma í Google Sheets með einni af aðferðunumhér að ofan, það mun ekki virka. Töflureikninn þinn mun skila tölum:

Til að sameina dagsetningu og tíma rétt í Google Sheets skaltu nota TEXT aðgerðina:

• þar sem tala er hvaða tala, dagsetning eða tími sem þú vilt fá á æskilegu sniði
• og snið er mynstrið sem þú vilt nota sjá í kjölfarið.

Ábending. Í dæminu mínu ætla ég að vísa til fruma með dagsetningum og tímum, en þér er frjálst að nota dagsetningar-/tímaeiningar eða jafnvel aðgerðir eins og DATE eða TIME beint í formúlunni.

1. Ég nota fyrstu TEXT formúluna til að breyta dagsetningarsniðinu úr 7/9/2019 í 9. júlí 2019 :

   =TEXT(B2,"D MMM YYYY")

2. Seinni TEXTI skilar tímanum:

   =TEXT(C2,"HH:MM:SS")

3. Með því að nota þetta í CONCATENATE leyfir Google Sheets mér að sameina dagsetningu og tíma á æskilegu sniði með öðrum stöfum eða texta:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

Samana dálka í Google Sheets

Með smávægilegum breytingum, allar þær leiðir sem ég nefndi eru færar um að sameina dálka í Google Sheets.

Dæmi 1. Google Sheets CONCAT

Til að sameina heila dálka í Google Sheets við CONCAT skaltu velja allt svið sem ætti að innihalda niðurstöðuna (C2:C11 í mínu tilfelli) og slá inn formúluumbúðirnar þínar það í ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

Athugið. Þú gætir notað CONCATENATE aðgerðina, en hún mun sameina allar færslur innan eins reits þar sem hún sameinar auðveldlega margar frumur og gagnasvið.

Dæmi 2.Samtengingartæki

Búðu til fylkisformúlur til að sameina dálka í Google Sheets með því að nota og-merki og bæta við skiljum á sama tíma:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

Þetta lítur vel út, en ég verð að benda á nokkra stóra galla.

Ef þú ert með of marga dálka getur það orðið sársauki í hálsinum að telja upp alla, sérstaklega ef þú sleppir/afritar/blandar saman einhverjum stöfum fyrir slysni. .

Einnig, ef þú ákveður að bæta fleiri dálkum við formúluna síðar, verður þú að breyta hverju og einu núverandi sviði í formúlunni handvirkt.

Næsta dæmi leysir þessi vandamál.

Dæmi 3. Google Sheets QUERY

Google Sheets QUERY aðgerðin hentar einnig til að sameina nokkra dálka í Google Sheets. Skoðaðu:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

Þú gætir haldið að þessi undarlega formúla sé þér ofviða, en leyfðu mér að leggja allt í sölurnar fyrir þig:

1. =TRANSPOSE(A2:D10) breytir gagnalínum í dálka.
2. =QUERY(TRANSPOSE(A2:D10),,9^9) sameinar færslur í hverjum dálki í efstu frumur.

   Ábending. Þegar ég set 9^9 inn í formúluna, passa ég að allar línur úr öllum dálkum verði dregnar inn í fyrstu línuna eins og þær væru hausar. Það er 9^9 þar sem þessi tjáning inniheldur allar mögulegar frumur í töflureikninum (munið þið eftir takmörkunum fyrir 10M frumur?) og er auðvelt að muna það. :)

3. =TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9)) tekur þessa hauslínu úr QUERY og breytir henni í dálk eins ogeinn sem ég á.

Hér eru fríðindi þess að sameina dálka í Google töflureiknum með því að nota QUERY:

• þú þarft ekki að velja allan dálkinn eins og þú gerir fyrir fylkisformúlur
• þarftu ekki að nefna hvern dálk í formúlunni nema þeir séu ekki aðliggjandi. Í þessu tilviki mun formúlan líta svona út:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

Tengdu saman og bættu við texta eftir staðsetningu

Þú veist nú þegar að þú getur bætt við texta sem vantar, tölur , og stafi í strengina þína með því að nota CONCATENATE aðgerðina.

Ábending. Sjáðu fleiri formúlur um það í þessari kennslu.

En ef það eru of margar skrár til að taka þátt í, geta allir aukastafir lengt formúluna þína langt umfram það sem þú hefur áætlað. Í tilfellum sem þessum er betra að sameina reiti í Google Sheets eins og þær eru eða nota einföld afmörkun eins og bil og bæta við textanum eftir það. Sérstakt tól okkar mun hjálpa þér.

Bæta við texta eftir staðsetningu setur inn allar stafir og strengi eftir staðsetningunni sem þú tilgreinir, engar formúlur eru nauðsynlegar. Leyfðu mér að sýna þér hvernig það virkar.

Í fyrra dæminu sameinaði QUERY nöfn og símanúmer fyrir mig. En mig langar að bæta við landsskammstöfunum: (USA/CA) á undan símanúmerum sem byrja á +1 og UK á undan +44 :

Skipta hólfum í Google Sheets

Ef þú sameinar hólfa í Google Sheets eru líkurnar á að þú þurfir að skipta þeim aftur á einhvern tíma . Það eru þrjár leiðir til að gera það:

1. Bygðu til formúlumeð því að nota Google Sheets SPLIT aðgerðina.
2. Notaðu staðlaða töflureiknitækið – Skiptu texta í dálka.
3. Eða prófaðu endurbættu útgáfuna af innbyggða tólinu – Skiptu texta í dálka fyrir Google Sheets:

Það gerir þér kleift að skipta frumum með hvaða afmörkun sem er eða jafnvel sett af skiljum, meðhöndla þær sem eina og innihalda samtengingar ef þörf krefur. Það býður einnig upp á möguleika á að skipta frumum í Google Sheets eftir staðsetningu.

Ábending. Það er möguleiki á að draga gögn úr Google Sheets hólfum frekar en að skipta innihaldinu.

Hvernig á að sameina reiti í Google Sheets án formúla

Ef að ná tökum á mismunandi formúlum er ekki hluti af áætlun þinni, muntu njóta góðs af Merge Values ​​viðbótinni okkar. Viðbótin sameinar færslur fljótt í röðum, dálkum eða öllu hólfinu. Valmöguleikarnir eru kristaltærir og allt sem þú þarft að gera er að velja svið og ákveða hvernig útkoman eigi að líta út.

1. Þú getur valið að sameina dálka í Google Sheets — jafnvel þær sem ekki eru aðliggjandi, aðskilja þær með komum og bilum og setja niðurstöðuna hægra megin við upprunalegu færslurnar:

Ef þú hefur áhuga á tólinu geturðu skoðaðí gegnum allt sem það gerir á þessari sérstöku síðu eða í þessu stutta kennslumyndbandi:

Lærðu hvernig á að nota Sameina tvíteknar línur í þessu myndbandi :

Ég vona að þú hafir nú ákveðið hvaða leið hentar þér best. Ef þú hefur einhverjar aðrar aðferðir í huga, vinsamlegast deildu með okkur í athugasemdahlutanum hér að neðan :)