Hướng dẫn giải thích ISNUMBER trong Excel là gì và cung cấp các ví dụ về cách sử dụng cơ bản và nâng cao.

Khái niệm về hàm ISNUMBER trong Excel rất đơn giản - nó chỉ kiểm tra xem một giá trị có phải là số hay không. Một điểm quan trọng ở đây là việc sử dụng thực tế của hàm vượt xa khái niệm cơ bản của nó, đặc biệt là khi được kết hợp với các hàm khác trong các công thức lớn hơn.

Hàm ISNUMBER của Excel

Hàm ISNUMBER trong Excel kiểm tra xem một ô có chứa giá trị số hay không. Nó thuộc nhóm hàm IS.

Hàm này có sẵn trong tất cả các phiên bản Excel dành cho Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 trở xuống.

Cú pháp ISNUMBER chỉ yêu cầu một đối số:

=ISNUMBER(value)

Trong đó giá trị là giá trị bạn muốn kiểm tra. Thông thường, giá trị này được biểu thị bằng một tham chiếu ô, nhưng bạn cũng có thể cung cấp một giá trị thực hoặc lồng một hàm khác vào bên trong ISNUMBER để kiểm tra kết quả.

Nếu giá trị là số, hàm sẽ trả về TRUE . Đối với bất kỳ điều gì khác (giá trị văn bản, lỗi, khoảng trống) ISNUMBER trả về FALSE.

Ví dụ: hãy kiểm tra các giá trị trong các ô từ A2 đến A6 và chúng tôi sẽ phát hiện ra rằng 3 giá trị đầu tiên là số và hai giá trị cuối cùng là số là văn bản:

2 điều bạn nên biết về hàm ISNUMBER trong Excel

Có một vài điểm thú vị cần lưu ý ở đây:

• Trongbiểu diễn Excel nội bộ, ngày và thời gian là các giá trị số, do đó, công thức ISNUMBER trả về TRUE cho chúng (vui lòng xem B3 và B4 trong ảnh chụp màn hình ở trên).
• Đối với các số được lưu dưới dạng văn bản, thì hàm ISNUMBER trả về SAI (xem ví dụ này).

Ví dụ về công thức ISNUMBER trong Excel

Các ví dụ dưới đây minh họa một vài cách sử dụng phổ biến và không tầm thường của ISNUMBER trong Excel.

Kiểm tra xem một giá trị có phải là số không

Khi bạn có nhiều giá trị trong trang tính của mình và bạn muốn biết giá trị nào là số, ISNUMBER là hàm phù hợp để sử dụng .

Trong ví dụ này, giá trị đầu tiên nằm trong ô A2, vì vậy chúng tôi sử dụng công thức bên dưới để kiểm tra giá trị đó, sau đó kéo công thức xuống bao nhiêu ô tùy ý:

=ISNUMBER(A2)

Xin lưu ý rằng mặc dù tất cả các giá trị trông giống như số nhưng công thức ISNUMBER đã trả về FALSE cho các ô A4 và A5, điều đó có nghĩa là các giá trị đó là chuỗi số , tức là các số được định dạng dưới dạng văn bản. Có thể có nhiều lý do khác nhau dẫn đến điều này, ví dụ như các số 0 ở đầu, dấu nháy đơn đứng trước, v.v. Dù lý do là gì, Excel không nhận dạng các giá trị đó dưới dạng số. Vì vậy, nếu các giá trị của bạn không tính toán chính xác, thì điều đầu tiên bạn cần kiểm tra là liệu chúng có thực sự là số trong Excel hay không, sau đó chuyển đổi văn bản thành số nếu cần.

Công thức TÌM KIẾM SỐ ISNUMBER của Excel

Ngoài việc xác định số, ExcelHàm ISNUMBER cũng có thể kiểm tra xem một ô có chứa văn bản cụ thể như một phần của nội dung hay không. Đối với điều này, hãy sử dụng ISNUMBER cùng với hàm SEARCH.

Ở dạng chung, công thức có dạng như sau:

Ở đâu chuỗi con là văn bản bạn muốn tìm.

Ví dụ: hãy kiểm tra xem chuỗi trong A3 có chứa một màu cụ thể không, chẳng hạn như màu đỏ:

=ISNUMBER(SEARCH("red", A3))

