Ce tutoriel explique ce qu'est ISNUMBER dans Excel et fournit des exemples d'utilisations de base et avancées.

Le concept de la fonction ISNUMBER dans Excel est très simple : elle vérifie simplement si une valeur donnée est un nombre ou non. Il est important de noter que les utilisations pratiques de la fonction vont bien au-delà de son concept de base, notamment lorsqu'elle est combinée à d'autres fonctions dans des formules plus importantes.

Fonction ISNUMBER d'Excel

La fonction ISNUMBER d'Excel vérifie si une cellule contient une valeur numérique ou non. Elle appartient au groupe des fonctions IS.

La fonction est disponible dans toutes les versions d'Excel pour Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 et inférieures.

La syntaxe ISNUMBER ne requiert qu'un seul argument :

=ISNUMBER(valeur)

Où valeur Généralement, elle est représentée par une référence de cellule, mais vous pouvez également fournir une valeur réelle ou imbriquer une autre fonction dans ISNUMBER pour vérifier le résultat.

Si valeur est numérique, la fonction renvoie VRAI. Pour tout le reste (valeurs de texte, erreurs, blancs), ISNUMBER renvoie FAUX.

Par exemple, testons les valeurs dans les cellules A2 à A6, et nous découvrirons que les 3 premières valeurs sont des chiffres et les deux dernières du texte :

2 choses à savoir sur la fonction ISNUMBER dans Excel

Il y a quelques points intéressants à noter ici :

• En représentation interne d'Excel, dates et temps sont des valeurs numériques, la formule ISNUMBER renvoie donc VRAI pour elles (voir B3 et B4 dans la capture d'écran ci-dessus).
• Pour les nombres stockés sous forme de texte, la fonction ISNUMBER renvoie FALSE (voir cet exemple).

Exemples de formules Excel ISNUMBER

Les exemples ci-dessous montrent quelques utilisations courantes et quelques utilisations non triviales de ISNUMBER dans Excel.

Vérifier si une valeur est un nombre

Lorsque vous avez un tas de valeurs dans votre feuille de calcul et que vous voulez savoir lesquelles sont des nombres, ISNUMBER est la bonne fonction à utiliser.

Dans cet exemple, la première valeur se trouve en A2, nous utilisons donc la formule ci-dessous pour la vérifier, puis nous faisons glisser la formule vers autant de cellules que nécessaire :

=ISNUMBER(A2)

Veuillez noter que bien que toutes les valeurs ressemblent à des nombres, la formule ISNUMBER a renvoyé FALSE pour les cellules A4 et A5, ce qui signifie que ces valeurs sont chaînes numériques Il peut y avoir différentes raisons à cela, par exemple des zéros en tête, une apostrophe précédente, etc. Quelle que soit la raison, Excel ne reconnaît pas ces valeurs comme des nombres. Par conséquent, si vos valeurs ne sont pas calculées correctement, la première chose à faire est de vérifier si elles sont réellement des nombres au sens d'Excel, puis de convertir le texte en nombre si nécessaire.

Formule Excel ISNUMBER SEARCH

La fonction ISNUMBER d'Excel permet non seulement d'identifier des numéros, mais aussi de vérifier si le contenu d'une cellule contient un texte spécifique.

Sous sa forme générique, la formule se présente comme suit :

Où sous-chaîne est le texte que vous voulez trouver.

Par exemple, vérifions si la chaîne de caractères en A3 contient une couleur spécifique, disons rouge :

=ISNUMBER(SEARCH("red", A3))

Cette formule fonctionne bien pour une seule cellule. Mais comme notre tableau d'exemple (voir ci-dessous) contient trois couleurs différentes, écrire une formule distincte pour chacune d'elles serait une perte de temps. Au lieu de cela, nous nous référerons à la cellule contenant la couleur qui nous intéresse (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Pour que la formule soit correctement copiée vers le bas et vers la droite, veillez à verrouiller les coordonnées suivantes avec le signe $ :

• Sur sous-chaîne La référence de colonne est relative car nous voulons qu'elle s'adapte à chaque colonne, c'est-à-dire que lorsque la formule est copiée dans C3, la référence de sous-chaîne devient C$2.
• Dans le cellule source référence, verrouillez la colonne ($A3) afin que toutes les formules vérifient les valeurs de la colonne A.

La capture d'écran ci-dessous montre le résultat :

ISNUMBER FIND - formule sensible à la casse

Comme la fonction SEARCH est insensible à la casse Si vous recherchez une formule sensible à la casse, utilisez la fonction FIND plutôt que SEARCH.

Pour notre ensemble de données d'exemple, la formule prendrait cette forme :

=ISNUMBER(FIND(B$2, $A3))

Comment fonctionne cette formule

La logique de la formule est assez évidente et facile à suivre :

• La fonction SEARCH / FIND recherche la sous-chaîne dans la cellule spécifiée. Si la sous-chaîne est trouvée, la position du premier caractère est renvoyée. Si la sous-chaîne n'est pas trouvée, la fonction produit une erreur #VALUE !
• La fonction ISNUMBER prend le relais et traite les positions numériques. Ainsi, si la sous-chaîne est trouvée et que sa position est renvoyée sous forme de nombre, ISNUMBER produit VRAI. Si la sous-chaîne n'est pas trouvée et qu'une erreur #VALUE ! se produit, ISNUMBER produit FAUX.

formule IF ISNUMBER

Si vous souhaitez obtenir une formule dont le résultat est autre que VRAI ou FAUX, utilisez ISNUMBER avec la fonction IF.

Exemple 1. quelle cellule contient quel texte

En reprenant l'exemple précédent, supposons que vous souhaitiez marquer la couleur de chaque élément par un "x" comme indiqué dans le tableau ci-dessous.

Pour ce faire, il suffit d'intégrer la formule ISNUMBER SEARCH dans l'instruction IF :

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Si ISNUMBER renvoie VRAI, la fonction IF produit "x" (ou toute autre valeur que vous fournissez à la fonction valeur_si_vrai Si ISNUMBER renvoie FALSE, la fonction IF produit une chaîne vide ("").

Exemple 2 : Le premier caractère d'une cellule est un numéro ou un texte.

Imaginez que vous travaillez avec une liste de chaînes alphanumériques et que vous voulez savoir si le premier caractère d'une chaîne est un chiffre ou une lettre.

Pour construire une telle formule, vous aurez besoin de 4 fonctions différentes :

• La fonction LEFT extrait le premier caractère du début d'une chaîne, par exemple dans la cellule A2 :

  GAUCHE(A2, 1)

• Comme LEFT appartient à la catégorie des fonctions Text, son résultat est toujours une chaîne de texte, même si elle ne contient que des chiffres. Par conséquent, avant de vérifier le caractère extrait, nous devons essayer de le convertir en un nombre. Pour cela, utilisez la fonction VALUE ou l'opérateur double unaire :

  VALEUR(GAUCHE(A2, 1)) ou (--GAUCHE(A2, 1))

• La fonction ISNUMBER détermine si le caractère extrait est numérique ou non :

  ISNUMBER(VALEUR(LEFT(A2, 1)))

• En fonction du résultat de l'ISNUMBER (VRAI ou FAUX), la fonction IF renvoie respectivement un "chiffre" ou une "lettre".

En supposant que nous testons une chaîne de caractères en A2, la formule complète prend cette forme :

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Nombre", "Lettre")

ou

=IF(ISNUMBER(--LEFT(A2, 1)), "Numéro", "Lettre")

La fonction ISNUMBER est également utile pour extraction de chiffres Voici un exemple : Obtenez un nombre à partir de n'importe quelle position dans une chaîne de caractères.

Vérifier si une valeur n'est pas un nombre

Bien que Microsoft Excel dispose d'une fonction spéciale, ISNONTEXT, permettant de déterminer si la valeur d'une cellule n'est pas du texte, une fonction analogue fait défaut pour les chiffres.

Une solution simple consiste à utiliser ISNUMBER en combinaison avec NOT qui renvoie l'opposé d'une valeur logique. En d'autres termes, lorsque ISNUMBER renvoie VRAI, NOT le convertit en FAUX, et inversement.

Pour la voir en action, veuillez observer les résultats de la formule suivante :

=NOT(ISNUMBER(A2))

Une autre approche consiste à utiliser conjointement les fonctions IF et ISNUMBER :

=IF(ISNUMBER(A2), "", "Pas de numéro")

Si A2 est numérique, la formule ne renvoie rien (une chaîne vide). Si A2 n'est pas numérique, la formule l'indique d'emblée : "Pas un nombre".

Si vous souhaitez effectuer des calculs avec des chiffres, placez une équation ou une autre formule dans le champ valeur_si_vrai Par exemple, la formule ci-dessous multipliera les nombres par 10 et donnera "Pas de nombre" pour les valeurs non numériques :

=IF(ISNUMBER(A2), A2*10, "Pas de numéro")

Vérifier si une plage contient un nombre quelconque

Lorsque vous souhaitez tester la plage entière de chiffres, utilisez la fonction ISNUMBER en combinaison avec SUMPRODUCT comme suit :

Par exemple, pour savoir si la plage A2:A5 contient une valeur numérique, les formules seraient les suivantes :

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Si vous souhaitez afficher "Oui" et "Non" au lieu de VRAI et FAUX, utilisez l'instruction IF comme "enveloppe" pour les formules ci-dessus, par exemple :

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Oui", "Non")

Comment fonctionne cette formule

Au cœur de la formule, la fonction ISNUMBER évalue chaque cellule de la plage spécifiée, disons B2:B5, et renvoie VRAI pour les nombres, FAUX pour tout le reste. Comme la plage contient 4 cellules, le tableau a 4 éléments :

{VRAI;FAUX;FAUX;FAUX}

L'opération de multiplication ou le double unaire (--) transforme VRAI et FAUX en 1 et 0, respectivement :

{1;0;0;0}

La fonction SUMPRODUCT additionne les éléments du tableau. Si le résultat est supérieur à zéro, cela signifie qu'il y a au moins un nombre dans la plage. Vous utilisez donc ">0" pour obtenir un résultat final de VRAI ou FAUX.

ISNUMBER dans la mise en forme conditionnelle pour mettre en évidence les cellules qui contiennent un certain texte.

Si vous souhaitez mettre en évidence des cellules ou des lignes entières contenant un texte spécifique, créez une règle de formatage conditionnel basée sur la formule ISNUMBER SEARCH (insensible à la casse) ou ISNUMBER FIND (sensible à la casse).

Dans cet exemple, nous allons mettre en surbrillance les lignes en fonction de la valeur de la colonne A. Plus précisément, nous allons mettre en surbrillance les éléments qui contiennent le mot "rouge". Voici comment procéder :

1. Sélectionnez toutes les lignes de données (A2:C6 dans cet exemple) ou seulement la colonne dans laquelle vous souhaitez mettre en évidence les cellules.
2. Sur le Accueil dans l'onglet Styles cliquez sur Nouvelle règle > ; Utilisez une formule pour déterminer les cellules à mettre en forme .
3. Dans le Formatez les valeurs pour lesquelles cette formule est vraie saisissez la formule ci-dessous (remarquez que la coordonnée de la colonne est verrouillée par le signe $) :

   =ISNUMBER(SEARCH("red", $A2))

4. Cliquez sur le bouton Format et choisissez le format que vous souhaitez.
5. Cliquez deux fois sur OK.

Si vous avez peu d'expérience avec le formatage conditionnel d'Excel, vous pouvez trouver les étapes détaillées avec des captures d'écran dans ce tutoriel : Comment créer une règle de formatage conditionnel basée sur une formule.

En conséquence, tous les éléments de couleur rouge sont mis en évidence :

Au lieu de coder en dur la couleur dans la règle de formatage conditionnel, vous pouvez la saisir dans une cellule prédéfinie, par exemple E2, et faire référence à cette cellule dans votre formule (attention à la référence de cellule absolue $E$2). En outre, vous devez vérifier que la cellule d'entrée n'est pas vide :

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2 "")

Ainsi, vous obtiendrez une règle plus souple qui met en évidence les lignes en fonction de votre saisie dans E2 :

Voilà comment utiliser la fonction ISNUMBER dans Excel. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Téléchargements disponibles

Exemples de formules Excel ISNUMBER