Tutorial ngajelaskeun naon ISNUMBER dina Excel sareng nyayogikeun conto-conto pamakean dasar sareng canggih.

Konsép fungsi ISNUMBER dina Excel saderhana pisan - éta ngan ukur mariksa naha anu dipasihkeun. nilai mangrupa angka atawa henteu. Poin penting di dieu nyaéta yén kagunaan praktis tina fungsi éta jauh saluareun konsép dasarna, khususna nalika digabungkeun sareng fungsi sanés dina rumus anu langkung ageung.

Fungsi Excel ISNUMBER

Fungsi ISNUMBER dina Excel mariksa naha sél ngandung nilai numerik atanapi henteu. Ieu kagolong kana grup fungsi IS.

Pungsi ieu sadia dina sagala vérsi Excel pikeun Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 jeung handap.

Sintaksis ISNUMBER ngan merlukeun hiji argumen:

=ISNUMBER(value)

Dimana nilai nyaeta nilai nu rek diuji. Biasana, éta diwakilan ku référénsi sél, tapi anjeun ogé tiasa nyayogikeun nilai nyata atanapi nyarang fungsi anu sanés dina ISNUMBER pikeun mariksa hasilna.

Upami nilai mangrupikeun angka, fungsina ngabalikeun BENER. . Pikeun naon waé (nilai téks, kasalahan, kosong) ISNUMBER mulih PALSU.

Salaku conto, hayu urang nguji nilai dina sél A2 dugi ka A6, sareng urang bakal terang yén 3 nilai anu munggaran nyaéta angka sareng dua anu terakhir. nyaéta téks:

2 hal anu anjeun kedah terang ngeunaan fungsi ISNUMBER dina Excel

Aya sababaraha titik anu pikaresepeun pikeun dicatet di dieu:

• Diperwakilan Excel internal, tanggal sareng kali mangrupikeun nilai numerik, janten rumus ISNUMBER ngabalikeun BENER pikeun aranjeunna (punten tingali B3 sareng B4 dina layar di luhur).
• Pikeun angka nu disimpen salaku téks, fungsi ISNUMBER mulangkeun PALSU (tingali conto ieu).

Conto rumus Excel ISNUMBER

Conto di handap nunjukkeun sababaraha pamakéan umum jeung sababaraha non-trivial. tina ISNUMBER dina Excel.

Parios upami nilaina mangrupikeun angka

Nalika anjeun gaduh sakumpulan nilai dina lembar kerja anjeun sareng anjeun hoyong terang mana anu nomer, ISNUMBER mangrupikeun fungsi anu leres pikeun dianggo. .

Dina conto ieu, nilai kahiji aya dina A2, ku kituna urang ngagunakeun rumus di handap pikeun mariksa éta, teras sered rumus ka handap ka saloba sél sakumaha diperlukeun:

=ISNUMBER(A2)

Punten perhatoskeun, sanaos sadaya nilai sapertos angka, rumus ISNUMBER parantos ngabalikeun FALSE pikeun sél A4 sareng A5, anu hartosna nilai-nilai éta mangrupikeun string numerik , nyaéta angka nu diformat jadi téks. Meureun aya alesan béda pikeun ieu, contona ngarah nol, saméméhna tanda kutip, jsb Naon alesanana, Excel teu ngakuan nilai kayaning angka. Janten, upami nilai anjeun henteu leres ngitung, hal anu munggaran pikeun anjeun pariksa nyaéta naha éta leres-leres nomer dina hal Excel, teras ngarobih téks kana angka upami diperyogikeun.

Rumus PENILAIAN ISNUMBER Excel

Salian ti ngidentipikasi nomer, ExcelFungsi ISNUMBER ogé tiasa mariksa naha sél ngandung téks khusus salaku bagian tina eusi. Jang ngalampahkeun ieu, paké ISNUMBER bareng jeung pungsi SEARCH.

Dina wangun generik, rumusna siga kieu:

Dimana substring mangrupa téks nu rék diteangan.

Salaku conto, hayu urang pariksa naha string dina A3 ngandung warna husus, sebutkeun beureum:

=ISNUMBER(SEARCH("red", A3))

