Tutorial ini menjelaskan dasar-dasar fungsi HYPERLINK Excel dan memberikan beberapa tip dan contoh rumus untuk menggunakannya dengan paling efisien.

Untuk menautkan ke halaman web tertentu, Anda cukup mengetikkan URL-nya di sel, tekan Enter, dan Microsoft Excel akan secara otomatis mengubah entri tersebut menjadi hyperlink yang dapat diklik. Untuk menautkan ke lembar kerja lain atau lokasi tertentu di file Excel lain, Anda dapat menggunakan perintah Hyperlink Jika Anda berencana untuk memasukkan banyak tautan yang identik atau serupa, cara tercepat adalah dengan menggunakan rumus Hyperlink, yang membuatnya lebih mudah untuk membuat, menyalin, dan mengedit hyperlink di Excel.

Fungsi HYPERLINK Excel - sintaks dan penggunaan dasar

Fungsi HYPERLINK di Excel digunakan untuk membuat referensi (pintasan) yang mengarahkan pengguna ke lokasi yang ditentukan dalam dokumen yang sama atau membuka dokumen atau halaman web lain. Dengan menggunakan rumus Hyperlink, Anda dapat menautkan ke item berikut:

• Tempat tertentu seperti sel atau rentang bernama dalam sebuah File Excel (di lembar yang ada atau di lembar kerja atau buku kerja lain)
• Word, PowerPoint atau lainnya dokumen disimpan pada hard disk drive Anda, jaringan lokal atau online
• Bookmark dalam dokumen Word
• Halaman web di Internet atau intranet
• Alamat email untuk membuat pesan baru

Fungsi ini tersedia di semua versi Excel 365 - 2000. Di Excel Online, fungsi HYPERLINK hanya dapat digunakan untuk alamat web (URL).

Sintaks fungsi HYPERLINK adalah sebagai berikut:

Di mana:

• Link_lokasi (wajib) adalah path ke halaman web atau file yang akan dibuka.

  Link_lokasi dapat diberikan sebagai referensi ke sel yang berisi tautan atau sebuah string teks diapit tanda kutip yang berisi jalur ke file yang disimpan di drive lokal, jalur UNC di server, atau URL di Internet atau intranet.

  Jika jalur tautan yang ditentukan tidak ada atau rusak, rumus Hyperlink akan menimbulkan kesalahan saat Anda mengklik sel.

• Friendly_name (opsional) adalah teks tautan (alias teks lompat atau teks jangkar) yang akan ditampilkan dalam sel. Jika dihilangkan, link_location ditampilkan sebagai teks tautan.

  Friendly_name dapat diberikan sebagai nilai numerik, string teks yang diapit tanda kutip, nama, atau referensi ke sel yang berisi teks tautan.

Mengklik sel dengan formula Hyperlink akan membuka file atau halaman web yang ditentukan di dalam sel tersebut. link_lokasi argumen.

Di bawah ini, Anda bisa melihat contoh paling sederhana dari rumus Hyperlink Excel, di mana A2 berisi friendly_name dan B2 berisi link_lokasi :

=HYPERLINK(B2, A2)

Hasilnya mungkin terlihat seperti ini:

Lebih banyak contoh rumus yang mendemonstrasikan penggunaan lain dari fungsi HYPERLINK Excel mengikuti di bawah ini.

Cara menggunakan HYPERLINK di Excel - contoh rumus

Beralih dari teori ke praktik, mari kita lihat bagaimana Anda dapat menggunakan fungsi HYPERLINK untuk membuka berbagai dokumen langsung dari lembar kerja Anda. Kami juga akan membahas rumus yang lebih kompleks di mana Excel HYPERLINK digunakan dalam kombinasi dengan beberapa fungsi lain untuk menyelesaikan tugas menantang yang tidak sepele.

Cara menautkan ke sheet, file, halaman web dan item lainnya

Fungsi Excel HYPERLINK memungkinkan Anda untuk menyisipkan hyperlink yang dapat diklik dari beberapa jenis yang berbeda tergantung pada nilai apa yang Anda berikan ke link_lokasi argumen.

Hyperlink ke lembar kerja lain

