Die tutoriaal verduidelik wat ISNUMBER in Excel is en verskaf voorbeelde van basiese en gevorderde gebruike.

Die konsep van die ISNUMBER-funksie in Excel is baie eenvoudig - dit kyk net of 'n gegewe waarde is 'n getal of nie. 'n Belangrike punt hier is dat die praktiese gebruike van die funksie veel verder gaan as die basiese konsep daarvan, veral wanneer dit gekombineer word met ander funksies binne groter formules.

Excel ISNUMBER-funksie

Die ISNUMBER-funksie in Excel kontroleer of 'n sel 'n numeriese waarde bevat of nie. Dit behoort aan die groep IS-funksies.

Die funksie is beskikbaar in alle weergawes van Excel vir Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 en laer.

Die ISNUMBER-sintaksis vereis net een argument:

=ISNUMBER(value)

Waar waarde die waarde is wat jy wil toets. Gewoonlik word dit deur 'n selverwysing voorgestel, maar jy kan ook 'n werklike waarde verskaf of 'n ander funksie binne ISNUMBER nes om die resultaat na te gaan.

As waarde numeries is, gee die funksie TRUE . Vir enigiets anders (tekswaardes, foute, spasies) gee ISNUMBER ONWAAR terug.

As 'n voorbeeld, kom ons toets waardes in selle A2 tot A6, en ons sal uitvind dat die eerste 3 waardes getalle is en die laaste twee is teks:

2 dinge wat jy moet weet oor ISNUMBER-funksie in Excel

Daar is 'n paar interessante punte om hier op te let:

• Ininterne Excel-voorstelling, datums en tye is numeriese waardes, dus die ISNUMBER-formule gee vir hulle WAAR terug (sien asseblief B3 en B4 in die skermkiekie hierbo).
• Vir nommers wat as teks gestoor is, gee die ISNUMBER-funksie ONWAAR terug (sien hierdie voorbeeld).

Excel ISNUMBER-formulevoorbeelde

Die onderstaande voorbeelde demonstreer 'n paar algemene en 'n paar nie-triviale gebruike van ISNUMBER in Excel.

Kyk of 'n waarde getal is

Wanneer jy 'n klomp waardes in jou werkblad het en jy wil weet watter een is getalle, is ISNUMBER die regte funksie om te gebruik .

In hierdie voorbeeld is die eerste waarde in A2, so ons gebruik die onderstaande formule om dit na te gaan, en sleep dan die formule af na soveel selle as wat nodig is:

=ISNUMBER(A2)

Let asseblief op dat alhoewel al die waardes soos getalle lyk, die ISNUMBER-formule ONWAAR vir selle A4 en A5 teruggegee het, wat beteken dat daardie waardes numeriese stringe is. , dit wil sê getalle geformateer as teks. Daar kan verskillende redes hiervoor wees, byvoorbeeld voorste nulle, voorafgaande apostrof, ens. Wat ook al die rede is, Excel herken nie waardes soos getalle nie. Dus, as jou waardes nie korrek bereken word nie, is die eerste ding wat jy moet kyk of dit werklik getalle is in terme van Excel, en skakel dan teks om na getal indien nodig.

Excel ISNUMBER SOEK formule

Behalwe om nommers te identifiseer, is die ExcelISNUMBER-funksie kan ook kyk of 'n sel spesifieke teks as deel van die inhoud bevat. Gebruik hiervoor ISNUMBER saam met die SEARCH-funksie.

In die generiese vorm lyk die formule soos volg:

Waar substring die teks is wat jy wil vind.

As 'n voorbeeld, kom ons kyk of die string in A3 'n spesifieke kleur bevat, sê rooi:

=ISNUMBER(SEARCH("red", A3))

Hierdie formule werk goed vir 'n enkele sel. Maar omdat ons voorbeeldtabel (sien asseblief hieronder) drie verskillende kleure bevat, sal die skryf van 'n aparte formule vir elkeen die tydmors wees. In plaas daarvan sal ons verwys na die sel wat die kleur van belang (B2) bevat.

=ISNUMBER(SEARCH(B$2, $A3))

Vir die formule om korrek af en na regs te kopieer, maak seker dat jy die volgende koördinate sluit met die $-teken:

