Овој туторијал ги објаснува основите на функцијата Excel HYPERLINK и дава неколку совети и примери на формула за најефикасно користење.

Постојат многу начини за креирање хиперврска во Excel. За да се поврзете до одредена веб-страница, можете едноставно да ја напишете нејзината URL-адреса во ќелија, притиснете Enter и Microsoft Excel автоматски ќе го претвори записот во хиперврска што може да се кликне. За да се поврзете со друг работен лист или одредена локација во друга датотека на Excel, можете да го користите контекстното мени Хиперврска или кратенката Ctrl + K. Ако планирате да вметнете многу идентични или слични врски, најбрзиот начин е да користите формула за хиперврска, што го олеснува креирањето, копирањето и уредувањето хиперврски во Excel.

Excel HYPERLINK функција - синтакса и основни употреби

Функцијата HYPERLINK во Excel се користи за креирање референца (кратенка) која го насочува корисникот до одредената локација во истиот документ или отвора друг документ или веб-страница. Со користење на формула за хиперврска, можете да се поврзете до следните ставки:

• Специфично место како што е ќелија или именуван опсег во Excel-датотека (во постоечкиот лист или во друг работен лист или работна книга)
• Word, PowerPoint или друг документ зачуван на вашиот хард диск, локална мрежа или онлајн
• Обележувач во Word документ
• Веб-страница на Интернет или интранет
• Адреса на е-пошта за да креирате нова порака

пример).

На сличен начин, можете истовремено да го уредувате текстот на врската (friendly_name) во сите формули за хиперврска. Кога го правите тоа, проверете дали текстот што треба да се замени во friendly_name не се појавува никаде во link_location за да не ги прекршите формулите.

Excel HYPERLINK не работи - причини и решенија

Најчеста причина зошто формулата за хиперврска не работи (и првата работа што треба да ја проверите!) е непостоечка или скршена патека во link_location аргумент. Ако не е така, проверете ги следните две работи:

1. Ако дестинацијата на врската не се отвори кога ќе кликнете на хиперврска, проверете дали локацијата на врската е обезбедена во правилен формат. Примери на формула за создавање различни типови хиперврски може да се најдат овде.
2. Ако наместо текстот на врската се појави грешка како VALUE! или N/A се појавува во ќелија, најверојатно проблемот е во аргументот friendly_name на формулата за хиперврска.

   Вообичаено, таквите грешки се случуваат кога пријателско_име се враќа од некоја друга функција(и), како во нашата Vlookup и хиперврска до првиот пример за совпаѓање. Во овој случај, грешката #N/A ќе се појави внатреќелијата со формулата ако вредноста за пребарување не е пронајдена во табелата за пребарување. За да спречите такви грешки, може да размислите за користење на функцијата IFERROR за да прикажете празен стринг или некој кориснички текст наместо вредноста на грешката.

Вака создавате хиперврски користејќи го Excel Функција HYPERLINK. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга за преземање

Примери на формула за хиперврска на Excel (датотека .xlsx)

Синтаксата на функцијата HYPERLINK е како што следува:

Каде:

• Локација_врска (задолжително) е патеката до веб-страницата или датотеката што треба да се отвори.

  Локација_врска може да се достави како референца за ќелија која ја содржи врската или текстуална низа затворена во наводници што содржи патека до зачуваната датотека на локален диск, патека UNC на сервер или URL на Интернет или интранет.

  Ако наведената патека за врска не постои или е скршена, формулата за хиперврска ќе исфрли грешка кога ќе кликнете на ќелијата.

• Friendly_name (незадолжително) е текстот на врската (познат како jump text или anchor text) што треба да се прикаже во ќелија. Ако се испушти, link_location се прикажува како текст на врската.

  Friendly_name може да се даде како нумеричка вредност, текстуална низа затворена во наводници, име или повикување на ќелија која го содржи текстот на врската.

Со кликнување на ќелија со формула за хиперврска се отвора датотеката или веб-страницата наведена во аргументот локација_врска .

Подолу, можете да ја видите наједноставен пример на формула за хиперврска на Excel, каде што А2 содржи пријателско_име , а Б2 содржи локација_врска :

=HYPERLINK(B2, A2)

Резултатот може да изгледа нешто слично наова:

Повеќе примери на формули кои покажуваат други намени на функцијата Excel HYPERLINK следуваат подолу.

Како да се користи HYPERLINK во Excel - примери на формули

Преминувајќи од теорија во пракса, ајде да видиме како можете да ја користите функцијата HYPERLINK за ​​да отворите разни документи директно од вашите работни листови. Ќе разговараме и за покомплексна формула каде што Excel HYPERLINK се користи во комбинација со неколку други функции за да се постигне нетривијална предизвикувачка задача.

