Mafunzo yanafafanua ISNUMBER ni nini katika Excel na hutoa mifano ya matumizi ya kimsingi na ya hali ya juu.

Dhana ya kitendakazi cha ISNUMBER katika Excel ni rahisi sana - inakagua tu kama imetolewa. thamani ni nambari au la. Jambo muhimu hapa ni kwamba matumizi ya vitendo ya chaguo za kukokotoa huenda mbali zaidi ya dhana yake ya msingi, hasa yanapounganishwa na vitendaji vingine ndani ya fomula kubwa zaidi.

Kitendakazi cha Excel ISNUMBER

Kitendaji cha ISNUMBER katika Excel hukagua kama kisanduku kina thamani ya nambari au la. Ni katika kundi la vitendaji vya IS.

Chaguo hili linapatikana katika matoleo yote ya Excel kwa Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 na matoleo mapya zaidi.

Sintaksia ya ISNUMBER inahitaji hoja moja tu:

=ISNUMBER(value)

Ambapo thamani ni thamani unayotaka kujaribu. Kwa kawaida, huwakilishwa na marejeleo ya kisanduku, lakini unaweza pia kutoa thamani halisi au kuweka kitendakazi kingine ndani ya ISNUMBER ili kuangalia matokeo.

Ikiwa thamani ni nambari, chaguo za kukokotoa hurejesha TRUE . Kwa kitu kingine chochote (thamani za maandishi, makosa, nafasi zilizoachwa wazi) ISNUMBER inarudisha FALSE.

Kwa mfano, hebu tujaribu thamani katika seli A2 hadi A6, na tutagundua kwamba thamani 3 za kwanza ni nambari na mbili za mwisho. ni maandishi:

Mambo 2 unapaswa kujua kuhusu chaguo la kukokotoa la ISNUMBER katika Excel

Kuna mambo kadhaa ya kuvutia ya kuzingatia hapa:

• Katikauwakilishi wa ndani wa Excel, tarehe na nyakati ni nambari, kwa hivyo fomula ya ISNUMBER inarudisha TRUE kwao (tafadhali angalia B3 na B4 katika picha ya skrini iliyo hapo juu).
• Kwa nambari zilizohifadhiwa kama maandishi, chaguo za kukokotoa za ISNUMBER hurejesha FALSE (angalia mfano huu).

Mifano ya fomula ya Excel ISNUMBER

Mifano iliyo hapa chini inaonyesha matumizi machache ya kawaida na kadhaa yasiyo ya kawaida. ya ISNUMBER katika Excel.

Angalia kama thamani ni nambari

Unapokuwa na rundo la thamani kwenye lahakazi yako na ukitaka kujua ni zipi ni nambari, ISNUMBER ndio chaguo sahihi la kutumia. .

Katika mfano huu, thamani ya kwanza iko katika A2, kwa hivyo tunatumia fomula iliyo hapa chini kuikagua, na kisha tuburute chini fomula hadi seli nyingi inavyohitajika:

=ISNUMBER(A2)

Tafadhali zingatia kwamba ingawa thamani zote zinaonekana kama nambari, fomula ya ISNUMBER imerejesha FALSE kwa seli A4 na A5, kumaanisha kwamba thamani hizo ni mifuatano ya nambari , yaani, nambari zilizoumbizwa kama maandishi. Kunaweza kuwa na sababu tofauti za hii, kwa mfano sufuri zinazoongoza, apostrofi iliyotangulia, n.k. Sababu yoyote ile, Excel haitambui maadili kama nambari. Kwa hivyo, ikiwa thamani zako hazihesabiwi ipasavyo, jambo la kwanza kwako kuangalia ni kama kweli ni nambari kulingana na Excel, na kisha ubadilishe maandishi kuwa nambari ikihitajika.

Fomula ya Excel ISNUMBER SEARCH

Mbali na kutambua nambari, ExcelChaguo za kukokotoa za ISNUMBER pia zinaweza kuangalia kama kisanduku kina maandishi maalum kama sehemu ya maudhui. Kwa hili, tumia ISNUMBER pamoja na chaguo za kukokotoa za SEARCH.

Katika fomu ya jumla, fomula inaonekana kama ifuatavyo:

Ambapo substring ni maandishi ambayo ungependa kupata.

Kama mfano, hebu tuangalie kama mfuatano katika A3 una rangi maalum, sema nyekundu:

=ISNUMBER(SEARCH("red", A3))

