این آموزش به شما می آموزد که چگونه با یا بدون فرمول یک میانگین را در اکسل پیدا کنید و نتایج را به هر تعداد اعشار که می خواهید گرد کنید.

در مایکروسافت اکسل یک تعداد انگشت شماری از توابع مختلف برای محاسبه میانگین برای مجموعه ای از مقادیر عددی. علاوه بر این، یک راه غیر فرمول فوری وجود دارد. در این صفحه، یک نمای کلی از تمام روش های نشان داده شده با نمونه هایی از استفاده و بهترین شیوه ها را خواهید دید. تمام توابع مورد بحث در این آموزش در هر نسخه از اکسل 365 تا اکسل 2007 کار می کنند.

متوسط ​​چیست؟

در زندگی روزمره، میانگین عددی است که بیانگر مقدار معمولی در مجموعه داده ها به عنوان مثال، اگر چند ورزشکار یک دوی 100 متر را دویده باشند، ممکن است بخواهید میانگین نتیجه را بدانید - یعنی انتظار می رود اکثر دوومیدانی ها چقدر زمان برای تکمیل مسابقه داشته باشند.

در ریاضیات، میانگین این است. مقدار میانی یا مرکزی در مجموعه ای از اعداد که با تقسیم مجموع همه مقادیر بر تعداد آنها محاسبه می شود.

در مثال فوق، با فرض اینکه ورزشکار اول مسافت را در 10.5 ثانیه طی کرده باشد، دومی نیاز دارد. 10.7 ثانیه، و سومی 11.2 ثانیه طول کشید، میانگین زمان 10.8 ثانیه خواهد بود:

(10.5+10.7+11.2)/3 = 10.8

چگونه در اکسل میانگین بدست آوریم بدون فرمول

در کاربرگ های اکسل، نیازی به انجام محاسبات دستی ندارید - توابع قدرتمند اکسل همه کارها را انجام خواهند داد.تابعی که میانگین حسابی اعداد را با نادیده گرفتن مقادیر منطقی محاسبه می کند.

نحوه گرد کردن میانگین در اکسل

هنگام محاسبه میانگین در اکسل، نتیجه اغلب یک عدد با چندین رقم اعشار است. . اگر می خواهید ارقام اعشاری کمتری نمایش دهید یا میانگین را به یک عدد صحیح گرد کنید، از یکی از راه حل های زیر استفاده کنید.

گزینه اعشاری را کاهش دهید

فقط برای گرد کردن میانگین نمایش داده شده بدون تغییر مقدار اساسی، سریعترین راه استفاده از دستور Decrease Decimal در برگه Home ، در گروه Number است. :

Format Cells کادر محاوره ای

تعداد ارقام اعشاری را می توان در کادر محاوره ای Format Cells نیز مشخص کرد. برای انجام این کار، سلول فرمول را انتخاب کنید و Ctrl + 1 را فشار دهید تا کادر گفتگوی Format Cells باز شود. سپس، به تب تعداد بروید و تعداد مکان‌هایی را که می‌خواهید در کادر مکان‌های اعشاری نشان دهید تایپ کنید.

مانند روش قبلی، این فقط تغییر می‌کند. فرمت نمایش هنگام ارجاع به سلول متوسط ​​در فرمول های دیگر، از مقدار غیر گرد اصلی در همه محاسبات استفاده می شود.

برای جزئیات کامل، لطفاً با تغییر قالب سلول، اعداد گرد را ببینید.

میانگین را با فرمول گرد کنید

برای گرد کردن خود مقدار محاسبه شده، میانگین خود را بپیچید. فرمول در یکی از توابع گرد کردن اکسل.

در اکثر مواقع، شما باید از آن استفاده کنیدتابع ROUND که از قوانین کلی ریاضی برای گرد کردن پیروی می کند. در آرگومان 1 ( عدد )، تابع AVERAGE، AVERAGEIF یا AVERAGEIFS را قرار دهید. در آرگومان دوم ( تعداد_رقم )، تعداد ارقام اعشاری برای گرد کردن میانگین را مشخص کنید.

برای مثال، برای گرد کردن میانگین به نزدیکترین عدد صحیح ، فرمول این است:

=ROUND(AVERAGE(B3:B15), 0)

برای گرد کردن میانگین به یک رقم اعشار ، این فرمولی است که باید استفاده کنید:

=ROUND(AVERAGE(B3:B15), 1)

برای گرد کردن میانگین به دو رقم اعشار ، این یکی کار خواهد کرد:

=ROUND(AVERAGE(B3:B15), 2)

نکته. برای گرد کردن، از تابع ROUNDUP استفاده کنید. برای گرد کردن - تابع ROUNDDOWN.

به این ترتیب می توانید میانگین را در اکسل انجام دهید. در زیر پیوندهایی به آموزش های مرتبط وجود دارد که در مورد موارد خاص تر میانگین بحث می کنند، امیدواریم که آنها برای شما مفید واقع شوند. ممنون که خواندید!

کتاب کار را برای دانلود تمرین کنید

محاسبه میانگین در اکسل - مثالها (فایل xlsx.)

>کار در پشت صحنه و ارائه نتیجه در کمترین زمان. قبل از بررسی دقیق توابع تخصصی، بیایید یک روش غیر فرمول ساده و سریع و شگفت‌انگیز را بیاموزیم.

برای یافتن سریع میانگین بدون فرمول، از نوار وضعیت Excel استفاده کنید:

1. انتخاب کنید سلول ها یا محدوده هایی که می خواهید میانگین بگیرید. برای انتخاب های غیر پیوسته، از کلید Ctrl استفاده کنید.
2. به نوار وضعیت در پایین پنجره اکسل نگاه کنید، که اطلاعات ضروری در مورد سلول های انتخاب شده فعلی را ارائه می دهد. یکی از مقادیری که اکسل به طور خودکار محاسبه می کند میانگین است.

نتیجه در تصویر زیر نشان داده شده است:

نحوه محاسبه میانگین به صورت دستی

در ریاضی، برای پیدا کردن میانگین حسابی یک لیست از اعداد، باید همه مقادیر را جمع کنید و سپس مجموع را بر تعداد اعداد موجود در لیست تقسیم کنید. در اکسل، این کار را می توان با استفاده از توابع SUM و COUNT به ترتیب انجام داد:

SUM( range )/COUNT( range )

برای محدوده اعداد زیر، فرمول به شرح زیر است:

=SUM(B3:B12)/COUNT(B3:B12)

همانطور که می بینید، نتیجه فرمول دقیقاً با مقدار متوسط ​​در نوار وضعیت مطابقت دارد.

در عمل، به سختی نیاز به انجام میانگین دستی در برگه های کاری خود ندارید. با این حال، ممکن است در صورت شک، بررسی مجدد نتیجه فرمول میانگین خود مفید باشد.

و اکنون، بیایید نگاهی بیندازیم که چگونه می توانید میانگین را در اکسل با استفاده از توابع خاص انجام دهید.برای این منظور طراحی شده است.

عملکرد AVERAGE - محاسبه میانگین اعداد

شما از تابع Excel AVERAGE برای به دست آوردن میانگین تمام اعداد در سلول ها یا محدوده های مشخص شده استفاده می کنید.

AVERAGE(number1, [number2], …)

که در آن number1, number2 , … مقادیر عددی هستند که می‌خواهید میانگین آنها را بیابید. حداکثر 255 آرگومان را می توان در یک فرمول گنجاند. آرگومان‌ها را می‌توان به صورت اعداد، ارجاع یا محدوده‌های نام‌گذاری شده ارائه کرد.

AVERAGE یکی از ساده‌ترین و آسان‌ترین توابع در اکسل است.

برای محاسبه میانگین اعداد، می‌توانید آنها را مستقیماً در یک فرمول تایپ کنید یا سلول‌ها یا مراجع محدوده مربوطه را تهیه کنید.

برای مثال، برای میانگین 2 محدوده و 1 سلول جداگانه در زیر، فرمول این است:

=AVERAGE(B4:B6, B8:B10, B12)

به غیر از اعداد، تابع AVERAGE Excel می تواند میانگین مقادیر عددی دیگر مانند درصد و زمان را بیابد.

فرمول Excel AVERAGE - یادداشت های استفاده

