Ovaj vodič objašnjava osnove funkcije Excel HYPERLINK i pruža nekoliko savjeta i primjera formula za najefikasnije korištenje.

Postoji mnogo načina za kreiranje hiperveze u Excelu. Da biste se povezali na određenu web stranicu, možete jednostavno upisati njen URL u ćeliju, pritisnuti Enter i Microsoft Excel će automatski pretvoriti unos u hipervezu na koju se može kliknuti. Da biste se povezali sa drugim radnim listom ili određenom lokacijom u drugoj Excel datoteci, možete koristiti kontekstni meni Hiperveza ili Ctrl + K prečicu. Ako planirate da umetnete mnogo identičnih ili sličnih veza, najbrži način je da koristite formulu hiperveze, koja olakšava kreiranje, kopiranje i uređivanje hiperveza u Excelu.

Excel funkcija HIPERLINK - sintaksa i osnovne upotrebe

Funkcija HYPERLINK u Excelu se koristi za kreiranje reference (prečice) koja usmjerava korisnika na određenu lokaciju u istom dokumentu ili otvara drugi dokument ili web-stranicu. Koristeći formulu hiperveze, možete se povezati sa sljedećim stavkama:

• Određeno mjesto kao što je ćelija ili imenovani raspon u Excel datoteci (na postojećem listu ili u drugi radni list ili radna knjiga)
• Word, PowerPoint ili drugi dokument pohranjen na vašem hard disku, lokalnoj mreži ili na mreži
• Bookmark u Wordu dokument
• Web-stranica na Internetu ili intranetu
• Adresa e-pošte za kreiranje nove poruke

primjer).

Na sličan način možete uređivati ​​tekst veze (prijateljsko_ime) u svim formulama hiperveze u isto vrijeme. Kada to radite, obavezno provjerite da se tekst koji treba zamijeniti u prijateljsko_ime ne pojavljuje nigdje u link_location kako ne biste prekršili formule.

Excel HYPERLINK ne radi - razlozi i rješenja

Najčešći razlog zašto formula Hyperlink ne radi (i prva stvar koju trebate provjeriti!) je nepostojeći ili prekinut put u link_location argument. Ako nije tako, provjerite sljedeće dvije stvari:

1. Ako se odredište veze ne otvori kada kliknete na hipervezu, provjerite je li lokacija veze navedena u odgovarajućem formatu. Ovdje možete pronaći primjere formula za kreiranje različitih tipova hiperveza.
2. Ako se umjesto teksta veze pojavi greška kao što je VALUE! ili N/A se pojavljuje u ćeliji, najvjerovatnije je problem u argumentu prijateljsko_name vaše formule hiperveze.

   Uobičajeno, takve greške se javljaju kada prijateljsko_ime vrati neka druga funkcija(e), kao u našem Vlookupu i hipervezi do prvog primjera podudaranja. U ovom slučaju će se pojaviti greška #N/Aćeliju formule ako tražena vrijednost nije pronađena unutar tabele pretraživanja. Da biste spriječili takve greške, možete razmisliti o korištenju funkcije IFERROR da prikažete prazan niz ili neki tekst prilagođen korisniku umjesto vrijednosti greške.

Ovako kreirate hiperveze koristeći Excel HYPERLINK funkcija. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Vježbanje za preuzimanje

Primjeri formule za Excel hipervezu (.xlsx datoteka)

Sintaksa funkcije HYPERLINK je sljedeća:

Gdje:

• Link_location (obavezno) je putanja do web-stranice ili datoteke koja se otvara.

  Link_location se može dostaviti kao referenca na ćeliju koja sadrži vezu ili tekstualni niz zatvoren u navodnike koji sadrži putanju do pohranjene datoteke na lokalnom disku, UNC stazi na serveru ili URL-u na Internetu ili intranetu.

  Ako navedena staza veze ne postoji ili je prekinuta, formula hiperveze će prikazati grešku kada kliknete na ćeliju.

• Friendly_name (opcionalno) je tekst veze (aka tekst za skok ili tekst sidra) koji će se prikazati u ćeliji. Ako se izostavi, link_location se prikazuje kao tekst veze.

  Friendly_name se može dostaviti kao numerička vrijednost, tekstualni niz zatvoren u navodnicima, ime ili referenca na ćeliju koja sadrži tekst veze.

Klik na ćeliju sa formulom hiperveze otvara datoteku ili web stranicu navedenu u argumentu link_location .

U nastavku možete vidjeti najjednostavniji primjer formule Excel hiperveze, gdje A2 sadrži prijateljsko_ime , a B2 sadrži lokaciju_veze :

=HYPERLINK(B2, A2)

Rezultat može izgledati nešto sličnoovo:

Više primjera formule koji demonstriraju drugu upotrebu Excel funkcije HYPERLINK slijedi ispod.

Kako koristiti HYPERLINK u Excelu - primjeri formule

Prelazeći od teorije do prakse, da vidimo kako možete koristiti funkciju HYPERLINK za otvaranje različitih dokumenata direktno iz vaših radnih listova. Također ćemo raspravljati o složenijoj formuli u kojoj se Excel HYPERLINK koristi u kombinaciji s nekoliko drugih funkcija za postizanje netrivijalnog izazovnog zadatka.

