El tutorial explica què és ISNUMBER a Excel i ofereix exemples d'usos bàsics i avançats.

El concepte de la funció ISNUMBER a Excel és molt senzill: només comprova si un determinat el valor és un nombre o no. Un punt important aquí és que els usos pràctics de la funció van molt més enllà del seu concepte bàsic, especialment quan es combinen amb altres funcions dins de fórmules més grans.

Funció d'Excel ISNUMBER

La funció ISNUMBER a Excel comprova si una cel·la conté un valor numèric o no. Pertany al grup de funcions IS.

La funció està disponible en totes les versions d'Excel per a Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 i anteriors.

La sintaxi ISNUMBER requereix només un argument:

=ISNUMBER(value)

On valor és el valor que voleu provar. Normalment, es representa amb una referència de cel·la, però també podeu proporcionar un valor real o anidar una altra funció dins ISNUMBER per comprovar el resultat.

Si valor és numèric, la funció retorna TRUE. . Per a qualsevol altra cosa (valors de text, errors, espais en blanc) ISNUMBER retorna FALSE.

Com a exemple, provem els valors de les cel·les A2 a A6, i descobrirem que els 3 primers valors són números i els dos últims. són text:

2 coses que hauríeu de saber sobre la funció ISNUMBER a Excel

Hi ha un parell de punts interessants a tenir en compte aquí:

• Enrepresentació interna d'Excel, dates i vegades són valors numèrics, de manera que la fórmula ISNUMBER els retorna TRUE (vegeu B3 i B4 a la captura de pantalla anterior).
• Per a nombres emmagatzemats com a text, la funció ISNUMBER retorna FALSE (vegeu aquest exemple).

Excels de fórmules ISNUMBER d'Excel

Els exemples següents mostren alguns usos comuns i un parell d'usos no trivials. d'ISNUMBER a Excel.

Comproveu si un valor és un nombre

Quan teniu un munt de valors al vostre full de treball i voleu saber quins són números, ISNUMBER és la funció adequada per utilitzar .

En aquest exemple, el primer valor és a A2, de manera que utilitzem la fórmula següent per comprovar-ho i, a continuació, arrossegueu la fórmula cap avall fins a tantes cel·les com calgui:

=ISNUMBER(A2)

Si us plau, tingueu en compte que, tot i que tots els valors semblen números, la fórmula ISNUMBER ha retornat FALSE per a les cel·les A4 i A5, el que significa que aquests valors són cadenes numèriques , és a dir, números amb format de text. Pot haver-hi diferents motius per a això, per exemple, zeros inicials, apòstrofs anteriors, etc. Sigui quina sigui la raó, Excel no reconeix aquests valors com a nombres. Per tant, si els vostres valors no es calculen correctament, el primer que heu de comprovar és si realment són números en termes d'Excel i, a continuació, convertir text en nombre si cal.

Fórmula de cerca d'Excel ISNUMBER

A part d'identificar números, l'ExcelLa funció ISNUMBER també pot comprovar si una cel·la conté text específic com a part del contingut. Per a això, utilitzeu ISNUMBER juntament amb la funció SEARCH.

En la forma genèrica, la fórmula té el següent aspecte:

On subcadena és el text que voleu trobar.

Com a exemple, comprovem si la cadena en A3 conté un color específic, per exemple vermell:

=ISNUMBER(SEARCH("red", A3))

Aquesta fórmula funciona bé per a una sola cel·la. Però com que la nostra taula de mostra (vegeu a continuació) conté tres colors diferents, escriure una fórmula separada per a cadascun seria una pèrdua de temps. En comptes d'això, ens referirem a la cel·la que conté el color d'interès (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Perquè la fórmula es copie correctament cap avall i cap a la dreta, assegureu-vos de bloquejar les coordenades següents amb el signe $:

• A la referència subcadena , bloquegeu la fila (B$2) de manera que les fórmules copiades sempre triin les subcadenes a la fila 2. La referència a la columna és relativa perquè voleu que s'ajusti per a cada columna, és a dir, quan la fórmula es copie a C3, la referència de la subcadena canviarà a C$2.
• A la referència cel·la font , bloquegeu la columna ($A3 ) perquè totes les fórmules comprovin els valors de la columna A.

La captura de pantalla següent mostra el resultat:

ISNUMBER FIND - distingeix entre majúscules i minúscules fórmula

Com que la funció de cerca no distingeix entre majúscules i minúscules , l'anteriorLa fórmula no diferencia els caràcters en majúscules i minúscules. Si busqueu una fórmula que distingeix entre majúscules i minúscules, utilitzeu la funció TROBA en lloc de CERCAR.

Per al nostre conjunt de dades de mostra , la fórmula tindria aquesta forma:

=ISNUMBER(FIND(B$2, $A3))

Com funciona aquesta fórmula

La lògica de la fórmula és força òbvia i fàcil de seguir:

• La funció CERCAR/TROBAR cerca la subcadena a la cel·la especificada. Si es troba la subcadena, es retorna la posició del primer caràcter. Si no es troba la subcadena, la funció produeix un #VALOR! error.
• La funció ISNUMBER l'agafa d'allà i processa les posicions numèriques. Per tant, si es troba la subcadena i es retorna la seva posició com a nombre, ISNUMBER mostra TRUE. Si no es troba la subcadena i un #VALOR! es produeix un error, ISNUMBER dóna FALSE.

IF ISNUMBER fórmula

Si voleu obtenir una fórmula que no sigui TRUE o FALSE, utilitzeu ISNUMBER juntament amb la funció SI.

Exemple 1. La cel·la conté quin text

Avant l'exemple anterior, suposem que voleu marcar el color de cada element amb "x" com es mostra a la taula següent.

Per fer-ho, simplement embolcalla la fórmula ISNUMBER SEARCH a la instrucció IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Si ISNUMBER retorna TRUE, la funció SI mostra "x" (o qualsevol altre valor que proporcioneu a el value_if_true argument). Si ISNUMBER retorna FALSE, la funció SI mostra una cadena buida ("").

Exemple 2. El primer caràcter d'una cel·la és el número o el text

Imagineu que esteu treballant amb una llista de cadenes alfanumèriques i voleu saber si el primer caràcter d'una cadena és un número o una lletra.

Per construir aquesta fórmula, necessitareu 4 funcions diferents:

• La funció LEFT extreu el primer caràcter de l'inici d'una cadena, per exemple a la cel·la A2:

  LEFT(A2, 1)

• Com que LEFT pertany a la categoria de funcions de text, la seva resultat sempre és una cadena de text, encara que només conté números. Per tant, abans de comprovar el caràcter extret, hem d'intentar convertir-lo en un número. Per a això, utilitzeu la funció VALOR o l'operador unari doble:

  VALUE(LEFT(A2, 1)) o (--LEFT(A2, 1))

• La funció ISNUMBER determina si el caràcter extret és numèric o no:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• En funció del resultat ISNUMBER (VERTADER o FALSE), la funció SI retorna "Número" o "Lletra", respectivament.

Suposant que estem provant una cadena en A2, la fórmula completa pren aquesta forma:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

o

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

La funció ISNUMBER també és útil per a extreu nombres d'una cadena. Aquí teniu un exemple: Obteniu un número de qualsevol posició d'una cadena.

Comproveu si un valor no és un nombre

Tot i que Microsoft Excel té una funció especial, ISNONTEXT, per determinarsi el valor d'una cel·la no és text, falta una funció anàloga per als números.

Una solució fàcil és utilitzar ISNUMBER en combinació amb NOT que retorna el contrari d'un valor lògic. En altres paraules, quan ISNUMBER retorna TRUE, NOT el converteix en FALSE i al revés.

Per veure'l en acció, observeu els resultats de la fórmula següent:

=NOT(ISNUMBER(A2))

Un altre enfocament és utilitzar les funcions SI i ISNUMBER juntes:

=IF(ISNUMBER(A2), "", "Not number")

Si A2 és numèric, la fórmula no retorna res (un buit corda). Si A2 no és numèric, la fórmula ho diu per endavant: "No és número".

Si voleu fer alguns càlculs amb números, poseu una equació o una altra. fórmula a l'argument value_if_true en lloc d'una cadena buida. Per exemple, la fórmula següent multiplicarà els nombres per 10 i donarà "No és número" per als valors no numèrics:

=IF(ISNUMBER(A2), A2*10, "Not number")

Comproveu si un interval conté algun nombre

En Si voleu provar tot l'interval de números, utilitzeu la funció ISNUMBER en combinació amb SUMPRODUCT com aquesta:

Per exemple, per esbrinar si l'interval A2:A5 conté algun valor numèric, les fórmules serien de la següent manera:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Si voleu mostrar "Sí" i "No" en lloc de VERTADER i FALS, utilitzeu la instrucció IF com a"embolcall" per a les fórmules anteriors. Per exemple:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Com funciona aquesta fórmula

Al cor de la fórmula, la funció ISNUMBER avalua cada cel·la de la interval especificat, per exemple B2:B5, i retorna TRUE per als números, FALSE per a qualsevol altra cosa. Com que l'interval conté 4 cel·les, la matriu té 4 elements:

{TRUE;FALSE;FALSE;FALSE}

L'operació de multiplicació o el doble unari (--) obliga a TRUE i FALSE a 1 i 0, respectivament:

{1;0;0;0}

La funció SUMAPRODUCTE suma els elements de la matriu. Si el resultat és superior a zero, vol dir que hi ha almenys un nombre en l'interval. Per tant, feu servir ">0" per obtenir un resultat final de TRUE o FALSE.

ISNUMBER en format condicional per ressaltar les cel·les que contenen cert text

Si voleu ressaltar cel·les o files senceres que continguin text específic, creeu una regla de format condicional basada en la fórmula ISNUMBER SEARCH (no distingeix entre majúscules i minúscules) o ISNUMBER FIND (distingeix entre majúscules i minúscules).

Per a aquest exemple, ressaltarem les files basades en el valor de la columna A. Més precisament, destacarem els elements que continguin la paraula "vermell". A continuació us indiquem com:

1. Seleccioneu totes les files de dades (A2:C6 en aquest exemple) o només la columna en què voleu ressaltar les cel·les.
2. A la Inici , al grup Estils , feu clic a Nova regla > Utilitzeu una fórmula per determinar quines cel·les voleu formatar .
3. Aal quadre Format dels valors on aquesta fórmula és certa , introduïu la fórmula següent (si us plau, tingueu en compte que la coordenada de la columna està bloquejada amb el signe $):

   =ISNUMBER(SEARCH("red", $A2))

4. Feu clic al botó Botó Format i trieu el format que vulgueu.
5. Feu clic a D'acord dues vegades.

Si teniu poca experiència amb el format condicional d'Excel, podeu trobar els passos detallats. amb captures de pantalla en aquest tutorial: Com crear una regla de format condicional basada en fórmules.

Com a resultat, es ressalten tots els elements del color vermell:

En lloc de "codificar" el color a la regla de format condicional, podeu escriure'l en una cel·la predefinida, per exemple E2, i referir-vos a aquesta cel·la a la vostra fórmula (si us plau, tingueu en compte la referència de cel·la absoluta $E$2). A més, heu de comprovar si la cel·la d'entrada no està buida:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Com a resultat, obtindreu una regla més flexible que ressalta les files segons la vostra entrada a E2:

Així és com s'utilitza la funció ISNUMBER a Excel. Us agraeixo la lectura i esperem veure-us al nostre blog la setmana vinent!

Descàrregues disponibles

Excels de fórmules ISNUMBER d'Excel