이 자습서에서는 Excel의 ISNUMBER가 무엇인지 설명하고 기본 및 고급 사용 예를 제공합니다.

Excel의 ISNUMBER 함수 개념은 매우 간단합니다. 값은 숫자인지 아닌지입니다. 여기서 중요한 점은 특히 더 큰 수식 내에서 다른 함수와 결합할 때 함수의 실제 사용이 기본 개념을 훨씬 뛰어넘는다는 것입니다.

Excel ISNUMBER 함수

Excel의 ISNUMBER 함수는 셀에 숫자 값이 포함되어 있는지 확인합니다. IS 함수 그룹에 속합니다.

이 함수는 Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 이하의 모든 버전의 Excel에서 사용할 수 있습니다.

ISNUMBER 구문에는 하나의 인수만 필요합니다.

=ISNUMBER(value)

여기서 값 은 테스트할 값입니다. 일반적으로 셀 참조로 표시되지만 실제 값을 제공하거나 ISNUMBER 내부에 다른 함수를 중첩하여 결과를 확인할 수도 있습니다.

value 가 숫자인 경우 함수는 TRUE를 반환합니다. . 다른 것(텍스트 값, 오류, 공백)의 경우 ISNUMBER는 FALSE를 반환합니다.

예를 들어 셀 A2에서 A6까지의 값을 테스트하면 처음 3개의 값이 숫자이고 마지막 2개가 숫자임을 알 수 있습니다. 텍스트:

Excel의 ISNUMBER 함수에 대해 알아야 할 2가지 사항

여기에 주목해야 할 몇 가지 흥미로운 점이 있습니다.

• 에서내부 Excel 표현, 날짜 및 시간 은 숫자 값이므로 ISNUMBER 수식이 TRUE를 반환합니다(위 스크린샷의 B3 및 B4 참조).
• 숫자를 텍스트로 저장하면 ISNUMBER 함수는 FALSE를 반환합니다(이 예 참조).

Excel ISNUMBER 수식 예

아래 예는 몇 가지 일반적인 용도와 몇 가지 중요하지 않은 용도를 보여줍니다.

값이 숫자인지 확인

워크시트에 여러 값이 있고 어떤 값이 숫자인지 알고 싶을 때 사용할 수 있는 올바른 함수는 ISNUMBER입니다. .

이 예에서 첫 번째 값은 A2에 있으므로 아래 수식을 사용하여 확인한 다음 수식을 필요한 만큼 셀로 드래그합니다.

=ISNUMBER(A2)

모든 값이 숫자처럼 보이지만 ISNUMBER 수식이 A4 및 A5 셀에 대해 FALSE를 반환했습니다. 즉, 해당 값이 숫자 문자열 임을 의미합니다. , 즉 텍스트 형식의 숫자입니다. 여기에는 여러 가지 이유가 있을 수 있습니다(예: 선행 0, 선행 아포스트로피 등). 이유가 무엇이든 Excel에서는 이러한 값을 숫자로 인식하지 않습니다. 따라서 값이 올바르게 계산되지 않으면 가장 먼저 Excel에서 실제로 숫자인지 확인한 다음 필요한 경우 텍스트를 숫자로 변환해야 합니다.

Excel ISNUMBER SEARCH 수식

숫자를 식별하는 것 외에도 엑셀은ISNUMBER 함수는 셀에 콘텐츠의 일부로 특정 텍스트가 포함되어 있는지 확인할 수도 있습니다. 이를 위해 SEARCH 함수와 함께 ISNUMBER를 사용합니다.

일반 형식에서 수식은 다음과 같습니다.

여기서 하위 문자열 은 찾으려는 텍스트입니다.

예를 들어 A3의 문자열에 특정 색상(예: 빨간색)이 포함되어 있는지 확인하겠습니다.

=ISNUMBER(SEARCH("red", A3))

이 공식은 단일 셀에 적합합니다. 그러나 샘플 테이블(아래 참조)에는 세 가지 다른 색상이 포함되어 있으므로 각 색상에 대해 별도의 수식을 작성하는 것은 시간 낭비입니다. 대신 관심 색상(B2)이 포함된 셀을 참조합니다.

=ISNUMBER(SEARCH(B$2, $A3))

수식이 오른쪽 아래로 올바르게 복사되도록 하려면 다음 좌표를 $ 기호:

• 하위 문자열 참조에서 복사된 수식이 항상 2행의 하위 문자열을 선택하도록 행(B$2)을 잠급니다. 열 참조는 상대적입니다. 즉, 수식이 C3에 복사되면 하위 문자열 참조가 C$2로 변경됩니다.
• 소스 셀 참조에서 열($A3 ) 모든 수식이 열 A의 값을 확인하도록 합니다.

아래 스크린샷은 결과를 보여줍니다.

ISNUMBER FIND - 대소문자 구분 수식

SEARCH 함수는 대소문자를 구분하지 않으므로 위의수식은 대문자와 소문자를 구분하지 않습니다. 대소문자를 구분하는 수식을 찾으려면 SEARCH 대신 FIND 함수를 사용하세요.

샘플 데이터세트의 경우 , 수식은 다음과 같은 형식을 취합니다.

=ISNUMBER(FIND(B$2, $A3))

이 수식이 작동하는 방식

수식의 논리는 매우 명확하고 따르기 쉽습니다.

• SEARCH / FIND 기능은 지정된 셀에서 하위 문자열을 찾습니다. 하위 문자열이 발견되면 첫 번째 문자의 위치가 반환됩니다. 하위 문자열이 없으면 함수는 #VALUE! 오류입니다.
• ISNUMBER 함수는 여기에서 이를 가져와서 숫자 위치를 처리합니다. 따라서 하위 문자열이 발견되고 해당 위치가 숫자로 반환되면 ISNUMBER는 TRUE를 출력합니다. 하위 문자열을 찾을 수 없고 #VALUE! 오류가 발생하면 ISNUMBER는 FALSE를 출력합니다.

IF ISNUMBER 수식

TRUE 또는 FALSE 이외의 값을 출력하는 수식을 얻으려면 IF 함수와 함께 ISNUMBER를 사용하십시오.

예시 1. Cell contains which text

이전 예에서 더 나아가 아래 표와 같이 각 항목의 색상을 "x"로 표시한다고 가정합니다.

이 작업을 수행하려면 ISNUMBER SEARCH 수식을 IF 문으로 래핑하면 됩니다.

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

ISNUMBER가 TRUE를 반환하면 IF 함수는 "x"(또는 사용자가 제공한 다른 값)를 출력합니다. value_if_true 논쟁). ISNUMBER가 FALSE를 반환하면 IF 함수는 빈 문자열("")을 출력합니다.

예 2. 셀의 첫 번째 문자는 숫자 또는 텍스트입니다

영숫자 문자열 목록으로 작업 중이고 문자열의 첫 번째 문자가 숫자인지 문자인지 알고 싶다고 상상해 보십시오.

이러한 수식을 작성하려면 4가지 함수가 필요합니다.

• LEFT 함수는 셀 A2에서와 같이 문자열의 시작 부분에서 첫 번째 문자를 추출합니다.

  LEFT(A2, 1)

• LEFT는 텍스트 함수의 범주에 속하기 때문에 결과는 숫자만 포함하는 경우에도 항상 텍스트 문자열입니다. 따라서 추출된 문자를 확인하기 전에 숫자로 변환을 시도해야 합니다. 이를 위해 VALUE 함수 또는 이중 단항 연산자를 사용합니다.

  VALUE(LEFT(A2, 1)) 또는 (--LEFT(A2, 1))

• ISNUMBER 함수는 추출된 문자가 숫자인지 여부를 결정합니다.

  ISNUMBER(VALUE(LEFT(A2, 1)))

• ISNUMBER 결과(TRUE 또는 FALSE)를 기준으로 IF 함수는 각각 "Number" 또는 "Letter"를 반환합니다.

A2에서 문자열을 테스트한다고 가정하면 전체 공식

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

또는

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER 함수는 <12에도 유용합니다>문자열에서 숫자 추출. 다음은 예입니다. 문자열의 모든 위치에서 숫자를 가져옵니다.

값이 숫자가 아닌지 확인합니다.

Microsoft Excel에는 ISNONTEXT라는 특수 함수가 있어셀의 값이 텍스트가 아니면 숫자에 대한 유사한 함수가 없습니다.

논리 값의 반대를 반환하는 NOT과 함께 ISNUMBER를 사용하는 것이 쉬운 해결책입니다. 즉, ISNUMBER가 TRUE를 반환하면 NOT은 이를 FALSE로 변환하고 그 반대도 마찬가지입니다.

작동을 확인하려면 다음 수식의 결과를 관찰하십시오.

=NOT(ISNUMBER(A2))

또 다른 접근 방식은 IF 및 ISNUMBER 함수를 함께 사용하는 것입니다.

=IF(ISNUMBER(A2), "", "Not number")

A2가 숫자인 경우 수식은 아무 것도 반환하지 않습니다(빈 끈). A2가 숫자가 아닌 경우 수식은 "Not number"라고 명시합니다.

숫자로 일부 계산을 수행하려면 방정식이나 다른 빈 문자열 대신 value_if_true 인수의 수식. 예를 들어 아래 수식은 숫자에 10을 곱하고 숫자가 아닌 값에 대해 "Not number"를 생성합니다.

=IF(ISNUMBER(A2), A2*10, "Not number")

범위에 숫자가 포함되어 있는지 확인

In 숫자의 전체 범위를 테스트하려는 경우 다음과 같이 SUMPRODUCT와 함께 ISNUMBER 함수를 사용하십시오.

예를 들어 A2:A5 범위에 숫자 값이 포함되어 있는지 확인하려면 공식은 다음과 같습니다.

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

TRUE와 FALSE 대신 "Yes"와 "No"를 출력하려면 IF 문을위 수식에 대한 "래퍼". 예:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

이 수식이 작동하는 방식

수식의 핵심에서 ISNUMBER 함수는 지정된 범위, 예를 들어 B2:B5, 숫자의 경우 TRUE를 반환하고 그 외의 경우 FALSE를 반환합니다. 범위에 4개의 셀이 포함되어 있으므로 배열에는 4개의 요소가 있습니다.

{TRUE;FALSE;FALSE;FALSE}

곱하기 연산 또는 이중 단항(--)은 TRUE와 FALSE를 각각 1과 0으로 강제 변환합니다.

{1;0;0;0}

SUMPRODUCT 함수는 배열의 요소를 더합니다. 결과가 0보다 크면 범위에 숫자가 하나 이상 있음을 의미합니다. 따라서 ">0"을 사용하여 TRUE 또는 FALSE의 최종 결과를 얻습니다.

특정 텍스트가 포함된 셀을 강조 표시하기 위한 조건부 서식의 ISNUMBER

셀을 강조 표시하거나 특정 텍스트를 포함하는 전체 행은 ISNUMBER SEARCH(대소문자 구분 안 함) 또는 ISNUMBER FIND(대소문자 구분) 수식을 기반으로 조건부 서식 규칙을 생성합니다.

이 예에서는 다음을 기반으로 행을 강조 표시합니다. A 열의 값. 보다 정확하게는 "red"라는 단어가 포함된 항목을 강조 표시합니다. 방법은 다음과 같습니다.

1. 모든 데이터 행(이 예에서는 A2:C6)을 선택하거나 셀을 강조 표시할 열만 선택합니다.
2. 홈 탭의 스타일 그룹에서 새 규칙 > 수식을 사용하여 서식을 지정할 셀 결정 을 클릭합니다.
3. 에서 이 수식이 참인 값 형식 지정 상자에 아래 수식을 입력합니다(열 좌표는 $ 기호로 잠겨 있음).

   =ISNUMBER(SEARCH("red", $A2))

4. 서식 버튼을 누르고 원하는 형식을 선택합니다.
5. 확인을 두 번 클릭합니다.

Excel 조건부 서식에 대한 경험이 거의 없는 경우 자세한 단계를 찾을 수 있습니다. 이 자습서의 스크린샷: 수식 기반 조건부 서식 규칙을 만드는 방법.

결과적으로 빨간색의 모든 항목이 강조 표시됩니다.

조건부 서식 규칙에서 색상을 "하드코딩"하는 대신 미리 정의된 셀(예: E2)에 입력하고 수식에서 해당 셀을 참조할 수 있습니다(절대 셀 참조 $E$2에 유의하십시오). 또한 입력 셀이 비어 있지 않은지 확인해야 합니다.

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

결과적으로 E2:<3의 입력에 따라 행을 강조 표시하는 보다 유연한 규칙을 얻게 됩니다>

엑셀에서 ISNUMBER 함수를 사용하는 방법입니다. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 바랍니다!

사용 가능한 다운로드

Excel ISNUMBER 수식 예제