همانطور که قبلاً مشاهده کردید، استفاده از تابع AVERAGE در اکسل آسان است. با این حال، برای به دست آوردن یک نتیجه صحیح، باید به وضوح درک کنید که چه مقادیری در میانگین گنجانده شده است و چه مقادیری نادیده گرفته می شوند.

شامل:

• سلول هایی با مقادیر صفر (0)
• مقادیر منطقی TRUE و FALSE مستقیماً در لیست آرگومان ها تایپ می شوند. برای مثال، فرمول AVERAGE(TRUE، FALSE) 0.5 را برمی گرداند که میانگین 1 و 0 است.

نادیده گرفته شد:

• Emptyسلول‌ها
• رشته‌های متنی
• سلول‌های حاوی مقادیر بولی TRUE و FALSE

برای اطلاعات بیشتر، لطفاً نحوه استفاده از تابع AVERAGE در اکسل را ببینید.

عملکرد AVERAGEA - میانگین تمام سلول های غیر خالی

عملکرد Excel AVERAGEA مشابه AVERAGE است که میانگین حسابی مقادیر موجود در آرگومان های خود را محاسبه می کند. تفاوت این است که AVERAGEA شامل همه سلول‌های غیر خالی در یک محاسبه است، خواه حاوی اعداد، متن، مقادیر منطقی یا رشته‌های خالی برگردانده شده توسط توابع دیگر باشد.

AVERAGEA(value1, [value2], ...)

که در آن value1، value2، … مقادیر، آرایه ها، مراجع سلولی یا محدوده هایی هستند که می خواهید میانگین بگیرید. آرگومان اول مورد نیاز است، بقیه (تا 255) اختیاری هستند.

فرمول Excel AVERAGEA - یادداشت های استفاده

همانطور که در بالا ذکر شد، تابع AVERAGEA انواع مختلف مقادیر مانند اعداد، رشته های متنی را پردازش می کند. و ارزش های منطقی و نحوه ارزیابی آنها به این صورت است:

شامل:

• مقادیر متن 0 ارزیابی می شوند.
• رشته های با طول صفر ("") به عنوان 0 ارزیابی می شوند.
• مقدار بولی TRUE به عنوان 1 و FALSE به عنوان 0 ارزیابی می شود.

نادیده گرفته شد:

• خانه های خالی

برای مثال، فرمول زیر 1 را برمی گرداند که میانگین 2 و 0 است.

=AVERAGEA(2, FALSE)

فرمول زیر 1.5 را برمی گرداند که میانگین 2 و 1 است.

=AVERAGEA(2, TRUE)

تصویر زیر فرمول های AVERAGE و AVERAGEA اعمال شده بر روی را نشان می دهدفهرستی از مقادیر یکسان و نتایج متفاوتی که برمی‌گردانند:

عملکرد AVERAGEIF - دریافت میانگین با شرط

برای به دست آوردن میانگین تمام سلول‌ها در محدوده مشخص شده که شرایط خاصی را دارند، از تابع AVERAGEIF استفاده کنید. .

AVERAGEIF(محدوده، معیار، [محدوده_متوسط])

تابع AVERAGEIF آرگومان های زیر را دارد:

• محدوده (الزامی) - محدوده سلول ها تا بر اساس یک معیار معین آزمایش کنید.
• معیار (الزامی) - شرطی که باید برآورده شود.
• میانگین_محدوده (اختیاری) - سلولها به میانگین. اگر حذف شود، محدوده میانگین می شود.

تابع AVERAGEIF در Excel 2007 - Excel 365 موجود است. در نسخه های قبلی، می توانید فرمول AVERAGE IF خود را بسازید.

و اکنون، بیایید ببینیم چگونه می‌توانید از تابع Excel AVERAGEIF برای میانگین سلول‌ها بر اساس شرطی که مشخص می‌کنید استفاده کنید.

فرض کنید برای موضوعات مختلف در C3:C15 امتیاز دارید و می‌خواهید یک عدد پیدا کنید. میانگین نمره ریاضی این کار را می توان با فرمول زیر انجام داد:

=AVERAGEIF(B3:B15, "math", C3:C15)

