عادةً ما تعني كلمة "Concatenate" ربط شيء ما معًا في سلسلة أو سلسلة. يتم استخدام هذه العملية كلما احتجت إلى ضم نص من عدة خلايا جداول بيانات Google. تجمع هذه المقالة الحلول الأكثر شيوعًا وسهولة لمساعدتك في حل أحجية التسلسل.

مهما كانت مجموعة البيانات كبيرة ، فقد تصادف مهمة دمج عدة خلايا في جداول بيانات Google معًا. وليس لدي شك في أنك لن ترغب فقط في الحفاظ على جميع القيم من الضياع ، ولكن أيضًا إضافة بعض الفواصل أو المسافات أو الأحرف الأخرى ، أو حتى فصل هذه السجلات بنص آخر.

حسنًا ، توفر جداول البيانات العديد من الأدوات لهذه المهمة.

وظيفة CONCAT لجداول بيانات Google

وظيفة CONCAT هي نسخة مبسطة من CONCATENATE من Google Sheets:

لربط الخلايا بهذه الوظيفة ، تحتاج إلى سرد القيم المطلوبة:

• value1 - السجل الذي يجب إلحاق value2 به.
• value2 - القيمة المراد ربطها.

للحصول على سلسلة واحدة من وحدتين نصيتين أو رقميتين ، ستبدو الصيغة أدناه ، مع كل سجل بين علامتي اقتباس:

=CONCAT("2019:","The Lion King")

في الواقع ، من المرجح أن تكون بياناتك موجودة بالفعل في الخلايا. يمكنك الرجوع إلى هذه الخلايا مباشرةً بدلاً من وضع كل رقم أو نص كوسيطة. لذلك ستكون صيغة البيانات الحقيقية كما يلي:

=CONCAT(A2,B2)

نصيحة. لنسخ الصيغة إلى العمود بأكمله ، حدد الخليةباستخدام الصيغة وانقر نقرًا مزدوجًا فوق المربع الصغير في الزاوية اليمنى السفلية للخلية. سيتم ملء العمود بالكامل تلقائيًا بالصيغة ، حتى نهاية الجدول.

كما ترى ، فإن الوظيفة بسيطة للغاية ، ولكنها تحتوي على نقاط ضعف رئيسية :

• فهي تدمج خليتين فقط في جداول بيانات Google في وقت واحد.
• لا يمكنها الجمع بين الأعمدة أو الصفوف أو نطاقات البيانات الضخمة الأخرى ، فهي تأخذ خلايا مفردة فقط. إذا حاولت الانضمام إلى عدة خلايا ، فسوف تحصل على خطأ أو سيتم ضم القيمتين الأوليين فقط ، على النحو التالي:

  =CONCAT(A2:A11,B2:B11)

  

بديل CONCAT: علامة العطف المشغل المتسلسلة (& amp؛)

هناك العديد من العوامل المختلفة لأغراض مختلفة في الصيغ. التسلسل ليس استثناء. سيوفر لك استخدام حرف العطف (& amp؛) في الصيغ بدلاً من وظيفة CONCAT نفس النتيجة:

=A2&B2

لكن القليل لا تعرفه أن عامل التسلسل هذا أكثر مرونة. إليك ما يمكنها فعله:

1. دمج أكثر من قيمتين في وقت واحد:

   =A2&B2&C2

   

2. ليس فقط دمج الخلايا في جداول بيانات Google ، ولكن افصل بينها أيضًا بأحرف مختلفة:

   =A2&" "&B2&"; "&C2

   

إذا كنت لا تزال لا تحصل على النتيجة المرجوة بهذه الخيارات ، هناك وظيفة أخرى يجب تجربتها.

كيفية استخدام CONCATENATE في جداول بيانات Google

أعتقد أن وظيفة CONCATENATE الخاصة بجداول بيانات Google هي أول وظيفة تستخدمعندما يتعلق الأمر بإلحاق عدة سجلات معًا.

تسلسل السلاسل النصية والأرقام في Google Sheets

يتكون نمط الصيغة من الوسيطات التالية:

• string1 هي السلسلة الأولى التي تريد إلحاق قيم أخرى بها. هذه الوسيطة مطلوبة.
• string2 ،… تمثل كل السلاسل الأخرى التي قد ترغب في إلحاقها. هذه الوسيطة اختيارية.

ملاحظة. سيتألف سجل النتيجة من السلاسل في ترتيب ظهورها في الصيغة.

إذا قمت بتكييف الصيغة مع بياناتي ، فسأحصل على هذا:

=CONCATENATE(A2,B2,C2)

أو ، نظرًا لأن الوظيفة تقبل النطاقات:

=CONCATENATE(A2:D2)

يمكنك على الفور ملاحظة الميزة الأولى لـ Google Sheets CONCATENATE: فهي تنضم بسهولة إلى خليتين مع كل من النص والأرقام.

Google Sheets: سلسلة سلاسل مع فواصل

دمج الخلايا في جداول بيانات Google هو نصف العمل. ولكن لجعل النتيجة تبدو جميلة وقابلة للقراءة ، يجب عليك إضافة بعض الأحرف الإضافية.

إذا احتفظت بالصيغة كما هي ، فستلصق كل شيء معًا: BonnieJacksonCA ، BonnieJacksonIN ، وما إلى ذلك ، ولكن Google Sheets CONCATENATE تأخذ الأحرف كوسيطات أيضًا.

وهكذا ، لإضافة بعض الفواصل لسهولة القراءة ، اذكرها بين علامتي اقتباس في الصيغة:

=CONCATENATE(A2," ",B2,", ",C2)

هنا أريد أن أجمع A2 & amp؛ B2 بمسافة ومنفصل B2 عن C2 بفاصلة ومسافة:

أنت حر في استخدام أي حرف تقريبًا في الوظيفة مثل هذه ، ومع ذلك فإن فاصل الأسطر يتطلب أسلوبًا مختلفًا.

نصيحة. في حالة وجود خلايا فارغة في بعض الأعمدة التي تدمجها ، فهناك وظيفة أخرى قد تكون مهتمًا بها. لا يدمج TEXTJOIN الخلايا في جداول بيانات Google فحسب ، بل يتجاهل الفراغات:

=TEXTJOIN(" ",TRUE,A2:C2)

إليك كيف يعمل:

1. حدد المحدد المطلوب كوسيطة أولى - مسافة ("") بالنسبة لي.
2. ضع TRUE كوسيطة ثانية لتخطي الخلايا الفارغة أو FALSE لتضمينها في النتيجة.
3. أدخل النطاق المراد دمجه.

التسلسل مع فاصل سطر في Google Sheets

بينما من الواضح كيفية إدخال معظم المحددات إلى الوظيفة ، لا يمكنك كتابة فاصل سطر بنفس الطريقة هناك. لكن لحسن الحظ تتيح لك Google لعب العديد من البطاقات المختلفة.

هناك وظيفة تساعد في الحصول على أحرف خاصة - تسمى CHAR. ترى ، كل حرف له مكان في جدول Unicode. تحتاج فقط إلى تغذية الرقم الترتيبي للحرف من هذا الجدول إلى الوظيفة وسيعيد الأخير الحرف نفسه.

إليك صيغة للحصول على فاصل السطر:

=CHAR(10)

أضفه إلى الصيغة للتسلسل مع فاصل الأسطر في جداول بيانات Google:

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2,CHAR(10),D2)

ادمج التاريخ والوقت في جداول بيانات Google

إذا حاولت دمج التاريخ والوقت في جداول بيانات Google باستخدام إحدى الطرقأعلاه ، لن يعمل. سيعرض جدول البيانات الأرقام:

لدمج التاريخ والوقت في جداول بيانات Google بشكل صحيح ، استخدم الدالة TEXT:

• حيث الرقم هو أي رقم أو تاريخ أو وقت ترغب في الحصول عليه بالتنسيق المطلوب
• و التنسيق هو النمط الذي تريده انظر نتيجة لذلك.

