Den här handledningen förklarar grunderna för Excel-funktionen HYPERLINK och ger några tips och exempel på formler för att använda den mest effektivt.

Det finns många sätt att skapa en hyperlänk i Excel. Om du vill länka till en viss webbsida kan du helt enkelt skriva in webbadressen i en cell, trycka på Enter och Microsoft Excel omvandlar automatiskt posten till en klickbar hyperlänk. Om du vill länka till ett annat kalkylblad eller till en specifik plats i en annan Excel-fil kan du använda Hyperlänkar Om du planerar att infoga många identiska eller liknande länkar är det snabbaste sättet att använda en formel för hyperlänkar, som gör det enklare att skapa, kopiera och redigera hyperlänkar i Excel.

Excel HYPERLINK-funktionen - syntax och grundläggande användningsområden

Funktionen HYPERLINK i Excel används för att skapa en referens (genväg) som leder användaren till den angivna platsen i samma dokument eller öppnar ett annat dokument eller en annan webbsida. Genom att använda en Hyperlink-formel kan du länka till följande objekt:

• En specifik plats, t.ex. en cell eller ett namngivet område i en Excel-fil (i det befintliga arket eller i ett annat arbetsblad eller en annan arbetsbok)
• Word, PowerPoint eller annat dokument lagras på din hårddisk, i ditt lokala nätverk eller på nätet.
• Bokmärke i ett Word-dokument
• Webbplats på Internet eller intranätet
• E-postadress för att skapa ett nytt meddelande

Funktionen finns i alla versioner av Excel 365-2000. I Excel Online kan funktionen HYPERLINK endast användas för webbadresser (URL).

Syntaxen för HYPERLINK-funktionen är följande:

Var:

• Link_location (krävs) är sökvägen till den webbsida eller fil som ska öppnas.

  Link_location kan tillhandahållas som en referens till en cell som innehåller länken eller en textsträng inom citationstecken som innehåller en sökväg till en fil som lagras på en lokal enhet, en UNC-sökväg på en server eller en URL på Internet eller intranätet.

  Om den angivna länkstigen inte finns eller är bruten kommer en formel för Hyperlänkar att ge ett felmeddelande när du klickar på cellen.

• Friendly_name (valfritt) är den länktext (även kallad hopptext eller ankartext) som ska visas i en cell. Om den utelämnas visas link_location som länktext.

  Friendly_name kan anges som ett numeriskt värde, en textsträng inom citationstecken, ett namn eller en referens till en cell som innehåller länktexten.

Om du klickar på en cell med en Hyperlink-formel öppnas den fil eller webbsida som anges i formeln. link_location argument.

Nedan kan du se det enklaste exemplet på en Excel Hyperlink-formel, där A2 innehåller namn på vänskap och B2 innehåller link_location :

=HYPERLINK(B2, A2)

Resultatet kan se ut ungefär så här:

Fler formelexempel som visar andra användningsområden för Excel-funktionen HYPERLINK följer nedan.

Hur man använder HYPERLINK i Excel - exempel på formler

Vi går från teori till praktik och ska se hur du kan använda HYPERLINK-funktionen för att öppna olika dokument direkt från dina kalkylblad. Vi kommer också att diskutera en mer komplex formel där Excel HYPERLINK används i kombination med några andra funktioner för att lösa en utmanande uppgift som inte är trivial.

Hur man länkar till ark, filer, webbsidor och andra objekt

Excel-funktionen HYPERLINK gör det möjligt att infoga klickbara hyperlänkar av några olika typer beroende på vilket värde du anger för link_location argument.

Hyperlänk till ett annat arbetsblad

