Το σεμινάριο εξηγεί τι είναι το ISNUMBER στο Excel και παρέχει παραδείγματα βασικών και προχωρημένων χρήσεων.

Η έννοια της συνάρτησης ISNUMBER στο Excel είναι πολύ απλή - απλώς ελέγχει αν μια δεδομένη τιμή είναι αριθμός ή όχι. Ένα σημαντικό σημείο εδώ είναι ότι οι πρακτικές χρήσεις της συνάρτησης ξεπερνούν κατά πολύ τη βασική της έννοια, ειδικά όταν συνδυάζεται με άλλες συναρτήσεις μέσα σε μεγαλύτερους τύπους.

Συνάρτηση ISNUMBER του Excel

Η συνάρτηση ISNUMBER στο Excel ελέγχει αν ένα κελί περιέχει αριθμητική τιμή ή όχι. Ανήκει στην ομάδα των συναρτήσεων IS.

Η λειτουργία είναι διαθέσιμη σε όλες τις εκδόσεις του Excel για το Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 και χαμηλότερες.

Η σύνταξη ISNUMBER απαιτεί μόνο ένα όρισμα:

=ISNUMBER(value)

Πού αξία είναι η τιμή που θέλετε να ελέγξετε. Συνήθως, αντιπροσωπεύεται από μια αναφορά κελιού, αλλά μπορείτε επίσης να δώσετε μια πραγματική τιμή ή να ενσωματώσετε μια άλλη συνάρτηση μέσα στο ISNUMBER για να ελέγξετε το αποτέλεσμα.

Εάν αξία είναι αριθμητική, η συνάρτηση επιστρέφει TRUE. Για οτιδήποτε άλλο (τιμές κειμένου, σφάλματα, κενά) η ISNUMBER επιστρέφει FALSE.

Για παράδειγμα, ας ελέγξουμε τις τιμές στα κελιά Α2 έως Α6 και θα διαπιστώσουμε ότι οι 3 πρώτες τιμές είναι αριθμοί και οι δύο τελευταίες είναι κείμενο:

2 πράγματα που πρέπει να γνωρίζετε για τη συνάρτηση ISNUMBER στο Excel

Υπάρχουν μερικά ενδιαφέροντα σημεία που πρέπει να σημειωθούν εδώ:

• Σε εσωτερική αναπαράσταση του Excel, ημερομηνίες και φορές είναι αριθμητικές τιμές, οπότε ο τύπος ISNUMBER επιστρέφει TRUE για αυτές (βλ. B3 και B4 στο παραπάνω στιγμιότυπο οθόνης).
• Για αριθμούς που είναι αποθηκευμένοι ως κείμενο, η συνάρτηση ISNUMBER επιστρέφει FALSE (βλέπε αυτό το παράδειγμα).

Παραδείγματα τύπου ISNUMBER του Excel

Τα παρακάτω παραδείγματα παρουσιάζουν μερικές κοινές και μερικές μη τετριμμένες χρήσεις του ISNUMBER στο Excel.

Έλεγχος αν μια τιμή είναι αριθμός

Όταν έχετε ένα σωρό τιμές στο φύλλο εργασίας σας και θέλετε να ξέρετε ποιες από αυτές είναι αριθμοί, η συνάρτηση ISNUMBER είναι η κατάλληλη για να χρησιμοποιήσετε.

Σε αυτό το παράδειγμα, η πρώτη τιμή βρίσκεται στο Α2, οπότε χρησιμοποιούμε τον παρακάτω τύπο για να την ελέγξουμε και στη συνέχεια σύρουμε τον τύπο σε όσα κελιά χρειάζεται:

=ISNUMBER(A2)

Προσέξτε ότι παρόλο που όλες οι τιμές μοιάζουν με αριθμούς, ο τύπος ISNUMBER επέστρεψε FALSE για τα κελιά A4 και A5, πράγμα που σημαίνει ότι οι τιμές αυτές είναι αριθμητικές συμβολοσειρές , δηλαδή αριθμοί που έχουν μορφοποιηθεί ως κείμενο. Μπορεί να υπάρχουν διάφοροι λόγοι γι' αυτό, για παράδειγμα αρχικά μηδενικά, προηγούμενη απόστροφος κ.λπ. Όποιος κι αν είναι ο λόγος, το Excel δεν αναγνωρίζει τέτοιες τιμές ως αριθμούς. Έτσι, αν οι τιμές σας δεν υπολογίζονται σωστά, το πρώτο πράγμα που πρέπει να ελέγξετε είναι αν είναι πραγματικά αριθμοί από την άποψη του Excel, και στη συνέχεια να μετατρέψετε κείμενο σε αριθμό, αν χρειάζεται.

