Aquest tutorial explica els conceptes bàsics de la funció HYPERLINK d'Excel i ofereix alguns consells i exemples de fórmules per utilitzar-la de la manera més eficient.

Hi ha moltes maneres de crear un hiperenllaç a Excel. Per enllaçar a una pàgina web determinada, simplement podeu escriure el seu URL en una cel·la, prémer Retorn i Microsoft Excel convertirà automàticament l'entrada en un hiperenllaç on es pot fer clic. Per enllaçar amb un altre full de treball o una ubicació específica en un altre fitxer Excel, podeu utilitzar el menú contextual Hiperenllaç o la drecera Ctrl + K. Si teniu previst inserir molts enllaços idèntics o similars, la manera més ràpida és utilitzar una fórmula d'hiperenllaç, que facilita la creació, la còpia i l'edició d'hiperenllaços a Excel.

Funció d'hiperenllaç d'Excel. - Sintaxi i usos bàsics

La funció HYPERLINK a Excel s'utilitza per crear una referència (drecera) que dirigeix ​​l'usuari a la ubicació especificada en el mateix document o obre un altre document o pàgina web. Mitjançant una fórmula d'hiperenllaç, podeu enllaçar amb els elements següents:

• Un lloc específic, com ara una cel·la o un interval amb nom en un fitxer d'Excel (al full existent o a un altre full de treball o llibre de treball)
• Word, PowerPoint o un altre document emmagatzemat a la vostra unitat de disc dur, xarxa local o en línia
• Marca d'interès en un Word document
• Pàgina web a Internet o intranet
• Adreça de correu electrònic per crear un missatge nou

Elexemple).

De manera similar, podeu editar el text de l'enllaç (nom_amic) a totes les fórmules d'hiperenllaç alhora. En fer-ho, assegureu-vos de comprovar que el text que voleu substituir a nom_amic no aparegui enlloc de ubicació_enllaç per tal de no trencar les fórmules.

L'HYPERLINK d'Excel no funciona: motius i solucions

El motiu més comú perquè una fórmula d'hiperenllaç no funcioni (i el primer que heu de comprovar!) és un camí inexistent o trencat a la ubicació_enllaç argument. Si no és el cas, comproveu les dues coses següents:

1. Si la destinació de l'enllaç no s'obre quan feu clic a un hiperenllaç, assegureu-vos que la ubicació de l'enllaç es proporcioni en el format adequat. Aquí es poden trobar exemples de fórmules per crear diferents tipus d'hiperenllaç.
2. Si en comptes de l'enllaç, apareix un error com ara VALOR! o N/A apareix en una cel·la, el més probable és que el problema sigui amb l'argument friendly_name de la vostra fórmula d'hiperenllaç.

   Típicament, aquests errors es produeixen quan friendly_name és retornat per altres funcions, com ara la nostra Vlookup i l'hiperenllaç al primer exemple de coincidència. En aquest cas, l'error #N/A apareixerà ala cel·la de la fórmula si el valor de cerca no es troba a la taula de cerca. Per evitar aquests errors, podeu considerar utilitzar la funció IFERROR per mostrar una cadena buida o un text fàcil d'utilitzar en lloc del valor d'error.

Així és com podeu crear hiperenllaços amb l'Excel. Funció HYPERLINK. Us agraeixo la lectura i espero veure-us al nostre bloc la setmana vinent!

Quader de pràctiques per descarregar

Excels de fórmules d'hiperenllaç d'Excel (fitxer .xlsx)

La sintaxi de la funció HYPERLINK és la següent:

On:

• Ubicació_enllaç (obligatori) és el camí a la pàgina web o fitxer que s'ha d'obrir.

  Ubicació_enllaç es pot proporcionar com a referència a una cel·la que conté l'enllaç o una cadena de text tancada entre cometes que conté un camí a un fitxer emmagatzemat en una unitat local, camí UNC en un servidor o URL a Internet o intranet.

  Si el camí d'enllaç especificat no existeix o està trencat, una fórmula d'hiperenllaç generarà un error quan feu clic a la cel·la.