Om du vill infoga en hyperlänk till ett annat ark i samma arbetsbok anger du namnet på målarket föregånget av ett pundtecken (#), följt av utropstecken och målcellsreferensen, på följande sätt:

=HYPERLINK("#Sheet2!A1", "Sheet2")

Formeln ovan skapar en hyperlänk med hopptexten "Sheet2" som öppnar Sheet2 i den aktuella arbetsboken.

Om arbetsbladets namn innehåller utrymmen eller . Icke-alfabetiska tecken. måste det omslutas av enkla citattecken, så här:

=HYPERLINK("#'Prislista'!A1", "Prislista")

På samma sätt kan du skapa en hyperlänk till en annan cell i samma arbetsblad. Om du till exempel vill infoga en hyperlänk som leder dig till cell A1 i samma arbetsblad använder du en formel som liknar den här:

=HYPERLINK("#A1", "Gå till cell A1")

Hyperlänka till en annan arbetsbok

Om du vill skapa en hyperlänk till en annan arbetsbok måste du ange fullständig sökväg till målarbetsboken i följande format:

"Drive:\Folder\Workbook.xlsx"

Till exempel:

=HYPERLINK("D:\Source data\Book3.xlsx", "Book3")

Om du vill hamna på ett specifikt ark och till och med i en specifik cell använder du det här formatet:

"[Drive:\Folder\Workbook.xlsx]Sheet!Cell"

Om du till exempel vill lägga till en hyperlänk med titeln "Bok3" som öppnar Blad2 i Bok3 som är lagrad i Källdata mapp på enhet D, använd den här formeln:

=HYPERLINK("[D:\Source data\Book3.xlsx]Sheet2!A1", "Book3")

Om du planerar att flytta dina arbetsböcker till en annan plats inom kort kan du skapa en relativ länk på följande sätt:

=HYPERLINK("Källdata\Book3.xlsx", "Book3")

När du flyttar filerna fortsätter den relativa hyperlänken att fungera så länge den relativa sökvägen till målarbetsboken är oförändrad. Mer information finns i Absoluta och relativa hyperlänkar i Excel.

Hyperlänk till ett namngivet område

Om du gör en hyperlänk till en namn på arbetsbladnivå inkludera den fullständiga sökvägen till målnamnet:

"[Drive:\Folder\Workbook.xlsx]Sheet!Name"

Om du till exempel vill infoga en länk till ett intervall som heter "Source_data" och som är lagrat på Blad1 i Bok1, använder du den här formeln:

=HYPERLINK("[D:\Excel-filer\Book1.xlsx]Sheet1!Source_data", "Source data")

Om du hänvisar till en namn på arbetsboksnivå behöver arkets namn inte anges, till exempel:

=HYPERLINK("[D:\Excel-filer\Book1.xlsx]Source_data", "Source data")

Hyperlänk för att öppna en fil som är lagrad på en hårddisk

Om du vill skapa en länk som öppnar ett annat dokument anger du fullständig sökväg till det dokumentet i detta format:

"Drive:\Folder\File_name.extension"

Om du till exempel vill öppna Word-dokumentet som heter Prislista som lagras i Word-filer mapp på enhet D använder du följande formel:

=HYPERLINK("D:\Word files\Price list.docx", "Prislista")

Hyperlänk till ett bokmärke i ett Word-dokument

Om du vill skapa en hyperlänk till en specifik plats i ett Word-dokument, omsluter du dokumentets sökväg med [hakparenteser] och använder en bokmärke för att ange den plats du vill navigera till.

Följande formel lägger till exempel till en hyperlänk till bokmärket som heter Priser för abonnemang i Prislista.docx:

=HYPERLINK("[D:\Word files\Price list.docx]Subscription_prices", "Prislista")

Hyperlänk till en fil på en nätverksenhet

Om du vill öppna en fil som finns lagrad i ditt lokala nätverk anger du sökvägen till filen i UNC-formatet (Universal Naming Convention) där dubbla backslashes används före serverns namn, till exempel så här:

"\\Server_name\Folder\File_name.extension"

Nedanstående formel skapar en hyperlänk med titeln "Prislista" som öppnar Prislista.xlsx arbetsbok som lagras på SERVER1 på Svetlana mapp:

=HYPERLINK("\\SERVER1\Svetlana\Prislista.xlsx", "Prislista")

Öppna en Excel-fil på en Särskilt arbetsblad. , ange sökvägen till filen inom [hakparenteser] och inkludera arkets namn följt av ett utropstecken (!) och den refererade cellen:

=HYPERLINK("[\\SERVER1\Svetlana\Prislista.xlsx]Sheet4!A1", "Prislista")

Hyperlänk till en webbsida

Om du vill skapa en hyperlänk till en webbsida på Internet eller intranätet anger du dess URL inom citationstecken, så här:

=HYPERLINK("//www.ablebits.com", "Gå till Ablebits.com")

Ovanstående formel infogar en hyperlänk med titeln "Go to Ablebits.com", som öppnar hemsidan på vår webbplats.

Hyperlänk för att skicka ett e-postmeddelande

Om du vill skapa ett nytt meddelande till en specifik mottagare anger du en e-postadress i det här formatet:

"mailto:email_address"

Till exempel:

=HYPERLINK("mailto:[email protected]", "Skicka oss ett e-postmeddelande")

Formeln ovan lägger till en hyperlänk med titeln "Skicka oss ett e-postmeddelande", och om du klickar på länken skapas ett nytt meddelande till vårt supportteam.

Vlookup och skapa en hyperlänk till den första matchningen

När du arbetar med stora datamängder kan du ofta hamna i en situation där du behöver söka upp ett specifikt värde och återge motsvarande data från en annan kolumn. För detta använder du antingen VLOOKUP-funktionen eller en mer kraftfull kombination av INDEX MATCH.

Men vad händer om du inte bara vill ta fram ett matchande värde utan också hoppa till positionen för det värdet i källdatasetet för att titta på andra detaljer i samma rad? Detta kan göras med hjälp av Excel-funktionen HYPERLINK med hjälp av CELL, INDEX och MATCH.

Den generiska formeln för att skapa en hyperlänk till den första matchningen är följande:

Om du vill se hur formeln ovan fungerar kan du ta följande exempel: Anta att du har en lista med leverantörer i kolumn A och sålda produkter i kolumn C. Du vill ta fram den första produkten som sålts av en viss leverantör och skapa en hyperlänk till en cell i den raden så att du kan se alla andra uppgifter som är kopplade till den aktuella beställningen.

Med uppslagsvärdet i cell E2, leverantörslistan (uppslagsintervall) i A2:A10 och produktlistan (returintervall) i C2:C10 får formeln följande form:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Som visas i skärmdumpen nedan tar formeln fram det matchande värdet och omvandlar det till en klickbar hyperlänk som leder användaren till den första matchningen i den ursprungliga datamängden.

Om du arbetar med långa datarader kan det vara mer praktiskt att låta hyperlänken peka på den första cellen i raden där matchningen hittas. För detta ställer du helt enkelt in returintervallet i den första INDEX MATCH-kombinationen till kolumn A ($A$2:$A$10 i det här exemplet):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Formeln tar dig till den första förekomsten av uppslagsvärdet ("Adam") i datasetet:

Hur denna formel fungerar

De av er som är bekanta med INDEX MATCH-formeln som ett mer mångsidigt alternativ till Excel VLOOKUP har förmodligen redan förstått den övergripande logiken.

I grunden använder du den klassiska kombinationen INDEX MATCH för att hitta den första förekomsten av uppslagsvärdet i uppslagsintervallet:

Du hittar alla detaljer om hur denna formel fungerar genom att följa länken ovan. Nedan beskriver vi de viktigaste punkterna:

• Funktionen MATCH bestämmer positionen för " Adam " (uppslagsvärde) i intervallet A2:A10 (uppslagsintervall) och returnerar 3.
• Resultatet av MATCH skickas till row_num argumentet för INDEX-funktionen som instruerar den att returnera värdet från den tredje raden i intervallet C2:C10 (returintervall). Och INDEX-funktionen returnerar " Citroner ".

På så sätt får du den namn på vänskap argumentet i din Hyperlink-formel.

Låt oss nu räkna ut link_location , dvs. den cell som hyperlänken ska peka på. För att få fram celladressen använder du funktionen CELL("address", [reference]) med INDEX MATCH som referens För att HYPERLINK-funktionen ska veta att målcellen finns i det aktuella arket, sammanfoga celladressen med pundetecknet ("#").

Observera att du använder absoluta cellreferenser för att fastställa uppslags- och returintervallen. Detta är viktigt om du planerar att infoga mer än en hyperlänk genom att kopiera formeln.

Hur man redigerar flera hyperlänkar samtidigt

Som vi nämnde i början av den här handledningen är en av de mest användbara fördelarna med formelstyrda hyperlänkar möjligheten att redigera flera Hyperlink-formler på en gång genom att använda Excels Ersätt alla funktion.

Låt oss säga att du vill ersätta ditt företags gamla URL (old-website.com) med den nya (new-website.com) i alla hyperlänkar på det aktuella arket eller i hela arbetsboken. För att göra det följer du stegen nedan:

1. Tryck på Ctrl + H för att öppna Ersätt på fliken Hitta och ersätta dialog.
2. I den högra delen av dialogrutan klickar du på Alternativ knapp.
3. I Hitta vad och skriv den text som du vill ändra ("old-website.com" i det här exemplet).
4. I Inom i rullgardinslistan, välj antingen Ark eller . Arbetsbok beroende på om du vill ändra hyperlänkar endast på det aktuella arbetsbladet eller på alla ark i den aktuella arbetsboken.
5. I Titta in i rullgardinslistan, välj Formler .
6. Som en extra försiktighetsåtgärd bör du klicka på Hitta alla så visar Excel en lista över alla formler som innehåller söktexten:

På samma sätt kan du redigera länktexten (friendly_name) i alla Hyperlink-formler samtidigt. När du gör det ska du kontrollera att den text som ska ersättas i namn på vänskap inte förekommer någonstans i link_location så att du inte bryter mot formlerna.

Excel HYPERLINK fungerar inte - orsaker och lösningar

Den vanligaste orsaken till att en hyperlänkformel inte fungerar (och det första du bör kontrollera!) är en obefintlig eller bruten sökväg i link_location Om så inte är fallet bör du kontrollera följande två saker:

1. Om länken inte öppnas när du klickar på en hyperlänk, kontrollera att länken är korrekt formaterad. Formelexempel för att skapa olika typer av hyperlänkar finns här.
2. Om det i stället för länktexten visas ett fel som VALUE! eller N/A i en cell, är det troligen problemet med namn på vänskap argumentet i din Hyperlink-formel.

   Sådana fel uppstår vanligtvis när namn på vänskap returneras av någon annan funktion, som i vårt exempel med Vlookup och hyperlänken till den första matchningen. I det här fallet visas felet #N/A i formelcellen om uppslagsvärdet inte hittas i uppslagstabellen. För att förhindra sådana fel kan du överväga att använda funktionen IFERROR för att visa en tom sträng eller någon användarvänlig text i stället för felvärdet.

Så här skapar du hyperlänkar med hjälp av Excel-funktionen HYPERLINK. Tack för att du läste och hoppas att vi ses på vår blogg nästa vecka!

Arbetsbok för övning för nedladdning

Exempel på Excel-formler för hyperlänkar (.xlsx-fil)