به جای "Hardcoding" شرط مستقیماً در یک فرمول، می توانید آن را در یک سلول جداگانه (F3) تایپ کنید و به آن سلول مراجعه کنید. در معیارها:

=AVERAGEIF(B3:B15, F3, C3:C15)

برای مثال های بیشتر فرمول، لطفاً تابع Excel AVERAGEIF را ببینید.

عملکرد AVERAGEIFS - میانگین با معیارهای چندگانه

برای انجام میانگین با دو یا چند شرط، از همتای جمع AVERAGEIF استفاده کنید -تابع AVERAGEIFS.

AVERAGEIFS(محدوده_متوسط، محدوده_معیار1، معیار1، [محدوده_معیار2، معیار2]، ...)

این تابع دارای نحو زیر است:

• محدوده_متوسط ( مورد نیاز) - محدوده تا میانگین.
• محدوده_معیار (الزامی) - محدوده ای که باید بر اساس معیار آزمایش شود.
• معیار (لازم) - شرایطی که تعیین می کند کدام سلول ها را به طور میانگین تعیین می کند. می‌توان آن را در قالب یک عدد، عبارت منطقی، مقدار متن یا مرجع سلول ارائه کرد. عرضه شود. جفت اول لازم است، جفت های بعدی اختیاری هستند.

در اصل، شما از AVERAGEIFS مشابه AVERAGEIF استفاده می کنید، با این تفاوت که بیش از یک شرط را می توان در یک فرمول آزمایش کرد.

فرض کنید برخی از دانش آموزان در دروس خاصی تست نگرفته و نمره صفر دارد. هدف شما یافتن میانگین نمره در یک موضوع خاص بدون نادیده گرفتن صفر است.

برای انجام کار، فرمول AVERAGEIFS را با دو معیار می سازید:

• محدوده را تا میانگین تعریف کنید (C3 :C15).
• محدوده ای را برای بررسی با شرط اول مشخص کنید (B3:B15 - موارد).
• شرط اول را بیان کنید ("ریاضی" یا F3 - مورد هدف که در نقل قول قرار داده شده است. علامت‌ها یا ارجاع به سلول حاوی مورد).
• محدوده را برای بررسی با شرط دوم مشخص کنید (C3:C15 - امتیازها).
• شرط دوم را بیان کنید (">0"- بزرگتر از صفر).

با جمع آوری اجزای فوق با هم فرمول زیر را بدست می آوریم:

=AVERAGEIFS(C3:C15, B3:B15, "math", C3:C15, ">0")

یا

=AVERAGEIFS(C3:C15, B3:B15, F3, C3:C15, ">0")

تصویر زیر مشخص می کند که تنها دو سلول (C6 و C10) هر دو شرایط را دارند و بنابراین فقط این سلول ها میانگین می شوند.

برای اطلاعات بیشتر، تابع Excel AVERAGEIFS را بررسی کنید.

فرمول‌های AVERAGEIF و AVERAGEIFS - یادداشت‌های استفاده

عملکردهای Excel AVERAGEIF و AVERAGEIFS شباهت‌های زیادی دارند، به ویژه اینکه چه مقادیری دارند. محاسبه کنید و کدام را نادیده بگیرید:

• در محدوده متوسط، سلول های خالی، مقادیر متن، مقادیر منطقی TRUE/FALSE نادیده گرفته می شوند.
• در معیارها، سلول های خالی به عنوان مقادیر صفر در نظر گرفته می شوند.
• کاراکترهای عام مانند علامت سوال (؟) و ستاره (*) را می توان در معیارهای تطابق جزئی استفاده کرد.
• اگر هیچ سلولی تمام معیارهای مشخص شده را برآورده نکرد، یک #DIV0! خطا رخ می دهد.

AVERAGEIF در مقابل AVERAGEIFS - تفاوت ها

از نظر عملکرد، اساسی ترین تفاوت این است که AVERAGEIF فقط می تواند یک شرط را مدیریت کند در حالی که AVERAGEIFS یک یا چند معیار را دارد. همچنین، چند تفاوت فنی مربوط به متوسط_محدوده وجود دارد.

