Αυτό το σεμινάριο εξηγεί τα βασικά στοιχεία της συνάρτησης HYPERLINK του Excel και παρέχει μερικές συμβουλές και παραδείγματα τύπων για την αποτελεσματικότερη χρήση της.

Υπάρχουν πολλοί τρόποι για να δημιουργήσετε έναν υπερσύνδεσμο στο Excel. Για να συνδεθείτε με μια συγκεκριμένη ιστοσελίδα, μπορείτε απλά να πληκτρολογήσετε τη διεύθυνση URL της σε ένα κελί, να πατήσετε Enter και το Microsoft Excel θα μετατρέψει αυτόματα την καταχώρηση σε υπερσύνδεσμο με δυνατότητα κλικ. Για να συνδεθείτε με ένα άλλο φύλλο εργασίας ή μια συγκεκριμένη θέση σε ένα άλλο αρχείο Excel, μπορείτε να χρησιμοποιήσετε την εντολή Υπερσύνδεσμος μενού περιβάλλοντος ή συντόμευση Ctrl + K. Εάν σκοπεύετε να εισαγάγετε πολλούς πανομοιότυπους ή παρόμοιους συνδέσμους, ο ταχύτερος τρόπος είναι να χρησιμοποιήσετε έναν τύπο υπερσυνδέσμου, ο οποίος διευκολύνει τη δημιουργία, την αντιγραφή και την επεξεργασία υπερσυνδέσμων στο Excel.

Συνάρτηση HYPERLINK του Excel - σύνταξη και βασικές χρήσεις

Η συνάρτηση HYPERLINK στο Excel χρησιμοποιείται για τη δημιουργία μιας αναφοράς (συντόμευσης) που κατευθύνει τον χρήστη στην καθορισμένη θέση στο ίδιο έγγραφο ή ανοίγει ένα άλλο έγγραφο ή ιστοσελίδα. Χρησιμοποιώντας έναν τύπο Hyperlink, μπορείτε να συνδέσετε τα ακόλουθα στοιχεία:

• Ένα συγκεκριμένο μέρος, όπως ένα κελί ή μια ονομαστική περιοχή σε ένα Αρχείο Excel (στο υπάρχον φύλλο ή σε άλλο φύλλο εργασίας ή βιβλίο εργασίας)
• Word, PowerPoint ή άλλο έγγραφο που είναι αποθηκευμένα στο σκληρό σας δίσκο, στο τοπικό δίκτυο ή στο διαδίκτυο.
• Σελιδοδείκτης σε ένα έγγραφο Word
• Ιστοσελίδα στο Διαδίκτυο ή στο intranet
• Διεύθυνση ηλεκτρονικού ταχυδρομείου για να δημιουργήσετε ένα νέο μήνυμα

Η συνάρτηση είναι διαθέσιμη σε όλες τις εκδόσεις του Excel 365 - 2000. Στο Excel Online, η συνάρτηση HYPERLINK μπορεί να χρησιμοποιηθεί μόνο για διευθύνσεις ιστού (URL).

Η σύνταξη της συνάρτησης HYPERLINK έχει ως εξής:

Πού:

• Link_location (υποχρεωτικό) είναι η διαδρομή της ιστοσελίδας ή του αρχείου που πρόκειται να ανοίξει.

  Link_location μπορεί να παρέχεται ως αναφορά σε ένα κελί που περιέχει το σύνδεσμο ή ένα συμβολοσειρά κειμένου που περικλείεται σε εισαγωγικά και περιέχει τη διαδρομή προς ένα αρχείο που είναι αποθηκευμένο σε έναν τοπικό δίσκο, τη διαδρομή UNC σε έναν διακομιστή ή τη διεύθυνση URL στο Διαδίκτυο ή στο εσωτερικό δίκτυο.

  Εάν η καθορισμένη διαδρομή συνδέσμου δεν υπάρχει ή είναι σπασμένη, ο τύπος Υπερσύνδεσμος θα εμφανίσει σφάλμα όταν κάνετε κλικ στο κελί.