Rumus ieu dianggo saé pikeun sél tunggal. Tapi kusabab tabel sampel urang (mangga tingali di handap) ngandung tilu kelir béda, nulis rumus misah pikeun tiap hiji bakal runtah waktu. Sabalikna, urang bakal ngarujuk kana sél anu ngandung warna anu dipikaresep (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Pikeun rumus leres nyalin ka handap sareng ka katuhu, pastikeun pikeun ngonci koordinat di handap ieu sareng tanda $:

• Dina rujukan substring , konci baris (B$2) supados rumus anu disalin salawasna milih substrings dina baris 2. Rujukan kolom relatif sabab urang hoyong disaluyukeun pikeun tiap kolom, nyaéta nalika rumus disalin ka C3, rujukan substring bakal robah jadi C$2.
• Dina rujukan sél sumber , konci kolom ($A3). ) supados sadaya rumus mariksa nilai-nilai dina kolom A.

Potret layar di handap nembongkeun hasilna:

ISNUMBER FIND - case-sensitive rumus

Salaku fungsi SEARCH henteu sensitip hurup , di luhurrumus teu ngabedakeun hurup gede jeung aksara leutik. Upami anjeun milarian rumus sénsitip-huruf, paké fungsi FIND tinimbang SEARCH.

Pikeun set data sampel kami , rumusna bakal kieu:

=ISNUMBER(FIND(B$2, $A3))

Kumaha rumus ieu jalan

Logika rumusna rada atra tur gampang diturutan:

• Fungsi SEARCH / FIND milarian substring dina sél anu ditangtukeun. Lamun substring nu kapanggih, posisi karakter kahiji balik. Upami substring henteu kapendak, fungsina ngahasilkeun #VALUE! kasalahan.
• Pungsi ISNUMBER nyokot ti dinya jeung ngolah posisi numerik. Janten, upami substringna kapanggih sareng posisina dipulangkeun salaku nomer, ISNUMBER kaluaran BENER. Upami substring henteu kapendak sareng #VALUE! aya kasalahan, ISNUMBER kaluaran FALSE.

IF rumus ISNUMBER

Lamun tujuanana pikeun meunangkeun rumus nu ngahasilkeun hal salian BENER atawa SALAH, pake ISNUMBER babarengan jeung fungsi IF.

Conto 1. Sél anu ngandung téks mana

Nyandak conto saméméhna salajengna, anggap anjeun rék nyirian warna unggal item ku "x" kawas ditémbongkeun dina tabel di handap ieu.

Jang ngalampahkeun ieu, cukup bungkus rumus ISNUMBER SEARCH kana pernyataan IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Mun ISNUMBER mulih BENER, fungsi IF kaluaran "x" (atawa nilai sejenna nu Anjeun suplai ka éta value_if_true argumen). Lamun ISNUMBER mulangkeun FALSE, fungsi IF ngahasilkeun string kosong ("").

Conto 2. Karakter kahiji dina sél nyaéta angka atawa téks

Bayangkeun yén anjeun damel sareng daptar senar alfanumerik sareng anjeun hoyong terang naha karakter senar anu munggaran nyaéta angka atanapi hurup.

Pikeun ngawangun rumus sapertos kitu, anjeun peryogi 4 fungsi anu béda:

• Fungsi LEFT nimba karakter kahiji ti mimiti string, sebutkeun dina sél A2:

  LEFT(A2, 1)

• Kusabab LEFT kaasup kana kategori fungsi Text, hasilna sok string téks, sanajan ngan ngandung angka. Ku alatan éta, saméméh mariksa karakter sasari, urang kudu nyobaan pikeun ngarobah kana angka. Jang ngalampahkeun ieu, paké fungsi VALUE atawa operator unary ganda:

  VALUE(LEFT(A2, 1)) atawa (--LEFT(A2, 1))

