Šioje pamokoje paaiškinami "Excel" funkcijos HYPERLINK pagrindai ir pateikiama keletas patarimų bei formulių pavyzdžių, kaip efektyviausiai ją naudoti.

Yra daugybė būdų, kaip "Excel" programoje sukurti hipersaitus. Norėdami sukurti nuorodą į tam tikrą tinklalapį, galite tiesiog ląstelėje įvesti jo URL adresą, paspausti "Enter" ir "Microsoft Excel" automatiškai pakeis įrašą į spustelėjamą hipersaitą. Norėdami sukurti nuorodą į kitą darbalapį arba tam tikrą vietą kitame "Excel" faile, galite naudoti Nuoroda kontekstinį meniu arba spartųjį klavišą Ctrl + K. Jei planuojate įterpti daug vienodų ar panašių nuorodų, greičiausias būdas - naudoti hipersaitų formulę, kuri palengvina hipersaitų kūrimą, kopijavimą ir redagavimą "Excel" programoje.

"Excel" HYPERLINK funkcija - sintaksė ir pagrindiniai naudojimo būdai

Funkcija HYPERLINK programoje "Excel" naudojama nuorodai (sparčiajai nuorodai), kuri nukreipia naudotoją į nurodytą vietą tame pačiame dokumente arba atveria kitą dokumentą ar tinklalapį, sukurti. Naudodami funkciją HYPERLINK formulę galite sukurti nuorodą į toliau nurodytus elementus:

• Konkreti vieta, pvz., ląstelė arba įvardytas diapazonas "Excel" failas (esamame lape arba kitame darbalapyje ar sąsiuvinyje)
• "Word", "PowerPoint" ar kt. dokumentas saugomi standžiajame diske, vietiniame tinkle arba internete.
• Žymė "Word" dokumente
• Tinklalapis internete arba intranete.
• El. pašto adresas sukurti naują pranešimą

Šią funkciją galima naudoti visose "Excel 365" - 2000 versijose. "Excel Online" programoje HYPERLINK funkciją galima naudoti tik žiniatinklio adresams (URL).

Funkcijos HYPERLINK sintaksė yra tokia:

Kur:

• Link_location (privaloma) - kelias iki atidaromo tinklalapio arba failo.

  Link_location galima pateikti kaip nuoroda į ląstelę kuriame yra nuoroda arba teksto eilutė su kabutėmis, kuriame yra kelias iki failo, saugomo vietiniame diske, UNC kelias serveryje arba URL adresas internete ar intranete.

  Taip pat žr: Kaip apskaičiuoti amžių "Excel" programoje iš gimtadienio

  Jei nurodytas nuorodos kelias neegzistuoja arba yra nutrūkęs, paspaudus ląstelę "Hyperlink" formulėje bus išmesta klaida.

• Friendly_name (neprivaloma) - nuorodos tekstas (dar žinomas kaip šuolio tekstas arba inkaro tekstas), kuris turi būti rodomas ląstelėje. Jei nepateikiama, nuorodos tekstas rodomas kaip nuorodos tekstas.

  Friendly_name galima pateikti kaip skaitinę vertę, kabutėse įrašytą teksto eilutę, pavadinimą arba nuorodą į ląstelę, kurioje yra nuorodos tekstas.

Spustelėjus ląstelę su hipersaito formule, atidaromas failas arba tinklalapis, nurodytas link_location argumentas.

Toliau pateikiamas paprasčiausias "Excel" hipersaito formulės pavyzdys, kuriame A2 yra draugiškas_vardas o B2 yra link_location :

=HYPERLINK(B2, A2)

Rezultatas gali būti panašus į šį:

Toliau pateikiama daugiau formulių pavyzdžių, rodančių kitus "Excel" funkcijos HYPERLINK naudojimo būdus.

Kaip naudoti HYPERLINK programoje "Excel" - formulių pavyzdžiai

Pereidami nuo teorijos prie praktikos, pažiūrėkime, kaip galite naudoti HYPERLINK funkciją, kad tiesiogiai iš darbalapių atidarytumėte įvairius dokumentus. Taip pat aptarsime sudėtingesnę formulę, kurioje "Excel" HYPERLINK naudojama kartu su keliomis kitomis funkcijomis, kad būtų įvykdyta netriviali sudėtinga užduotis.

Kaip sukurti nuorodas į lapus, failus, tinklalapius ir kitus elementus

"Excel" funkcija HYPERLINK leidžia įterpti kelių skirtingų tipų paspaudžiamas hipersaitus, priklausomai nuo to, kokią reikšmę pateikiate parametrui link_location argumentas.