Τύπος αναζήτησης του Excel ISNUMBER SEARCH

Εκτός από την αναγνώριση αριθμών, η συνάρτηση ISNUMBER του Excel μπορεί επίσης να ελέγξει εάν ένα κελί περιέχει συγκεκριμένο κείμενο ως μέρος του περιεχομένου. Για το σκοπό αυτό, χρησιμοποιήστε την ISNUMBER μαζί με τη συνάρτηση SEARCH.

Σε γενική μορφή, ο τύπος έχει ως εξής:

Πού substring είναι το κείμενο που θέλετε να βρείτε.

Για παράδειγμα, ας ελέγξουμε αν η συμβολοσειρά στο Α3 περιέχει ένα συγκεκριμένο χρώμα, ας πούμε κόκκινο:

=ISNUMBER(SEARCH("red", A3))

Αυτός ο τύπος λειτουργεί ωραία για ένα μόνο κελί. Αλλά επειδή ο πίνακας του δείγματός μας (βλ. παρακάτω) περιέχει τρία διαφορετικά χρώματα, το να γράψουμε έναν ξεχωριστό τύπο για το καθένα θα ήταν χάσιμο χρόνου. Αντ' αυτού, θα αναφερθούμε στο κελί που περιέχει το χρώμα που μας ενδιαφέρει (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Για να αντιγραφεί σωστά ο τύπος προς τα κάτω και προς τα δεξιά, βεβαιωθείτε ότι έχετε κλειδώσει τις ακόλουθες συντεταγμένες με το σύμβολο $:

• Στο substring αναφορά, κλειδώστε τη γραμμή (B$2) ώστε οι αντιγραμμένοι τύποι να επιλέγουν πάντα τις υποομάδες στη γραμμή 2. Η αναφορά στήλης είναι σχετική επειδή θέλουμε να προσαρμόζεται για κάθε στήλη, δηλαδή όταν ο τύπος αντιγράφεται στη C3, η αναφορά υποομάδας θα αλλάξει σε C$2.
• Στο κύτταρο πηγής αναφοράς, κλειδώστε τη στήλη ($A3) ώστε όλοι οι τύποι να ελέγχουν τις τιμές της στήλης Α.

Το παρακάτω στιγμιότυπο οθόνης δείχνει το αποτέλεσμα:

ISNUMBER FIND - τύπος με ευαισθησία στην πεζότητα

Καθώς η λειτουργία SEARCH είναι case-insensitive , ο παραπάνω τύπος δεν διακρίνει τους κεφαλαίους και τους πεζούς χαρακτήρες. Εάν αναζητάτε έναν τύπο με ευαισθησία στην πεζότητα, χρησιμοποιήστε τη λειτουργία FIND αντί για SEARCH.

Για το σύνολο δεδομένων του δείγματός μας, ο τύπος θα έχει την εξής μορφή:

=ISNUMBER(FIND(B$2, $A3))

Πώς λειτουργεί αυτή η φόρμουλα

Η λογική του τύπου είναι αρκετά προφανής και εύκολο να ακολουθηθεί:

• Η συνάρτηση SEARCH / FIND αναζητά την υποομάδα στο καθορισμένο κελί. Εάν η υποομάδα βρεθεί, επιστρέφεται η θέση του πρώτου χαρακτήρα. Εάν η υποομάδα δεν βρεθεί, η συνάρτηση παράγει ένα σφάλμα #VALUE!.
• Η συνάρτηση ISNUMBER το παίρνει από εκεί και επεξεργάζεται αριθμητικές θέσεις. Έτσι, εάν η υποσειρά βρεθεί και η θέση της επιστραφεί ως αριθμός, η ISNUMBER εξάγει TRUE. Εάν η υποσειρά δεν βρεθεί και προκύψει σφάλμα #VALUE!, η ISNUMBER εξάγει FALSE.

IF ISNUMBER τύπος

Αν θέλετε να λάβετε έναν τύπο που να βγάζει κάτι διαφορετικό από TRUE ή FALSE, χρησιμοποιήστε το ISNUMBER μαζί με τη συνάρτηση IF.

Παράδειγμα 1. Το κελί περιέχει ποιο κείμενο

Συνεχίζοντας το προηγούμενο παράδειγμα, υποθέστε ότι θέλετε να σημειώσετε το χρώμα κάθε στοιχείου με "x" όπως φαίνεται στον παρακάτω πίνακα.

Για να το κάνετε αυτό, απλά τυλίξτε τον τύπο ISNUMBER SEARCH στη δήλωση IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Εάν η ISNUMBER επιστρέψει TRUE, η συνάρτηση IF εξάγει την τιμή "x" (ή οποιαδήποτε άλλη τιμή δώσετε στη συνάρτηση value_if_true Εάν η ISNUMBER επιστρέψει FALSE, η συνάρτηση IF εξάγει ένα κενό αλφαριθμητικό ("").

Παράδειγμα 2. Ο πρώτος χαρακτήρας σε ένα κελί είναι αριθμός ή κείμενο

Φανταστείτε ότι εργάζεστε με μια λίστα αλφαριθμητικών συμβολοσειρών και θέλετε να μάθετε αν ο πρώτος χαρακτήρας μιας συμβολοσειράς είναι αριθμός ή γράμμα.

Για να φτιάξετε μια τέτοια φόρμουλα, θα χρειαστείτε 4 διαφορετικές συναρτήσεις:

• Η συνάρτηση LEFT εξάγει τον πρώτο χαρακτήρα από την αρχή μιας συμβολοσειράς, π.χ. στο κελί A2:

  LEFT(A2, 1)

• Επειδή η LEFT ανήκει στην κατηγορία των συναρτήσεων κειμένου, το αποτέλεσμά της είναι πάντα μια συμβολοσειρά κειμένου, ακόμη και αν περιέχει μόνο αριθμούς. Επομένως, πριν ελέγξουμε τον εξαγόμενο χαρακτήρα, πρέπει να προσπαθήσουμε να τον μετατρέψουμε σε αριθμό. Για το σκοπό αυτό, χρησιμοποιήστε είτε τη συνάρτηση VALUE είτε τον διπλό μοναδιαίο τελεστή:

  VALUE(LEFT(A2, 1)) ή (--LEFT(A2, 1))

• Η συνάρτηση ISNUMBER καθορίζει αν ο εξαγόμενος χαρακτήρας είναι αριθμητικός ή όχι:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Με βάση το αποτέλεσμα ISNUMBER (TRUE ή FALSE), η συνάρτηση IF επιστρέφει "Αριθμός" ή "Γράμμα", αντίστοιχα.

Αν υποθέσουμε ότι δοκιμάζουμε μια συμβολοσειρά στην Α2, ο πλήρης τύπος παίρνει αυτή τη μορφή:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ή

=IF(ISNUMBER(--LEFT(A2, 1)), "Αριθμός", "Γράμμα")

Η συνάρτηση ISNUMBER είναι επίσης χρήσιμη για εξαγωγή αριθμών από μια συμβολοσειρά. Ακολουθεί ένα παράδειγμα: Λήψη αριθμού από οποιαδήποτε θέση σε μια συμβολοσειρά.

Έλεγχος αν μια τιμή δεν είναι αριθμός

Αν και το Microsoft Excel διαθέτει μια ειδική συνάρτηση, ISNONTEXT, για να προσδιορίζει αν η τιμή ενός κελιού δεν είναι κείμενο, δεν υπάρχει ανάλογη συνάρτηση για τους αριθμούς.

Μια εύκολη λύση είναι η χρήση του ISNUMBER σε συνδυασμό με το NOT που επιστρέφει το αντίθετο μιας λογικής τιμής. Με άλλα λόγια, όταν το ISNUMBER επιστρέφει TRUE, το NOT το μετατρέπει σε FALSE και το αντίστροφο.

Για να το δείτε στην πράξη, παρατηρήστε τα αποτελέσματα του ακόλουθου τύπου:

=NOT(ISNUMBER(A2))

Μια άλλη προσέγγιση είναι η χρήση των συναρτήσεων IF και ISNUMBER μαζί:

=IF(ISNUMBER(A2), "", "Δεν είναι αριθμός")

Εάν το A2 είναι αριθμητικό, ο τύπος δεν επιστρέφει τίποτα (μια κενή συμβολοσειρά). Εάν το A2 δεν είναι αριθμητικό, ο τύπος το αναφέρει εκ των προτέρων: "Δεν είναι αριθμός".

Αν θέλετε να εκτελέσετε κάποιους υπολογισμούς με αριθμούς, τότε βάλτε μια εξίσωση ή έναν άλλο τύπο στο πεδίο value_if_true Για παράδειγμα, ο παρακάτω τύπος θα πολλαπλασιάσει τους αριθμούς με το 10 και θα δώσει την τιμή "Not number" για μη αριθμητικές τιμές:

=IF(ISNUMBER(A2), A2*10, "Δεν είναι αριθμός")

Ελέγξτε αν μια περιοχή περιέχει οποιονδήποτε αριθμό

Σε περίπτωση που θέλετε να ελέγξετε ολόκληρο το εύρος αριθμών, χρησιμοποιήστε τη συνάρτηση ISNUMBER σε συνδυασμό με τη συνάρτηση SUMPRODUCT ως εξής:

Για παράδειγμα, για να διαπιστώσετε αν η περιοχή A2:A5 περιέχει οποιαδήποτε αριθμητική τιμή, οι τύποι έχουν ως εξής:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Αν θέλετε να εξάγετε "Ναι" και "Όχι" αντί για TRUE και FALSE, χρησιμοποιήστε τη δήλωση IF ως "περιτύλιγμα" για τους παραπάνω τύπους. Για παράδειγμα:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Ναι", "Όχι")

Πώς λειτουργεί αυτή η φόρμουλα

Στο επίκεντρο του τύπου, η συνάρτηση ISNUMBER αξιολογεί κάθε κελί της καθορισμένης περιοχής, ας πούμε B2:B5, και επιστρέφει TRUE για αριθμούς, FALSE για οτιδήποτε άλλο. Καθώς η περιοχή περιέχει 4 κελιά, ο πίνακας έχει 4 στοιχεία:

{TRUE;FALSE;FALSE;FALSE;FALSE}

Η πράξη πολλαπλασιασμού ή η διπλή μοναδιαία πράξη (--) εξαναγκάζει το TRUE και το FALSE σε 1 και 0, αντίστοιχα:

{1;0;0;0}

Η συνάρτηση SUMPRODUCT προσθέτει τα στοιχεία του πίνακα. Εάν το αποτέλεσμα είναι μεγαλύτερο από το μηδέν, αυτό σημαίνει ότι υπάρχει τουλάχιστον ένας αριθμός στην περιοχή. Έτσι, χρησιμοποιείτε το ">0" για να λάβετε ένα τελικό αποτέλεσμα TRUE ή FALSE.

ISNUMBER σε μορφοποίηση υπό όρους για να επισημάνετε τα κελιά που περιέχουν συγκεκριμένο κείμενο

Αν θέλετε να επισημάνετε κελιά ή ολόκληρες γραμμές που περιέχουν συγκεκριμένο κείμενο, δημιουργήστε έναν κανόνα μορφοποίησης υπό όρους με βάση τον τύπο ISNUMBER SEARCH (χωρίς ευαισθησία στην πεζότητα) ή ISNUMBER FIND (με ευαισθησία στην πεζότητα).

Για αυτό το παράδειγμα, θα επισημάνουμε τις γραμμές με βάση την τιμή στη στήλη Α. Πιο συγκεκριμένα, θα επισημάνουμε τα στοιχεία που περιέχουν τη λέξη "κόκκινο". Ακούστε πώς:

1. Επιλέξτε όλες τις γραμμές δεδομένων (A2:C6 σε αυτό το παράδειγμα) ή μόνο τη στήλη στην οποία θέλετε να επισημάνετε τα κελιά.
2. Στο Αρχική σελίδα στην καρτέλα Στυλ ομάδα, κάντε κλικ στο Νέος κανόνας >, Χρησιμοποιήστε έναν τύπο για να καθορίσετε ποια κελιά θα μορφοποιηθούν .
3. Στο Μορφοποίηση τιμών όπου αυτός ο τύπος είναι αληθής πληκτρολογήστε τον παρακάτω τύπο (προσέξτε ότι η συντεταγμένη της στήλης είναι κλειδωμένη με το σύμβολο $):

   =ISNUMBER(SEARCH("red", $A2))

4. Κάντε κλικ στο Μορφή και επιλέξτε τη μορφή που θέλετε.
5. Κάντε κλικ στο OK δύο φορές.

Εάν έχετε μικρή εμπειρία με την υπό όρους μορφοποίηση του Excel, μπορείτε να βρείτε τα λεπτομερή βήματα με εικόνες οθόνης σε αυτό το σεμινάριο: Πώς να δημιουργήσετε έναν κανόνα υπό όρους μορφοποίησης με βάση τον τύπο.

Ως αποτέλεσμα, όλα τα στοιχεία με κόκκινο χρώμα επισημαίνονται:

Αντί να "κωδικοποιήσετε" το χρώμα στον κανόνα μορφοποίησης υπό όρους, μπορείτε να το πληκτρολογήσετε σε ένα προκαθορισμένο κελί, π.χ. στο E2, και να αναφερθείτε σε αυτό το κελί στον τύπο σας (προσέξτε την απόλυτη αναφορά κελιού $E$2). Επιπλέον, πρέπει να ελέγξετε αν το κελί εισόδου δεν είναι κενό:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Ως αποτέλεσμα, θα έχετε έναν πιο ευέλικτο κανόνα που θα επισημαίνει τις γραμμές με βάση την εισαγωγή σας στο E2:

Αυτός είναι ο τρόπος χρήσης της συνάρτησης ISNUMBER στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα τύπου ISNUMBER του Excel