نصيحة. في المثال الخاص بي ، سأشير إلى الخلايا بالتواريخ والأوقات ، لكن يمكنك استخدام وحدات التاريخ / الوقت أو حتى وظائف مثل DATE أو TIME مباشرةً في الصيغة.

1. أستخدم أول صيغة TEXT لتغيير تنسيق التاريخ من 7/9/2019 إلى 9 Jul 2019 :

   =TEXT(B2,"D MMM YYYY")

2. يعرض TEXT الثاني الوقت:

   =TEXT(C2,"HH:MM:SS")

3. باستخدام هذين في CONCATENATE ، تتيح لي جداول بيانات Google دمج التاريخ والوقت بالتنسيق المطلوب مع أحرف أو نص آخر:

   =CONCATENATE(TEXT(B2,"D MMM YYYY"),", ",TEXT(C2,"HH:MM:SS"))

ادمج الأعمدة في جداول بيانات Google

مع تعديلات طفيفة ، فإن جميع الطرق التي ذكرتها قادرة على دمج الأعمدة في جداول بيانات Google.

مثال 1. جداول بيانات Google CONCAT

لدمج أعمدة كاملة في جداول بيانات Google باستخدام CONCAT ، حدد النطاق الكامل الذي يجب أن يحتوي على النتيجة (C2: C11 في حالتي) وأدخل التفاف الصيغة في ARRAYFORMULA:

=ARRAYFORMULA(CONCAT(A2:A11,B2:B11))

ملاحظة. يمكنك استخدام دالة CONCATENATE ، لكنها ستضم جميع السجلات في خلية واحدة لأنها تدمج بسهولة خلايا ونطاقات بيانات متعددة.

مثال 2.عامل تشغيل السلسلة

إنشاء صيغ مصفوفة لدمج الأعمدة في جداول بيانات Google باستخدام علامة العطف وإضافة فواصل في نفس الوقت:

=ARRAYFORMULA(A2:A11&" "&B2:B11&"; "&C2:C11)

يبدو هذا جيدًا ، لكن لا بد لي من الإشارة إلى بعض السلبيات الرئيسية.

إذا كان لديك عدد كبير جدًا من الأعمدة ، فإن تعدادها جميعًا يمكن أن يصبح ألمًا في الرقبة ، خاصةً إذا تخطيت / تنسخ / تخلط بين أي أحرف بطريق الخطأ .

أيضًا ، إذا قررت إضافة المزيد من الأعمدة إلى الصيغة لاحقًا ، فسيتعين عليك تحرير كل نطاق موجود في الصيغة يدويًا.

يحل المثال التالي هذه المشكلات.

مثال 3. استعلام جداول بيانات Google

تعد وظيفة QUERY في جداول بيانات Google مناسبة أيضًا لدمج عدة أعمدة في جداول بيانات Google. ألقِ نظرة:

=TRANSPOSE(QUERY(TRANSPOSE(A2:D10),,9^9))

قد تعتقد أن هذه الصيغة الغريبة خارجة عن متناول يدك ، ولكن دعني أضع لك كل التفاصيل:

1. = TRANSPOSE (A2: D10) يحول صفوف البيانات إلى أعمدة.
2. = QUERY (TRANSPOSE (A2: D10) ،، 9 ^ 9) يدمج السجلات في كل عمود إلى أعلى الخلايا.

   نصيحة. عندما أضع 9 ^ 9 في الصيغة ، أتأكد من أن جميع الصفوف من جميع الأعمدة سيتم سحبها إلى الصف الأول كما لو كانت رؤوسًا. إنه 9 ^ 9 نظرًا لأن هذا التعبير يتضمن جميع الخلايا الممكنة في جدول البيانات (تذكر الحد الأقصى لعدد الخلايا البالغ 10 مليون خلية؟) ويسهل تذكره. :)

3. = TRANSPOSE (QUERY (TRANSPOSE (A2: D10) ،، 9 ^ 9)) يأخذ صف الرأس هذا من QUERY ويحوله إلى عمود مثلواحد لدي.