• Friendly_name (προαιρετικό) είναι το κείμενο συνδέσμου (ή αλλιώς κείμενο άλματος ή κείμενο άγκυρας) που θα εμφανίζεται σε ένα κελί. Αν παραλειφθεί, το link_location εμφανίζεται ως κείμενο συνδέσμου.

  Το Friendly_name μπορεί να παρέχεται ως αριθμητική τιμή, συμβολοσειρά κειμένου που περικλείεται σε εισαγωγικά, όνομα ή αναφορά σε ένα κελί που περιέχει το κείμενο συνδέσμου.

Κάνοντας κλικ σε ένα κελί με έναν τύπο Υπερσύνδεσμου ανοίγει το αρχείο ή την ιστοσελίδα που καθορίζεται στο link_location επιχείρημα.

Παρακάτω, μπορείτε να δείτε το απλούστερο παράδειγμα ενός τύπου υπερσύνδεσης του Excel, όπου το A2 περιέχει friendly_name και το B2 περιέχει link_location :

=HYPERLINK(B2, A2)

Το αποτέλεσμα μπορεί να μοιάζει κάπως έτσι:

Παρακάτω ακολουθούν περισσότερα παραδείγματα τύπων που δείχνουν άλλες χρήσεις της συνάρτησης HYPERLINK του Excel.

Πώς να χρησιμοποιήσετε το HYPERLINK στο Excel - παραδείγματα τύπων

Περνώντας από τη θεωρία στην πράξη, ας δούμε πώς μπορείτε να χρησιμοποιήσετε τη συνάρτηση HYPERLINK για να ανοίγετε διάφορα έγγραφα απευθείας από τα φύλλα εργασίας σας. Θα συζητήσουμε επίσης έναν πιο σύνθετο τύπο όπου το Excel HYPERLINK χρησιμοποιείται σε συνδυασμό με μερικές άλλες συναρτήσεις για να επιτευχθεί μια όχι τετριμμένη δύσκολη εργασία.

Πώς να συνδέετε φύλλα, αρχεία, ιστοσελίδες και άλλα στοιχεία

Η συνάρτηση HYPERLINK του Excel σας επιτρέπει να εισάγετε υπερσυνδέσμους με δυνατότητα κλικ σε μερικούς διαφορετικούς τύπους, ανάλογα με την τιμή που θα δώσετε στη γραμμή link_location επιχείρημα.

Υπερσύνδεσμος σε άλλο φύλλο εργασίας

Για να εισαγάγετε έναν υπερσύνδεσμο προς ένα διαφορετικό φύλλο στο ίδιο βιβλίο εργασίας, δώστε το όνομα του φύλλου-στόχου, πριν από ένα σύμβολο λίρας (#), και ακολουθούμενο από το θαυμαστικό και την αναφορά κελιού-στόχου, όπως παρακάτω:

=HYPERLINK("#Φύλλο2!A1", "Φύλλο2")

Ο παραπάνω τύπος δημιουργεί έναν υπερσύνδεσμο με το κείμενο άλματος "Sheet2" που ανοίγει το Sheet2 στο τρέχον βιβλίο εργασίας.

Εάν το όνομα του φύλλου εργασίας περιλαμβάνει χώροι ή μη αλφαβητικοί χαρακτήρες , πρέπει να περικλείεται σε απλά εισαγωγικά, όπως εδώ:

=HYPERLINK("#'Τιμοκατάλογος'!A1", "Τιμοκατάλογος")

Με τον ίδιο τρόπο, μπορείτε να δημιουργήσετε έναν υπερσύνδεσμο προς ένα άλλο κελί στο ίδιο φύλλο. Για παράδειγμα, για να εισαγάγετε έναν υπερσύνδεσμο που θα σας μεταφέρει στο κελί A1 του ίδιου φύλλου εργασίας, χρησιμοποιήστε έναν τύπο παρόμοιο με αυτόν:

=HYPERLINK("#A1", "Μετάβαση στο κελί A1")

Υπερσύνδεσμος σε διαφορετικό βιβλίο εργασίας

Για να δημιουργήσετε έναν υπερσύνδεσμο προς ένα άλλο βιβλίο εργασίας, πρέπει να καθορίσετε το πλήρης διαδρομή στο βιβλίο εργασίας-στόχο με την ακόλουθη μορφή:

"Drive:\Folder\Workbook.xlsx"

Για παράδειγμα:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Για να προσγειωθείτε σε ένα συγκεκριμένο φύλλο και μάλιστα σε ένα συγκεκριμένο κελί, χρησιμοποιήστε αυτή τη μορφή:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Για παράδειγμα, για να προσθέσετε έναν υπερσύνδεσμο με τίτλο "Βιβλίο3" που ανοίγει το φύλλο2 στο Βιβλίο3 που είναι αποθηκευμένο στο Δεδομένα πηγής φάκελο στη μονάδα δίσκου D, χρησιμοποιήστε αυτόν τον τύπο:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Αν σκοπεύετε να μετακινήσετε σύντομα τα βιβλία εργασίας σας σε άλλη τοποθεσία, μπορείτε να δημιουργήσετε έναν σχετικό σύνδεσμο όπως αυτός:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Όταν μετακινείτε τα αρχεία, ο σχετικός υπερσύνδεσμος θα συνεχίσει να λειτουργεί εφόσον η σχετική διαδρομή προς το βιβλίο εργασίας-στόχο παραμένει αμετάβλητη. Για περισσότερες πληροφορίες, ανατρέξτε στην ενότητα Απόλυτοι και σχετικοί υπερσύνδεσμοι στο Excel.

Υπερσύνδεσμος σε μια ονομαστική περιοχή

Εάν δημιουργείτε έναν υπερσύνδεσμο προς ένα όνομα επιπέδου φύλλου εργασίας , περιλαμβάνουν την πλήρη διαδρομή προς το όνομα του στόχου:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Για παράδειγμα, για να εισαγάγετε έναν σύνδεσμο σε μια περιοχή με όνομα "Source_data" που είναι αποθηκευμένη στο φύλλο1 στο βιβλίο1, χρησιμοποιήστε τον ακόλουθο τύπο:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data", "Source data")

Εάν αναφέρεστε σε ένα όνομα επιπέδου βιβλίου εργασίας , το όνομα του φύλλου δεν χρειάζεται να συμπεριληφθεί, για παράδειγμα:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data", "Source data")

Υπερσύνδεσμος για να ανοίξετε ένα αρχείο που είναι αποθηκευμένο σε έναν σκληρό δίσκο

Για να δημιουργήσετε έναν σύνδεσμο που θα ανοίγει ένα άλλο έγγραφο, καθορίστε το πλήρης διαδρομή σε αυτό το έγγραφο με αυτή τη μορφή:

"Drive:\Folder\File_name.extension"

Για παράδειγμα, για να ανοίξετε το έγγραφο του Word με όνομα Τιμοκατάλογος που είναι αποθηκευμένο στο Αρχεία Word φάκελο στη μονάδα δίσκου D, χρησιμοποιείτε τον ακόλουθο τύπο:

=HYPERLINK("D:\Word files\Price list.docx", "Τιμοκατάλογος")

Υπερσύνδεσμος σε σελιδοδείκτη σε έγγραφο του Word

Για να δημιουργήσετε έναν υπερσύνδεσμο προς μια συγκεκριμένη θέση σε ένα έγγραφο του Word, περικλείστε τη διαδρομή του εγγράφου σε [αγκύλες] και χρησιμοποιήστε ένα σελιδοδείκτης για να ορίσετε τη θέση στην οποία θέλετε να πλοηγηθείτε.

Για παράδειγμα, ο παρακάτω τύπος προσθέτει έναν υπερσύνδεσμο στο σελιδοδείκτη με όνομα Subscription_prices στο αρχείο Price list.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices", "Τιμοκατάλογος")

Υπερσύνδεσμος σε αρχείο σε μονάδα δίσκου δικτύου

Για να ανοίξετε ένα αρχείο που είναι αποθηκευμένο στο τοπικό σας δίκτυο, δώστε τη διαδρομή προς το αρχείο σε μορφή UNC (Universal Naming Convention) που χρησιμοποιεί διπλές κάθετες πριν από το όνομα του διακομιστή, όπως παρακάτω:

"\\Όνομα_διακομιστή\Φάκελος\Όνομα_αρχείου.επέκταση"

Ο παρακάτω τύπος δημιουργεί έναν υπερσύνδεσμο με τίτλο "Τιμοκατάλογος" που θα ανοίξει το Τιμοκατάλογος.xlsx βιβλίο εργασίας αποθηκευμένο στο SERVER1 στο Σβετλάνα φάκελος:

=HYPERLINK("\\SERVER1\Svetlana\Price list.xlsx", "Τιμοκατάλογος")

Για να ανοίξετε ένα αρχείο Excel σε συγκεκριμένο φύλλο εργασίας , περικλείει τη διαδρομή προς το αρχείο σε [αγκύλες] και περιλαμβάνει το όνομα του φύλλου ακολουθούμενο από το θαυμαστικό (!) και το κελί στο οποίο αναφέρεται:

=HYPERLINK("[\\SERVER1\Svetlana\Price list.xlsx]Sheet4!A1", "Price list")

Υπερσύνδεσμος σε μια ιστοσελίδα

Για να δημιουργήσετε έναν υπερσύνδεσμο προς μια ιστοσελίδα στο Internet ή στο intranet, δώστε τη διεύθυνση URL μέσα σε εισαγωγικά, όπως παρακάτω:

=HYPERLINK("//www.ablebits.com", "Μεταβείτε στο Ablebits.com")

Ο παραπάνω τύπος εισάγει έναν υπερσύνδεσμο με τίτλο "Go to Ablebits.com", ο οποίος ανοίγει την αρχική σελίδα του ιστοτόπου μας.

Υπερσύνδεσμος για να στείλετε ένα email

Για να δημιουργήσετε ένα νέο μήνυμα προς έναν συγκεκριμένο παραλήπτη, δώστε μια διεύθυνση ηλεκτρονικού ταχυδρομείου σε αυτή τη μορφή:

"mailto:email_address"

Για παράδειγμα:

=HYPERLINK("mailto:[email protected]", "Στείλτε μας ένα email")

Ο παραπάνω τύπος προσθέτει έναν υπερσύνδεσμο με τίτλο "Στείλτε μας ένα email" και κάνοντας κλικ στο σύνδεσμο δημιουργείται ένα νέο μήνυμα προς την ομάδα υποστήριξης.

Vlookup και δημιουργήστε έναν υπερσύνδεσμο προς την πρώτη αντιστοιχία

Όταν εργάζεστε με μεγάλα σύνολα δεδομένων, μπορεί συχνά να βρεθείτε σε μια κατάσταση όπου πρέπει να αναζητήσετε μια συγκεκριμένη τιμή και να επιστρέψετε τα αντίστοιχα δεδομένα από μια άλλη στήλη. Για το σκοπό αυτό, χρησιμοποιείτε είτε τη συνάρτηση VLOOKUP είτε έναν πιο ισχυρό συνδυασμό INDEX MATCH.

Τι γίνεται όμως αν θέλετε όχι μόνο να τραβήξετε μια τιμή που ταιριάζει, αλλά και να μεταβείτε στη θέση αυτής της τιμής στο σύνολο δεδομένων της πηγής για να ρίξετε μια ματιά σε άλλες λεπτομέρειες στην ίδια γραμμή; Αυτό μπορεί να γίνει με τη χρήση της συνάρτησης HYPERLINK του Excel με λίγη βοήθεια από τις λειτουργίες CELL, INDEX και MATCH.

Ο γενικός τύπος για να δημιουργήσετε έναν υπερσύνδεσμο προς την πρώτη αντιστοιχία έχει ως εξής:

Για να δείτε τον παραπάνω τύπο σε δράση, αναλογιστείτε το ακόλουθο παράδειγμα. Ας υποθέσουμε ότι έχετε μια λίστα με τους προμηθευτές στη στήλη Α και τα πωληθέντα προϊόντα στη στήλη Γ. Στόχος σας είναι να τραβήξετε το πρώτο προϊόν που πωλήθηκε από έναν συγκεκριμένο προμηθευτή και να δημιουργήσετε έναν υπερσύνδεσμο προς κάποιο κελί σε αυτή τη γραμμή, ώστε να μπορείτε να δείτε όλες τις άλλες λεπτομέρειες που σχετίζονται με τη συγκεκριμένη παραγγελία.

Με την τιμή αναζήτησης στο κελί E2, τη λίστα προμηθευτών (περιοχή αναζήτησης) στα A2:A10 και τη λίστα προϊόντων (περιοχή επιστροφής) στα C2:C10, ο τύπος παίρνει την ακόλουθη μορφή:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))))

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, ο τύπος αντλεί την τιμή αντιστοίχισης και τη μετατρέπει σε έναν υπερσύνδεσμο που μπορεί να πατηθεί και κατευθύνει τον χρήστη στη θέση της πρώτης αντιστοίχισης στο αρχικό σύνολο δεδομένων.

Εάν εργάζεστε με μεγάλες σειρές δεδομένων, μπορεί να είναι πιο βολικό να έχετε τον υπερσύνδεσμο να δείχνει στο πρώτο κελί της γραμμής όπου βρέθηκε η αντιστοιχία. Για το σκοπό αυτό, απλά ορίζετε την περιοχή επιστροφής στον πρώτο συνδυασμό INDEX MATCH στη στήλη A ($A$2:$A$10 σε αυτό το παράδειγμα):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))))

Αυτός ο τύπος θα σας μεταφέρει στην πρώτη εμφάνιση της τιμής αναζήτησης ("Adam") στο σύνολο δεδομένων:

Πώς λειτουργεί αυτή η φόρμουλα

Όσοι από εσάς είστε εξοικειωμένοι με τον τύπο INDEX MATCH ως μια πιο ευέλικτη εναλλακτική λύση για το VLOOKUP του Excel, πιθανόν να έχετε ήδη καταλάβει τη συνολική λογική.

Στον πυρήνα, χρησιμοποιείτε τον κλασικό συνδυασμό INDEX MATCH για να εντοπίσετε την πρώτη εμφάνιση της τιμής αναζήτησης στην περιοχή αναζήτησης:

Μπορείτε να βρείτε πλήρεις λεπτομέρειες για το πώς λειτουργεί αυτός ο τύπος ακολουθώντας τον παραπάνω σύνδεσμο. Παρακάτω, θα περιγράψουμε τα βασικά σημεία:

• Η συνάρτηση MATCH καθορίζει τη θέση του " Adam " (τιμή αναζήτησης) στην περιοχή A2:A10 (περιοχή αναζήτησης) και επιστρέφει 3.
• Το αποτέλεσμα της MATCH περνάει στην εντολή row_num όρισμα της συνάρτησης INDEX δίνοντάς της εντολή να επιστρέψει την τιμή από την 3η γραμμή στο εύρος C2:C10 (εύρος επιστροφής). Και η συνάρτηση INDEX επιστρέφει " Λεμόνια ".

Με αυτόν τον τρόπο, έχετε το friendly_name του τύπου Υπερσύνδεσμος.

Τώρα, ας δουλέψουμε link_location Για να λάβετε τη διεύθυνση του κελιού, χρησιμοποιείτε τη συνάρτηση CELL("address", [reference]) με INDEX MATCH ως εξής αναφορά Για να γνωρίζει η συνάρτηση HYPERLINK ότι το κελί-στόχος βρίσκεται στο τρέχον φύλλο, συνδέστε τη διεύθυνση του κελιού με τον χαρακτήρα λίρας ("#").

Σημείωση. Παρακαλούμε προσέξτε τη χρήση απόλυτων αναφορών κελιών για τον καθορισμό των περιοχών αναζήτησης και επιστροφής. Αυτό είναι κρίσιμο εάν σκοπεύετε να εισαγάγετε περισσότερους από έναν υπερσυνδέσμους αντιγράφοντας τον τύπο.

Πώς να επεξεργαστείτε πολλαπλούς υπερσυνδέσμους ταυτόχρονα

Όπως αναφέρθηκε στην αρχή αυτού του σεμιναρίου, ένα από τα πιο χρήσιμα πλεονεκτήματα των υπερσυνδέσμων με βάση τον τύπο είναι η δυνατότητα επεξεργασίας πολλαπλές φόρμουλες υπερσυνδέσμου με μία κίνηση χρησιμοποιώντας την λειτουργία του Excel Αντικαταστήστε όλα χαρακτηριστικό.

Ας υποθέσουμε ότι θέλετε να αντικαταστήσετε την παλιά διεύθυνση URL της εταιρείας σας (old-website.com) με τη νέα (new-website.com) σε όλους τους υπερσυνδέσμους στο τρέχον φύλλο ή σε ολόκληρο το βιβλίο εργασίας. Για να γίνει αυτό, ακολουθήστε τα βήματα που περιγράφονται παρακάτω:

1. Πατήστε Ctrl + H για να ανοίξετε το Αντικαταστήστε το της καρτέλας Εύρεση και αντικατάσταση διάλογος.
2. Στο δεξιό μέρος του πλαισίου διαλόγου, κάντε κλικ στην επιλογή Επιλογές κουμπί.
3. Στο Βρείτε τι πληκτρολογήστε το κείμενο που θέλετε να αλλάξετε ("old-website.com" σε αυτό το παράδειγμα).
4. Στο Εντός του αναπτυσσόμενη λίστα, επιλέξτε είτε Φύλλο ή Βιβλίο εργασίας ανάλογα με το αν θέλετε να αλλάξετε τους υπερσυνδέσμους μόνο στο τρέχον φύλλο εργασίας ή σε όλα τα φύλλα του τρέχοντος βιβλίου εργασίας.
5. Στο Κοιτάξτε μέσα αναπτυσσόμενη λίστα, επιλέξτε Τύποι .
6. Ως επιπλέον προφύλαξη, κάντε κλικ στο Βρείτε όλα και το Excel θα εμφανίσει μια λίστα με όλους τους τύπους που περιέχουν το κείμενο αναζήτησης:

Με παρόμοιο τρόπο, μπορείτε να επεξεργαστείτε το κείμενο του συνδέσμου (friendly_name) σε όλους τους τύπους Hyperlink ταυτόχρονα. Όταν το κάνετε αυτό, βεβαιωθείτε ότι το κείμενο που πρέπει να αντικατασταθεί στο friendly_name δεν εμφανίζεται πουθενά στο link_location έτσι ώστε να μην παραβιάζετε τους τύπους.

Το Excel HYPERLINK δεν λειτουργεί - λόγοι και λύσεις

Ο πιο συνηθισμένος λόγος που ένας τύπος Υπερσύνδεσμου δεν λειτουργεί (και το πρώτο πράγμα που πρέπει να ελέγξετε!) είναι μια ανύπαρκτη ή σπασμένη διαδρομή στο αρχείο link_location Αν δεν είναι έτσι, ελέγξτε τα ακόλουθα δύο πράγματα:

1. Εάν ο προορισμός του συνδέσμου δεν ανοίγει όταν κάνετε κλικ σε έναν υπερσύνδεσμο, βεβαιωθείτε ότι η θέση του συνδέσμου παρέχεται στη σωστή μορφή. Παραδείγματα τύπων για τη δημιουργία διαφορετικών τύπων υπερσυνδέσμων μπορείτε να βρείτε εδώ.
2. Αν αντί για το κείμενο του συνδέσμου εμφανίζεται ένα σφάλμα όπως VALUE! ή N/A σε ένα κελί, το πιθανότερο είναι ότι το πρόβλημα είναι με το friendly_name του τύπου σας Hyperlink.

   Συνήθως, τα σφάλματα αυτά συμβαίνουν όταν friendly_name επιστρέφεται από κάποια άλλη(ες) συνάρτηση(ες), όπως στο παράδειγμά μας Vlookup και υπερσύνδεση με την πρώτη αντιστοίχιση. Σε αυτή την περίπτωση, το σφάλμα #N/A θα εμφανιστεί στο κελί του τύπου εάν η τιμή αναζήτησης δεν βρεθεί μέσα στον πίνακα αναζήτησης. Για να αποφύγετε τέτοια σφάλματα, μπορείτε να εξετάσετε το ενδεχόμενο να χρησιμοποιήσετε τη συνάρτηση IFERROR για να εμφανίσετε μια κενή συμβολοσειρά ή κάποιο φιλικό προς το χρήστη κείμενο αντί της τιμής σφάλματος.

Έτσι δημιουργείτε υπερσυνδέσμους χρησιμοποιώντας τη συνάρτηση HYPERLINK του Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Βιβλίο ασκήσεων για κατέβασμα

Παραδείγματα τύπων υπερσυνδέσμου του Excel (.xlsx αρχείο)