Nuoroda į kitą darbalapį

Norėdami įterpti hipersaitą į kitą tos pačios darbo knygos lapą, nurodykite tikslinio lapo pavadinimą, prieš kurį rašomas svaro ženklas (#), o po jo - šauktukas ir tikslinės ląstelės nuoroda, pvz:

=HYPERLINK("#Sheet2!A1", "Sheet2")

Pirmiau pateikta formulė sukuria hipersaitą su peršokimo tekstu "Lapas2", kuris atveria esamo sąsiuvinio lapą2.

Jei darbalapio pavadinime yra erdvės arba ne abėcėlės ženklai , ji turi būti pateikiama viengubomis kabutėmis, pvz., taip:

=HYPERLINK("#'Kainoraštis'!A1", "Kainoraštis")

Tokiu pat būdu galite sukurti hipersaitą į kitą to paties lapo langelį. Pavyzdžiui, norėdami įterpti hipersaitą, kuri jus nukreips į to paties darbalapio langelį A1, naudokite panašią formulę:

=HYPERLINK("#A1", "Pereiti į ląstelę A1")

Nuoroda į kitą sąsiuvinį

Norėdami sukurti hipersaitą į kitą sąsiuvinį, turite nurodyti pilnas kelias į tikslinį sąsiuvinį tokiu formatu:

"Drive:\Folder\Workbook.xlsx"

Pavyzdžiui:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Jei norite nusileisti konkrečiame lape ir net konkrečioje ląstelėje, naudokite šį formatą:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Pavyzdžiui, norėdami pridėti hipersaitą pavadinimu "Book3", kuris atveria 3 knygos 2 lapą, saugomą Šaltinio duomenys aplanką diske D, naudokite šią formulę:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Jei planuojate netrukus perkelti sąsiuvinius į kitą vietą, galite sukurti tokią santykinę nuorodą:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Perkėlus failus, santykinė hipersaitas veiks tol, kol nepasikeis santykinis kelias į tikslinį sąsiuvinį. Daugiau informacijos rasite skyriuje Absoliučios ir santykinės hipersaitys programoje "Excel".

Hipersaitas į pavadintą diapazoną

Jei darote hipersaitą į darbalapio lygmens pavadinimas , įtraukite visą kelią iki tikslo pavadinimo:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Pavyzdžiui, norėdami įterpti nuorodą į diapazoną, pavadintą "Source_data", saugomą 1 knygos 1 lape, naudokite šią formulę:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data", "Šaltinio duomenys")

Jei pateikiate nuorodą į sąsiuvinio lygmens pavadinimas , lapo pavadinimo įtraukti nereikia, pvz:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data", "Šaltinio duomenys")

Hipersaitas, skirtas atverti kietajame diske saugomą failą

Norėdami sukurti nuorodą, kuri atvertų kitą dokumentą, nurodykite pilnas kelias į šį dokumentą šiuo formatu:

"Drive:\Folder\File_name.extension"

Pavyzdžiui, norėdami atidaryti "Word" dokumentą pavadinimu Kainoraštis kuris saugomas Word failai aplanke, esančiame diske D, naudokite šią formulę:

=HYPERLINK("D:\Word files\Price list.docx", "Price list")

Hipersaitas į žymę "Word" dokumente

Norėdami sukurti hipersaitą į konkrečią "Word" dokumento vietą, dokumento kelią įrašykite į [laužtiniuose skliaustuose] ir naudokite skirtukas nustatyti vietą, į kurią norite naviguoti.

Pavyzdžiui, toliau pateikta formulė prideda hipersaitą prie žymės, pavadintos Prenumeratos_kainos į Kainoraštis.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices", "Kainoraštis")

Hipersaitas į tinklo diske esantį failą

Norėdami atidaryti vietiniame tinkle saugomą failą, nurodykite to failo kelią universaliu pavadinimų suteikimo konvencijos (UNC) formatu, kuriame prieš serverio pavadinimą naudojamas dvigubas atgalinis brūkšnys, pvz., taip:

"\\Serverio_pavadinimas\Papildyklė\Failas_pavadinimas.išplėtimas"

Toliau pateikta formulė sukuria hipersaitą "Kainoraštis", kuris atvers Kainoraštis.xlsx darbo knyga, saugoma SERVER1 svetainėje Svetlana aplankas:

=HYPERLINK("\\SERVER1\Svetlana\Kainoraštis.xlsx", "Kainoraštis")

Jei norite atidaryti "Excel" failą specifinis darbalapis , įrašykite failo kelią [laužtiniuose skliaustuose] ir įtraukite lapo pavadinimą, po kurio rašomas šauktukas (!), ir ląstelę, į kurią daroma nuoroda:

=HYPERLINK("[\\SERVER1\Svetlana\Kainoraštis.xlsx]Lapas4!A1", "Kainoraštis")

Nuoroda į tinklalapį

Norėdami sukurti hipersaitą į interneto ar intraneto tinklalapį, pateikite jo URL adresą su kabutėmis, pvz., taip:

=HYPERLINK("//www.ablebits.com", "Eiti į Ablebits.com")

Pirmiau pateikta formulė įterpia hipersaitą "Eiti į Ablebits.com", kuri atveria mūsų svetainės pagrindinį puslapį.

Hipersaitas, skirtas siųsti el. laišką

Jei norite sukurti naują pranešimą konkrečiam gavėjui, nurodykite el. pašto adresą šiuo formatu:

"mailto:email_address"

Pavyzdžiui:

=HYPERLINK("mailto:[email protected]", "Parašykite mums el. laišką")

Pirmiau pateiktoje formulėje pridėta nuoroda "Parašykite mums el. laišką", o spustelėjus šią nuorodą sukuriamas naujas pranešimas mūsų palaikymo komandai.

"Vlookup" ir sukurkite nuorodą į pirmąjį atitikmenį

Dirbdami su dideliais duomenų rinkiniais dažnai galite susidurti su situacija, kai reikia surasti tam tikrą reikšmę ir grąžinti atitinkamus duomenis iš kito stulpelio. Tam naudojama VLOOKUP funkcija arba galingesnis INDEX MATCH derinys.

Tačiau ką daryti, jei norite ne tik ištraukti sutampančią reikšmę, bet ir pereiti į tos reikšmės vietą šaltinio duomenų rinkinyje, kad galėtumėte peržiūrėti kitas tos pačios eilutės detales? Tai galima padaryti naudojant "Excel" funkciją HYPERLINK, pasitelkus CELL, INDEX ir MATCH.

Bendra formulė, pagal kurią sukuriama hipersaitė į pirmąją atitiktį, yra tokia:

Kad pamatytumėte, kaip veikia pirmiau pateikta formulė, panagrinėkite toliau pateiktą pavyzdį. Tarkime, A stulpelyje turite pardavėjų sąrašą, o C stulpelyje - parduotus gaminius. Norite ištraukti pirmąjį konkretaus pardavėjo parduotą gaminį ir sukurti hipersaitą į tam tikrą tos eilutės ląstelę, kad galėtumėte peržiūrėti visą kitą su konkrečiu užsakymu susijusią informaciją.

Kai paieškos vertė yra ląstelėje E2, pardavėjų sąrašas (paieškos diapazonas) - A2:A10, o produktų sąrašas (grąžinimo diapazonas) - C2:C10, formulė įgauna tokią formą:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Kaip parodyta toliau pateiktoje ekrano kopijoje, formulė ištraukia sutampančią reikšmę ir paverčia ją paspaudžiama hipersaite, nukreipiančia naudotoją į pirmosios sutampančios reikšmės vietą pradiniame duomenų rinkinyje.

Jei dirbate su ilgomis duomenų eilutėmis, gali būti patogiau, kad hipersaitas būtų nukreiptas į pirmąjį eilutės langelį, kuriame rastas atitikmuo. Šiuo atveju tiesiog nustatykite pirmosios INDEX MATCH kombinacijos grąžinimo intervalą į A stulpelį (šiame pavyzdyje $A$2:$A$10):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Ši formulė nukreips jus į pirmąjį paieškos reikšmės ("Adam") pasikartojimą duomenų rinkinyje:

Kaip veikia ši formulė

Tie, kurie yra susipažinę su INDEX MATCH formule kaip universalesne "Excel" VLOOKUP alternatyva, tikriausiai jau suprato bendrą logiką.

Iš esmės naudojate klasikinį INDEX MATCH derinį, kad surastumėte pirmą ieškomos reikšmės pasikartojimą ieškojimo intervale:

Išsamią informaciją apie tai, kaip veikia ši formulė, rasite paspaudę pirmiau pateiktą nuorodą. Toliau pateiksime pagrindinius aspektus:

• Funkcija MATCH nustato " Adomas " (paieškos vertė) intervale A2:A10 (paieškos intervalas) ir grąžina 3.
• MATCH rezultatas perduodamas į eilutės_num funkcijos INDEX argumentas, nurodantis jai grąžinti 3-iosios eilutės vertę iš intervalo C2:C10 (grąžinimo intervalas). O funkcija INDEX grąžina " Citrinos ".

Taip gausite draugiškas_vardas argumentas jūsų hipersaitų formulėje.

Dabar išsiaiškinkime link_location t. y. ląstelę, į kurią turėtų nukreipti hipersaitas. Norėdami gauti ląstelės adresą, naudokite funkciją CELL("address", [nuoroda]) su INDEX MATCH kaip nuoroda Kad HYPERLINK funkcija žinotų, jog tikslinė ląstelė yra dabartiniame lape, ląstelės adresą sutraukite su svaro ženklu ("#").

Pastaba. Atkreipkite dėmesį į absoliučių langelių nuorodų naudojimą ieškos ir grąžinimo intervalams nustatyti. Tai labai svarbu, jei kopijuodami formulę planuojate įterpti daugiau nei vieną hipersaitą.

Kaip vienu metu redaguoti kelias hipersaitus

Kaip minėta šio vadovėlio pradžioje, vienas iš naudingiausių formulėmis valdomų hipersaitų privalumų yra galimybė redaguoti kelios hipersaitų formulės vienu ypu, naudodami "Excel Pakeisti visus funkcija.

Tarkime, norite pakeisti senąjį savo įmonės URL (old-website.com) naujuoju (new-website.com) visose hipersaitose dabartiniame lape arba visame sąsiuvinyje. Norėdami tai padaryti, atlikite toliau nurodytus veiksmus:

1. Paspauskite Ctrl + H, kad atidarytumėte Pakeisti skirtukas Rasti ir pakeisti dialogas.
2. Dešinėje dialogo lango dalyje spustelėkite Parinktys mygtuką.
3. Į Raskite, ką įveskite tekstą, kurį norite pakeisti (šiame pavyzdyje - "old-website.com").
4. Į Per išskleidžiamajame sąraše pasirinkite Lapas arba Darbo knyga priklausomai nuo to, ar norite pakeisti hipersaitus tik dabartiniame darbalapyje, ar visuose dabartinio sąsiuvinio lapuose.
5. Į Žvilgsnis į išplečiamajame sąraše pasirinkite Formulės .
6. Kaip papildomą atsargumo priemonę spustelėkite Rasti viską mygtuką, ir "Excel" parodys visų formulių, kuriose yra paieškos tekstas, sąrašą:

Panašiai galite redaguoti nuorodos tekstą (draugiškas_pavadinimas) visose "Hyperlink" formulėse vienu metu. Tai darydami būtinai patikrinkite, ar tekstas, kurį reikia pakeisti draugiškas_vardas niekur nėra link_location kad nepažeistumėte formulių.

"Excel" HYPERLINK neveikia - priežastys ir sprendimai

Dažniausia priežastis, dėl kurios neveikia hipersaitų formulė (ir pirmoji, kurią turite patikrinti!), yra neegzistuojantis arba pažeistas kelias į link_location argumentas. Jei taip nėra, patikrinkite šiuos du dalykus:

1. Jei paspaudus hipersaitą nuorodos paskirties vieta neatsidaro, įsitikinkite, kad nuorodos vieta pateikta tinkamu formatu. Formulės pavyzdžių, kaip sukurti skirtingų tipų hipersaitus, rasite čia.
2. Jei vietoje nuorodos teksto ląstelėje atsiranda klaida, pvz., VALUE! arba N/A, greičiausiai problema susijusi su draugiškas_vardas argumentas jūsų hipersaitų formulėje.

   Paprastai tokios klaidos pasitaiko, kai draugiškas_vardas grąžinama kai kurių kitų funkcijų, kaip mūsų Vlookup ir hipersaito į pirmąjį atitikmenį pavyzdyje. Šiuo atveju formulės ląstelėje bus rodoma klaida #N/A, jei paieškos lentelėje nerandama paieškos reikšmė. Kad išvengtumėte tokių klaidų, galite apsvarstyti galimybę naudoti funkciją IFERROR, kad vietoj klaidos reikšmės būtų rodoma tuščia eilutė arba koks nors vartotojui patogus tekstas.

Taip sukursite hipersaitus naudodami "Excel" funkciją HYPERLINK. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Atsisiųsti praktikos sąsiuvinį

"Excel" hipersaitų formulių pavyzdžiai (.xlsx failas)