Како да се поврзете со листови, датотеки, веб-страници и други ставки

Функцијата Excel HYPERLINK ви овозможува да вметнете хиперврски што може да се кликнат од неколку различни типови во зависност од тоа која вредност ја давате на аргументот link_location .

Хиперврска до друг работен лист

За да вметнете хиперврска до друг лист во истата работна книга, наведете го името на целниот лист пред знакот на фунтата (#), а потоа извичникот и референцата на целната ќелија, вака:

=HYPERLINK("#Sheet2!A1", "Sheet2")

Горената формула создава хиперврска со прескокнувачкиот текст „Лист 2“ што го отвора листот2 во тековната работна книга.

Ако името на работниот лист вклучува простори или неазбучни знаци , мора да биде затворен во единечни наводници, вака:

=HYPERLINK("#'Price list'!A1", "Price list")

На ист начин, можете да направите хиперврска до друга ќелија на истиотлист. На пример, да вметнете хиперврска што ќе ве однесе до ќелијата А1 во истатаработен лист, користете формула слична на оваа:

=HYPERLINK("#A1", "Go to cell A1")

Хиперврска до друга работна книга

За да креирате хиперврска до друга работна книга, треба да наведете целосна патека до целната работна книга во следниот формат:

„Drive:\Folder\Workbook.xlsx“

На пример:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

За слетување на одреден лист, па дури и во одредена ќелија, користете го овој формат:

„[Drive:\Folder\Workbook.xlsx]Sheet!Cell“

На пример, за да додадете хиперврска со наслов „Book3“ што отвора Sheet2 во Book3 зачувана во папката Source data на уредот D, користете ја оваа формула:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Ако планирате наскоро да ги преместите вашите работни книги на друга локација, можете да креирате релативна врска како оваа:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Кога ќе ги преместите датотеките, релативната хиперврска ќе продолжи да работи се додека релативната патека до целната работна книга останува непроменета. За повеќе информации, погледнете ги Апсолутни и релативни хиперврски во Excel.

Хиперврска до именуван опсег

Ако правите хиперврска до име на ниво на работен лист , вклучете целосната патека до името на целта:

„[Drive:\Folder\Workbook.xlsx]Sheet!Name“

На пример, да се вметне врска до опсег со име „Source_data“ зачуван на Sheet1 во Book1, користете ја оваа формула:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data","Source data")

Ако упатувате име на ниво на работна книга , името на листот не треба да се вклучи, на пример:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data","Source data")

Хиперврска за отворањедатотека зачувана на хард диск

За да креирате врска што ќе отвори друг документ, наведете ја целосната патека до тој документ во овој формат:

„Drive:\ Folder\File_name.extension"

На пример, за да го отворите документот Word со име Список на цени што е зачуван во папката Word датотеки на уредот D, го користите следнава формула:

=HYPERLINK("D:\Word files\Price list.docx","Price list")

Хиперврска до обележувач во документ Word

За да направите хиперврска до одредена локација во документ Word, приложете ја патеката на документот во [квадрат загради] и користете обележувач за да ја дефинирате локацијата до која сакате да се движите.

На пример, следнава формула додава хиперврска до обележувачот со име цени_претплати во цена list.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices","Price list")

Хиперврска до датотека на мрежен уред

За да отворите датотека зачувана во вашата локална мрежа, наведете ја патеката до таа датотека во Universal Формат на Конвенција за именување (UNC) кој користи двојни задни црти за да му претходат на името на серверот, како ова:

"\\Име_сервер\ Folder\File_name.extension"

Со формулата подолу се создава хиперврска со наслов „Список на цени“ што ќе ја отвори Price list.xlsx работната книга зачувана на SERVER1 во Svetlana папка:

=HYPERLINK("\\SERVER1\Svetlana\Price list.xlsx", "Price list")

За да отворите датотека Excel на специфичен работен лист , затворете ја патеката до датотеката во [квадратни загради] и вклучете ја име на листот проследено со извичник (!) и наведенотоќелија:

=HYPERLINK("[\\SERVER1\Svetlana\Price list.xlsx]Sheet4!A1", "Price list")

Хиперврска до веб-страница

За да креирате хиперврска до веб-страница на Интернет или интранет, наведете ја нејзината URL-адреса затворена во наводници, како ова:

=HYPERLINK("//www.ablebits.com","Go to Ablebits.com")

Горената формула вметнува хиперврска, насловена како „Оди на Ablebits.com“, која ја отвора почетната страница на нашата веб-страница.

Хиперврска до испрати е-пошта

За да креирате нова порака до одреден примач, наведете адреса на е-пошта во овој формат:

"mailto:email_address"

На пример:

=HYPERLINK("mailto:[email protected]","Drop us an email")

Горената формула додава хиперврска со наслов „Пушти ни е-пошта“ и со кликнување на врската се создава нова порака до нашиот тим за поддршка.

Погледни и креирај хиперврска до прв натпревар

Кога работите со големи збирки на податоци, често може да се најдете во ситуација кога треба да побарате одредена вредност и да ги вратите соодветните податоци од друга колона. За ова, ја користите или функцијата VLOOKUP или помоќна комбинација INDEX MATCH.

Но, што ако не само што сакате да повлечете соодветна вредност, туку и да скокнете на позицијата на таа вредност во изворната база на податоци за да имате поглед на други детали во истиот ред? Ова може да се направи со користење на функцијата Excel HYPERLINK со помош од CELL, INDEX и MATCH.

Генеричката формула за правење хиперврска до првото совпаѓање е следнава:

За да ја видите горната формула во акција, разгледајте го следниот пример. Да претпоставиме дека имате листа на продавачи во колоната А и продадените производи во колоната В. Имате за цел да го повлечете првиот производ продаден од даден продавач и да направите хиперврска до некоја ќелија во тој ред за да можете да ги прегледате сите други детали поврзани со тој конкретен редослед.

Со вредноста за пребарување во ќелијата E2, листата на продавачи (опсег на пребарување) во A2:A10 и списокот на производи (повратен опсег) во C2:C10, формулата ја добива следната форма:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Како што е прикажано на сликата од екранот подолу, формулата ја повлекува вредноста што одговара и ја претвора во хиперврска што може да се кликне што го насочува корисникот до позицијата на првото совпаѓање во оригиналната база на податоци.

Ако работите со долги редови на податоци, можеби е попогодно хиперврската да покажува до првата ќелија во редот каде што се наоѓа совпаѓањето. За ова, едноставно го поставите опсегот за враќање во првата комбинација INDEX MATCH на колона А ($A$2:$A$10 во овој пример):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Оваа формула ќе ве однесе до првото појавување на вредноста за пребарување („Адам“) во базата на податоци:

Како функционира оваа формула

Оние од вас кои се запознаени со ИНДЕКС Формулата MATCH како поразноврсна алтернатива на Excel VLOOKUP, веројатно веќе ја сфатиле целокупнаталогика.

Во суштина, ја користите класичната комбинација INDEX MATCH за да ја лоцирате првата појава на вредноста за пребарување во опсегот на пребарување:

Можете да најдете целосни детали за тоа како функционира оваа формула следејќи ја горната врска. Подолу, ќе ги наведеме клучните точки:

• Функцијата MATCH ја одредува позицијата на „ Adam “ (вредност за пребарување) во опсегот A2:A10 (опсег на пребарување) и враќа 3.
• Резултатот од MATCH е предаден на аргументот row_num на функцијата INDEX со инструкции да ја врати вредноста од 3-от ред во опсегот C2:C10 (повратен опсег). И функцијата INDEX враќа „ Лимони “.

На овој начин, го добивате аргументот friendly_name на формулата за хиперврска.

Сега , ајде да одработиме локација_врска , т.е. ќелијата на која хиперврската треба да покажува. За да ја добиете адресата на ќелијата, ја користите функцијата CELL("адреса", [референца]) со INDEX MATCH како референца . За функцијата HYPERLINK да знае дека целната ќелија се наоѓа во тековниот лист, поврзете ја адресата на ќелијата со знакот фунта („#“).

Забелешка. Забележете ја употребата на апсолутни референци на ќелиите за да се поправат опсезите за пребарување и враќање. Ова е критично ако планирате да вметнете повеќе од една хиперврска со копирање на формулата.

Како да уредувате повеќе хиперврски истовремено

Како што беше споменато на почетокот наова упатство, една од најкорисните придобивки од хиперврските управувани од формула е можноста за уредување повеќе формули за хиперврска во еден чекор со користење на функцијата Замени ги сите на Excel.

Да речеме дека сакате да го замените стариот URL на вашата компанија (old-website.com) со новиот (new-website.com) во сите хиперврски на тековниот лист или во целата работна книга. За да го направите тоа, ве молиме следете ги чекорите наведени подолу:

1. Притиснете Ctrl + H за да го отворите јазичето Замени во дијалогот Најди и замени .
2. Во десниот дел од прозорецот за дијалог, кликнете на копчето Опции .
3. Во полето Најди што , напишете го саканиот текст за да се промени („old-website.com“ во овој пример).
4. Во паѓачката листа Во , изберете или Лист или Работна книга во зависност од тоа дали сакате да менувате хиперврски само на тековниот работен лист или во сите листови од тековната работна книга.
5. Во паѓачката листа Погледни во , изберете Формули .
6. Како дополнителна претпазливост, прво кликнете на копчето Најди ги сите и Excel ќе прикаже листа на сите формули што го содржат текстот за пребарување: