Daftar Isi
Posting blog hari ini adalah tentang mencari tahu perbedaan antara dua tanggal di Google Sheets. Anda akan melihat banyak rumus DATEDIF untuk menghitung hari, bulan, dan tahun, dan pelajari bagaimana NETWORKDAYS digunakan untuk menghitung hari kerja hanya bahkan jika hari libur Anda didasarkan pada jadwal khusus.
Banyak pengguna spreadsheet merasa tanggal membingungkan, jika tidak sangat sulit, untuk ditangani. Tapi percaya atau tidak, ada beberapa fungsi yang berguna dan mudah untuk tujuan itu. DATEDIF dan NETWORKDAYS adalah beberapa di antaranya.
Fungsi DATEDIF di Google Sheets
Seperti yang terjadi pada fungsi-fungsi, nama mereka menunjukkan tindakannya. Hal yang sama berlaku untuk DATEDIF. Ini harus dibaca sebagai perbedaan tanggal , bukan tanggal jika , dan itu adalah singkatan dari perbedaan tanggal Oleh karena itu, DATEDIF di Google Sheets menghitung perbedaan tanggal antara dua tanggal.
Mari kita uraikan menjadi beberapa bagian. Fungsi ini memerlukan tiga argumen:
=DATEDIF(tanggal_awal, tanggal_akhir, unit)- start_date - tanggal yang digunakan sebagai titik awal. Harus salah satu dari yang berikut ini:
- tanggal itu sendiri dalam tanda kutip ganda: "8/13/2020"
- referensi ke sel dengan tanggal: A2
- rumus yang mengembalikan tanggal: TANGGAL(2020, 8, 13)
- angka yang merupakan singkatan dari tanggal tertentu dan yang dapat ditafsirkan sebagai tanggal oleh Google Sheets, misalnya 44056 mewakili 13 Agustus 2020 .
- end_date - tanggal yang digunakan sebagai titik akhir. Ini harus memiliki format yang sama dengan format start_date .
- unit - digunakan untuk memberi tahu fungsi perbedaan apa yang akan dikembalikan. Berikut daftar lengkap unit yang dapat Anda gunakan:
- "D" - (kependekan dari hari ) mengembalikan jumlah hari di antara dua tanggal.
- "M" - (bulan) jumlah bulan penuh antara dua tanggal.
- "Y" - (tahun) jumlah tahun penuh.
- "MD" - (hari mengabaikan bulan) jumlah hari setelah dikurangi seluruh bulan.
- "YD" - (hari mengabaikan tahun) jumlah hari setelah dikurangi seluruh tahun.
- "YM" - (bulan mengabaikan tahun) jumlah bulan lengkap setelah dikurangi tahun penuh.
Catatan. Semua unit harus dimasukkan ke rumus dengan cara yang sama seperti yang muncul di atas - dalam tanda kutip ganda.
Sekarang mari kita gabungkan semua bagian ini dan lihat bagaimana rumus DATEDIF bekerja di Google Sheets.
Hitung hari di antara dua tanggal di Google Sheets
Contoh 1. Hitung semua hari
Saya memiliki meja kecil untuk melacak beberapa pesanan. Semuanya telah dikirim pada paruh pertama bulan Agustus - Tanggal pengiriman - yang akan menjadi tanggal mulai saya. Ada juga perkiraan tanggal pengiriman - Tanggal jatuh tempo .
Saya akan menghitung hari - "D" - antara pengiriman dan tanggal jatuh tempo untuk melihat berapa lama waktu yang dibutuhkan untuk barang tiba. Berikut adalah rumus yang harus saya gunakan:
=DATEDIF(B2, C2, "D")
Saya memasukkan rumus DATEDIF ke D2 dan kemudian menyalinnya ke bawah kolom untuk diterapkan ke baris lain.
jenis. Anda selalu dapat menghitung seluruh kolom sekaligus dengan satu rumus menggunakan ARRAYFORMULA:
=ArrayFormula(DATEDIF(B2:B13, C2:C13, "D"))
Contoh 2. Menghitung hari mengabaikan bulan
Bayangkan ada beberapa bulan di antara dua tanggal:
Bagaimana Anda menghitung hanya hari-hari seolah-olah mereka termasuk dalam bulan yang sama? Itu benar: dengan mengabaikan bulan-bulan penuh yang telah berlalu. DATEDIF menghitung ini secara otomatis ketika Anda menggunakan perintah "MD" unit:
=DATEDIF(A2, B2, "MD")
Fungsi ini mengurangi bulan-bulan yang telah berlalu dan menghitung hari-hari yang tersisa.
Contoh 3. Menghitung hari mengabaikan tahun
Unit lain - "YD" - akan membantu ketika tanggal memiliki lebih dari satu tahun di antara mereka:
=DATEDIF(A2, B2, "YD")
Rumus ini akan mengurangi tahun terlebih dahulu, dan kemudian menghitung hari-hari yang tersisa seolah-olah mereka termasuk dalam tahun yang sama.
Hitung hari kerja di Google Sheets
Ada kasus khusus ketika Anda hanya perlu menghitung hari kerja di Google Sheets. Rumus DATEDIF tidak akan banyak membantu di sini. Dan saya yakin Anda akan setuju bahwa mengurangi akhir pekan secara manual bukanlah pilihan yang paling elegan.
Untungnya, Google Sheets memiliki beberapa mantra yang tidak terlalu ajaib untuk itu :)
Contoh 1. Fungsi NETWORKDAYS
Fungsi ini menghitung jumlah hari kerja antara dua tanggal tidak termasuk akhir pekan (Sabtu dan Minggu) dan bahkan hari libur jika perlu:
=NETWORKDAYS(tanggal_awal, tanggal_akhir, [hari libur])- start_date - tanggal yang digunakan sebagai titik awal. Diperlukan.
Catatan. Jika tanggal ini bukan hari libur, maka dihitung sebagai hari kerja.
- end_date - tanggal yang digunakan sebagai titik akhir. Diperlukan.
Catatan. Jika tanggal ini bukan hari libur, maka dihitung sebagai hari kerja.
- liburan - yang satu ini bersifat opsional ketika Anda perlu menunjukkan hari libur tertentu. Ini harus berupa rentang tanggal atau angka yang mewakili tanggal.
Untuk mengilustrasikan cara kerjanya, saya akan menambahkan daftar hari libur yang terjadi di antara tanggal pengiriman dan tanggal jatuh tempo:
Jadi, kolom B adalah tanggal mulai saya, kolom C - tanggal akhir. Tanggal di kolom E adalah hari libur yang perlu dipertimbangkan. Berikut adalah bagaimana rumus seharusnya terlihat:
=NETWORKDAYS(B2, C2, $E$2:$E$4)
Tip. Jika Anda akan menyalin rumus ke sel lain, gunakan referensi sel absolut untuk hari libur untuk menghindari kesalahan atau hasil yang salah. Atau pertimbangkan untuk membuat rumus array sebagai gantinya.
Pernahkah Anda memperhatikan bagaimana jumlah hari berkurang dibandingkan dengan rumus DATEDIF? Karena sekarang fungsinya secara otomatis mengurangi semua hari Sabtu, Minggu, dan dua hari libur yang berlangsung pada hari Jumat dan Senin.
Catatan. Tidak seperti DATEDIF di Google Sheets, NETWORKDAYS dihitung start_day dan end_day sebagai hari kerja kecuali hari libur. Oleh karena itu, D7 mengembalikan 1 .
Contoh 2. NETWORKDAYS.INTL untuk Google Sheets
Jika Anda memiliki jadwal akhir pekan khusus, Anda akan mendapat manfaat dari fungsi lain: NETWORKDAYS.INTL. Ini memungkinkan Anda menghitung hari kerja di Google Sheets berdasarkan akhir pekan yang ditetapkan secara pribadi:
=NETWORKDAYS.INTL(tanggal_mulai, tanggal_akhir, [akhir pekan], [hari libur])- start_date - tanggal yang digunakan sebagai titik awal. Diperlukan.
- end_date - tanggal yang digunakan sebagai titik akhir. Diperlukan.
Catatan. NETWORKDAYS.INTL di Google Sheets juga dihitung start_day dan end_day sebagai hari kerja kecuali hari libur.
- akhir pekan - yang satu ini bersifat opsional. Jika dihilangkan, hari Sabtu dan Minggu dianggap sebagai akhir pekan. Tetapi Anda dapat mengubahnya dengan menggunakan dua cara:
- Masker .
Tip. Cara ini sangat cocok ketika hari libur Anda tersebar di sepanjang minggu.
Mask adalah pola tujuh digit 1 dan 0. 1 berarti akhir pekan, 0 untuk hari kerja. Digit pertama dalam pola ini selalu Senin, yang terakhir - Minggu.
Contohnya, "1100110" berarti Anda bekerja pada hari Rabu, Kamis, Jumat, dan Sabtu.
Catatan. Masker harus dimasukkan ke dalam tanda kutip ganda.
- Angka .
Gunakan angka satu digit (1-7) yang menunjukkan sepasang akhir pekan yang ditetapkan:
Nomor Akhir Pekan 1 Sabtu, Minggu 2 Minggu, Senin 3 Senin, Selasa 4 Selasa, Rabu 5 Rabu, Kamis 6 Kamis, Jumat 7 Jumat, Sabtu Atau bekerja dengan angka dua digit (11-17) yang menunjukkan satu hari untuk beristirahat dalam seminggu:
Nomor Hari akhir pekan 11 Minggu 12 Senin 13 Selasa 14 Rabu 15 Kamis 16 Jumat 17 Sabtu
- Masker .
- liburan - ini juga opsional dan digunakan untuk menentukan hari libur.
Fungsi ini mungkin tampak rumit karena semua angka-angka itu, tetapi saya mendorong Anda untuk mencobanya.
Pertama, dapatkan pemahaman yang jelas tentang hari libur Anda. Mari kita buat Minggu dan Senin Kemudian, putuskan cara untuk menunjukkan akhir pekan Anda.
Jika Anda menggunakan masker, maka akan menjadi seperti ini - 1000001 :
=NETWORKDAYS.INTL(B2, C2, "1000001")
Tetapi karena saya memiliki dua hari akhir pekan berturut-turut, saya bisa menggunakan angka dari tabel di atas, 2 dalam kasus saya:
=NETWORKDAYS.INTL(B2, C2, 2)
Kemudian cukup tambahkan argumen terakhir - lihat hari libur di kolom E, dan rumusnya sudah siap:
=NETWORKDAYS.INTL(B2, C2, 2, $E$2:$E$4)
Google Sheets dan perbedaan tanggal dalam bulan
Terkadang bulan lebih penting daripada hari. Jika ini benar untuk Anda dan Anda lebih suka mendapatkan perbedaan tanggal dalam bulan daripada hari, biarkan Google Sheets DATEDIF melakukan pekerjaan itu.
Contoh 1. Jumlah bulan penuh antara dua tanggal
Latihannya sama: latihan start_date berjalan lebih dulu, diikuti oleh end_date dan "M" - yang berdiri selama berbulan-bulan - sebagai argumen terakhir:
=DATEDIF(A2, B2, "M")
Tip. Jangan lupa tentang fungsi ARRAUFORMULA yang dapat membantu Anda menghitung bulan pada semua baris sekaligus:
=ARRAYFORMULA(DATEDIF(A2:A13, B2:B13, "M"))
Contoh 2. Jumlah bulan mengabaikan tahun
Anda mungkin tidak perlu menghitung bulan sepanjang tahun di antara tanggal awal dan akhir. Dan DATEDIF memungkinkan Anda melakukan itu.
Gunakan saja "YM" unit dan rumus akan mengurangi seluruh tahun terlebih dahulu, lalu menghitung jumlah bulan di antara tanggal:
=DATEDIF(A2, B2, "YM")
Hitung tahun antara dua tanggal di Google Sheets
Hal terakhir (tapi tidak kalah pentingnya) yang akan ditunjukkan kepada Anda adalah bagaimana Google Sheets DATEDIF menghitung perbedaan tanggal dalam tahun.
Saya akan menghitung jumlah tahun pasangan telah menikah berdasarkan tanggal pernikahan mereka dan tanggal hari ini:
Seperti yang mungkin sudah Anda duga, saya akan menggunakan "Y" unit untuk itu:
=DATEDIF(A2, B2, "Y")
Semua rumus DATEDIF ini adalah yang pertama dicoba saat menghitung hari, bulan, dan tahun antara dua tanggal di Google Sheets.
Jika kasus Anda tidak dapat diselesaikan dengan ini atau jika Anda memiliki pertanyaan, saya mendorong Anda untuk membagikannya dengan kami di bagian komentar di bawah ini.
