Tutorialak Excel-en ISNUMBER zer den azaltzen du eta erabilera oinarrizko eta aurreratuen adibideak ematen ditu.

Excel-en ISNUMBER funtzioaren kontzeptua oso erraza da; jakina den ala ez egiaztatzen du. balioa zenbaki bat da ala ez. Puntu garrantzitsu bat da funtzioaren erabilera praktikoak bere oinarrizko kontzeptua baino askoz haratago doazela, batez ere formula handien barruan beste funtzio batzuekin konbinatzen direnean.

Excel ISNUMBER funtzioa

Excel-en ISNUMBER funtzioak gelaxka batek zenbakizko balio bat duen edo ez egiaztatzen du. IS funtzioen taldekoa da.

Funtzioa Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 eta aurreko bertsio guztietan dago eskuragarri.

ISNUMBER sintaxiak argumentu bakarra behar du:

=ISNUMBER(value)

Non balioa den probatu nahi duzun balioa. Normalean, gelaxka-erreferentzia batek adierazten du, baina balio erreal bat eman edo ISNUMBER barruan beste funtzio bat habiatu dezakezu emaitza egiaztatzeko.

balioa zenbakizkoa bada, funtzioak EGIA ematen du. . Beste edozertarako (testu-balioak, akatsak, hutsuneak) ISNUMERAK GEZURRA itzultzen du.

Adibide gisa, proba ditzagun A2tik A6 bitarteko gelaxketako balioak, eta lehen 3 balioak zenbakiak direla eta azken biak jakingo dugu. testua dira:

Excel-en ISNUMBER funtzioari buruz jakin behar dituzun 2 gauza

Hemen kontuan hartu beharreko pare bat puntu interesgarri daude:

• InExcel barneko irudikapena, datak eta aldiz zenbakizko balioak dira, beraz, ISNUMBER formulak EGIA itzultzen du haientzat (mesedez, ikusi B3 eta B4 goiko pantaila-argazkian).
• Horretarako testu gisa gordetako zenbakiak, ISNUMBER funtzioak GEZURRA itzultzen du (ikusi adibide hau).

Excel ISNUMBER formula adibideak

Beheko adibideek erabilera arrunt batzuk eta ez-trivial batzuk erakusten dituzte. Excel-en ISNUMBER.

Egiaztatu balio bat zenbakia den

Zure lan-orrian balio mordoa dituzunean eta zeintzuk diren zenbakiak jakin nahi duzunean, ISNUMBER da erabiltzeko funtzio egokia. .

Adibide honetan, lehenengo balioa A2n dago, beraz, beheko formula erabiltzen dugu hura egiaztatzeko, eta, ondoren, arrastatu behera formula behar adina gelaxkaraino:

=ISNUMBER(A2)

Mesedez, kontutan izan balio guztiak zenbaki itxura duten arren, ISNUMBER formulak GEZURRA itzuli duela A4 eta A5 gelaxketarako, hau da, balio horiek zenbakizko kateak direla esan nahi du. , hau da, testu gisa formateatutako zenbakiak. Arrazoi desberdinak egon daitezke, adibidez, zero hasierakoak, apostrofoa aurrekoa, etab. Arrazoia edozein dela ere, Excel-ek ez ditu zenbaki gisa ezagutzen baliorik. Beraz, zure balioak ez badira behar bezala kalkulatzen, egiaztatzen duzun lehenengo gauza da benetan zenbakiak ote diren Excel-en arabera, eta gero testua zenbaki bihurtzea behar izanez gero.

Excel ISNUMERAKO BILAKETA formula

Zenbakiak identifikatzeaz gain, ExcelISNUMBER funtzioak ere egiazta dezake gelaxka batek testu zehatza duen edukiaren zati gisa. Horretarako, erabili ISNUMBER (BILATZAILEA) funtzioarekin batera.

Formula generikoan, formulak honela dauka:

Non azpikatea den aurkitu nahi duzun testua.

Adibide gisa, egiaztatu dezagun A3-ko kateak kolore zehatzik duen ala ez, esan gorria:

=ISNUMBER(SEARCH("red", A3))

Formula honek ondo funtzionatzen du gelaxka bakarrerako. Baina gure lagin-taulak (ikus behean) hiru kolore ezberdin dituenez, bakoitzarentzat formula bereizia idaztea denbora galtzea litzateke. Horren ordez, kolore interesgarria (B2) duen gelaxkara aipatuko dugu.

=ISNUMBER(SEARCH(B$2, $A3))

Formula ondo kopiatzeko eta eskuinera, ziurtatu ondoko koordenatuak blokeatzen dituzula. $ ikurra:

