این آموزش راه های مختلف برای افزایش سن از تولد در اکسل را نشان می دهد. شما چندین فرمول برای محاسبه سن به عنوان تعدادی سال کامل، دریافت سن دقیق بر حسب سال، ماه و روز در تاریخ امروز یا یک تاریخ خاص یاد خواهید گرفت.

هیچ تابع خاصی برای محاسبه وجود ندارد. سن در اکسل، با این حال چند راه مختلف برای تبدیل تاریخ تولد به سن وجود دارد. این آموزش مزایا و معایب هر روش را توضیح می دهد، نشان می دهد که چگونه می توان یک فرمول محاسبه سن کامل در اکسل ایجاد کرد و آن را برای حل برخی از وظایف خاص بهینه سازی کرد.

چگونه سن را از تاریخ محاسبه کنیم. تولد در اکسل

در زندگی روزمره، سؤال " چند ساله هستید؟ " معمولاً به پاسخی اشاره می کند که نشان می دهد چند سال زندگی کرده اید. در مایکروسافت اکسل، می توانید فرمولی برای محاسبه سن دقیق بر حسب ماه، روز، ساعت و حتی دقیقه ایجاد کنید. اما بیایید سنتی باشیم و ابتدا یاد بگیریم که چگونه سن را از DOB بر حسب سال محاسبه کنیم.

فرمول پایه اکسل برای سن بر حسب سال

به طور معمول چگونه سن افراد را تشخیص می دهید؟ به سادگی با کم کردن تاریخ تولد از تاریخ فعلی. این فرمول سن متعارف را می توان در اکسل نیز استفاده کرد.

با فرض اینکه تاریخ تولد در سلول B2 باشد، فرمول محاسبه سن بر حسب سال به شرح زیر است:

=(TODAY()-B2)/365

قسمت اول فرمول (TODAY()-B2) تفاوت بین تاریخ فعلی و تاریخ تولد را روز برمی گرداند و سپس آن را تقسیم می کنید.مرجع سلول یا تاریخ در قالب mm/dd/yyyy.

انجام شد!

> 0>همانطور که ممکن است متوجه شده باشید، فرمول ایجاد شده توسط ماشین حساب سن اکسل ما پیچیده تر از فرمول هایی است که تاکنون در مورد آن صحبت کردیم، اما برای واحدهای زمانی مفرد و جمع مانند "روز" و "روز" استفاده می کند.

اگر می خواهید از شر واحدهای صفر مانند "0 روز" خلاص شوید، کادر انتخاب عدم نمایش واحدهای صفر را انتخاب کنید:

اگر کنجکاو هستید که این ماشین حساب سن را آزمایش کنید و همچنین 60 افزونه دیگر برای اکسل را که صرفه جویی در زمان می کنند را کشف کنید، می توانید یک نسخه آزمایشی از Ultimate Suite ما را در پایان دانلود کنید. این پست.

نحوه برجسته کردن سنین خاص (زیر یا بالای یک سن خاص)

در برخی شرایط، ممکن است نه تنها نیاز به محاسبه سن در اکسل داشته باشید، بلکه سلول هایی را که حاوی سنین کمتر یا بالاتر از یک سن خاص هستند نیز برجسته کنید.

اگر فرمول محاسبه سن شما تعداد سال‌های کامل را برمی‌گرداند، سپس می‌توانید یک قاعده قالب‌بندی شرطی منظم بر اساس فرمول ساده‌ای مانند موارد زیر ایجاد کنید:

• برای برجسته کردن سن‌های مساوی یا بزرگ‌تر از18: =$C2>=18
• برای برجسته کردن سنین زیر 18 سال: =$C2<18

جایی که C2 بالاترین سلول در ستون Age است (بدون شامل سربرگ ستون).

اما اگر فرمول شما سن را بر حسب سال و ماه، یا سال، ماه و روز نمایش دهد، چه؟ در این مورد، شما باید یک قانون بر اساس فرمول DATEDIF ایجاد کنید که سن را از تاریخ تولد به سال محاسبه می کند.

با فرض اینکه تاریخ تولد در ستون B باشد که با ردیف 2 شروع می شود، فرمول ها به شرح زیر است:

• برای برجسته کردن سن زیر 18 (زرد): =DATEDIF($B2, TODAY(),"Y")<18
• برای برجسته کردن سن بین 18 تا 65 (سبز): =AND(DATEDIF($B2, TODAY(),"Y")>=18, DATEDIF($B2, TODAY(),"Y")<=65)
• برای برجسته کردن سن بیش از 65 (آبی): =DATEDIF($B2, TODAY(),"Y")>65

برای ایجاد قوانین بر اساس فرمول های بالا، سلول ها یا کل ردیف هایی را که می خواهید برجسته کنید انتخاب کنید. ، به گروه صفحه اصلی > Styles بروید و قالب بندی شرطی > قانون جدید… > استفاده را کلیک کنید فرمولی برای تعیین اینکه کدام سلول ها را قالب بندی کنید .

مراحل دقیق را می توانید در اینجا بیابید: نحوه ایجاد یک قانون قالب بندی شرطی بر اساس فرمول.

به این ترتیب سن را در اکسل محاسبه می کنید. امیدوارم یادگیری فرمول ها برای شما آسان بوده باشد و آنها را در کاربرگ های خود امتحان کنید. از اینکه خواندید متشکریم و امیدواریم هفته آینده شما را در وبلاگ خود ببینیم!

بارگیری های موجود

نمونه های محاسبه سن اکسل (فایل xlsx.)

Ultimate Suite 14 روزه کاملاً -نسخه کاربردی (فایل exe)

فرمول واضح است و به راحتی قابل یادآوری است، با این حال، یک مشکل کوچک وجود دارد. در بیشتر موارد، یک عدد اعشاری را همانطور که در تصویر زیر نشان داده شده است، برمی گرداند.

برای نمایش تعداد سال های کامل، از تابع INT برای گرد کردن اعشار به پایین استفاده کنید. نزدیکترین عدد صحیح:

=INT((TODAY()-B2)/365)

مشکلات: استفاده از این فرمول سن در اکسل نتایج بسیار دقیقی را ایجاد می کند، اما بی عیب نیست. تقسیم بر میانگین تعداد روزهای یک سال در بیشتر مواقع خوب عمل می کند، اما گاهی اوقات سن را اشتباه می کند. به عنوان مثال، اگر فردی در 29 فوریه متولد شده باشد و امروز 28 فوریه است، فرمول فرد را یک روز بزرگتر می کند.

به عنوان جایگزین، می توانید به جای 365 بر 365.25 تقسیم کنید زیرا هر سال چهارم دارای 366 است. روزها. با این حال، این رویکرد نیز کامل نیست. برای مثال، اگر سن کودکی را محاسبه می‌کنید که هنوز یک سال کبیسه را سپری نکرده است، تقسیم بر 365.25 نتیجه اشتباهی به دست می‌دهد.

به طور کلی، کم کردن تاریخ تولد از تاریخ فعلی در زندگی عادی است، اما رویکرد ایده آل در اکسل نیست. در ادامه این آموزش، چند تابع ویژه را یاد خواهید گرفت که سن را بدون توجه به سال محاسبه می کند.

محاسبه سن از تاریخ تولد با تابع YEARFRAC

روشی مطمئن تر برای تبدیل DOB to age در اکسل از تابع YERFRAC استفاده می کند کهکسر سال، یعنی تعداد روزهای کامل بین دو تاریخ را برمی گرداند.

نحو تابع YEARFRAC به شرح زیر است:

دو استدلال اول واضح هستند و به سختی نیاز به توضیح اضافی دارند. Basis یک آرگومان اختیاری است که مبنای شمارش روز را برای استفاده تعریف می کند.

برای ایجاد فرمول سنی کاملاً واقعی، مقادیر زیر را به تابع YEARFRAC ارائه دهید:

• Start_date - تاریخ تولد.
• End_date - TODAY() تابع برای برگرداندن تاریخ امروز.
• Basis - از مبنای 1 استفاده کنید که به اکسل می گوید تعداد واقعی روزهای ماه را بر تعداد واقعی روزهای سال تقسیم کند.