فيما يلي مزايا دمج الأعمدة في جداول بيانات Google باستخدام QUERY:

• لست بحاجة إلى تحديد العمود بأكمله كما تفعل بالنسبة إلى صيغ الصفيف
• لا تحتاج إلى ذكر كل عمود في الصيغة ما لم تكن غير متجاورة. في هذه الحالة ، إليك كيف ستبدو الصيغة:

  =TRANSPOSE(QUERY(TRANSPOSE({A2:A10,C2:C10,E2:E10,G2:G10}),,9^9))

اربط وأضف النص حسب الموضع

أنت تعلم بالفعل أنه يمكنك إضافة نص وأرقام مفقودة ، والأحرف إلى السلاسل الخاصة بك باستخدام وظيفة CONCATENATE.

نصيحة. شاهد المزيد من الصيغ حول ذلك في هذا البرنامج التعليمي.

ولكن إذا كان هناك عدد كبير جدًا من السجلات للانضمام إليها ، فيمكن لأي أحرف إضافية توسيع طريق الصيغة الخاصة بك إلى ما هو أبعد مما خططت له. في مثل هذه الحالات ، من الأفضل دمج الخلايا في جداول بيانات Google كما هي أو استخدام محددات بسيطة مثل المسافة وإضافة النص بعد ذلك. ستساعدك أداة خاصة لنا.

إضافة نص حسب الموضع تُدخل أي أحرف وسلاسل حسب الموضع الذي تحدده ، ولا توجد حاجة إلى صيغ. دعني أوضح لك كيف يعمل.

في المثال السابق ، انضم QUERY إلى الأسماء وأرقام الهواتف بالنسبة لي. لكني أرغب في إضافة اختصارات البلد: (USA / CA) قبل أرقام الهواتف التي تبدأ بـ +1 و UK قبل +44 :

انقسام الخلايا في جداول بيانات Google

إذا قمت بدمج الخلايا في جداول بيانات Google ، فستحتاج إلى تقسيمها مرة أخرى في وقت ما . هناك ثلاث طرق للقيام بذلك:

1. إنشاء صيغةباستخدام وظيفة Google Sheets SPLIT.
2. استخدم أداة جداول البيانات القياسية - تقسيم النص إلى أعمدة.
3. أو جرب الإصدار المحسن من الأداة المضمنة - تقسيم النص إلى أعمدة لجداول بيانات Google:

يتيح لك تقسيم الخلايا عن طريق أي محدد أو حتى مجموعات من الفواصل ، ومعاملتها كواحد وتضمين اقترانات إذا لزم الأمر. كما يوفر خيار تقسيم الخلايا في جداول بيانات Google حسب الموضع.

نصيحة. هناك خيار لاستخراج البيانات من خلايا جداول بيانات Google بدلاً من تقسيم المحتويات.

كيفية دمج الخلايا في جداول بيانات Google بدون صيغ

إذا لم يكن إتقان الصيغ المختلفة جزءًا من خطتك ، الاستفادة من إضافة "قيم الدمج" الخاصة بنا. تنضم الوظيفة الإضافية بسرعة إلى السجلات في صفوف أو أعمدة أو نطاق الخلايا بأكمله. خياراته واضحة تمامًا ، وكل ما عليك فعله هو تحديد النطاق وتحديد الشكل الذي يجب أن تبدو عليه النتيجة.

1. يمكنك اختيار دمج الأعمدة في جداول بيانات Google - حتى غير المتجاورة ، افصل بينها بفاصلات ومسافات ، ثم ضع النتيجة على يمين السجلات الأصلية:

إذا كنت مهتمًا بالأداة ، فيمكنك البحثمن خلال كل ما تفعله في هذه الصفحة الخاصة أو في هذا الفيديو التعليمي القصير:

تعرف على كيفية استخدام دمج الصفوف المكررة في هذا الفيديو :

آمل الآن أن تكون قد قررت أي الطرق تناسب حالتك بشكل أفضل. إذا كان لديك أي طرق أخرى في الاعتبار ، فيرجى مشاركتنا في قسم التعليقات أدناه :)