• azpikatea erreferentzian, blokeatu errenkada (B$2), kopiatutako formulek 2. errenkadako azpikateak beti har ditzaten. Zutabe-erreferentzia erlatiboa da, zeren eta. zutabe bakoitzerako doitzea nahi du, hau da, formula C3-n kopiatzen denean, azpikatearen erreferentzia C$2-ra aldatuko da.
• iturburu-gelaxka erreferentzian, blokeatu zutabea ($A3 ) formula guztiek A zutabeko balioak egiaztatzeko.

Beheko pantaila-argazkiak emaitza erakusten du:

ISNUMBER FIND - maiuskulak eta minuskulak bereizten ditu. formula

BILATZAILEA funtzioak maiuskulak eta minuskulak bereizten ez dituenez , goikoaformulak ez ditu letra larriak eta minuskulak bereizten. Maiuskulak eta minuskulak bereizten dituen formula baten bila bazabiltza, erabili BILATU funtzioa baino.

Gure lagin-datu multzorako , formulak forma hau hartuko luke:

=ISNUMBER(FIND(B$2, $A3))

Nola funtzionatzen duen formula

Formularen logika nahiko agerikoa da eta erraza da jarraitzeko:

• BILATU / BILATU funtzioak zehaztutako gelaxkan azpikatea bilatzen du. Azpikatea aurkitzen bada, lehenengo karakterearen posizioa itzultzen da. Azpikatea aurkitzen ez bada, funtzioak #BALIOA sortzen du! errorea.
• ISNUMBER funtzioak hortik hartzen du eta zenbakizko posizioak prozesatzen ditu. Beraz, azpikatea aurkitzen bada eta bere posizioa zenbaki gisa itzultzen bada, ISNUMBER EGIA ateratzen du. Azpikatea aurkitzen ez bada eta #BALIOA! errorea gertatzen da, ZENBAKIA ZENBAKIA GEZURRA ematen du.

ZENBAKIA ZENBAKIA formula

EGIA edo GEZURRA ez den beste zerbait ateratzen duen formula bat lortu nahi baduzu, erabili ZENBAKIA IZENA funtzioarekin batera.

1. Adibidea. Gelaxkak zein testu dauka

Aurreko adibidea gehiago hartuz, demagun elementu bakoitzaren kolorea "x"rekin markatu nahi duzula beheko taulan agertzen den bezala.

Hau egin ahal izateko, besterik gabe, bildu ISNUMBER SEARCH formula IF adierazpenean:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

ISNUMBER EGIA itzultzen badu, IF funtzioak "x" ateratzen du (edo zuk ematen duzun beste edozein balio). balio_egia_baldin argumentua). ISNUMBER FALSE itzultzen badu, IF funtzioak kate huts bat ateratzen du ("").

Adibidea 2. Gelaxka bateko lehen karakterea zenbakia edo testua da

Imajinatu kate alfanumerikoen zerrenda batekin lanean ari zarela eta kate baten lehen karakterea zenbaki bat edo letra den jakin nahi duzula.

Halako formula bat eraikitzeko, 4 funtzio ezberdin beharko dituzu:

• EZKERRA funtzioak kate baten hasieratik lehen karakterea ateratzen du, esan A2 gelaxkan:

  LEFT(A2, 1)

• EZKERRA Testu-funtzioen kategoriakoa denez, bere emaitza testu-kate bat da beti, nahiz eta zenbakiak bakarrik eduki. Horregatik, ateratako karakterea egiaztatu aurretik, zenbaki bat bihurtzen saiatu behar dugu. Horretarako, erabili BALIOA funtzioa edo operadore unario bikoitza:

  VALUE(LEFT(A2, 1)) edo (--LEFT(A2, 1))

• ISNUMBER funtzioak zehazten du ateratako karakterea zenbakizkoa den ala ez:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• ISNUMBER emaitzan oinarrituta (EGIA edo GEZURRA), IF funtzioak "Zenbakia" edo "Letra" itzultzen du, hurrenez hurren.

A2-ko kate bat probatzen ari garela suposatuz, formula osoa. Forma hau hartzen du:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

edo

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER funtzioa ere ondo dator <12rako>zenbakiak kate batetik ateratzen. Hona hemen adibide bat: Lortu zenbakia kate bateko edozein posiziotatik.

Egiaztatu balio bat zenbakia ez den

Microsoft Excel-ek funtzio berezi bat duen arren, ISNONTEXT, zehazteko.gelaxka baten balioa testua ez den ala ez, zenbakietarako funtzio analogo bat falta da.

Irtenbide erraz bat balio logiko baten kontrakoa itzultzen duen ISNUMBER erabiltzea da ZENBURUarekin batera. Beste era batera esanda, ISNUMBER EGIA itzultzen duenean, EZ GEZURRA bihurtzen du, eta alderantziz.

Ekintzan ikusteko, begiratu formula honen emaitzak:

=NOT(ISNUMBER(A2))

Beste ikuspegi bat IF eta ISNUMBER funtzioak batera erabiltzea da:

=IF(ISNUMBER(A2), "", "Not number")

A2 zenbakizkoa bada, formulak ez du ezer itzultzen (hutsik katea). A2 zenbakizkoa ez bada, formulak aldez aurretik esaten du: "Ez zenbakia".

Zenbakiekin kalkulu batzuk egin nahi badituzu, jarri ekuazio bat edo beste. formula value_if_true argumentuan kate huts baten ordez. Adibidez, beheko formulak zenbakiak 10ez biderkatuko ditu eta zenbakizkoak ez diren balioetarako "Zenbakia ez" emango du:

=IF(ISNUMBER(A2), A2*10, "Not number")

Egiaztatu barruti batek edozein zenbaki duen

In Zenbakien barruti osoa probatu nahi duzun egoeran, erabili ISNUMBER funtzioa SUMPRODUCT-ekin konbinatuta honela:

Adibidez, A2:A5 barrutiak zenbakizko baliorik duen jakiteko, formulak honela geratuko lirateke:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

"Bai" eta "Ez" atera nahi badituzu EGIA eta GEZURRA ordez, erabili IF adierazpena gisa"bilgarri" aurreko formuletarako. Adibidez:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Formula honek nola funtzionatzen duen

Formularen muinean, ISNUMBER funtzioak gelaxka bakoitza ebaluatzen du. zehaztutako barrutia, esan B2:B5, eta EGIA ematen du zenbakietarako, GEZURRA beste edozertarako. Barrutiak 4 gelaxka dituenez, matrizeak 4 elementu ditu:

{TRUE;FALSE;FALSE;FALSE}

Biderketa eragiketak edo unario bikoitzak (--) TRUE eta FALSE behartzen ditu 1 eta 0etan, hurrenez hurren:

{1;0;0;0}

SUMPRODUCT funtzioak matrizeko elementuak gehitzen ditu. Emaitza zero baino handiagoa bada, horrek esan nahi du gutxienez zenbaki bat dagoela barrutian. Beraz, ">0" erabiltzen duzu TRUE edo FALSE azken emaitza lortzeko.

ISNUMBER baldintzazko formatuan testu jakin bat duten gelaxkak nabarmentzeko. testu espezifikoa duten errenkada osoak, formatu baldintzapeko arau bat sortu ISNUMBER SEARCH (maiuskulak eta minuskulak bereizten ez dituena) edo ISNUMBER FIND (maiuskulak eta minuskulak bereizten dituena) formulan oinarrituta.

Adibide honetarako, errenkadak nabarmenduko ditugu. A zutabeko balioa. Zehatzago esanda, "gorria" hitza duten elementuak nabarmenduko ditugu. Hona hemen nola:

1. Hautatu datu-lerro guztiak (A2:C6 adibide honetan) edo soilik gelaxkak nabarmendu nahi dituzun zutabea.
2. Hasierako fitxan, Estiloak taldean, sakatu Arau berria > Erabili formula bat zein gelaxka formateatu behar den zehazteko .
3. In Formatu balioak non formula hau egia den koadroan, sartu beheko formula (mesedez, konturatu zutabearen koordenatua $ zeinuarekin blokeatuta dagoela):

   =ISNUMBER(SEARCH("red", $A2))

4. Egin klik botoian. Formatu botoia eta aukeratu nahi duzun formatua.
5. Sakatu Ados bi aldiz.

Excel baldintzapeko formatearekin esperientzia gutxi baduzu, urrats zehatzak aurki ditzakezu. Tutorial honetako pantaila-argazkiekin: Formulan oinarritutako baldintzazko formatu-arau bat nola sortu.

Ondorioz, kolore gorriko elementu guztiak nabarmentzen dira:

Baldintzazko formatu-arauan kolorea "gogor kodetu" beharrean, aurrez definitutako gelaxka batean idatz dezakezu, esan E2, eta zure formulako gelaxka horri erreferentzia egin dezakezu (mesedez, kontuan izan $E$2 gelaxka absolutua). Gainera, sarrerako gelaxka hutsik ez dagoen egiaztatu behar duzu:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Ondorioz, E2-n zure sarreran oinarritutako errenkadak nabarmentzen dituen arau malguagoa lortuko duzu:

Horrela erabiltzen da ISNUMBER funtzioa Excel-en. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Deskarga erabilgarri

Excel ISNUMBER formula adibideak