با توجه به موارد فوق، یک فرمول اکسل برای محاسبه سن از تاریخ تولد به شرح زیر است:

با فرض اینکه تاریخ تولد در سلول B2 باشد، فرمول به شکل زیر است:

=YEARFRAC(B2, TODAY(), 1)

مانند مثال قبل، نتیجه تابع YEARFRAC نیز یک عدد اعشاری است. برای رفع این مشکل، از تابع ROUNDDOWN با 0 در آخرین آرگومان استفاده کنید زیرا هیچ رقم اعشاری نمی‌خواهید.

بنابراین، در اینجا یک فرمول YEARFRAC بهبود یافته برای محاسبه سن در اکسل وجود دارد:

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

محاسبه سن در اکسل با DATEDIF

یک راه دیگر برای تبدیل تاریخ تولد به سن در اکسل استفاده از تابع DATEDIF است:

این تابع بسته به مقداری که در آرگومان unit ارائه می کنید، می تواند تفاوت بین دو تاریخ را در واحدهای زمانی مختلف مانند سال، ماه و روز برگرداند:

• Y - تعداد سالهای کامل بین تاریخ شروع و پایان را برمی‌گرداند.
• M - تعداد ماه‌های کامل بین تاریخ را برمی‌گرداند. تاریخ ها.
• D - تعداد روز بین دو تاریخ را برمی گرداند.
• YM - ماه را برمی گرداند، روزها و سال ها را نادیده می گیرد.
• MD - تفاوت را در روز ، با نادیده گرفتن ماهها و سالها برمی گرداند.
• YD - تفاوت را در روز ، با نادیده گرفتن سالها برمی گرداند.

از آنجایی که هدف ما محاسبه سن در سال است، از واحد "y" استفاده می کنیم:

در این مثال، DOB در سلول B2 است، و شما به این سلول در فرمول سن خود اشاره می کنید:

=DATEDIF(B2, TODAY(), "y")

در این مورد به تابع گرد اضافی نیاز نیست زیرا فرمول DATEDIF با t واحد "y" تعداد سالهای کامل را محاسبه می کند:

چگونه سن را از تاریخ تولد بر حسب سال، ماه و روز بدست آوریم

همانطور که مشاهده کردید ، محاسبه سن به عنوان تعداد سالهای کاملی که فرد زندگی کرده است آسان است، اما همیشه کافی نیست. اگر می خواهید سن دقیق را بدانید، یعنی چند سال، ماه و چند روز بین تاریخ تولد یک نفر و تاریخ فعلی وجود دارد، بنویسید 3توابع مختلف DATEDIF:

1. برای بدست آوردن تعداد سالها: =DATEDIF(B2, TODAY(), "Y")
2. برای بدست آوردن تعداد ماهها: =DATEDIF(B2, TODAY(), "YM")
3. برای بدست آوردن تعداد روزها: =DATEDIF(B2,TODAY(),"MD")

جایی که B2 تاریخ تولد است.

و سپس، توابع فوق را در یک فرمول به هم متصل کنید، مانند این:

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

فرمول بالا 3 عدد (سال، ماه و روز) را که در یک رشته متن به هم پیوسته اند، برمی گرداند، همانطور که در تصویر زیر نشان داده شده است:

خیلی منطقی نیست، اوه ? برای معنادارتر کردن نتایج، اعداد را با کاما جدا کنید و معنی هر مقدار را مشخص کنید:

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

در حال حاضر نتیجه بسیار بهتر به نظر می رسد:

این فرمول عالی کار می کند، اما می توانید با پنهان کردن مقادیر صفر، آن را حتی بیشتر بهبود ببخشید. برای این کار، 3 عبارت IF را اضافه کنید که 0 ها را بررسی می کند، یکی برای هر DATEDIF:

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

تصویر صفحه زیر فرمول نهایی سن اکسل را در عمل نشان می دهد - سن را به سال، ماه برمی گرداند. و روز، نمایش فقط مقادیر غیر صفر :

نکته. اگر به دنبال یک فرمول اکسل برای محاسبه سن در سال و ماه هستید، فرمول بالا را انتخاب کنید و آخرین بلوک IF(DATEDIF()) را که روز را محاسبه می کند حذف کنید.