• Friendly_name (opcional) és el text de l'enllaç (també conegut com text de salt o text d'ancoratge) que es mostrarà en una cel·la. Si s'omet, link_location es mostra com a text de l'enllaç.

  Friendly_name es pot proporcionar com a valor numèric, cadena de text entre cometes, nom o referència a una cel·la que conté el text de l'enllaç.

  Vegeu també: Com canviar el format de la data a Google Sheets i convertir la data en número i text

Fent clic a una cel·la amb una fórmula d'hiperenllaç s'obre el fitxer o la pàgina web especificada a l'argument ubicació_enllaç .

A continuació, podeu veure el l'exemple més senzill d'una fórmula d'hiperenllaç d'Excel, on A2 conté nom_amic i B2 conté ubicació_enllaç :

=HYPERLINK(B2, A2)

El resultat pot semblar semblant aaixò:

Més exemples de fórmules que demostren altres usos de la funció HYPERLINK d'Excel a continuació.

Com utilitzar HYPERLINK a Excel - exemples de fórmules

Passant de la teoria a la pràctica, vegem com podeu utilitzar la funció HYPERLINK per obrir diversos documents directament des dels vostres fulls de treball. També parlarem d'una fórmula més complexa on Excel HYPERLINK s'utilitza en combinació amb algunes altres funcions per dur a terme una tasca difícil no trivial.

Com enllaçar a fulls, fitxers, pàgines web i altres elements.

La funció HYPERLINK d'Excel us permet inserir hiperenllaços clicables d'uns quants tipus diferents en funció del valor que proporcioneu a l'argument link_location .

Hiperenllaç a un altre full de treball

Per inserir un hiperenllaç a un full diferent al mateix llibre de treball, proporcioneu el nom del full de destinació precedit d'un signe de lletra (#) i seguit del signe d'exclamació i la referència de la cel·la de destinació, com aquest:

=HYPERLINK("#Sheet2!A1", "Sheet2")

La fórmula anterior crea un hiperenllaç amb el text de salt "Full2" que obre Full2 al llibre de treball actual.

Si el nom del full de treball inclou espais o caràcters no alfabètics , ha d'anar entre cometes simples, com aquest:

=HYPERLINK("#'Price list'!A1", "Price list")

De la mateixa manera, podeu fer un hiperenllaç a una altra cel·la de la mateixafulla. Per exemple, per inserir un hiperenllaç que us portarà a la cel·la A1 de la mateixafull de treball, utilitzeu una fórmula semblant a aquesta:

=HYPERLINK("#A1", "Go to cell A1")

Hiperenllaç a un llibre de treball diferent

Per crear un hiperenllaç a un altre llibre de treball, heu d'especificar el complet ruta al llibre de treball de destinació en el format següent:

"Unitat:\Carpeta\Workbook.xlsx"

Per exemple:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Per aterrar en un full específic i fins i tot en una cel·la específica, utilitzeu aquest format:

"[Unitat:\Carpeta\Workbook.xlsx]Full!Cel·la"

Per exemple, per afegir un hiperenllaç titulat "Llibre3" que obre Sheet2 al Llibre3 emmagatzemat a la carpeta Dades d'origen de la unitat D, utilitzeu aquesta fórmula:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Si teniu previst moure els vostres llibres de treball a una altra ubicació aviat, podeu crear un enllaç relatiu com aquest:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Quan moveu els fitxers, l'hiperenllaç relatiu continuar treballant mentre el camí relatiu al llibre de treball de destinació es mantingui sense canvis. Per obtenir-ne més informació, vegeu Hiperenllaços absoluts i relatius a Excel.

Hiperenllaç a un interval amb nom

Si feu un hiperenllaç a un nom a nivell de full de treball , inclou el camí complet al nom de destinació:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Per exemple, per inserir un enllaç a un rang anomenat "Source_data" emmagatzemat al Sheet1 al Book1, utilitzeu aquesta fórmula:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data","Source data")