Công thức này hoạt động độc đáo cho một ô duy nhất. Nhưng vì bảng mẫu của chúng tôi (vui lòng xem bên dưới) có ba màu khác nhau nên việc viết một công thức riêng cho từng màu sẽ rất lãng phí thời gian. Thay vào đó, chúng ta sẽ tham chiếu đến ô chứa màu quan tâm (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Để công thức sao chép chính xác xuống dưới và sang phải, hãy đảm bảo khóa các tọa độ sau bằng ký hiệu $:

• Trong tham chiếu chuỗi con , hãy khóa hàng (B$2) để các công thức được sao chép luôn chọn các chuỗi con trong hàng 2. Tham chiếu cột là tương đối vì chúng ta muốn nó điều chỉnh cho từng cột, tức là khi công thức được sao chép sang C3, tham chiếu chuỗi con sẽ thay đổi thành C$2.
• Trong tham chiếu ô nguồn , hãy khóa cột ($A3 ) để tất cả các công thức kiểm tra các giá trị trong cột A.

Ảnh chụp màn hình bên dưới hiển thị kết quả:

TÌM SỐ SỐ - phân biệt chữ hoa chữ thường công thức

Vì chức năng TÌM KIẾM phân biệt chữ hoa chữ thường nên ở trêncông thức không phân biệt chữ hoa và chữ thường. Nếu bạn đang tìm kiếm một công thức phân biệt chữ hoa chữ thường, hãy sử dụng hàm FIND thay vì SEARCH.

Đối với tập dữ liệu mẫu của chúng tôi , công thức sẽ có dạng này:

=ISNUMBER(FIND(B$2, $A3))

Cách thức hoạt động của công thức này

Logic của công thức khá rõ ràng và dễ thực hiện:

• Hàm TÌM KIẾM / TÌM tìm kiếm chuỗi con trong ô đã chỉ định. Nếu chuỗi con được tìm thấy, vị trí của ký tự đầu tiên sẽ được trả về. Nếu không tìm thấy chuỗi con, hàm sẽ tạo ra lỗi #VALUE! lỗi.
• Hàm ISNUMBER lấy lỗi từ đó và xử lý các vị trí số. Vì vậy, nếu chuỗi con được tìm thấy và vị trí của nó được trả về dưới dạng một số, ISNUMBER sẽ xuất ra TRUE. Nếu không tìm thấy chuỗi con và lỗi #VALUE! xảy ra lỗi, ISNUMBER cho kết quả FALSE.

Công thức IF ISNUMBER

Nếu bạn muốn có một công thức cho kết quả không phải TRUE hoặc FALSE, hãy sử dụng ISNUMBER cùng với hàm IF.

Ví dụ 1. Ô chứa văn bản nào

Tham khảo thêm ví dụ trước, giả sử bạn muốn đánh dấu màu của từng mục bằng "x" như trong bảng bên dưới.

Để hoàn thành việc này, chỉ cần đưa công thức ISNUMBER SEARCH vào câu lệnh IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Nếu ISNUMBER trả về TRUE, thì hàm IF sẽ xuất ra "x" (hoặc bất kỳ giá trị nào khác mà bạn cung cấp cho value_if_true tranh luận). Nếu ISNUMBER trả về FALSE, hàm IF sẽ xuất ra một chuỗi rỗng ("").

Ví dụ 2. Ký tự đầu tiên trong một ô là số hoặc văn bản

Hãy tưởng tượng rằng bạn đang làm việc với một danh sách các chuỗi chữ và số và bạn muốn biết ký tự đầu tiên của chuỗi là một số hay một chữ cái.

Để xây dựng một công thức như vậy, bạn sẽ cần 4 hàm khác nhau:

• Hàm LEFT trích xuất ký tự đầu tiên từ đầu một chuỗi, chẳng hạn như trong ô A2:

  LEFT(A2, 1)

• Vì LEFT thuộc danh mục hàm Văn bản, kết quả luôn là một chuỗi văn bản, ngay cả khi nó chỉ chứa các số. Do đó, trước khi kiểm tra ký tự được trích xuất, chúng ta cần thử chuyển đổi nó thành số. Đối với điều này, hãy sử dụng hàm VALUE hoặc toán tử một ngôi kép:

  VALUE(LEFT(A2, 1)) hoặc (--LEFT(A2, 1))

• Hàm ISNUMBER xác định xem ký tự được trích xuất có phải là số hay không:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Dựa trên kết quả ISNUMBER (TRUE hoặc FALSE), hàm IF trả về "Số" hoặc "Chữ" tương ứng.

Giả sử chúng ta đang kiểm tra một chuỗi trong A2, công thức hoàn chỉnh có dạng này:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

or

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Hàm ISNUMBER cũng có ích cho trích xuất số từ một chuỗi. Đây là một ví dụ: Lấy số từ bất kỳ vị trí nào trong chuỗi.

Kiểm tra xem giá trị có phải là số không

Mặc dù Microsoft Excel có một chức năng đặc biệt, ISNONTEXT, để xác địnhnếu giá trị của một ô không phải là văn bản, thì hàm tương tự cho các số bị thiếu.

Một giải pháp dễ dàng là sử dụng ISNUMBER kết hợp với NOT để trả về giá trị ngược lại của giá trị lô-gic. Nói cách khác, khi ISNUMBER trả về TRUE, NOT chuyển đổi nó thành FALSE và ngược lại.

Để xem nó hoạt động như thế nào, vui lòng quan sát kết quả của công thức sau:

=NOT(ISNUMBER(A2))

Một phương pháp khác là sử dụng hàm IF và ISNUMBER cùng nhau:

=IF(ISNUMBER(A2), "", "Not number")

Nếu A2 là số, công thức sẽ không trả về giá trị nào (ô trống sợi dây). Nếu A2 không phải là số, thì công thức sẽ hiển thị trước: "Không phải số".

Nếu bạn muốn thực hiện một số phép tính với các số, hãy đặt một phương trình hoặc một phương trình khác công thức trong đối số value_if_true thay vì một chuỗi trống. Ví dụ: công thức dưới đây sẽ nhân các số với 10 và cho kết quả "Không phải số" cho các giá trị không phải là số:

=IF(ISNUMBER(A2), A2*10, "Not number")

Kiểm tra xem một dải ô có chứa bất kỳ số nào không

Trong trường hợp khi bạn muốn kiểm tra toàn bộ dải ô để tìm số, hãy sử dụng hàm ISNUMBER kết hợp với SUMPRODUCT như sau:

Ví dụ: để tìm hiểu xem dải ô A2:A5 có chứa bất kỳ giá trị số nào hay không, các công thức sẽ như sau:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Nếu bạn muốn xuất "Có" và "Không" thay vì TRUE và FALSE, hãy sử dụng câu lệnh IF làm"trình bao bọc" cho các công thức trên. Ví dụ:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Cách thức hoạt động của công thức này

Trọng tâm của công thức, hàm ISNUMBER đánh giá từng ô của phạm vi đã chỉ định, chẳng hạn B2:B5 và trả về TRUE cho các số, FALSE cho bất kỳ giá trị nào khác. Vì phạm vi chứa 4 ô nên mảng có 4 phần tử:

{TRUE;FALSE;FALSE;FALSE}

Phép toán nhân hoặc phép toán đơn thức kép (--) buộc TRUE và FALSE lần lượt thành 1 và 0:

{1;0;0;0}

Hàm SUMPRODUCT cộng các phần tử của mảng. Nếu kết quả lớn hơn 0, điều đó có nghĩa là có ít nhất một số trong phạm vi. Vì vậy, bạn sử dụng ">0" để nhận kết quả cuối cùng là TRUE hoặc FALSE.

ISNUMBER ở định dạng có điều kiện để đánh dấu các ô chứa văn bản nhất định

Nếu bạn đang muốn đánh dấu các ô hoặc toàn bộ các hàng chứa văn bản cụ thể, hãy tạo quy tắc định dạng có điều kiện dựa trên công thức ISNUMBER SEARCH (phân biệt chữ hoa chữ thường) hoặc ISNUMBER FIND (phân biệt chữ hoa chữ thường).

Đối với ví dụ này, chúng tôi sẽ đánh dấu các hàng dựa trên giá trị trong cột A. Chính xác hơn, chúng tôi sẽ đánh dấu các mục có chứa từ "đỏ". Dưới đây là cách thực hiện:

1. Chọn tất cả các hàng dữ liệu (A2:C6 trong ví dụ này) hoặc chỉ cột mà bạn muốn đánh dấu các ô.
2. Trên Trang chủ , trong nhóm Kiểu , hãy nhấp vào Quy tắc mới > Sử dụng công thức để xác định các ô cần định dạng .
3. Tronghộp Định dạng giá trị trong đó công thức này đúng , hãy nhập công thức bên dưới (xin lưu ý rằng tọa độ cột bị khóa bằng ký hiệu $):

   =ISNUMBER(SEARCH("red", $A2))

4. Nhấp vào Định dạng và chọn định dạng bạn muốn.
5. Nhấp OK hai lần.

Nếu bạn có ít kinh nghiệm về định dạng có điều kiện trong Excel, bạn có thể tìm thấy các bước chi tiết bằng ảnh chụp màn hình trong hướng dẫn này: Cách tạo quy tắc định dạng có điều kiện dựa trên công thức.

Kết quả là tất cả các mục có màu đỏ đều được đánh dấu:

Thay vì "mã hóa cứng" màu trong quy tắc định dạng có điều kiện, bạn có thể nhập màu đó vào một ô được xác định trước, chẳng hạn như E2, và tham chiếu ô đó trong công thức của bạn (vui lòng lưu ý tham chiếu ô tuyệt đối $E$2). Ngoài ra, bạn cần kiểm tra xem ô đầu vào có trống không:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Kết quả là bạn sẽ nhận được một quy tắc linh hoạt hơn làm nổi bật các hàng dựa trên thông tin bạn nhập trong E2:

Đó là cách sử dụng hàm ISNUMBER trong Excel. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Các bản tải xuống có sẵn

Ví dụ về công thức ISNUMBER của Excel