Vodič objašnjava šta je ISNUMBER u Excelu i pruža primjere osnovne i napredne upotrebe.

Koncept funkcije ISNUMBER u Excelu je vrlo jednostavan - samo provjerava da li vrijednost je broj ili ne. Ovdje je važna stvar da praktična upotreba funkcije nadilazi njen osnovni koncept, posebno kada se kombinira s drugim funkcijama unutar većih formula.

Excel funkcija ISNUMBER

Funkcija ISNUMBER u Excelu provjerava sadrži li ćelija numeričku vrijednost ili ne. Spada u grupu IS funkcija.

Funkcija je dostupna u svim verzijama Excela za Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 i starije.

Sintaksa ISNUMBER zahtijeva samo jedan argument:

=ISNUMBER(value)

Gdje je vrijednost vrijednost koju želite testirati. Obično je predstavljen referencom ćelije, ali također možete dostaviti stvarnu vrijednost ili ugnijezditi drugu funkciju unutar ISNUMBER da biste provjerili rezultat.

Ako je vrijednost numerička, funkcija vraća TRUE . Za bilo šta drugo (tekstualne vrijednosti, greške, praznine) ISNUMBER vraća FALSE.

Kao primjer, testirajmo vrijednosti u ćelijama A2 do A6, i otkrit ćemo da su prve 3 vrijednosti brojevi, a posljednje dvije su tekst:

2 stvari koje biste trebali znati o funkciji ISNUMBER u Excelu

Ovdje treba napomenuti nekoliko zanimljivih stvari:

• Uinterna Excel reprezentacija, datumi i puta su numeričke vrijednosti, tako da formula ISNUMBER vraća TRUE za njih (pogledajte B3 i B4 na slici iznad).
• Za brojeva pohranjenih kao tekst, funkcija ISNUMBER vraća FALSE (pogledajte ovaj primjer).

Primjeri formule ISNUMBER u Excelu

Primjeri u nastavku pokazuju nekoliko uobičajenih i nekoliko netrivijalnih upotreba od ISNUMBER u Excelu.

Provjerite da li je vrijednost broj

Kada imate gomilu vrijednosti u svom radnom listu i želite znati koje su to brojevi, ISNUMBER je prava funkcija za korištenje .

U ovom primjeru, prva vrijednost je u A2, tako da koristimo formulu ispod da je provjerimo, a zatim povlačimo formulu na onoliko ćelija koliko je potrebno:

=ISNUMBER(A2)

Obratite pažnju da iako sve vrijednosti izgledaju kao brojevi, formula ISNUMBER je vratila FALSE za ćelije A4 i A5, što znači da su te vrijednosti numerički nizovi , tj. brojevi formatirani kao tekst. Za to mogu postojati različiti razlozi, na primjer vodeće nule, prethodni apostrof itd. Bez obzira na razlog, Excel ne prepoznaje takve vrijednosti kao brojeve. Dakle, ako se vaše vrijednosti ne izračunaju ispravno, prva stvar koju trebate provjeriti je da li su to zaista brojevi u smislu Excela, a zatim pretvoriti tekst u broj ako je potrebno.

Formula za PRETRAŽIVANJE BROJEVA u Excelu

Osim identifikacionih brojeva, ExcelFunkcija ISNUMBER također može provjeriti da li ćelija sadrži određeni tekst kao dio sadržaja. Za ovo koristite ISNUMBER zajedno sa funkcijom SEARCH.

U generičkom obliku, formula izgleda ovako:

Gdje je podniz tekst koji želite pronaći.

Kao primjer, provjerimo da li niz u A3 sadrži određenu boju, recimo crvenu:

=ISNUMBER(SEARCH("red", A3))

Ova formula dobro funkcionira za jednu ćeliju. Ali pošto naša tabela sa uzorcima (pogledajte dole) sadrži tri različite boje, pisanje posebne formule za svaku bilo bi gubljenje vremena. Umjesto toga, pozivaćemo se na ćeliju koja sadrži boju od interesa (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Da bi se formula ispravno kopirala dolje i udesno, obavezno zaključajte sljedeće koordinate pomoću znak $:

• U referenci podniz , zaključajte red (B$2) tako da kopirane formule uvijek biraju podnizove u redu 2. Referenca kolone je relativna jer mi želite da se prilagodi za svaku kolonu, tj. kada se formula kopira u C3, referenca podniza će se promijeniti u C$2.
• U izvornoj ćeliji referenci, zaključajte stupac ($A3 ) tako da sve formule provjeravaju vrijednosti u koloni A.

Snimak ekrana ispod pokazuje rezultat:

ISBROJ PRONAĐI - razlikuje velika i mala slova formula

Kako je funkcija SEARCH neosjetljiva na velika i mala slova , gore navedenoformula ne razlikuje velika i mala slova. Ako tražite formulu osjetljivu na velika i mala slova, koristite funkciju FIND umjesto SEARCH.

Za naš skup uzoraka podataka , formula bi imala ovaj oblik:

=ISNUMBER(FIND(B$2, $A3))

Kako ova formula funkcionira

Logika formule je prilično očigledna i lako je slijediti:

• Funkcija SEARCH / FIND traži podniz u navedenoj ćeliji. Ako je podniz pronađen, vraća se pozicija prvog znaka. Ako podniz nije pronađen, funkcija proizvodi #VRIJEDNOST! greška.
• Funkcija ISNUMBER preuzima je odatle i obrađuje numeričke pozicije. Dakle, ako je podniz pronađen i njegova pozicija se vrati kao broj, ISNUMBER daje TRUE. Ako podniz nije pronađen i #VALUE! dogodi se greška, ISNUMBER daje FALSE.

IF ISNUMBER formula

Ako želite dobiti formulu koja daje nešto drugo osim TRUE ili FALSE, koristite ISNUMBER zajedno s funkcijom IF.

Primjer 1. Ćelija sadrži koji tekst

Uzmimo dalje u prethodni primjer, pretpostavimo da želite da označite boju svake stavke sa "x" kao što je prikazano u tabeli ispod.

Da biste to učinili, jednostavno umotajte formulu ISNUMBER SEARCH u IF naredbu:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Ako ISNUMBER vrati TRUE, funkcija IF daje "x" (ili bilo koju drugu vrijednost koju unesete u vrijednost_ako_tačno argument). Ako ISNUMBER vrati FALSE, funkcija IF daje prazan niz ("").

Primjer 2. Prvi znak u ćeliji je broj ili tekst

Zamislite da radite sa listom alfanumeričkih nizova i želite da znate da li je prvi znak stringa broj ili slovo.

Da bismo napravili takvu formulu, trebaće vam 4 različite funkcije:

• Funkcija LEFT izdvaja prvi znak sa početka niza, recimo u ćeliji A2:

  LEFT(A2, 1)

• Budući da LEFT pripada kategoriji tekstualnih funkcija, rezultat je uvijek tekstualni niz, čak i ako sadrži samo brojeve. Stoga, prije nego što provjerimo izdvojeni znak, moramo ga pokušati pretvoriti u broj. Za ovo koristite funkciju VALUE ili dvostruki unarni operator:

  VALUE(LEFT(A2, 1)) ili (--LEFT(A2, 1))

• Funkcija ISNUMBER određuje je li izdvojeni znak numerički ili ne:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Na osnovu rezultata ISNUMBER (TRUE ili FALSE), funkcija IF vraća "Broj" ili "Slovo", respektivno.

Pod pretpostavkom da testiramo niz u A2, kompletna formula poprima ovaj oblik:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ili

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Funkcija ISNUMBER također je zgodna za izdvajanje brojeva iz niza. Evo primjera: Dobijte broj sa bilo koje pozicije u nizu.

Provjerite da li vrijednost nije broj

Iako Microsoft Excel ima posebnu funkciju, ISNONTEXT, za određivanjebez obzira da li vrijednost ćelije nije tekst, analogna funkcija za brojeve nedostaje.

Jednostavno rješenje je korištenje ISNUMBER u kombinaciji sa NOT koji vraća suprotnu logičku vrijednost. Drugim riječima, kada ISNUMBER vrati TRUE, NOT ga konvertuje u FALSE, i obrnuto.

Da biste ga vidjeli u akciji, pogledajte rezultate sljedeće formule:

=NOT(ISNUMBER(A2))

Drugi pristup je korištenje funkcija IF i ISNUMBER zajedno:

=IF(ISNUMBER(A2), "", "Not number")

Ako je A2 numerički, formula ne vraća ništa (prazan string). Ako A2 nije numerički, formula to kaže unaprijed: "Nije broj".

Ako želite izvršiti neke proračune s brojevima, onda stavite jednačinu ili neku drugu formula u argumentu value_if_true umjesto praznog niza. Na primjer, donja formula će pomnožiti brojeve sa 10 i dati "Nije broj" za nenumeričke vrijednosti:

=IF(ISNUMBER(A2), A2*10, "Not number")

Provjerite da li raspon sadrži bilo koji broj

In u situaciji kada želite da testirate ceo opseg za brojeve, koristite funkciju ISBROJ u kombinaciji sa ZBIRNI PROIZVOD na sledeći način:

Na primjer, da biste saznali da li raspon A2:A5 sadrži bilo koju numeričku vrijednost, formule bi išle na sljedeći način:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Ako želite ispisati "Da" i "Ne" umjesto TRUE i FALSE, koristite IF naredbu kao"omotač" za gornje formule. Na primjer:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Kako ova formula funkcionira

U srcu formule, funkcija ISNUMBER procjenjuje svaku ćeliju specificirani opseg, recimo B2:B5, i vraća TRUE za brojeve, FALSE za bilo šta drugo. Kako raspon sadrži 4 ćelije, niz ima 4 elementa:

{TRUE;FALSE;FALSE;FALSE}

Operacija množenja ili dvostruka unarna (--) prisiljava TRUE i FALSE u 1 i 0, respektivno:

{1;0;0;0}

Funkcija SUMPRODUCT zbraja elemente niza. Ako je rezultat veći od nule, to znači da postoji barem jedan broj u rasponu. Dakle, koristite ">0" da dobijete konačni rezultat TRUE ili FALSE.

ISNUMBER u uvjetnom formatiranju da biste istaknuli ćelije koje sadrže određeni tekst

Ako želite istaknuti ćelije ili cijeli redovi koji sadrže određeni tekst, kreirajte pravilo uvjetnog oblikovanja na osnovu formule ISNUMBER SEARCH (neosjetljivo na velika i mala slova) ili ISNUMBER FIND (osjetljivo na velika i mala slova).

Za ovaj primjer, istaći ćemo redove na osnovu vrijednost u koloni A. Tačnije, označićemo stavke koje sadrže riječ "crveno". Evo kako:

1. Izaberite sve redove podataka (A2:C6 u ovom primjeru) ili samo kolonu u kojoj želite istaknuti ćelije.
2. Na Početnoj , u grupi Stilovi kliknite na Novo pravilo > Koristite formulu da odredite koje ćelije želite formatirati .
3. Uu polje Format vrijednosti gdje je ova formula istinita , unesite formulu ispod (imajte na umu da je koordinata stupca zaključana znakom $):

   =ISNUMBER(SEARCH("red", $A2))

4. Kliknite na Dugme Format i odaberite format koji želite.
5. Kliknite dvaput OK.

Ako imate malo iskustva s Excel uslovnim formatiranjem, možete pronaći detaljne korake sa snimkama ekrana u ovom vodiču: Kako kreirati pravilo uslovnog formatiranja zasnovano na formuli.

Kao rezultat, sve stavke crvene boje su istaknute:

Umjesto da "čvrsto kodirate" boju u pravilu uvjetnog oblikovanja, možete je upisati u unaprijed definiranu ćeliju, recimo E2, i uputiti se na tu ćeliju u vašoj formuli (molimo vas da obratite pažnju na apsolutnu referencu ćelije $E$2). Dodatno, morate provjeriti da li ulazna ćelija nije prazna:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Kao rezultat, dobit ćete fleksibilnije pravilo koje ističe redove na osnovu vašeg unosa u E2:

Tako se koristi funkcija ISNUMBER u Excelu. Zahvaljujem vam što čitate i nadam se da se vidimo na našem blogu sljedeće sedmice!

Dostupna preuzimanja

Primjeri formule ISNUMBER u Excelu