Mfumo huu hufanya kazi vizuri kwa seli moja. Lakini kwa sababu jedwali letu la sampuli (tafadhali tazama hapa chini) lina rangi tatu tofauti, kuandika fomula tofauti kwa kila moja itakuwa ni kupoteza muda. Badala yake, tutarejelea kisanduku chenye rangi ya kuvutia (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Ili fomula inakili kwa usahihi chini na kulia, hakikisha kuwa umefunga viwianishi vifuatavyo kwa kutumia. alama ya $:

• Katika mfuatano mdogo rejeleo, funga safu mlalo (B$2) ili fomula zilizonakiliwa kila wakati ziteue mistari midogo katika safu mlalo ya 2. Rejeleo la safu wima ni linganifu kwa sababu sisi unataka irekebishe kwa kila safu, yaani, fomula inaponakiliwa hadi C3, rejeleo la kamba ndogo litabadilika kuwa C$2.
• Kwenye kisanduku chanzo marejeleo, funga safu wima ($A3 ) ili fomula zote ziangalie thamani katika safu wima A.

Picha ya skrini iliyo hapa chini inaonyesha matokeo:

ISNUMBER FIND - nyeti kwa ukubwa formula

Kwa vile kipengele cha UTAFUTA ni haijalishi , kilicho hapo juufomula haitofautishi herufi kubwa na ndogo. Iwapo unatafuta fomula ambayo ni nyeti kwa kesi, tumia kipengele cha KUTAFUTA badala ya TAFUTA.

Kwa sampuli ya mkusanyiko wetu wa data. , fomula inaweza kuchukua fomu hii:

=ISNUMBER(FIND(B$2, $A3))

Jinsi fomula hii inavyofanya kazi

mantiki ya fomula ni dhahiri kabisa na ni rahisi kufuata:

• Tafuta/TAFUTA chaguo za kukokotoa hutafuta mfuatano mdogo katika kisanduku maalum. Ikiwa kifungu kidogo kinapatikana, nafasi ya herufi ya kwanza inarudishwa. Ikiwa kifungu kidogo hakipatikani, chaguo za kukokotoa hutoa #VALUE! hitilafu.
• Chaguo za kukokotoa za ISNUMBER huichukua kutoka hapo na kuchakata nafasi za nambari. Kwa hivyo, ikiwa kifungu kidogo kitapatikana na nafasi yake kurejeshwa kama nambari, matokeo ya ISNUMBER yanatoka TRUE. Ikiwa kifungu kidogo hakipatikani na #VALUE! hitilafu hutokea, matokeo ya ISNUMBER FALSE.

IF ISNUMBER formula

Ikiwa unalenga kupata fomula inayotoa kitu kingine isipokuwa TRUE au FALSE, tumia ISNUMBER pamoja na chaguo za kukokotoa za IF.

Mfano 1. Kisanduku kina maandishi gani

Tukichukua mfano uliotangulia zaidi, tuseme unataka kuweka alama ya "x" rangi ya kila kipengee kama inavyoonyeshwa kwenye jedwali hapa chini.

Ili kufanya hili, funga tu fomula ya ISNUMBER SEARCH kwenye taarifa ya IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Ikiwa ISNUMBER itarudisha TRUE, chaguo za kukokotoa za IF hutoa matokeo "x" (au thamani nyingine yoyote unayosambaza thamani_kama_kweli hoja). ISNUMBER ikileta FALSE, chaguo za kukokotoa za IF hutoa mfuatano tupu ("").

Mfano wa 2. Herufi ya kwanza katika kisanduku ni nambari au maandishi

Fikiria kuwa unafanya kazi na orodha ya mifuatano ya alphanumeric na unataka kujua ikiwa herufi ya kwanza ya mfuatano ni nambari au herufi.

Ili kuunda fomula kama hii, utahitaji vitendaji 4 tofauti:

• Kitendo cha kukokotoa cha LEFT hutoa herufi ya kwanza tangu mwanzo wa mfuatano, sema katika kisanduku A2:

  LEFT(A2, 1)

• Kwa sababu LEFT ni ya kategoria ya vitendaji vya maandishi, yake matokeo huwa ni mfuatano wa maandishi kila mara, hata kama una nambari pekee. Kwa hiyo, kabla ya kuangalia tabia iliyotolewa, tunahitaji kujaribu kuibadilisha kuwa nambari. Kwa hili, tumia kipengele cha kukokotoa cha VALUE au opereta mara mbili ya unary:

  VALUE(LEFT(A2, 1)) au (--LEFT(A2, 1))

  Angalia pia: Kitabu cha kazi kilichoshirikiwa cha Excel: Jinsi ya kushiriki faili ya Excel kwa watumiaji wengi
• Chaguo za kukokotoa za ISNUMBER huamua ikiwa herufi iliyotolewa ni nambari au la:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Kulingana na matokeo ya ISNUMBER (TRUE au FALSE), chaguo za kukokotoa za IF hurejesha "Nambari" au "Barua", mtawalia.

Tukichukulia kuwa tunajaribu mfuatano katika A2, fomula kamili. inachukua umbo hili:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

au

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Kitendaji cha ISNUMBER pia kinafaa kwa kutoa nambari kutoka kwa mfuatano. Huu hapa mfano: Pata nambari kutoka kwa nafasi yoyote katika mfuatano.

Angalia kama thamani si nambari

Ingawa Microsoft Excel ina kazi maalum, ISNONTEXT, ili kubainisha.ikiwa thamani ya kisanduku si maandishi, chaguo la kukokotoa mlinganisho la nambari halipo.

Suluhisho rahisi ni kutumia ISNUMBER pamoja na NOT inayorejesha kinyume cha thamani ya kimantiki. Kwa maneno mengine, wakati ISNUMBER inarejesha TRUE, SIO kuibadilisha kuwa FALSE, na kinyume chake.

Ili kuiona ikitekelezwa, tafadhali angalia matokeo ya fomula ifuatayo:

=NOT(ISNUMBER(A2))

Mbinu nyingine ni kutumia chaguo za kukokotoa za IF na ISNUMBER pamoja:

=IF(ISNUMBER(A2), "", "Not number")

Ikiwa A2 ni nambari, fomula hairejeshi chochote (tupu. kamba). Ikiwa A2 si nambari, fomula inasema hivi mbele: "Si nambari".

Ikiwa ungependa kufanya hesabu kwa kutumia nambari, basi weka mlinganyo au nyingine. formula katika value_if_true hoja badala ya mfuatano tupu. Kwa mfano, fomula iliyo hapa chini itazidisha nambari kwa 10 na kutoa "Si nambari" kwa thamani zisizo za nambari:

=IF(ISNUMBER(A2), A2*10, "Not number")

Angalia ikiwa safu ina nambari yoyote

Katika hali unapotaka kujaribu fungu zima la nambari, tumia kitendakazi cha ISNUMBER pamoja na SUMPRODUCT kama hii:

Kwa mfano, ili kujua kama safu A2:A5 ina thamani yoyote ya nambari, fomula zingeenda kama ifuatavyo:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Ikiwa ungependa kutoa "Ndiyo" na "Hapana" badala ya TRUE na FALSE, tumia taarifa ya IF kama"rapper" kwa fomula zilizo hapo juu. Kwa mfano:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Jinsi fomula hii inavyofanya kazi

Katika kiini cha fomula, chaguo za kukokotoa za ISNUMBER hutathmini kila seli ya fomula. masafa maalum, sema B2:B5, na kurejesha TRUE kwa nambari, FALSE kwa kitu kingine chochote. Kwa vile safu ina visanduku 4, safu ina vipengele 4:

{TRUE;FALSE;FALSE;FALSE}

Operesheni ya kuzidisha au isiyo ya mara mbili (--) inalazimisha TRUE na FALSE kuwa 1 na 0, mtawalia:

{1;0;0;0}

Chaguo za kukokotoa za SUMPRODUCT huongeza vipengele vya safu. Ikiwa matokeo ni makubwa kuliko sifuri, hiyo inamaanisha kuwa kuna angalau nambari moja ya safu. Kwa hivyo, unatumia ">0" kupata matokeo ya mwisho ya TRUE au FALSE.

ISNUMBER katika umbizo la masharti ili kuangazia visanduku vilivyo na maandishi fulani

Ikiwa unatafuta kuangazia visanduku au safu mlalo zote ambazo zina maandishi mahususi, tengeneza sheria ya uumbizaji wa masharti kulingana na fomula ya ISNUMBER SEARCH (isiyojali kesi) au ISNUMBER FIND (isiyojali kesi).

Kwa mfano huu, tutaangazia safu mlalo kulingana na thamani katika safu A. Kwa usahihi, tutaangazia vitu vilivyo na neno "nyekundu". Hivi ndivyo unavyofanya:

1. Chagua safu mlalo zote za data (A2:C6 katika mfano huu) au safu wima pekee ambayo ungependa kuangazia visanduku.
2. Kwenye Nyumbani kichupo, katika kikundi cha Mitindo , bofya Kanuni Mpya > Tumia fomula ili kubainisha ni visanduku vipi vya umbizo .
3. Ndanikisanduku cha umbizo la thamani ambapo fomula hii ni kweli , weka fomula iliyo hapa chini (tafadhali kumbuka kuwa safu wima ya kuratibu imefungwa kwa ishara $):

   =ISNUMBER(SEARCH("red", $A2))

4. Bofya Kitufe cha Umbizo na uchague umbizo unayotaka.
5. Bofya Sawa mara mbili.

Ikiwa huna uzoefu na umbizo la masharti la Excel, unaweza kupata hatua za kina. na picha za skrini katika somo hili: Jinsi ya kuunda sheria ya uumbizaji wa masharti kulingana na fomula.

Kutokana na hayo, vipengee vyote vya rangi nyekundu vinaangaziwa:

Badala ya "kuweka msimbo mgumu" rangi katika sheria ya uumbizaji wa masharti, unaweza kuiandika katika kisanduku kilichobainishwa awali, tuseme E2, na kurejelea kisanduku hicho katika fomula yako (tafadhali kumbuka rejeleo kamili la kisanduku $E$2). Zaidi ya hayo, unahitaji kuangalia ikiwa kisanduku cha ingizo si tupu:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Kwa matokeo, utapata sheria inayoweza kunyumbulika zaidi inayoangazia safu mlalo kulingana na ingizo lako katika E2:

Hiyo ndivyo jinsi ya kutumia chaguo za kukokotoa za ISNUMBER katika Excel. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

Mifano ya fomula ya Excel ISNUMBER