Untuk menyisipkan hyperlink ke sheet berbeda di buku kerja yang sama, berikan nama sheet target yang didahului oleh tanda pound (#), dan diikuti oleh tanda seru dan referensi sel target, seperti ini:

=HYPERLINK ("#Sheet2!A1", "Sheet2")

Rumus di atas membuat hyperlink dengan teks lompat "Sheet2" yang membuka Sheet2 di buku kerja saat ini.

Jika nama lembar kerja mencakup ruang atau karakter non-alfabetis , harus diapit oleh tanda kutip tunggal, seperti ini:

=HYPERLINK("#'Daftar harga'!A1", "Daftar harga")

Dengan cara yang sama, Anda dapat membuat hyperlink ke sel lain di lembar yang sama. Misalnya, untuk menyisipkan hyperlink yang akan membawa Anda ke sel A1 di lembar kerja yang sama, gunakan rumus yang mirip dengan ini:

=HYPERLINK ("#A1", "Pergi ke sel A1")

Hyperlink ke buku kerja yang berbeda

Untuk membuat hyperlink ke buku kerja lain, Anda perlu menentukan jalur penuh ke buku kerja target dalam format berikut ini:

"Drive:\Folder\Workbook.xlsx"

Contohnya:

=HYPERLINK("D:\Sumber data\Book3.xlsx", "Book3")

Untuk mendarat pada lembar tertentu dan bahkan dalam sel tertentu, gunakan format ini:

"[Drive: \ Folder \ Workbook.xlsx] Sheet! Sel"

Contohnya, untuk menambahkan hyperlink berjudul "Book3" yang membuka Sheet2 dalam Book3 yang tersimpan di dalam Sumber data folder pada drive D, gunakan rumus ini:

=HYPERLINK("[D:\Sumber data\Book3.xlsx]Sheet2!A1", "Book3")

Jika Anda berencana untuk segera memindahkan buku kerja Anda ke lokasi lain, Anda bisa membuat link relatif seperti ini:

=HYPERLINK ("Sumber data\Book3.xlsx", "Book3")

Saat Anda memindahkan file, hyperlink relatif akan terus berfungsi selama jalur relatif ke buku kerja target tetap tidak berubah. Untuk informasi lebih lanjut, silakan lihat Hyperlink absolut dan relatif di Excel.

Hyperlink ke rentang bernama

Jika Anda membuat hyperlink ke nama tingkat lembar kerja , termasuk jalur lengkap ke nama target:

"[Drive:\Folder\Workbook.xlsx] Sheet! Nama"

Misalnya, untuk menyisipkan tautan ke rentang bernama "Source_data" yang disimpan di Sheet1 di Book1, gunakan rumus ini:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Sheet1!Source_data", "Source data")

Jika Anda merujuk ke nama tingkat buku kerja , nama sheet tidak perlu disertakan, misalnya:

=HYPERLINK("[D:\Excel files\Book1.xlsx]Source_data", "Source data")

Hyperlink untuk membuka file yang tersimpan pada drive hard disk

Untuk membuat tautan yang akan membuka dokumen lain, tentukan jalur penuh ke dokumen itu dalam format ini:

"Drive:\Folder\Nama_file.extension"

Contohnya, untuk membuka dokumen Word bernama Daftar harga yang disimpan di dalam File kata folder pada drive D, Anda menggunakan rumus berikut ini:

=HYPERLINK("D:\Word files\Daftar harga.docx", "Daftar harga")

Hyperlink ke bookmark dalam dokumen Word

Untuk membuat hyperlink ke lokasi tertentu dalam dokumen Word, apit jalur dokumen dalam [tanda kurung siku] dan gunakan penanda buku untuk menentukan lokasi yang ingin Anda navigasikan.

Contohnya, rumus berikut ini menambahkan hyperlink ke bookmark bernama Harga_langganan dalam Daftar harga.docx:

=HYPERLINK("[D:\Word files\Daftar harga.docx]Harga_langganan", "Daftar harga")

Hyperlink ke file pada drive jaringan

Untuk membuka file yang tersimpan di jaringan lokal Anda, berikan path ke file tersebut dalam format Universal Naming Convention (UNC) yang menggunakan backslash ganda untuk mendahului nama server, seperti ini:

"\\Nama_Server\Nama_Folder\Nama_File.extension"

Rumus di bawah ini menciptakan hyperlink berjudul "Price list" yang akan membuka Daftar harga.xlsx buku kerja yang disimpan pada SERVER1 di Svetlana folder:

=HYPERLINK("\\SERVER1\Svetlana\Daftar harga.xlsx", "Daftar harga")

Untuk membuka file Excel di a lembar kerja khusus , apit jalur ke file dalam [tanda kurung siku] dan sertakan nama sheet yang diikuti dengan tanda seru (!) dan sel yang direferensikan:

=HYPERLINK("[\\SERVER1\Svetlana\Daftar harga.xlsx]Sheet4!A1", "Daftar harga")

Hyperlink ke halaman web

Untuk membuat hyperlink ke halaman web di Internet atau intranet, sediakan URL-nya yang diapit oleh tanda kutip, seperti ini:

=HYPERLINK("//www.ablebits.com", "Pergi ke Ablebits.com")

Rumus di atas menyisipkan hyperlink, berjudul "Go to Ablebits.com", yang membuka halaman beranda situs web kami.

Hyperlink untuk mengirim email

Untuk membuat pesan baru ke penerima tertentu, berikan alamat email dalam format ini:

"mailto:email_address"

Contohnya:

=HYPERLINK("mailto:[email protected]", "Kirimkan email kepada kami")

Rumus di atas menambahkan hyperlink berjudul "Kirimkan email kepada kami", dan mengklik tautan tersebut akan membuat pesan baru ke tim dukungan kami.

Vlookup dan buat hyperlink ke pertandingan pertama

Saat bekerja dengan dataset besar, Anda mungkin sering menemukan diri Anda dalam situasi ketika Anda perlu mencari nilai tertentu dan mengembalikan data yang sesuai dari kolom lain. Untuk ini, Anda menggunakan fungsi VLOOKUP atau kombinasi INDEX MATCH yang lebih kuat.

Tetapi bagaimana jika Anda tidak hanya ingin menarik nilai yang cocok tetapi juga melompat ke posisi nilai itu di dataset sumber untuk melihat detail lain di baris yang sama? Ini dapat dilakukan dengan menggunakan fungsi HYPERLINK Excel dengan beberapa bantuan dari CELL, INDEX dan MATCH.

Rumus umum untuk membuat hyperlink ke pertandingan pertama adalah sebagai berikut:

Untuk melihat rumus di atas beraksi, pertimbangkan contoh berikut. Misalkan, Anda memiliki daftar vendor di kolom A, dan produk yang terjual di kolom C. Anda bertujuan untuk menarik produk pertama yang dijual oleh vendor tertentu dan membuat hyperlink ke beberapa sel di baris itu sehingga Anda dapat meninjau semua detail lain yang terkait dengan pesanan tertentu.

Dengan nilai pencarian di sel E2, daftar vendor (rentang pencarian) di A2: A10, dan daftar produk (rentang pengembalian) di C2: C10, rumusnya mengambil bentuk berikut:

=HYPERLINK("#"&CELL("address", INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0))))

Seperti yang ditunjukkan pada gambar di bawah ini, rumus menarik nilai yang cocok dan mengubahnya menjadi hyperlink yang dapat diklik yang mengarahkan pengguna ke posisi kecocokan pertama dalam kumpulan data asli.

Jika Anda bekerja dengan baris data yang panjang, mungkin lebih nyaman untuk mengarahkan hyperlink ke sel pertama di baris tempat kecocokan ditemukan. Untuk ini, Anda cukup mengatur rentang pengembalian dalam kombinasi INDEX MATCH pertama ke kolom A ($ A $ 2: $ A $ 10 dalam contoh ini):

=HYPERLINK("#"&CELL("address", INDEX($A$2:$A$10, MATCH($E2,$A$2:$A$10,0))), INDEX($C$2:$C$10, MATCH($E2,$A$2:$A$10,0)))

Rumus ini akan membawa Anda ke kemunculan pertama dari nilai pencarian ("Adam") dalam dataset:

Bagaimana formula ini bekerja

Bagi kamu yang sudah familiar dengan rumus INDEX MATCH sebagai alternatif yang lebih serbaguna dari VLOOKUP Excel, mungkin sudah mengetahui logika keseluruhannya.

Pada intinya, Anda menggunakan kombinasi INDEX MATCH klasik untuk menemukan kemunculan pertama dari nilai pencarian dalam kisaran pencarian:

Anda bisa menemukan detail lengkap mengenai cara kerja formula ini dengan mengikuti tautan di atas. Di bawah ini, kami akan menguraikan poin-poin penting:

• Fungsi MATCH menentukan posisi " Adam " (nilai pencarian) dalam rentang A2:A10 (rentang pencarian), dan mengembalikan 3.
• Hasil dari MATCH diteruskan ke row_num argumen fungsi INDEX yang menginstruksikannya untuk mengembalikan nilai dari baris ke-3 dalam rentang C2: C10 (rentang pengembalian). Dan fungsi INDEX mengembalikan " Lemon ".

Dengan cara ini, Anda mendapatkan friendly_name argumen dari rumus Hyperlink Anda.

Sekarang, mari kita bekerja link_lokasi Untuk mendapatkan alamat sel, Anda menggunakan fungsi CELL ("address", [reference]) dengan INDEX MATCH sebagai referensi Agar fungsi HYPERLINK mengetahui bahwa sel target berada di sheet saat ini, gabungkan alamat sel dengan karakter pound ("#").

Catatan Harap perhatikan penggunaan referensi sel absolut untuk memperbaiki pencarian dan mengembalikan rentang. Ini penting jika Anda berencana untuk memasukkan lebih dari satu hyperlink dengan menyalin rumus.

Cara mengedit beberapa hyperlink sekaligus

Seperti yang disebutkan di awal tutorial ini, salah satu manfaat yang paling berguna dari hyperlink berbasis rumus adalah kemampuan untuk mengedit beberapa rumus Hyperlink dalam sekali jalan dengan menggunakan Excel Ganti Semua fitur.

Katakanlah Anda ingin mengganti URL lama perusahaan Anda (old-website.com) dengan yang baru (new-website.com) di semua hyperlink pada sheet saat ini atau di seluruh workbook. Untuk menyelesaikannya, ikuti langkah-langkah yang diuraikan di bawah ini:

1. Tekan Ctrl + H untuk membuka Ganti tab dari Temukan dan Ganti dialog.
2. Di bagian kanan kotak dialog, klik tombol Opsi tombol.
3. Dalam Temukan apa yang kotak, ketik teks yang ingin Anda ubah ("old-website.com" dalam contoh ini).
4. Dalam Dalam daftar drop-down, pilih salah satu Lembar atau Buku Kerja tergantung pada apakah Anda ingin mengubah hyperlink pada lembar kerja saat ini saja atau di semua lembar buku kerja saat ini.
5. Dalam Lihatlah ke dalam daftar drop-down, pilih Rumus .
6. Sebagai tindakan pencegahan ekstra, klik tombol Temukan Semua tombol pertama, dan Excel akan menampilkan daftar semua rumus yang berisi teks pencarian:

Dengan cara yang sama, Anda dapat mengedit teks tautan (friendly_name) di semua rumus Hyperlink pada saat yang bersamaan. Saat melakukannya, pastikan untuk memeriksa bahwa teks yang akan diganti di friendly_name tidak muncul di mana pun dalam link_lokasi sehingga Anda tidak akan merusak rumus.

HYPERLINK Excel tidak berfungsi - alasan dan solusi

Alasan paling umum untuk formula Hyperlink tidak berfungsi (dan hal pertama yang harus Anda periksa!) adalah jalur yang tidak ada atau rusak di dalam link_lokasi Jika tidak demikian, periksa dua hal berikut ini:

1. Jika tujuan tautan tidak terbuka ketika Anda mengklik hyperlink, pastikan lokasi tautan disediakan dalam format yang tepat. Contoh rumus untuk membuat jenis hyperlink yang berbeda dapat ditemukan di sini.
2. Jika alih-alih teks tautan, kesalahan seperti VALUE! atau N/A muncul dalam sel, kemungkinan besar masalahnya adalah pada friendly_name argumen dari rumus Hyperlink Anda.

   Biasanya, kesalahan tersebut terjadi apabila friendly_name dikembalikan oleh beberapa fungsi lain, seperti dalam Vlookup dan hyperlink ke contoh kecocokan pertama. Dalam kasus ini, kesalahan # N / A akan muncul di sel rumus jika nilai pencarian tidak ditemukan di dalam tabel pencarian. Untuk mencegah kesalahan seperti itu, Anda dapat mempertimbangkan untuk menggunakan fungsi IFERROR untuk menampilkan string kosong atau teks yang ramah pengguna alih-alih nilai kesalahan.

Beginilah cara Anda membuat hyperlink menggunakan fungsi Excel HYPERLINK. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Contoh rumus Hyperlink Excel (file .xlsx)