Si feu referència a un nom de llibre de treball , el nom del full no necessita incloure, per exemple:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data","Source data")

Hiperenllaç per obrir unfitxer emmagatzemat en una unitat de disc dur

Per crear un enllaç que obrirà un altre document, especifiqueu el camí complet a aquest document en aquest format:

"Unitat:\ Folder\File_name.extension"

Per exemple, per obrir el document de Word anomenat Llista de preus que s'emmagatzema a la carpeta Fitxers de Word de la unitat D, feu servir el fórmula següent:

=HYPERLINK("D:\Word files\Price list.docx","Price list")

Hiperenllaç a una adreça d'interès en un document de Word

Per crear un hiperenllaç a una ubicació específica en un document de Word, tanqueu la ruta del document a [quadrat claudàtors] i utilitzeu un adreces d'interès per definir la ubicació a la qual voleu navegar.

Per exemple, la fórmula següent afegeix un hiperenllaç al marcador anomenat Preus_subscripció a Preu. list.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices","Price list")

Hiperenllaç a un fitxer d'una unitat de xarxa

Per obrir un fitxer emmagatzemat a la vostra xarxa local, proporcioneu la ruta d'aquest fitxer a l'Universal Format de convenció de nomenclatura (UNC) que utilitza barres invertides dobles per precedir el nom del servidor, com aquest:

"\\Server_name\ Folder\File_name.extension"

La fórmula següent crea un hiperenllaç titulat "Llista de preus" que obrirà el llibre de treball Lista de preus.xlsx emmagatzemat a SERVIDOR1 a <1 Carpeta>Svetlana :

=HYPERLINK("\\SERVER1\Svetlana\Price list.xlsx", "Price list")

Per obrir un fitxer d'Excel en un full de treball específic , afegiu el camí al fitxer entre [parèntesis] i incloeu el nom del full seguit del signe d'exclamació (!) i de la referènciacel·la:

=HYPERLINK("[\\SERVER1\Svetlana\Price list.xlsx]Sheet4!A1", "Price list")

Hiperenllaç a una pàgina web

Per crear un hiperenllaç a una pàgina web a Internet o intranet, introduïu el seu URL entre cometes, com ara això:

=HYPERLINK("//www.ablebits.com","Go to Ablebits.com")

La fórmula anterior insereix un hiperenllaç, titulat "Vés a Ablebits.com", que obre la pàgina d'inici del nostre lloc web.

Hiperenllaç a enviar un correu electrònic

Per crear un missatge nou a un destinatari específic, proporcioneu una adreça de correu electrònic en aquest format:

"mailto:email_address"

Per exemple:

=HYPERLINK("mailto:[email protected]","Drop us an email")

La fórmula anterior afegeix un hiperenllaç titulat "Envia'ns un correu electrònic" i fent clic a l'enllaç es crea un missatge nou per al nostre equip d'assistència.

Busca i creeu un hiperenllaç al first match

Quan treballeu amb conjunts de dades grans, sovint us trobeu en una situació en què necessiteu cercar un valor específic i retornar les dades corresponents d'una altra columna. Per a això, utilitzeu la funció BUSCAR V o una combinació d'INDEX MATCH més potent.

Però què passa si no només voleu obtenir un valor coincident, sinó que també voleu saltar a la posició d'aquest valor al conjunt de dades d'origen per tenir un cop d'ull a altres detalls a la mateixa fila? Això es pot fer utilitzant la funció HYPERLINK d'Excel amb ajuda de CELL, INDEX i MATCH.

La fórmula genèrica per fer un hiperenllaç a la primera coincidència és la següent:

Per veure la fórmula anterior en acció, considereu l'exemple següent. Suposant que teniu una llista de venedors a la columna A i els productes venuts a la columna C. L'objectiu és treure el primer producte venut per un determinat proveïdor i fer un hiperenllaç a alguna cel·la d'aquesta fila perquè pugueu revisar tots els altres detalls associats. amb aquest ordre concret.