• In substring -verwysing, sluit die ry (B$2) sodat die gekopieerde formules altyd die substringe in ry 2 kies. Die kolomverwysing is relatief omdat ons wil hê dat dit vir elke kolom moet aanpas, dit wil sê wanneer die formule na C3 gekopieer word, sal die substringverwysing na C$2 verander.
• In die bronsel -verwysing, sluit die kolom ($A3) ) sodat al die formules die waardes in kolom A nagaan.

Die skermkiekie hieronder wys die resultaat:

ISNUMMER VIND - hooflettersensitief formule

Aangesien die SEARCH-funksie hoofletter-onsensitief is, is die bogenoemdeformule onderskei nie hoofletters en kleinletters nie. As jy op soek is na 'n hooflettersensitiewe formule, gebruik die FIND-funksie eerder as SEARCH.

Vir ons voorbeelddatastel , sal die formule hierdie vorm aanneem:

=ISNUMBER(FIND(B$2, $A3))

Hoe hierdie formule werk

Die formule se logika is redelik voor die hand liggend en maklik om te volg:

• Die SOEK / VIND-funksie soek die substring in die gespesifiseerde sel. As die substring gevind word, word die posisie van die eerste karakter teruggestuur. As die substring nie gevind word nie, produseer die funksie 'n #VALUE! fout.
• Die ISNUMBER-funksie neem dit van daar af en verwerk numeriese posisies. Dus, as die substring gevind word en sy posisie as 'n getal teruggestuur word, voer ISNUMBER uit WAAR uit. As die substring nie gevind word nie en 'n #VALUE! fout kom voor, ISNUMBER voer ONWAAR uit.

IF ISNUMBER formule

As jy mik om 'n formule te kry wat iets anders as WAAR of ONWAAR uitstuur, gebruik ISNUMBER saam met die IF funksie.

Voorbeeld 1. Sel bevat watter teks

Om die vorige voorbeeld verder te neem, veronderstel jy wil die kleur van elke item met "x" merk soos in die tabel hieronder getoon.

Om dit te laat doen, draai eenvoudig die ISNUMBER SEARCH formule in die IF-stelling:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

As ISNUMBER TRUE gee, voer die IF-funksie "x" uit (of enige ander waarde wat jy verskaf aan die waarde_as_waar argument). As ISNUMBER ONWAAR gee, voer die IF-funksie 'n leë string ("") uit.

Voorbeeld 2. Eerste karakter in 'n sel is getal of teks

Stel jou voor dat jy met 'n lys alfanumeriese stringe werk en jy wil weet of 'n string se eerste karakter 'n nommer of letter is.

Om so 'n formule te bou, het jy 4 verskillende funksies nodig:

• Die LEFT-funksie onttrek die eerste karakter van die begin van 'n string, sê in sel A2:

  LEFT(A2, 1)

• Omdat LEFT aan die kategorie Teksfunksies behoort, resultaat is altyd 'n teksstring, selfs al bevat dit net syfers. Daarom, voordat ons die onttrekte karakter nagaan, moet ons probeer om dit na 'n getal om te skakel. Gebruik hiervoor óf die VALUE-funksie óf dubbel unêre operateur:

  VALUE(LEFT(A2, 1)) of (--LEFT(A2, 1))

• Die ISNUMBER-funksie bepaal of die onttrekte karakter numeries is of nie:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Op grond van die ISNUMBER-resultaat (WAAR of ONWAAR), gee die IF-funksie onderskeidelik "Getal" of "Letter" terug.

As ons aanvaar dat ons 'n string in A2 toets, die volledige formule neem hierdie vorm aan:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

of

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Die ISNUMBER-funksie is ook handig vir getalle uit 'n string te onttrek. Hier is 'n voorbeeld: Kry nommer van enige posisie in 'n string.

Kyk of 'n waarde nie getal is nie

Alhoewel Microsoft Excel 'n spesiale funksie, ISNONTEXT, het om te bepaalof 'n sel se waarde nie teks is nie, ontbreek 'n analoge funksie vir getalle.

'n Maklike oplossing is om ISNUMBER in kombinasie met NOT te gebruik wat die teenoorgestelde van 'n logiese waarde terugstuur. Met ander woorde, wanneer ISNUMBER WAAR teruggee, skakel dit NIE na ONWAAR om nie, en andersom.