• Pungsi ISNUMBER nangtukeun naha karakter nu diekstrak téh numerik atawa henteu:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Dumasar kana hasil ISNUMBER (BENER atawa SALAH), fungsi IF ngabalikeun "Angka" atawa "Letter". bentukna kieu:

  =IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

  atawa

  =IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

  

  Pungsi ISNUMBER ogé mangpaat pikeun nimba angka tina string. Ieu conto: Kéngingkeun nomer tina posisi mana waé dina senar.

  Parios upami nilai sanés angka

  Sanaos Microsoft Excel gaduh pungsi khusus, ISNONTEXT, pikeun nangtukeunnaha nilai sél teu téks, fungsi analog pikeun angka leungit.

  Solusi gampang ngagunakeun ISNUMBER dina kombinasi jeung NOT anu balik sabalikna ti nilai logis. Dina basa sejen, nalika ISNUMBER mulangkeun BENER, NOT ngarobahna jadi PALSU, jeung sabalikna.

  Pikeun ningali eta tindakan, mangga titénan hasil tina rumus ieu:

  =NOT(ISNUMBER(A2))

  

  Pendekatan séjén nyaéta ngagunakeun fungsi IF jeung ISNUMBER babarengan:

  =IF(ISNUMBER(A2), "", "Not number")

  Mun A2 numerik, rumusna teu ngahasilkeun nanaon (kosong string). Upami A2 sanes numerik, rumusna nyebatkeun di payun: "Sanes angka".

  

  Upami anjeun hoyong ngalakukeun sababaraha itungan nganggo angka, teras pasang persamaan atanapi anu sanés. rumus dina value_if_true argumen tinimbang string kosong. Contona, rumus di handap bakal ngalikeun angka ku 10 sarta ngahasilkeun "Henteu angka" pikeun nilai non-numerik:

  =IF(ISNUMBER(A2), A2*10, "Not number")

  Pariksa lamun rentang ngandung angka wae

  Dina kaayaan nalika anjeun hoyong nguji sakabeh rentang pikeun angka, make fungsi ISNUMBER dina kombinasi jeung SUMPRODUCT kawas kieu:

  SUMPRODUCT(--ISNUMBER( rentang ))>0 SUMPRODUCT(ISNUMBER( rentang )*1)>0

  Contona, pikeun manggihan lamun rentang A2:A5 ngandung nilai numerik, rumusna bakal kieu:

  =SUMPRODUCT(--ISNUMBER(A2:A5))>0

  =SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

  

  Upami anjeun hoyong kaluaran "Leres" sareng "Henteu" tibatan BENER sareng SALAH, paké pernyataan IF salaku"wrapper" pikeun rumus di luhur. Contona:

  =IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

  

  Kumaha rumus ieu jalan

  Dina inti rumus, fungsi ISNUMBER ngaevaluasi unggal sél tina rentang dieusian, nyebutkeun B2: B5, sarta mulih BENER pikeun angka, PALSU keur nanaon sejenna. Kusabab rentang ngandung 4 sél, array ngabogaan 4 elemen:

  {TRUE;FALSE;FALSE;FALSE}

  Operasi multiplikasi atawa ganda unary (--) maksa BENER jeung SALAH jadi 1 jeung 0, masing-masing:

  {1;0;0;0}

  Pungsi SUMPRODUCT nambahan unsur-unsur array. Lamun hasilna leuwih gede ti enol, hartina aya sahanteuna hiji angka rentang. Janten, anjeun nganggo ">0" pikeun kéngingkeun hasil ahir BENER atanapi SALAH.

  ISNUMBER dina pormat kondisional pikeun nyorot sél anu ngandung téks tangtu

  Upami anjeun milarian nyorot sél atanapi sakabéh baris anu ngandung téks husus, jieun aturan pormat kondisional dumasar kana rumus ISNUMBER SEARCH (case-insensitive) atawa ISNUMBER FIND (case-sensitive).

  Pikeun conto ieu, urang bade nyorot baris dumasar kana nilai dina kolom A. Leuwih tepat, urang bakal nyorot item nu ngandung kecap "beureum". Kieu carana:

  1. Pilih sadaya baris data (A2:C6 dina conto ieu) atawa ukur kolom nu rék disorot sél.
  2. Dina Imah tab, dina grup Styles , klik Aturan Anyar > Paké rumus pikeun nangtukeun sél mana nu rék diformat .
  3. Dinakotak Format dimana rumus ieu leres , lebetkeun rumus di handap ieu (mangga perhatikeun yén koordinat kolom dikonci ku tanda $):

     =ISNUMBER(SEARCH("red", $A2))

  4. Klik Tombol Format sareng pilih format anu anjeun pikahoyong.
  5. Klik OK dua kali.

  Upami anjeun sakedik pangalaman sareng pormat kondisional Excel, anjeun tiasa mendakan léngkah-léngkah anu lengkep. kalawan screenshot dina tutorial ieu: Cara nyieun aturan pormat kondisional dumasar rumus.

  Hasilna, sadaya item nu warna beureum disorot:

  

  Gantina "hardcoding" warna dina aturan pormat kondisional, anjeun tiasa ngetik dina sél nu tos siap, sebutkeun E2, sarta tingal sél dina rumus anjeun (punten pikiran rujukan sél mutlak $E$2). Salaku tambahan, anjeun kedah mariksa naha sél input henteu kosong:

  =AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

  Kusabab hasilna, anjeun bakal nampi aturan anu langkung fleksibel anu nyorot baris dumasar kana input anjeun dina E2:

  

  Kukituna cara ngagunakeun fungsi ISNUMBER dina Excel. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog kami minggu payun!

  Sadia undeuran

  Conto rumus Excel ISNUMBER