Tento výukový kurz vysvětluje základy funkce Excel HYPERLINK a poskytuje několik tipů a příkladů vzorců pro její co nejefektivnější použití.

Existuje mnoho způsobů, jak v aplikaci Excel vytvořit hypertextový odkaz. Chcete-li odkázat na určitou webovou stránku, můžete jednoduše zadat její adresu URL do buňky, stisknout klávesu Enter a aplikace Microsoft Excel automaticky převede zadání na hypertextový odkaz, na který lze kliknout. Chcete-li odkázat na jiný list nebo konkrétní místo v jiném souboru aplikace Excel, můžete použít příkaz Hypertextový odkaz kontextové nabídky nebo klávesové zkratky Ctrl + K. Pokud plánujete vložit mnoho stejných nebo podobných odkazů, nejrychlejší je použít vzorec Hypertextový odkaz, který usnadňuje vytváření, kopírování a úpravy hypertextových odkazů v aplikaci Excel.

Funkce Excel HYPERLINK - syntaxe a základní použití

Funkce HYPERLINK v aplikaci Excel slouží k vytvoření odkazu (zástupce), který uživatele přesměruje na zadané místo v témže dokumentu nebo otevře jiný dokument či webovou stránku. Pomocí vzorce Hyperlink můžete odkazovat na následující položky:

• Konkrétní místo, jako je buňka nebo pojmenovaný rozsah ve Soubor Excel (ve stávajícím listu nebo v jiném listu či sešitě).
• Word, PowerPoint nebo jiné dokument uložené na pevném disku, v místní síti nebo online.
• Záložka v dokumentu aplikace Word
• Webové stránky na internetu nebo intranetu
• E-mailová adresa vytvořit novou zprávu

Funkce je k dispozici ve všech verzích aplikace Excel 365 - 2000. V aplikaci Excel Online lze funkci HYPERLINK použít pouze pro webové adresy (URL).

Syntaxe funkce HYPERLINK je následující:

Kde:

• Link_location (povinné) je cesta k webové stránce nebo souboru, který se má otevřít.

  Link_location lze dodat jako odkaz na buňku obsahující odkaz nebo textový řetězec uzavřený v uvozovkách, který obsahuje cestu k souboru uloženému na místní jednotce, cestu UNC na serveru nebo adresu URL na internetu nebo intranetu.

  Pokud zadaná cesta odkazu neexistuje nebo je přerušena, vzorec Hypertextový odkaz vyhodí po kliknutí na buňku chybu.

• Friendly_name (nepovinné) je text odkazu (také známý jako text skoku nebo text kotvy), který se má zobrazit v buňce. Pokud je vynechán, zobrazí se text odkazu link_location.

  Friendly_name lze zadat jako číselnou hodnotu, textový řetězec uzavřený v uvozovkách, název nebo odkaz na buňku, která obsahuje text odkazu.

Kliknutím na buňku se vzorcem hypertextového odkazu otevřete soubor nebo webovou stránku zadanou ve vzorci. link_location argument.

Níže vidíte nejjednodušší příklad vzorce hypertextového odkazu aplikace Excel, kde A2 obsahuje friendly_name a B2 obsahuje link_location :

=HYPERLINK(B2, A2)

Výsledek může vypadat podobně:

Další příklady vzorců demonstrující další použití funkce Excel HYPERLINK jsou uvedeny níže.

Jak používat HYPERLINK v aplikaci Excel - příklady vzorců

Přejdeme-li od teorie k praxi, ukážeme si, jak lze funkci HYPERLINK použít k otevření různých dokumentů přímo z pracovních listů. Probereme si také složitější vzorec, kdy je funkce Excel HYPERLINK použita v kombinaci s několika dalšími funkcemi k provedení netriviálně náročného úkolu.

Jak odkazovat na listy, soubory, webové stránky a další položky

Funkce Excel HYPERLINK umožňuje vkládat klikací hypertextové odkazy několika různých typů v závislosti na tom, jakou hodnotu zadáte do pole link_location argument.

Hypertextový odkaz na jiný pracovní list

Chcete-li vložit hypertextový odkaz na jiný list ve stejném sešitě, zadejte název cílového listu, před kterým je znak libry (#) a za kterým následuje vykřičník a odkaz na cílovou buňku, například takto:

=HYPERLINK("#List2!A1", "List2")

Výše uvedený vzorec vytvoří hypertextový odkaz s textem skoku "List2", který otevře List2 v aktuálním sešitě.

Pokud název pracovního listu obsahuje prostory nebo nealfabetické znaky , musí být uzavřen v jednoduchých uvozovkách, například takto:

=HYPERLINK("#'Ceník'!A1", "Ceník")

Stejným způsobem můžete vytvořit hypertextový odkaz na jinou buňku ve stejném listu. Chcete-li například vložit hypertextový odkaz, který vás přenese do buňky A1 ve stejném listu, použijte podobný vzorec:

=HYPERLINK("#A1", "Přejít na buňku A1")

Hypertextový odkaz na jiný sešit

Chcete-li vytvořit hypertextový odkaz na jiný sešit, musíte zadat parametr úplná cesta do cílového sešitu v následujícím formátu:

"Drive:\Folder\Workbook.xlsx"

Například:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Chcete-li přistát na konkrétním listu a dokonce v konkrétní buňce, použijte tento formát:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Chcete-li například přidat hypertextový odkaz s názvem "Kniha3", který otevře list2 v knize3 uložené ve složce Zdrojová data na jednotce D, použijte tento vzorec:

=HYPERLINK("[D:\Source data\Book3.xlsx]List2!A1", "Book3")

Pokud plánujete sešity brzy přesunout do jiného umístění, můžete vytvořit relativní odkaz, jako je tento:

=HYPERLINK("Zdrojová data\Book3.xlsx", "Book3")

Při přesunu souborů bude relativní hypertextový odkaz fungovat i nadále, pokud se relativní cesta k cílovému sešitu nezmění. Další informace naleznete v části Absolutní a relativní hypertextové odkazy v aplikaci Excel.

Hypertextový odkaz na pojmenovaný rozsah

Pokud vytváříte hypertextový odkaz na název na úrovni listu , uveďte úplnou cestu k názvu cíle:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Chcete-li například vložit odkaz na rozsah s názvem "Source_data" uložený na listu 1 v knize 1, použijte tento vzorec:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data", "Zdrojová data")

Pokud odkazujete na název na úrovni pracovního sešitu , název listu nemusí být uveden, např.:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data", "Zdrojová data")

Hypertextový odkaz pro otevření souboru uloženého na jednotce pevného disku

Chcete-li vytvořit odkaz, který otevře jiný dokument, zadejte příkaz úplná cesta k tomuto dokumentu v tomto formátu:

"Drive:\Folder\File_name.extension"

Chcete-li například otevřít dokument aplikace Word s názvem Ceník který je uložen v Soubory Word na jednotce D, použijete následující vzorec:

=HYPERLINK("D:\Word files\Ceník.docx", "Ceník")

Hypertextový odkaz na záložku v dokumentu aplikace Word

Chcete-li vytvořit hypertextový odkaz na konkrétní místo v dokumentu aplikace Word, uzavřete cestu k dokumentu do [hranatých závorek] a použijte znak záložka definovat místo, na které chcete navigovat.

Například následující vzorec přidá hypertextový odkaz na záložku s názvem Subscription_prices v dokumentu Price list.docx:

=HYPERLINK("[D:\Word files\Ceník.docx]Předplatné_cen", "Ceník")

Hypertextový odkaz na soubor na síťové jednotce

Chcete-li otevřít soubor uložený v místní síti, zadejte cestu k tomuto souboru ve formátu UNC (Universal Naming Convention), který používá dvojitá zpětná lomítka před názvem serveru, například takto:

"\\Server_name\Folder\File_name.extension"

Níže uvedený vzorec vytvoří hypertextový odkaz s názvem "Ceník", který otevře stránku Ceník.xlsx sešit uložený v SERVER1 na adrese Světlana složka:

=HYPERLINK("\\SERVER1\Svetlana\Ceník.xlsx", "Ceník")

Otevření souboru aplikace Excel v specifický pracovní list , uzavřete cestu k souboru do [hranatých závorek] a uveďte název listu následovaný vykřičníkem (!) a odkazovanou buňkou:

=HYPERLINK("[\\SERVER1\Svetlana\Ceník.xlsx]List4!A1", "Ceník")

Hypertextový odkaz na webovou stránku

Chcete-li vytvořit hypertextový odkaz na webovou stránku na internetu nebo intranetu, zadejte její adresu URL v uvozovkách, například takto:

=HYPERLINK("//www.ablebits.com", "Přejít na Ablebits.com")

Výše uvedený vzorec vloží hypertextový odkaz s názvem "Go to Ablebits.com", který otevře domovskou stránku našich webových stránek.

Hypertextový odkaz pro odeslání e-mailu

Chcete-li vytvořit novou zprávu pro konkrétního příjemce, zadejte e-mailovou adresu v tomto formátu:

"mailto:email_address"

Například:

=HYPERLINK("mailto:[email protected]", "Napište nám e-mail")

Výše uvedený vzorec přidá hypertextový odkaz s názvem "Napište nám e-mail" a kliknutím na tento odkaz se vytvoří nová zpráva našemu týmu podpory.

Vlookup a vytvořit hypertextový odkaz na první shodu

Při práci s rozsáhlými soubory dat se můžete často dostat do situace, kdy potřebujete vyhledat určitou hodnotu a vrátit odpovídající údaje z jiného sloupce. K tomu slouží buď funkce VLOOKUP, nebo výkonnější kombinace INDEX MATCH.

Ale co když chcete nejen vytáhnout odpovídající hodnotu, ale také přejít na pozici této hodnoty ve zdrojovém souboru dat a podívat se na další údaje ve stejném řádku? To lze provést pomocí funkce Excel HYPERLINK s pomocí funkcí CELL, INDEX a MATCH.

Obecný vzorec pro vytvoření hypertextového odkazu na první shodu je následující:

Chcete-li vidět výše uvedený vzorec v akci, uvažujte následující příklad. Předpokládejme, že máte seznam prodejců ve sloupci A a prodané výrobky ve sloupci C. Chcete vytáhnout první výrobek prodaný daným prodejcem a vytvořit hypertextový odkaz na některou buňku v tomto řádku, abyste mohli zkontrolovat všechny další podrobnosti spojené s danou objednávkou.

S vyhledávací hodnotou v buňce E2, seznamem prodejců (vyhledávací rozsah) v A2:A10 a seznamem produktů (návratový rozsah) v C2:C10 má vzorec následující tvar:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Jak ukazuje obrázek níže, vzorec vytáhne odpovídající hodnotu a převede ji na klikatelný hypertextový odkaz, který uživatele přesměruje na pozici první shody v původním souboru dat.

Pokud pracujete s dlouhými řádky dat, může být vhodnější, aby hypertextový odkaz směřoval na první buňku v řádku, kde byla nalezena shoda. V tomto případě jednoduše nastavíte návratový rozsah v první kombinaci INDEX MATCH na sloupec A (v tomto příkladu $A$2:$A$10):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Tento vzorec vás přenese na první výskyt vyhledávací hodnoty ("Adam") v souboru dat:

Jak tento vzorec funguje

Ti z vás, kteří znají vzorec INDEX MATCH jako univerzálnější alternativu k VLOOKUP aplikace Excel, již pravděpodobně pochopili celkovou logiku.

V jádru se používá klasická kombinace INDEX MATCH pro vyhledání prvního výskytu hodnoty vyhledávání v rozsahu vyhledávání:

Podrobné informace o tom, jak tento vzorec funguje, najdete na výše uvedeném odkazu. Níže vám nastíníme klíčové body:

• Funkce MATCH určuje pozici " Adam " (hodnota vyhledávání) v rozsahu A2:A10 (rozsah vyhledávání) a vrátí 3.
• Výsledek funkce MATCH se předá příkazu row_num argumentu funkce INDEX, který jí přikazuje vrátit hodnotu ze 3. řádku v rozsahu C2:C10 (návratový rozsah). A funkce INDEX vrací " Citrony ".

Tímto způsobem získáte friendly_name argumentu vzorce Hypertextový odkaz.

Nyní vyřešíme link_location , tj. buňku, na kterou má hypertextový odkaz ukazovat. Pro získání adresy buňky se použije funkce CELL("address", [reference]) s INDEX MATCH jako odkaz Aby funkce HYPERLINK věděla, že se cílová buňka nachází v aktuálním listu, spojte adresu buňky se znakem libry ("#").

Poznámka: Všimněte si prosím použití absolutních odkazů na buňky pro upevnění vyhledávacích a návratových rozsahů. To je velmi důležité, pokud plánujete vložit více než jeden hypertextový odkaz zkopírováním vzorce.

Jak upravit více hypertextových odkazů najednou

Jak již bylo zmíněno na začátku tohoto návodu, jednou z nejužitečnějších výhod hypertextových odkazů řízených vzorci je možnost upravovat více vzorců hypertextových odkazů najednou pomocí funkce Excelu Nahradit vše funkce.

Řekněme, že chcete nahradit starou adresu URL vaší společnosti (old-website.com) novou (new-website.com) ve všech hypertextových odkazech na aktuálním listu nebo v celém sešitě. Chcete-li to provést, postupujte podle níže uvedených kroků:

1. Stisknutím klávesové zkratky Ctrl + H otevřete Vyměňte stránky na kartě Najít a nahradit dialog.
2. V pravé části dialogového okna klikněte na tlačítko Možnosti tlačítko.
3. V Zjistěte, co zadejte text, který chcete změnit ("old-website.com" v tomto příkladu).
4. V V rámci v rozevíracím seznamu vyberte List nebo Pracovní sešit podle toho, zda chcete změnit hypertextové odkazy pouze na aktuálním listu nebo na všech listech aktuálního sešitu.
5. V Podívejte se do v rozevíracím seznamu vyberte Vzorce .
6. Jako dodatečné opatření klikněte na tlačítko Najít vše a Excel zobrazí seznam všech vzorců obsahujících hledaný text:

Podobným způsobem můžete upravit text odkazu (friendly_name) ve všech vzorcích hypertextového odkazu současně. Přitom nezapomeňte zkontrolovat, zda je text, který má být nahrazen, ve vzorci friendly_name se nikde neobjevuje link_location abyste neporušili vzorce.

Nefunkční HYPERLINK aplikace Excel - důvody a řešení

Nejčastějším důvodem nefunkčnosti vzorce hypertextového odkazu (a první věcí, kterou byste měli zkontrolovat!) je neexistující nebo přerušená cesta ve vzorci. link_location argument. Pokud tomu tak není, podívejte se na následující dvě věci:

1. Pokud se cíl odkazu po kliknutí na hypertextový odkaz neotevře, zkontrolujte, zda je umístění odkazu zadáno ve správném formátu. Příklady vzorců pro vytvoření různých typů hypertextových odkazů naleznete zde.
2. Pokud se v buňce místo textu odkazu objeví chyba, například VALUE! nebo N/A, je problém nejspíše v souboru. friendly_name argumentu vzorce Hypertextový odkaz.

   K těmto chybám dochází obvykle tehdy, když friendly_name je vrácena nějakou jinou funkcí (funkcemi), jako v našem příkladu Vlookup a hypertextového odkazu na první shodu. V tomto případě se v buňce vzorce zobrazí chyba #N/A, pokud není hodnota vyhledávání nalezena v tabulce vyhledávání. Chcete-li takovým chybám zabránit, můžete zvážit použití funkce IFERROR, která místo chybové hodnoty zobrazí prázdný řetězec nebo nějaký uživatelsky přívětivý text.

Takto se vytvářejí hypertextové odkazy pomocí funkce Excel HYPERLINK. Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!

Cvičebnice ke stažení

Příklady vzorců pro hypertextové odkazy v aplikaci Excel (.xlsx soubor)