Kako povezati na listove, datoteke, web stranice i druge stavke

Excel funkcija HYPERLINK vam omogućava da umetnete hiperveze nekoliko različitih tipova na koje se može kliknuti u zavisnosti od toga koju vrednost date argumentu link_location .

Hiperveza na drugi radni list

Da biste umetnuli hipervezu na drugi list u istoj radnoj knjizi, navedite naziv ciljnog lista kojem prethodi znak funte (#), a nakon njega slijedi uskličnik i referenca ciljne ćelije, na primjer:

=HYPERLINK("#Sheet2!A1", "Sheet2")

Gorenja formula kreira hipervezu sa tekstom za skok "Sheet2" koja otvara Sheet2 u trenutnoj radnoj knjizi.

Ako naziv radnog lista uključuje razmake ili neabecedni znakovi , mora biti stavljen u jednostruke navodnike, ovako:

=HYPERLINK("#'Price list'!A1", "Price list")

Na isti način možete napraviti hipervezu na drugu ćeliju u istojlist. Na primjer, da umetnete hipervezu koja će vas odvesti do ćelije A1 u istojradni list, koristite formulu sličnu ovoj:

=HYPERLINK("#A1", "Go to cell A1")

Hiperveza na drugu radnu knjigu

Da biste kreirali hipervezu na drugu radnu svesku, morate navesti full put do ciljne radne knjige u sljedećem formatu:

"Disk:\Folder\Workbook.xlsx"

Na primjer:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Da sletite na određeni list, pa čak i u određenu ćeliju, koristite ovaj format:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Na primjer, da dodate hipervezu pod nazivom "Knjiga3" koja otvara Sheet2 u Book3 pohranjenoj u mapi Izvorni podaci na disku D, koristite ovu formulu:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Ako uskoro planirate premjestiti svoje radne knjige na drugu lokaciju, možete kreirati relativnu vezu poput ove:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Kada premjestite datoteke, relativna hiperveza će nastaviti s radom sve dok relativna putanja do ciljne radne knjige ostane nepromijenjena. Za više informacija pogledajte Apsolutne i relativne hiperveze u Excelu.

Hiperveza do imenovanog raspona

Ako pravite hipervezu na naziv na nivou radnog lista , uključite puna putanja do ciljanog imena:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Na primjer, da umetnete vezu do raspon pod nazivom "Source_data" pohranjen na Sheet1 u Knjizi 1, koristite ovu formulu:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data","Source data")

Ako referencirate naziv na nivou radne knjige , naziv lista ne treba biti uključeni, na primjer:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data","Source data")

Hiperlink za otvaranjedatoteka pohranjena na hard disku

Da kreirate vezu koja će otvoriti drugi dokument, navedite punu putanju do tog dokumenta u ovom formatu:

"Drive:\ Folder\File_name.extension"

Na primjer, da biste otvorili Word dokument pod nazivom Cjenik koji je pohranjen u folderu Word files na disku D, koristite sljedeća formula:

=HYPERLINK("D:\Word files\Price list.docx","Price list")

Hiperveza do oznake u Word dokumentu

Da biste napravili hipervezu na određenu lokaciju u Word dokumentu, priložite putanju dokumenta u [kvadrat zagrade] i koristite bookmark da definirate lokaciju na koju želite navigirati.

Na primjer, sljedeća formula dodaje hipervezu na bookmark pod nazivom Price_subscription_prices u Price list.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices","Price list")

Hiperveza na datoteku na mrežnom disku

Da biste otvorili datoteku pohranjenu u vašoj lokalnoj mreži, navedite putanju do te datoteke u Universal Format konvencije o imenovanju (UNC) koji koristi dvostruke kose crte ispred imena servera, kao što je ovaj:

"\\ime_servera\ Folder\File_name.extension"

Formula u nastavku kreira hipervezu pod nazivom "Lista cijena" koja će otvoriti radnu knjigu Price list.xlsx pohranjenu na SERVER1 u Svetlana folder:

=HYPERLINK("\\SERVER1\Svetlana\Price list.xlsx", "Price list")

Da biste otvorili Excel datoteku na određenom radnom listu , stavite putanju do datoteke u [uglate zagrade] i uključite naziv lista iza kojeg slijedi uzvičnik (!) i referencaćelija:

=HYPERLINK("[\\SERVER1\Svetlana\Price list.xlsx]Sheet4!A1", "Price list")

Hiperveza na web stranicu

Da biste kreirali hipervezu na web-stranicu na Internetu ili intranetu, navedite njen URL pod navodnicima, npr. ovo:

=HYPERLINK("//www.ablebits.com","Go to Ablebits.com")

Gorenja formula umeće hipervezu pod nazivom "Idi na Ablebits.com", koja otvara početnu stranicu naše web stranice.

Hiperveza do pošaljite e-poštu

Da kreirate novu poruku određenom primaocu, navedite adresu e-pošte u ovom formatu:

"mailto:email_address"

Na primjer:

=HYPERLINK("mailto:[email protected]","Drop us an email")

Gorenja formula dodaje hipervezu pod nazivom "Pošaljite nam e-poštu", a klikom na vezu kreirate novu poruku našem timu za podršku.

Potražite i kreirajte hipervezu do first match

Kada radite s velikim skupovima podataka, često se možete naći u situaciji kada trebate potražiti određenu vrijednost i vratiti odgovarajuće podatke iz druge kolone. Za ovo koristite ili funkciju VLOOKUP ili moćniju kombinaciju INDEX MATCH.

Ali što ako ne samo da želite izvući odgovarajuću vrijednost već i skočiti na poziciju te vrijednosti u izvornom skupu podataka da biste imali pogledati ostale detalje u istom redu? Ovo se može učiniti korištenjem Excel HYPERLINK funkcije uz pomoć CELL, INDEX i MATCH.

Generička formula za stvaranje hiperveze do prvog podudaranja je sljedeća:

Da vidite gornju formulu u akciji, razmotrite sljedeći primjer. Pretpostavimo da imate listu dobavljača u koloni A, a prodate proizvode u koloni C. Cilj vam je da izvučete prvi proizvod koji je prodao dati prodavač i napravite hipervezu na neku ćeliju u tom redu tako da možete pregledati sve ostale povezane detalje s tim određenim redoslijedom.

Sa vrijednošću pretraživanja u ćeliji E2, listom dobavljača (opseg traženja) u A2:A10 i listom proizvoda (opseg povrata) u C2:C10, formula poprima sljedeći oblik:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Kao što je prikazano na slici ispod, formula izvlači odgovarajuću vrijednost i pretvara je u hipervezu na koju se može kliknuti i koja usmjerava korisnika na poziciju prvog podudaranja u originalnom skupu podataka.

Ako radite sa dugim redovima podataka, možda bi bilo zgodnije da hiperveza ukazuje na prvu ćeliju u redu u kojoj se nalazi podudaranje. Za ovo jednostavno postavite raspon povrata u prvoj kombinaciji INDEX MATCH na stupac A ($A$2:$A$10 u ovom primjeru):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Ova formula će vas odvesti do prvo pojavljivanje vrijednosti pretraživanja ("Adam") u skupu podataka:

Kako ova formula funkcionira

Oni od vas koji ste upoznati s INDEX-om MATCH formula kao svestranija alternativa Excel VLOOKUP-u, vjerovatno su već shvatili sveukupnologika.

U osnovi, koristite klasičnu kombinaciju INDEX MATCH da biste locirali prvo pojavljivanje vrijednosti pretraživanja u rasponu pretraživanja:

Možete pronaći sve detalje o tome kako ova formula radi slijedeći gornji link. U nastavku ćemo opisati ključne tačke:

• Funkcija MATCH određuje poziciju " Adam " (vrijednost traženja) u rasponu A2:A10 (opseg pretraživanja) i vraća 3.
• Rezultat MATCH se prosljeđuje argumentu broj_reda funkcije INDEX dajući mu upute da vrati vrijednost iz 3. reda u rasponu C2:C10 (povratni raspon). A funkcija INDEX vraća " Limuni ".

Na ovaj način dobijate friendly_name argument vaše formule hiperveze.

Sada , razradimo link_location , tj. ćeliju na koju bi hiperveza trebala upućivati. Da biste dobili adresu ćelije, koristite funkciju CELL("address", [reference]) sa INDEX MATCH kao referenca . Da bi funkcija HYPERLINK znala da se ciljna ćelija nalazi u trenutnom listu, spojite adresu ćelije sa znakom funte ("#").

Napomena. Obratite pažnju na upotrebu apsolutnih referenci ćelija za popravljanje raspona pretraživanja i povrata. Ovo je kritično ako planirate da umetnete više od jedne hiperveze kopiranjem formule.

Kako uređivati ​​više hiperveza u isto vrijeme

Kao što je spomenuto na početkuU ovom vodiču, jedna od najkorisnijih prednosti hiperveza vođenih formulom je mogućnost uređivanja više formula hiperveza u jednom potezu korištenjem Excelove funkcije Zamijeni sve .

Recimo da želite zamijeniti stari URL svoje kompanije (old-website.com) novim (new-website.com) u svim hipervezama na trenutnom listu ili u cijeloj radnoj knjizi. Da biste to učinili, slijedite dolje navedene korake:

1. Pritisnite Ctrl + H da otvorite karticu Zamijeni u dijaloškom okviru Pronađi i zamijeni .
2. U desnom dijelu dijaloškog okvira, kliknite na dugme Opcije .
3. U okviru Pronađi šta unesite tekst koji želite za promjenu ("old-website.com" u ovom primjeru).
4. U padajućoj listi Unutar odaberite ili Sheet ili Workbook u zavisnosti od toga da li želite promijeniti hiperveze samo na trenutnom radnom listu ili na svim listovima trenutne radne knjige.
5. U padajućoj listi Pogledaj u odaberite Formule .
6. Kao dodatnu mjeru opreza, prvo kliknite gumb Pronađi sve i Excel će prikazati listu svih formula koje sadrže tekst za pretragu: