В този урок се обясняват основите на функцията HYPERLINK на Excel и се дават няколко съвета и примери за формули за нейното най-ефективно използване.

Има много начини за създаване на хипервръзка в Excel. За да направите връзка към определена уеб страница, можете просто да въведете нейния URL адрес в клетка, да натиснете Enter и Microsoft Excel автоматично ще преобразува записа в хипервръзка, която може да се кликне. За да направите връзка към друг работен лист или към определено място в друг файл на Excel, можете да използвате Хипервръзка контекстното меню или клавишната комбинация Ctrl + K. Ако планирате да вмъкнете много идентични или подобни връзки, най-бързият начин е да използвате формула за хипервръзки, която улеснява създаването, копирането и редактирането на хипервръзки в Excel.

Функция Excel HYPERLINK - синтаксис и основни приложения

Функцията HYPERLINK (Хипервръзка) в Excel се използва за създаване на препратка (пряк път), която насочва потребителя към определено място в същия документ или отваря друг документ или уебстраница. Като използвате формулата Hyperlink (Хипервръзка), можете да създавате връзки към следните елементи:

• Определено място, например клетка или именуван диапазон в Файл на Excel (в съществуващия лист или в друг работен лист или работна книга)
• Word, PowerPoint или други документ съхранени на твърдия ви диск, в локалната мрежа или онлайн
• Отметка в документ на Word
• Уебстраница в интернет или интранет
• Имейл адрес за създаване на ново съобщение

Функцията е налична във всички версии на Excel 365 - 2000. В Excel Online функцията HYPERLINK може да се използва само за уеб адреси (URL).

Синтаксисът на функцията HYPERLINK е следният:

Къде:

• Link_location (задължително) е пътят до уебстраницата или файла, който трябва да се отвори.

  Link_location може да се предостави като препратка към клетка съдържащ връзката или текстов низ затворен в кавички, който съдържа път до файл, съхраняван на локално устройство, UNC път на сървър или URL адрес в интернет или интранет.

  Ако посоченият път на връзката не съществува или е прекъснат, формулата за хипервръзка ще хвърли грешка, когато щракнете върху клетката.

• Friendly_name (незадължително) е текстът на връзката (известен още като текст на скок или текст на котва), който трябва да бъде показан в клетката. Ако се пропусне, link_location се показва като текст на връзката.

  Friendly_name може да се предостави като числова стойност, текстов низ, затворен в кавички, име или препратка към клетка, която съдържа текста на връзката.

Щракването върху клетка с формула за хипервръзка отваря файла или уебстраницата, посочена в link_location аргумент.

По-долу можете да видите най-простия пример за формула за хипервръзка в Excel, където A2 съдържа friendly_name а B2 съдържа link_location :

=ХИПЕРВРЪЗКА(B2, A2)

Резултатът може да изглежда по следния начин:

По-долу следват още примери за формули, демонстриращи други приложения на функцията Excel HYPERLINK.

Как да използвате HYPERLINK в Excel - примери за формули

Преминавайки от теорията към практиката, нека видим как можете да използвате функцията HYPERLINK, за да отваряте различни документи директно от работните си листове. Ще обсъдим и една по-сложна формула, в която Excel HYPERLINK се използва в комбинация с няколко други функции за изпълнение на нетривиална предизвикателна задача.

Как да се свързвате с листове, файлове, уеб страници и други елементи

Функцията HYPERLINK на Excel ви позволява да вмъквате хипервръзки с възможност за кликване от няколко различни типа в зависимост от стойността, която предоставяте на link_location аргумент.

Хипервръзка към друг работен лист

За да вмъкнете хипервръзка към друг лист в същата работна книга, въведете името на целевия лист, предшествано от знака за паунд (#), последвано от възклицателен знак и референция към целевата клетка, както е показано по-долу:

=HYPERLINK("#Sheet2!A1", "Sheet2")

Горната формула създава хипервръзка с текста за скок "Sheet2", която отваря Sheet2 в текущата работна книга.

Ако името на работния лист включва пространства или неалфабетни знаци , то трябва да бъде оградено с единични кавички, както е показано по-долу:

=HYPERLINK("#'Ценоразпис'!A1", "Ценоразпис")

По същия начин можете да създадете хипервръзка към друга клетка в същия лист. Например, за да поставите хипервръзка, която ще ви отведе до клетка А1 в същия работен лист, използвайте формула, подобна на тази:

=HYPERLINK("#A1", "Отиди на клетка A1")

Хипервръзка към друга работна книга

За да създадете хипервръзка към друга работна книга, трябва да посочите пълен път в целевата работна книга в следния формат:

"Drive:\Folder\Workbook.xlsx"

Например:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

За да попаднете в конкретен лист и дори в конкретна клетка, използвайте този формат:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Например, за да добавите хипервръзка, озаглавена "Book3", която отваря лист 2 в Book3, съхранен в Източник на данни папка на устройство D, използвайте тази формула:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Ако планирате скоро да преместите работните си книги на друго място, можете да създадете относителна връзка по следния начин:

=HYPERLINK("Source data\Book3.xlsx", "Book3")

Когато преместите файловете, относителната хипервръзка ще продължи да работи, докато относителният път до целевата работна книга остане непроменен. За повече информация вижте Абсолютни и относителни хипервръзки в Excel.

Хипервръзка към именуван диапазон

Ако правите хипервръзка към име на ниво работен лист , включете пълния път до името на целта:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Например, за да вмъкнете връзка към диапазон с име "Source_data", съхранен в лист 1 в Book1, използвайте тази формула:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data", "Източни данни")

Ако се позовавате на име на ниво работна книга , не е необходимо да се включва името на листа, например:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data", "Източни данни")

Хипервръзка за отваряне на файл, съхранен на твърдия диск

За да създадете връзка, която ще отвори друг документ, посочете пълен път към този документ в този формат:

"Drive:\Folder\File_name.extension"

Например, за да отворите документа на Word с име Ценова листа която се съхранява в Word файлове на устройство D, използвате следната формула:

=HYPERLINK("D:\Word files\Price list.docx", "Ценова листа")

Хипервръзка към отметки в документ на Word

За да направите хипервръзка към определено място в документ на Word, оградете пътя към документа в [квадратни скоби] и използвайте отметки за да определите местоположението, до което искате да навигирате.

Например следната формула добавя хипервръзка към отметките с име Subscription_prices в Price list.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices", "Ценоразпис")

Хипервръзка към файл в мрежово устройство

За да отворите файл, съхраняван в локалната мрежа, въведете пътя до този файл във формат UNC (Universal Naming Convention), който използва двойни обратни наклонени черти пред името на сървъра, както е показано по-долу:

"\\Server_name\Folder\File_name.extension"

Формулата по-долу създава хипервръзка със заглавие "Ценова листа", която ще отвори Ценова листа.xlsx работна книга, съхранявана в СЕРВЪР1 в Светлана папка:

=HYPERLINK("\\SERVER1\Svetlana\Ценоразпис.xlsx", "Ценоразпис")

Отваряне на файл на Excel в специфичен работен лист , заградете пътя до файла в [квадратни скоби] и включете името на листа, последвано от възклицателния знак (!) и препратената клетка:

=HYPERLINK("[\\SERVER1\Svetlana\Price list.xlsx]Sheet4!A1", "Price list")

Хипервръзка към уеб страница

За да създадете хипервръзка към уебстраница в интернет или интранет, въведете нейния URL адрес, поставен в кавички, по следния начин:

=HYPERLINK("//www.ablebits.com", "Отидете на Ablebits.com")

Горната формула вмъква хипервръзка, озаглавена "Go to Ablebits.com", която отваря началната страница на нашия уебсайт.

Хипервръзка за изпращане на имейл

За да създадете ново съобщение до конкретен получател, посочете имейл адрес в този формат:

"mailto:email_address"

Например:

=HYPERLINK("mailto:[email protected]", "Изпратете ни имейл")

Горната формула добавя хипервръзка, озаглавена "Изпратете ни имейл", и щракването върху връзката създава ново съобщение до нашия екип за поддръжка.

Vlookup и създайте хипервръзка към първото съвпадение

Когато работите с големи масиви от данни, често може да се окажете в ситуация, в която трябва да потърсите определена стойност и да върнете съответните данни от друга колона. За тази цел се използва или функцията VLOOKUP, или по-мощната комбинация INDEX MATCH.

Но какво става, ако искате не само да извлечете съответстваща стойност, но и да преминете към позицията на тази стойност в изходния набор от данни, за да разгледате други детайли в същия ред? Това може да стане с помощта на функцията Excel HYPERLINK с известна помощ от CELL, INDEX и MATCH.

Общата формула за създаване на хипервръзка към първото съвпадение е следната:

За да видите горната формула в действие, разгледайте следния пример. Предполагаме, че имате списък с продавачи в колона А и продадени продукти в колона В. Целта ви е да извлечете първия продукт, продаден от даден продавач, и да направите хипервръзка към някоя клетка в този ред, за да можете да прегледате всички други подробности, свързани с тази конкретна поръчка.

Когато стойността за търсене е в клетка E2, списъкът на доставчиците (диапазон за търсене) е в A2:A10, а списъкът на продуктите (диапазон за връщане) е в C2:C10, формулата придобива следната форма:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Както е показано на екранната снимка по-долу, формулата извлича съвпадащата стойност и я превръща в хипервръзка, върху която може да се кликне и която насочва потребителя към позицията на първото съвпадение в оригиналния набор от данни.

Ако работите с дълги редове от данни, може да е по-удобно хипервръзката да сочи към първата клетка в реда, в който е намерено съвпадение. За тази цел просто задайте диапазона на връщане в първата комбинация INDEX MATCH към колона A ($A$2:$A$10 в този пример):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Тази формула ще ви отведе до първата поява на стойността за търсене ("Adam") в набора от данни:

Как работи тази формула

Тези от вас, които са запознати с формулата INDEX MATCH като по-универсална алтернатива на Excel VLOOKUP, вероятно вече са разбрали цялостната логика.

В основата си използвате класическата комбинация INDEX MATCH, за да откриете първата поява на стойността за търсене в диапазона за търсене:

Можете да намерите подробна информация за това как работи тази формула, като последвате горната връзка. По-долу ще изложим основните моменти:

• Функцията MATCH определя позицията на " Адам " (стойност за търсене) в диапазона A2:A10 (диапазон за търсене) и връща 3.
• Резултатът от MATCH се предава на row_num аргумент на функцията INDEX, която я инструктира да върне стойността от третия ред в диапазона C2:C10 (диапазон на връщане). И функцията INDEX връща " Лимони ".

По този начин получавате friendly_name на формулата за хипервръзка.

Сега нека да изработим link_location За да получите адреса на клетката, използвайте функцията CELL("address", [reference]) с INDEX MATCH, както следва справка За да може функцията HYPERLINK да разбере, че целевата клетка се намира в текущия лист, свържете адреса на клетката със знака за паунд ("#").

Забележка. Обърнете внимание на използването на абсолютни препратки към клетките за фиксиране на диапазоните за търсене и връщане. Това е от решаващо значение, ако планирате да вмъкнете повече от една хипервръзка чрез копиране на формулата.

Как да редактирате няколко хипервръзки едновременно

Както беше споменато в началото на този урок, едно от най-полезните предимства на хипервръзките, управлявани от формула, е възможността да се редактират множество формули за хипервръзки наведнъж с помощта на функцията на Excel Замяна на всички функция.

Да речем, че искате да замените стария URL адрес на вашата компания (old-website.com) с новия (new-website.com) във всички хипервръзки на текущия лист или в цялата работна книга. За да го направите, следвайте стъпките, описани по-долу:

1. Натиснете Ctrl + H, за да отворите Замяна на в раздела Намиране и заместване диалог.
2. В дясната част на диалоговия прозорец щракнете върху Опции бутон.
3. В Открийте какво въведете текста, който искате да промените ("old-website.com" в този пример).
4. В В рамките на от падащия списък, изберете или Лист или Работна тетрадка в зависимост от това дали искате да промените хипервръзките само в текущия работен лист или във всички листове на текущата работна книга.
5. В Погледнете в от падащия списък, изберете Формули .
6. Като допълнителна предпазна мярка щракнете върху Намерете всички и Excel ще покаже списък с всички формули, съдържащи текста за търсене:

По подобен начин можете да редактирате текста на връзката (friendly_name) във всички формули за хипервръзки едновременно. Когато правите това, не забравяйте да проверите дали текстът, който трябва да бъде заменен в friendly_name не се появява никъде в link_location за да не нарушавате формулите.

Excel HYPERLINK не работи - причини и решения

Най-честата причина за неработеща формула за хипервръзка (и първото нещо, което трябва да проверите!) е несъществуващ или прекъснат път в link_location аргумент. Ако случаят не е такъв, проверете следните две неща:

1. Ако местоназначението на връзката не се отваря, когато щракнете върху хипервръзка, уверете се, че местоположението на връзката е предоставено в подходящ формат. Примери за формули за създаване на различни видове хипервръзки можете да намерите тук.
2. Ако вместо текста на връзката в клетката се появи грешка, например VALUE! или N/A, най-вероятно проблемът е в friendly_name на формулата за хипервръзка.

   Обикновено такива грешки възникват, когато friendly_name е върната от друга(и) функция(и), както в нашия пример с Vlookup и хипервръзката към първото съвпадение. В този случай грешката #N/A ще се покаже в клетката на формулата, ако стойността за търсене не е намерена в таблицата за търсене. За да предотвратите такива грешки, може да помислите за използване на функцията IFERROR, за да се покаже празен низ или някакъв удобен за потребителя текст вместо стойността на грешката.

Ето как се създават хипервръзки с помощта на функцията HYPERLINK на Excel. Благодаря ви, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Практическа работна тетрадка за изтегляне

Примери за формула на хипервръзка в Excel (.xlsx файл)