Om dit in aksie te sien, let asseblief op die resultate van die volgende formule:

=NOT(ISNUMBER(A2))

'n Ander benadering is om die IF- en ISNUMBER-funksies saam te gebruik:

=IF(ISNUMBER(A2), "", "Not number")

As A2 numeries is, gee die formule niks terug nie ('n leë tou). As A2 nie numeries is nie, sê die formule dit vooraf: "Nie nommer nie".

As jy 'n paar berekeninge met getalle wil doen, stel dan 'n vergelyking of 'n ander formule in die waarde_as_waar argument in plaas van 'n leë string. Byvoorbeeld, die onderstaande formule sal getalle met 10 vermenigvuldig en "Nie getal" vir nie-numeriese waardes oplewer:

=IF(ISNUMBER(A2), A2*10, "Not number")

Kyk of 'n reeks enige getal bevat

In situasie wanneer jy die hele reeks vir getalle wil toets, gebruik die ISNUMBER-funksie in kombinasie met SUMPRODUCT soos hierdie:

Om byvoorbeeld uit te vind of die reeks A2:A5 enige numeriese waarde bevat, sal die formules soos volg wees:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

As jy "Ja" en "Nee" wil uitvoer in plaas van WAAR en ONWAAR, gebruik die IF-stelling as 'n"omhulsel" vir die bogenoemde formules. Byvoorbeeld:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Hoe hierdie formule werk

In die kern van die formule evalueer die ISNUMBER-funksie elke sel van die gespesifiseerde reeks, sê B2:B5, en gee TRUE vir getalle, ONWAAR vir enigiets anders terug. Aangesien die reeks 4 selle bevat, het die skikking 4 elemente:

{TRUE;FALSE;FALSE;FALSE}

Die vermenigvuldigingsbewerking of die dubbel unêre (--) dwing WAAR en ONWAAR in onderskeidelik 1'e en 0'e:

{1;0;0;0}

Die SUMPRODUCT-funksie voeg die elemente van die skikking by. As die resultaat groter as nul is, beteken dit dat daar ten minste een getal in die reeks is. Dus, jy gebruik ">0" om 'n finale resultaat van WAAR of ONWAAR te kry.

ISNUMBER in voorwaardelike formatering om selle uit te lig wat sekere teks bevat

As jy selle wil uitlig of hele rye wat spesifieke teks bevat, skep 'n voorwaardelike formatering reël gebaseer op die ISNUMBER SEARCH (hoofletter-onsensitief) of ISNUMBER FIND (hooflettergevoelig) formule.

Vir hierdie voorbeeld gaan ons rye uitlig gebaseer op die waarde in kolom A. Meer presies, ons sal die items uitlig wat die woord "rooi" bevat. Dit is hoe:

1. Kies al die datarye (A2:C6 in hierdie voorbeeld) of slegs die kolom waarin jy selle wil uitlig.
2. Op die Tuis -oortjie, in die Style -groep, klik Nuwe reël > Gebruik 'n formule om te bepaal watter selle om te formateer .
3. Indie Formaatwaardes waar hierdie formule waar is -boks, voer die onderstaande formule in (let asseblief daarop dat die kolomkoördinaat met die $-teken gesluit is):

   =ISNUMBER(SEARCH("red", $A2))

4. Klik die Format -knoppie en kies die formaat wat jy wil hê.
5. Klik twee keer OK.

As jy min ervaring het met Excel-voorwaardelike formatering, kan jy die gedetailleerde stappe vind met skermkiekies in hierdie tutoriaal: Hoe om 'n formule-gebaseerde voorwaardelike formateringreël te skep.

As gevolg hiervan word al die items van die rooi kleur uitgelig:

In plaas daarvan om die kleur in die voorwaardelike formateringreël te "hardkodeer", kan jy dit in 'n voorafbepaalde sel tik, sê E2, en na daardie sel in jou formule verwys (let asseblief op die absolute selverwysing $E$2). Daarbenewens moet jy kyk of die invoersel nie leeg is nie:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

As gevolg hiervan sal jy 'n meer buigsame reël kry wat rye uitlig op grond van jou invoer in E2:

Dis hoe om die ISNUMBER-funksie in Excel te gebruik. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!

Beskikbare aflaaie

Excel ISNUMBER formule voorbeelde