Õpik selgitab, mis on ISNUMBER Excelis, ning toob näiteid põhiliste ja edasijõudnute kasutusvõimaluste kohta.

Funktsiooni ISNUMBER kontseptsioon Excelis on väga lihtne - see lihtsalt kontrollib, kas antud väärtus on arv või mitte. Oluline on see, et selle funktsiooni praktilised kasutusvõimalused lähevad kaugemale selle põhikontseptsioonist, eriti kui seda kombineerida teiste funktsioonidega suuremates valemites.

Exceli ISNUMBER funktsioon

Exceli funktsioon ISNUMBER kontrollib, kas lahter sisaldab numbrilist väärtust või mitte. See kuulub IS-funktsioonide rühma.

Funktsioon on saadaval kõigis Exceli versioonides Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 ja madalamad versioonid.

ISNUMBER süntaks nõuab ainult ühte argumenti:

=ISNUMBER(väärtus)

Kus väärtus on väärtus, mida soovite testida. Tavaliselt on see esindatud lahtriviitena, kuid te võite anda ka reaalse väärtuse või pesitseda tulemuse kontrollimiseks ISNUMBERi sisse mõne teise funktsiooni.

Kui väärtus on numbriline, tagastab funktsioon TRUE. Kõigi muude väärtuste (tekstiväärtused, vead, tühikud) puhul tagastab ISNUMBER FALSE.

Näiteks testime lahtrites A2 kuni A6 olevaid väärtusi ja leiame, et esimesed 3 väärtust on numbrid ja kaks viimast on tekst:

2 asja, mida peaksite teadma ISNUMBER-funktsioonist Excelis

Siin on paar huvitavat punkti, mida tuleb tähele panna:

• Exceli sisemises esituses, kuupäevad ja korda on numbrilised väärtused, nii et valem ISNUMBER tagastab nende jaoks TRUE (vt B3 ja B4 ülaltoodud ekraanipildil).
• Tekstina salvestatud numbrite puhul tagastab funktsioon ISNUMBER FALSE (vt seda näidet).

Exceli ISNUMBER valemi näited

Allpool toodud näited näitavad mõningaid tavalisi ja paar mittetriviaalset ISNUMBERi kasutamist Excelis.

Kontrollida, kas väärtus on number

Kui teie töölehel on hulk väärtusi ja te tahate teada, millised neist on numbrid, on ISNUMBER õige funktsioon, mida kasutada.

Selles näites on esimene väärtus A2-s, seega kasutame selle kontrollimiseks allpool esitatud valemit ja lohistame seejärel valemi nii paljudesse lahtritesse, kui vaja:

=ISNUMBER(A2)

Pöörake tähelepanu, et kuigi kõik väärtused näevad välja nagu numbrid, on valem ISNUMBER tagastanud FALSE lahtrite A4 ja A5 puhul, mis tähendab, et need väärtused on numbrilised stringid , st numbrid, mis on vormistatud tekstina. Sellel võivad olla erinevad põhjused, näiteks juhtivad nullid, eelnev apostroof jne. Mis iganes põhjus, Excel ei tunnista selliseid väärtusi numbritena. Seega, kui teie väärtused ei arvuta õigesti, siis kontrollige kõigepealt, kas need on tõesti numbrid Exceli mõttes, ja seejärel konverteerige tekst vajadusel numbriks.

Exceli ISNUMBER SEARCH valemiga

Lisaks numbrite tuvastamisele saab Exceli funktsiooniga ISNUMBER kontrollida ka seda, kas lahtri sisuks on konkreetne tekst. Selleks kasutage funktsiooni ISNUMBER koos funktsiooniga SEARCH.

Üldisel kujul näeb valem välja järgmiselt:

Kus substring on tekst, mida soovite leida.

Kontrollime näiteks, kas string A3 sisaldab mingit kindlat värvi, näiteks punast:

=ISNUMBER(SEARCH("red", A3))

See valem töötab kenasti ühe lahtri jaoks. Kuid kuna meie näidistabel (vt allpool) sisaldab kolme erinevat värvi, oleks iga värvi jaoks eraldi valemi kirjutamine ajaraiskamine. Selle asemel viitame me lahtrisse, mis sisaldab huvipakkuvat värvi (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Selleks, et valemit õigesti alla ja paremale kopeerida, tuleb järgmised koordinaadid kindlasti lukustada $-märgiga:

• Veebilehel substring viide, lukustage rida (B$2), nii et kopeeritavad valemid valivad alati alamjooned reas 2. Veerguviide on suhteline, sest me tahame, et see kohanduks iga veeru puhul, st kui valemit kopeeritakse C3, muutub alamjoonte viide C$2-ks.
• In the lähteelement viide, lukustage veerg ($A3), et kõik valemid kontrolliksid veerus A olevaid väärtusi.

Tulemus on näha alloleval ekraanipildil:

ISNUMBER FIND - suur- ja väiketähelepanu arvestav valem

Kuna funktsioon SEARCH on suur- ja väiketähelepanuta , ei tee ülaltoodud valemiga vahet suur- ja väiketähtedel. Kui otsite suur- ja väiketähtedest sõltuvat valemit, kasutage pigem funktsiooni FIND kui funktsiooni SEARCH.

Meie näidisandmestiku puhul on valem järgmine:

=ISNUMBER(FIND(B$2, $A3))

Kuidas see valem töötab

Valemi loogika on üsna ilmne ja kergesti järgitav:

• Funktsioon SEARCH / FIND otsib määratud lahtrist alamjada. Kui alamjada leitakse, tagastatakse esimese tähemärgi positsioon. Kui alamjada ei leita, annab funktsioon vea #VALUE!.
• Funktsioon ISNUMBER võtab selle sealt ja töötleb numbrilisi positsioone. Seega, kui alamjada on leitud ja selle positsioon tagastatakse numbrina, annab ISNUMBER välja TRUE. Kui alamjada ei ole leitud ja esineb viga #VALUE!, annab ISNUMBER välja FALSE.

IF ISNUMBER valemiga

Kui teie eesmärk on saada valem, mis väljastab midagi muud kui TRUE või FALSE, kasutage ISNUMBER koos IF-funktsiooniga.

Näide 1. Millist teksti sisaldab lahter

Võttes eelmist näidet edasi, oletame, et soovite märkida iga elemendi värvi "x"-iga, nagu on näidatud allolevas tabelis.

Selleks lihtsalt mähkige ISNUMBER SEARCH valem IF avalduse sisse:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Kui ISNUMBER tagastab TRUE, siis IF funktsioon väljastab "x" (või mõne muu väärtuse, mille annate funktsiooni value_if_true argument). Kui ISNUMBER tagastab FALSE, väljastab funktsioon IF tühja stringi ("").

Näide 2. Esimene märk lahtris on number või tekst

Kujutage ette, et töötate tähtnumbriliste stringide loeteluga ja soovite teada, kas stringi esimene märk on number või täht.

Sellise valemi loomiseks vajame 4 erinevat funktsiooni:

• Funktsioon LEFT eraldab esimese tähemärgi stringi algusest, näiteks lahtrist A2:

  LEFT(A2, 1)

• Kuna LEFT kuulub funktsioonide kategooriasse Text, on selle tulemus alati tekstijada, isegi kui see sisaldab ainult numbreid. Seetõttu peame enne väljavõetud tähemärgi kontrollimist püüdma selle teisendada numbriks. Selleks kasutame kas funktsiooni VALUE või kahekordset unaarset operaatorit:

  VALUE(LEFT(A2, 1)) või (--LEFT(A2, 1))

• Funktsioon ISNUMBER määrab kindlaks, kas väljavõetud märk on numbriline või mitte:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• ISNUMBER tulemuse (TRUE või FALSE) põhjal tagastab IF funktsioon vastavalt "Number" või "Letter".

Eeldades, et me testime stringi A2, võtab täielik valem sellise kuju:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

või

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Funktsioon ISNUMBER on kasulik ka järgmiste funktsioonide puhul numbrite väljavõtmine stringist. Siin on näide: saada number stringi mis tahes positsioonist.

Kontrollida, kas väärtus ei ole number

Kuigi Microsoft Excelil on olemas spetsiaalne funktsioon ISNONTEXT, mille abil saab kindlaks teha, kas lahtri väärtus ei ole tekst, puudub analoogne funktsioon numbrite jaoks.

Lihtne lahendus on kasutada ISNUMBERi koos NOTiga, mis tagastab loogilise väärtuse vastupidise väärtuse. Teisisõnu, kui ISNUMBER tagastab TRUE, muudab NOT selle FALSE'ks ja vastupidi.

Et näha seda praktikas, vaadake järgmise valemi tulemusi:

=NOT(ISNUMBER(A2))

Teine lähenemisviis on IF ja ISNUMBER funktsioonide kasutamine koos:

=IF(ISNUMBER(A2), "", "Mitte number")

Kui A2 on numbriline, ei tagasta valem midagi (tühi string). Kui A2 ei ole numbriline, ütleb valem seda ette: "Mitte number".

Kui soovid teha arvutusi numbritega, siis pane võrrand või mõni muu valem lahtrisse value_if_true Näiteks korrutab alljärgnev valem arvud 10ga ja annab mittenumbriliste väärtuste puhul tulemuseks "Not number":

=IF(ISNUMBER(A2), A2*10, "Mitte number")

Kontrollida, kas vahemik sisaldab mingit arvu

Kui soovite testida kogu numbrite vahemikku, kasutage funktsiooni ISNUMBER koos funktsiooniga SUMPRODUCT järgmiselt:

Näiteks selleks, et leida, kas vahemik A2:A5 sisaldab numbrilist väärtust, läheksid valemid järgmiselt:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Kui soovite TRUE ja FALSE asemel väljastada "JAH" ja "EI", kasutage IF avaldust ülaltoodud valemite "mähisena". Näiteks:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Jah", "Ei")

Kuidas see valem töötab

Valemi keskmes on funktsioon ISNUMBER, mis hindab iga lahtrit määratud vahemikus, näiteks B2:B5, ja tagastab TRUE numbrite puhul, FALSE kõigi muude elementide puhul. Kuna vahemik sisaldab 4 lahtrit, on massiivil 4 elementi:

{TRUE;FALSE;FALSE;FALSE;FALSE}

Korrutamisoperatsioon või topeltühik (--) sunnib TRUE ja FALSE vastavalt 1 ja 0:

{1;0;0;0}

Funktsioon SUMPRODUCT liidab massiivi elemendid kokku. Kui tulemus on suurem kui null, tähendab see, et vahemikus on vähemalt üks number. Seega kasutate ">0", et saada lõpptulemuseks TRUE või FALSE.

ISNUMBER tingimuslikus vorminduses, et rõhutada teatud teksti sisaldavaid lahtreid

Kui soovite esile tõsta konkreetset teksti sisaldavaid lahtreid või terveid ridu, looge tingimuslik vormindusreegel, mis põhineb valemil ISNUMBER SEARCH (ei ole tundlik suur- ja väiketähtede suhtes) või ISNUMBER FIND (on tundlik suur- ja väiketähtede suhtes).

Selle näite puhul tõstame ridu esile veerus A oleva väärtuse alusel. Täpsemalt öeldes tõstame esile elemendid, mis sisaldavad sõna "punane". Järgnevalt on kirjeldatud, kuidas:

1. Valige kõik andmeread (antud näites A2:C6) või ainult see veerg, mille lahtrid soovite esile tõsta.
2. On Kodu vahekaardil Stiilid rühma, klõpsake Uus reegel > Kasutage valemit, et määrata, millised lahtrid tuleb vormindada .
3. In the Vormindage väärtused, mille puhul see valem on tõene sisestage alljärgnev valem (märkige, et veeru koordinaat on lukustatud $-märgiga):

   =ISNUMBER(SEARCH("red", $A2))

4. Klõpsake nuppu Formaat nuppu ja valige soovitud formaat.
5. Klõpsake kaks korda OK.

Kui teil on vähe kogemusi Exceli tingimusliku vormindamisega, leiate üksikasjalikud sammud koos ekraanipiltidega sellest juhendmaterjalist: Kuidas luua valemipõhine tingimusliku vormindamise reegel.

Selle tulemusena on kõik punast värvi elemendid esile tõstetud:

Selle asemel, et "kõvakodeerida" värvi tingimusliku vormindamise reeglisse, võite selle sisestada eelnevalt määratud lahtrisse, näiteks E2, ja viidata sellele lahtrisse oma valemis (pidage meeles absoluutset lahtriviidet $E$2). Lisaks peate kontrollima, kas sisendlahter ei ole tühi:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Selle tulemusena saate paindlikuma reegli, mis tõstab read esile teie E2 sisestuse põhjal:

Nii kasutatakse Excelis funktsiooni ISNUMBER. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Saadaolevad allalaadimised

Exceli ISNUMBER valemi näited