• با AVERAGEIF، محدوده_متوسط آخرین و اختیاری آرگومان است. در فرمول های AVERAGEIFS، اولین و مورد نیاز آرگومان است.
• با AVERAGEIF، میانگین_محدوده لزوماً نباید هم اندازه باشد. محدوده زیرا سلول‌های واقعی که باید میانگین‌گیری شوند با اندازه آرگومان range تعیین می‌شوند - سلول سمت چپ بالای maverage_range به عنوان نقطه شروع در نظر گرفته می‌شود، و به تعداد سلول هایی که در آرگومان range گنجانده شده است میانگین می شود. AVERAGEIFS نیاز دارد که هر محدوده_معیار هم اندازه و شکل محدوده_متوسط باشد، در غیر این صورت یک #VALUE! خطا رخ می دهد.

AVERAGE IF OR فرمول در Excel

از آنجایی که تابع Excel AVERAGEIFS همیشه با منطق AND کار می کند (همه معیارها باید درست باشند)، شما باید خودتان را بسازید. فرمول به میانگین سلول‌ها با منطق OR (هر معیار منفرد باید درست باشد).

در اینجا فرمول عمومی برای میانگین‌گیری سلول X یا Y است.

AVERAGE(IF(ISNUMBER(MATCH( محدوده ، { معیار1 ، معیار2 ،…}، 0))، محدوده_متوسط ))

اکنون، بیایید ببینیم در عمل چگونه کار می کند . در جدول زیر، فرض کنید می خواهید نمره متوسط ​​دو درس زیست شناسی و شیمی را پیدا کنید که در سلول های F3 و F4 ورودی هستند. این را می توان با فرمول آرایه زیر انجام داد:

=AVERAGE(IF(ISNUMBER(MATCH(B3:B15, {"biology", "chemistry"}, 0)), C3:C15))

که به زبان انسانی ترجمه شده است، فرمول می گوید: سلول های متوسط ​​در C3:C15 اگر یک سلول متناظر در B3:B15 یکی باشد " زیست‌شناسی یا شیمی درست کار کردن،لطفاً به یاد داشته باشید که Ctrl + Shift + Enter را در اکسل 2019 و پایین تر فشار دهید. در آرایه پویا Excel (365 و 2021)، یک ضربه معمولی Enter کافی است:

این فرمول چگونه کار می کند:

برای خوانندگان کنجکاو و متفکر ما که نه تنها می خواهند برای اینکه از یک فرمول استفاده کنید اما بفهمید که چه کاری انجام می دهند، در اینجا توضیح مفصلی از منطق ارائه شده است.

در هسته فرمول، تابع IF تعیین می کند که کدام مقادیر در محدوده منبع با هر یک از معیارهای مشخص شده مطابقت دارند و پاس می شوند. آن مقادیر به تابع AVERAGE. به این صورت است:

تابع MATCH از نام موضوع در B3:B15 به عنوان مقادیر جستجو استفاده می کند و هر یک از آن مقادیر را با آرایه جستجو در F3:F4 (موضوعات هدف ما) مقایسه می کند. آرگومان سوم ( match_type ) برای جستجوی تطابق دقیق روی 0 تنظیم شده است:

MATCH(B3:B15, F3:F4, 0)

وقتی یک مطابق پیدا شد، MATCH موقعیت نسبی خود را در آرایه جستجو برمی گرداند. ، در غیر این صورت یک خطای #N/A:

{1;2;1;#N/A;1;#N/A;2;#N/A;1;2;2;1;#N/A}

تابع ISNUMBER اعداد را به TRUE و خطاها را به FALSE تبدیل می کند:

{TRUE;TRUE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE}

این آرایه می رود به آزمون منطقی IF. در فرم کامل، آزمون منطقی باید به این صورت نوشته شود:

IF(ISNUMBER(MATCH(B3:B15, F3:F4, 0))=TRUE

برای اختصار، قسمت =TRUE را به دلیل ضمنی بودن حذف می کنیم.

توسط با تنظیم آرگومان value_if_true روی C3:C15، به تابع IF می گویید که مقادیر واقعی را با مقادیر واقعی از C3:C15 جایگزین کند:

{89;78;75;FALSE;64;FALSE;62;FALSE;78;56;93;88;FALSE}

این آرایه نهایی تحویل داده می شود. به AVERAGE