Amb el valor de cerca a la cel·la E2, la llista de proveïdors (interval de cerca) a A2:A10 i la llista de productes (interval de retorn) a C2:C10, la fórmula pren la forma següent:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Com es mostra a la captura de pantalla següent, la fórmula extreu el valor coincident i el converteix en un hiperenllaç on es pot fer clic que dirigeix ​​l'usuari a la posició de la primera coincidència al conjunt de dades original.

Si esteu treballant amb files llargues de dades, pot ser més convenient que l'hiperenllaç apunti a la primera cel·la de la fila on es troba la coincidència. Per a això, simplement establiu l'interval de retorn de la primera combinació INDEX MATCH a la columna A ($A$2:$A$10 en aquest exemple):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Aquesta fórmula us portarà a la primera ocurrència del valor de cerca ("Adam") al conjunt de dades:

Com funciona aquesta fórmula

Aquells de vosaltres que esteu familiaritzats amb l'INDEX Fórmula MATCH com a alternativa més versàtil a Excel VLOOKUP, probablement ja hagin descobert el conjuntlògica.

En el fons, feu servir la combinació clàssica INDEX MATCH per localitzar la primera ocurrència del valor de cerca a l'interval de cerca:

Podeu trobar tots els detalls sobre com funciona aquesta fórmula seguint l'enllaç anterior. A continuació, descriurem els punts clau:

• La funció MATCH determina la posició de " Adam " (valor de cerca) a l'interval A2:A10 (interval de cerca) i retorna 3.
• El resultat de MATCH es passa a l'argument row_num de la funció INDEX que li indica que retorni el valor de la 3a fila de l'interval C2:C10 (interval de retorn). I la funció INDEX retorna " Lemons ".

D'aquesta manera, obtindreu l'argument friendly_name de la vostra fórmula d'Hiperenllaç.

Ara. , anem a determinar ubicació_enllaç , és a dir, la cel·la a la qual hauria d'apuntar l'hiperenllaç. Per obtenir l'adreça de la cel·la, utilitzeu la funció CELL("adreça", [referència]) amb INDEX MATCH com a referència . Perquè la funció HYPERLINK sàpiga que la cel·la de destinació resideix al full actual, concatena l'adreça de la cel·la amb el caràcter de lletra ("#").

Nota. Tingueu en compte l'ús de referències de cel·les absolutes per corregir els intervals de cerca i de retorn. Això és fonamental si teniu previst inserir més d'un hiperenllaç copiant la fórmula.

Com editar diversos hiperenllaços alhora

Com s'ha esmentat al principi deEn aquest tutorial, un dels avantatges més útils dels hiperenllaços basats en fórmules és la possibilitat d'editar múltiples fórmules d'hiperenllaç d'una sola vegada mitjançant la funció Substitueix-ho tot d'Excel.

Suposem que voleu substituir l'URL antic de la vostra empresa (antic-website.com) pel nou (new-website.com) a tots els hiperenllaços del full actual o a tot el llibre de treball. Per fer-ho, seguiu els passos que es descriuen a continuació:

1. Premeu Ctrl + H per obrir la pestanya Substitueix del diàleg Cerca i substitueix .
2. A la part dreta del quadre de diàleg, feu clic al botó Opcions .
3. Al quadre Cerca què , escriviu el text que voleu per canviar ("old-website.com" en aquest exemple).
4. A la llista desplegable Dins de , seleccioneu Full o Llibre de treball en funció de si voleu canviar els hiperenllaços només al full de treball actual o a tots els fulls del llibre de treball actual.
5. A la llista desplegable Busca a , seleccioneu Fórmules .
6. Com a precaució addicional, feu clic primer al botó Troba-ho tot i Excel mostrarà una llista de totes les fórmules que continguin el text de cerca: