O titorial explica o que é ISNUMBER en Excel e ofrece exemplos de usos básicos e avanzados.

O concepto da función ISNUMBER en Excel é moi sinxelo: só verifica se un determinado o valor é un número ou non. Un punto importante aquí é que os usos prácticos da función van moito máis alá do seu concepto básico, especialmente cando se combinan con outras funcións dentro de fórmulas máis grandes.

Función ISNUMBER de Excel

A función ISNUMBER en Excel verifica se unha cela contén un valor numérico ou non. Pertence ao grupo de funcións IS.

A función está dispoñible en todas as versións de Excel para Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 e anteriores.

A sintaxe ISNUMBER require só un argumento:

=ISNUMBER(value)

Onde valor é o valor que quere probar. Normalmente, está representado por unha referencia de cela, pero tamén pode proporcionar un valor real ou aniñar outra función dentro de ISNUMBER para comprobar o resultado.

Se valor é numérico, a función devolve VERDADEIRO. . Para calquera outra cousa (valores de texto, erros, espazos en branco) ISNUMBER devolve FALSE.

A modo de exemplo, comprobamos os valores das celas da A2 á A6, e descubriremos que os 3 primeiros valores son números e os dous últimos. son texto:

2 cousas que debes saber sobre a función ISNUMBER en Excel

Hai un par de puntos interesantes a destacar aquí:

• Enrepresentación interna de Excel, datas e veces son valores numéricos, polo que a fórmula ISNUMBER devolve VERDADEIRO para eles (consulta B3 e B4 na captura de pantalla anterior).
• Para números almacenados como texto, a función ISNUMBER devolve FALSE (consulta este exemplo).

Exemplos de fórmulas de Excel ISNUMBER

Os exemplos seguintes mostran algúns usos comúns e un par de usos non triviais. de ISNUMBER en Excel.

Comproba se un valor é un número

Cando tes un montón de valores na túa folla de traballo e queres saber cales son números, ISNUMBER é a función correcta para usar .

Neste exemplo, o primeiro valor está en A2, polo que usamos a seguinte fórmula para comprobalo e, a continuación, arrastramos a fórmula ata tantas celas como sexa necesario:

=ISNUMBER(A2)

Por favor, preste atención a que, aínda que todos os valores parecen números, a fórmula ISNUMBER devolveu FALSO para as celas A4 e A5, o que significa que eses valores son cadeas numéricas , é dicir, números con formato de texto. Pode haber diferentes razóns para iso, por exemplo, ceros ao principio, apóstrofes anteriores, etc. Sexa cal sexa o motivo, Excel non recoñece tales valores como números. Polo tanto, se os teus valores non se calculan correctamente, o primeiro que debes comprobar é se realmente son números en termos de Excel e, a continuación, converter o texto en número se é necesario.

Fórmula de BUSCA DE NÚMEROS de Excel

Ademais de identificar números, o ExcelA función ISNUMBER tamén pode comprobar se unha cela contén texto específico como parte do contido. Para iso, use ISNUMBER xunto coa función SEARCH.

Na forma xenérica, a fórmula ten o seguinte aspecto:

Onde subcadea é o texto que quere atopar.

A modo de exemplo, comprobemos se a cadea en A3 contén unha cor específica, digamos vermello:

=ISNUMBER(SEARCH("red", A3))

Esta fórmula funciona ben para unha única cela. Pero como a nosa táboa de mostra (consulta a continuación) contén tres cores diferentes, escribir unha fórmula separada para cada unha sería unha perda de tempo. No seu lugar, referirémonos á cela que contén a cor de interese (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Para que a fórmula se copie correctamente cara abaixo e cara á dereita, asegúrate de bloquear as seguintes coordenadas con o signo $:

• Na referencia subcadea , bloquee a fila (B$2) para que as fórmulas copiadas escollen sempre as subcadeas na fila 2. A referencia da columna é relativa porque quere que se axuste para cada columna, é dicir, cando a fórmula se copie en C3, a referencia da subcadea cambiará a C$2.
• Na referencia cela fonte , bloquea a columna ($A3 ) para que todas as fórmulas comproben os valores da columna A.

A seguinte captura de pantalla mostra o resultado:

ISNUMBER FIND - distingue entre maiúsculas e minúsculas fórmula

Como a función de BUSCA é insensible entre maiúsculas e minúsculas , o anteriorfórmula non diferencia caracteres en maiúscula e minúscula. Se está a buscar unha fórmula que distinga entre maiúsculas e minúsculas, use a función BUSCAR en lugar de BUSCAR.

Para o noso conxunto de datos de mostra , a fórmula tomaría esta forma:

=ISNUMBER(FIND(B$2, $A3))

Como funciona esta fórmula

A lóxica da fórmula é bastante obvia e fácil de seguir:

• A función BUSCAR/BUSCAR busca a subcadea na cela especificada. Se se atopa a subcadea, devólvese a posición do primeiro carácter. Se non se atopa a subcadea, a función produce un #VALOR! erro.
• A función ISNUMBER tómao de alí e procesa posicións numéricas. Entón, se se atopa a subcadea e a súa posición se devolve como un número, ISNUMBER mostra TRUE. Se non se atopa a subcadea e un #VALOR! ocorre un erro, ISNUMBER dá como resultado FALSE.

IF ISNUMBER fórmula

Se pretende obter unha fórmula que dea algo distinto de VERDADEIRO ou FALSO, use ISNUMBER xunto coa función SE.

Exemplo 1. A cela contén que texto

Levando máis lonxe o exemplo anterior, supoña que quere marcar a cor de cada elemento con "x" como se mostra na táboa seguinte.

Para facer isto, simplemente envolve a fórmula ISNUMBER SEARCH na instrución IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Se ISNUMBER devolve VERDADEIRO, a función IF mostra "x" (ou calquera outro valor que lle proporcione). o valor_se_verdadeiro argumento). Se ISNUMBER devolve FALSE, a función SE mostra unha cadea baleira ("").

Exemplo 2. O primeiro carácter dunha cela é un número ou texto

Imaxina que estás a traballar cunha lista de cadeas alfanuméricas e queres saber se o primeiro carácter dunha cadea é un número ou unha letra.

Para crear unha fórmula deste tipo, necesitaremos 4 funcións diferentes:

• A función LEFT extrae o primeiro carácter do inicio dunha cadea, digamos na cela A2:

  LEFT(A2, 1)

• Debido a que LEFT pertence á categoría de funcións de texto, a súa O resultado é sempre unha cadea de texto, aínda que só conteña números. Polo tanto, antes de comprobar o carácter extraído, debemos tentar convertelo nun número. Para iso, use a función VALOR ou o operador unario dobre: ​​

  VALUE(LEFT(A2, 1)) ou (--LEFT(A2, 1))

• A función ISNUMBER determina se o carácter extraído é numérico ou non:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• En función do resultado ISNUMBER (VERDADEIRO ou FALSO), a función SE devolve "Número" ou "Letra", respectivamente.

Supoñendo que estamos probando unha cadea en A2, a fórmula completa toma esta forma:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ou

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

A función ISNUMBER tamén é útil para extraer números dunha cadea. Aquí tes un exemplo: Obter un número de calquera posición nunha cadea.

Comproba se un valor non é un número

Aínda que Microsoft Excel ten unha función especial, ISNONTEXT, para determinarse o valor dunha cela non é texto, falta unha función análoga para os números.

Unha solución sinxela é usar ISNUMBER en combinación con NOT que devolve o contrario dun valor lóxico. Noutras palabras, cando ISNUMBER devolve TRUE, NON convérteo en FALSO e ao revés.

Para velo en acción, observe os resultados da seguinte fórmula:

=NOT(ISNUMBER(A2))

Outro enfoque é usar as funcións SE e ISNUMBER xuntos:

=IF(ISNUMBER(A2), "", "Not number")

Se A2 é numérico, a fórmula non devolve nada (unha baleira corda). Se A2 non é numérico, a fórmula di diante: "Non é número".

Se queres realizar algúns cálculos con números, pon unha ecuación ou outra. fórmula no argumento value_if_true en lugar dunha cadea baleira. Por exemplo, a seguinte fórmula multiplicará os números por 10 e producirá "Non número" para os valores non numéricos:

=IF(ISNUMBER(A2), A2*10, "Not number")

Comproba se un intervalo contén algún número

En Situación na que quere probar todo o intervalo de números, use a función ISNUMBER en combinación con SUMPRODUCT como este:

Por exemplo, para saber se o intervalo A2:A5 contén algún valor numérico, as fórmulas serían as seguintes:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Se desexa mostrar "Si" e "Non" en lugar de VERDADEIRO e FALSO, use a instrución IF como"envoltorio" para as fórmulas anteriores. Por exemplo:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Como funciona esta fórmula

No corazón da fórmula, a función ISNUMBER avalía cada cela da intervalo especificado, digamos B2:B5, e devolve VERDADEIRO para os números, FALSO para calquera outra cousa. Como o intervalo contén 4 celas, a matriz ten 4 elementos:

{TRUE;FALSE;FALSE;FALSE}

A operación de multiplicación ou o dobre unario (--) obriga a TRUE e FALSE a 1 e 0, respectivamente:

{1;0;0;0}

A función SUMAPRODUTO suma os elementos da matriz. Se o resultado é maior que cero, significa que hai polo menos un número no intervalo. Entón, usa ">0" para obter un resultado final de VERDADEIRO ou FALSO.

ISNUMBER en formato condicional para resaltar as celas que conteñan determinado texto

Se estás buscando resaltar celas ou filas enteiras que conteñan texto específico, cree unha regra de formato condicional baseada na fórmula ISNUMBER SEARCH (insensible entre maiúsculas e minúsculas) ou ISNUMBER FIND (distingue entre maiúsculas e minúsculas).

Para este exemplo, imos destacar as filas baseadas en o valor da columna A. Máis precisamente, destacaremos os elementos que conteñan a palabra "vermello". Vexa como:

1. Seleccione todas as filas de datos (A2:C6 neste exemplo) ou só a columna na que quere resaltar as celas.
2. Na Inicio , no grupo Estilos , faga clic en Nova regra > Utilice unha fórmula para determinar que celas formatar .
3. Enna caixa Formato de valores onde esta fórmula é verdadeira , introduza a seguinte fórmula (ten en conta que a coordenada da columna está bloqueada co signo $):

   =ISNUMBER(SEARCH("red", $A2))

4. Fai clic no botón Formatar e escolla o formato que desexe.
5. Fai clic en Aceptar dúas veces.

Se tes pouca experiencia co formato condicional de Excel, podes atopar os pasos detallados con capturas de pantalla neste titorial: Como crear unha regra de formato condicional baseada en fórmulas.

Como resultado, todos os elementos da cor vermella están resaltados:

En lugar de "codificar" a cor na regra de formato condicional, pode tecleala nunha cela predefinida, digamos E2, e referirse a esa cela na súa fórmula (ten en conta a referencia absoluta da cela $E$2). Ademais, debes comprobar se a cela de entrada non está baleira:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Como resultado, obterás unha regra máis flexible que resalta as filas en función da túa entrada en E2:

Así é como usar a función ISNUMBER en Excel. Grazas por ler e espero verte no noso blog a próxima semana!

Descargas dispoñibles

Exemplos de fórmulas ISNUMBER de Excel