فرمول های خاص برای محاسبه سن در اکسل

فرمول‌های محاسبه سن عمومی که در بالا توضیح داده شد در بیشتر موارد عالی عمل می‌کنند. با این حال، در برخی شرایط، ممکن است به چیزی بسیار خاص نیاز داشته باشید. البته نمی توان همه را پوشش دادو هر سناریو، اما مثال‌های زیر به شما ایده‌هایی می‌دهند که چگونه می‌توانید فرمول سن را بسته به وظیفه خاص خود تغییر دهید.

نحوه محاسبه سن در یک تاریخ خاص در اکسل

اگر می‌خواهید سن کسی را در تاریخ خاصی بدانید، از فرمول سنی DATEDIF که در بالا توضیح داده شد استفاده کنید، اما تابع TODAY() را در آرگومان دوم با تاریخ خاص جایگزین کنید.

با فرض اینکه تاریخ تولد در B1 باشد، فرمول زیر از 1 ژانویه 2020 سن را برمی گرداند:

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

برای انعطاف پذیرتر کردن فرمول سن خود، می توانید تاریخ را در برخی از سلول ها وارد کنید و به سلول فرمول خود ارجاع دهید:

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

که در آن B1 DOB است، و B2 تاریخی است که می خواهید سن را در آن محاسبه کنید.

سن را در یک معین محاسبه کنید. سال

این فرمول در مواقعی مفید است که تاریخ کامل محاسبه در آن مشخص نیست و شما فقط سال را می دانید.

فرض کنید که با یک پایگاه داده پزشکی کار می کنید و هدف این است که سن بیماران را در زمانی که آنها زیر سن دارند، پیدا کنیم آخرین معاینه پزشکی کامل را انجام داده است.

با فرض اینکه تاریخ تولد در ستون B باشد که با ردیف 3 شروع می شود، و سال آخرین معاینه پزشکی در ستون C باشد، فرمول محاسبه سن به شرح زیر است:

=DATEDIF(B3,DATE(C3, 1, 1),"y")

از آنجایی که تاریخ دقیق معاینه پزشکی تعریف نشده است، از تابع DATE با آرگومان تاریخ و ماه دلخواه استفاده می کنید، به عنوان مثال. DATE(C3, 1, 1).

Theتابع DATE سال را از سلول B3 استخراج می کند، با استفاده از اعداد ماه و روزی که شما ارائه کرده اید (در این مثال 1-Jan) یک تاریخ کامل می سازد و آن تاریخ را به DATEDIF منتقل می کند. در نتیجه، سن بیمار را از اول ژانویه یک سال خاص دریافت می‌کنید:

تاریخی را پیدا کنید که یک فرد به N سال سن می‌رسد

فرض کنید دوست شما در 8 مارس 1978 به دنیا آمده باشد. معمولاً شما به سادگی 50 سال به تاریخ تولد فرد اضافه می کنید. در اکسل، این کار را با استفاده از تابع DATE انجام می‌دهید:

=DATE(YEAR(B2) + 50, MONTH(B2), DAY(B2))

که در آن B2 تاریخ تولد است.

به‌جای کدگذاری سخت تعداد سال‌ها در فرمول، شما می توانید به سلول خاصی اشاره کنید که در آن کاربران شما می توانند هر تعداد سال را وارد کنند (F1 در تصویر زیر):

محاسبه سن از روز، ماه و سال در موارد مختلف سلول ها

وقتی تاریخ تولد به 3 سلول مختلف تقسیم می شود (به عنوان مثال سال در B3، ماه در C3 و روز در D3 است)، می توانید سن را به این ترتیب محاسبه کنید:

• دریافت کنید تاریخ تولد با استفاده از توابع DATE و DATEVALUE:

  DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)

• فرمول بالا را در DATEDIF جاسازی کنید تا سن را از تاریخ تولد بر حسب سال، ماه و روز محاسبه کنید: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

برای مثال‌های بیشتر از محاسبه تعداد روزهای قبل/بعد از تاریخ، لطفاً به نحوه محاسبه روزهای از تاریخ یا تا تاریخ در اکسل مراجعه کنید.

سن ماشین حساب در اکسل

اگر مایلید ماشین حساب خود را داشته باشیدماشین حساب سن در اکسل، می توانید با استفاده از چند فرمول مختلف DATEDIF که در زیر توضیح داده شده است، یکی بسازید. اگر ترجیح می‌دهید چرخ را دوباره اختراع نکنید، می‌توانید از ماشین‌حساب سن ایجاد شده توسط متخصصان اکسل ما استفاده کنید.

نحوه ایجاد یک ماشین حساب سن در اکسل

اکنون که می‌دانید چگونه یک ماشین حساب بسازید. فرمول سن در اکسل، می توانید یک ماشین حساب سن سفارشی بسازید، برای مثال این یکی:

توجه داشته باشید. برای مشاهده کتاب کار تعبیه‌شده، لطفاً کوکی‌های بازاریابی را مجاز کنید.

آنچه در بالا می‌بینید یک برگه آنلاین اکسل تعبیه‌شده است، بنابراین با خیال راحت تاریخ تولد خود را در سلول مربوطه وارد کنید تا در یک لحظه سن خود را دریافت کنید.

ماشین حساب از فرمول های زیر برای محاسبه سن بر اساس تاریخ تولد در سلول A3 و تاریخ امروز استفاده می کند.

• فرمول در B5 سن را بر حسب سال، ماه و روز محاسبه می کند: =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• Formula در B6 سن را بر حسب ماه محاسبه می کند: =DATEDIF($B$3,TODAY(),"m")
• Formula در B7 سن را بر حسب روز محاسبه می کند: =DATEDIF($B$3,TODAY(),"d")

اگر تجربه ای با کنترل های فرم اکسل دارید، می‌توانید گزینه‌ای برای محاسبه سن در یک تاریخ خاص اضافه کنید، مانند تصویر زیر:

برای این کار، چند دکمه گزینه اضافه کنید ( برگه برنامه‌نویس > درج > کنترلهای فرم > دکمه گزینه )، و آنها را به سلولی پیوند دهید. و سپس، یک فرمول IF/DATEDIF بنویسید تا سن را در تاریخ امروز یا در تاریخ مشخص شده توسط کاربر بدست آورید.

فرمول با موارد زیر کار می کند.منطق:

• اگر کادر گزینه تاریخ امروز انتخاب شده باشد، مقدار 1 در سلول پیوند داده شده ظاهر می شود (در این مثال I5) و فرمول سن بر اساس تاریخ امروز محاسبه می شود. : IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• اگر دکمه گزینه تاریخ خاص انتخاب شود و تاریخ در سلول B7 وارد شود، سن در تاریخ مشخص شده محاسبه می شود: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

در نهایت ، توابع بالا را درون یکدیگر قرار دهید و فرمول کامل محاسبه سن را دریافت خواهید کرد (در B9):

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

فرمول های B10 و B11 با منطق یکسانی کار می کنند. البته آنها بسیار ساده تر هستند زیرا فقط یک تابع DATEDIF را شامل می شوند تا سن را به ترتیب به تعداد ماه ها یا روزهای کامل برگرداند.

برای اطلاع از جزئیات، از شما دعوت می کنم این ماشین حساب سن اکسل را دانلود کرده و بررسی کنید. فرمول های موجود در سلول های B9:B11.

دانلود ماشین حساب سن برای اکسل

ماشین حساب سن آماده برای استفاده برای اکسل

کاربران مجموعه نهایی ما ندارند برای ایجاد زحمت در مورد ساخت ماشین حساب سن خود در اکسل - فقط چند کلیک فاصله دارد:

1. سلولی را انتخاب کنید که می خواهید فرمول سن را در آن درج کنید، به ابزارهای Ablebits<بروید. 2> برگه > تاریخ & گروه Time ، و روی Date & دکمه Time Wizard .

   

2. Date & جادوگر زمان شروع می شود و شما مستقیماً به برگه سن می روید.
3. در برگه سن ، 3 چیز وجود دارد که باید مشخص کنید:
   • داده های تولد به عنوان یک