La lernilo klarigas, kio estas ISNUMBER en Excel kaj provizas ekzemplojn de bazaj kaj altnivelaj uzoj.

La koncepto de la funkcio ISNUMBER en Excel estas tre simpla - ĝi nur kontrolas ĉu antaŭfiksita. valoro estas nombro aŭ ne. Grava punkto ĉi tie estas, ke la praktikaj uzoj de la funkcio iras multe preter ĝia baza koncepto, precipe se kombinite kun aliaj funkcioj ene de pli grandaj formuloj.

Excel ISNUMBER-funkcio

La funkcio ISNUMBER en Excel kontrolas ĉu ĉelo enhavas nombran valoron aŭ ne. Ĝi apartenas al la grupo de IS-funkcioj.

La funkcio disponeblas en ĉiuj versioj de Excel por Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 kaj pli malaltaj.

La sintakso ISNUMBER postulas nur unu argumenton:

=ISNUMBER(value)

Kie valoro estas la valoro, kiun vi volas testi. Kutime, ĝi estas reprezentita per ĉela referenco, sed vi ankaŭ povas provizi realan valoron aŭ nesti alian funkcion ene de ISNUMBER por kontroli la rezulton.

Se valoro estas nombra, la funkcio liveras VERA. . Por io alia (tekstaj valoroj, eraroj, malplenaj) ISNUMERO donas FALSE.

Ekzemple, ni provu valorojn en ĉeloj A2 ĝis A6, kaj ni ekscios, ke la unuaj 3 valoroj estas nombroj kaj la lastaj du. estas teksto:

2 aferoj, kiujn vi devus scii pri ISNUMBER-funkcio en Excel

Estas kelkaj interesaj punktoj por noti ĉi tie:

• Eninterna Excel-reprezento, datoj kaj fojoj estas nombraj valoroj, do la formulo ISNUMBER liveras VERA por ili (bonvolu vidi B3 kaj B4 en la supra ekrankopio).
• Por nombroj stokitaj kiel teksto, la funkcio ISNUMBER liveras FALSE (vidu ĉi tiun ekzemplon).

Excel ISNUMBER-formulekzemploj

La malsupraj ekzemploj montras kelkajn komunajn kaj kelkajn ne-trivialajn uzojn. de ISNUMBER en Excel.

Kontrolu ĉu valoro estas nombro

Kiam vi havas amason da valoroj en via laborfolio kaj vi volas scii kiuj estas nombroj, ISNUMBER estas la ĝusta funkcio por uzi .

En ĉi tiu ekzemplo, la unua valoro estas en A2, do ni uzas la malsupran formulon por kontroli ĝin, kaj poste trenu la formulon al tiom da ĉeloj kiom necesas:

=ISNUMBER(A2)

Bonvolu atenti, ke kvankam ĉiuj valoroj aspektas kiel nombroj, la formulo ISNUMBER donis FALSE por ĉeloj A4 kaj A5, kio signifas, ke tiuj valoroj estas nombraj ĉenoj , t.e. nombroj formatitaj kiel teksto. Povas esti malsamaj kialoj por tio, ekzemple antaŭaj nuloj, antaŭaj apostrofoj, ktp. Kia ajn la kialo, Excel ne rekonas tiajn valorojn kiel nombrojn. Do, se viaj valoroj ne korekte kalkulas, la unua afero por vi kontroli estas ĉu ili vere estas nombroj laŭ Excel, kaj poste konverti tekston al nombro se necese.

Excel ISNUMMERA SERĈA formulo

Krom identigaj nombroj, la ExcelISNUMBER-funkcio ankaŭ povas kontroli ĉu ĉelo enhavas specifan tekston kiel parto de la enhavo. Por tio, uzu ISNUMBER kune kun la SERĈA funkcio.

En la ĝenerala formo, la formulo aspektas jene:

Kie subĉeno estas la teksto, kiun vi volas trovi.

Ekzemple, ni kontrolu ĉu la ĉeno en A3 enhavas specifan koloron, diru ruĝa:

=ISNUMBER(SEARCH("red", A3))

Ĉi tiu formulo bone funkcias por ununura ĉelo. Sed ĉar nia specimena tabelo (bonvolu vidi malsupre) enhavas tri malsamajn kolorojn, skribi apartan formulon por ĉiu estus la tempoperdo. Anstataŭe, ni raportos al la ĉelo enhavanta la interesan koloron (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Por ke la formulo ĝuste kopiu malsupren kaj dekstren, nepre ŝlosu la sekvajn koordinatojn per la $-signo:

• En subĉeno referenco, ŝlosu la vicon (B$2) tiel ke la kopiitaj formuloj ĉiam elektu la subĉenojn en la vico 2. La kolumna referenco estas relativa ĉar ni volas, ke ĝi ĝustiĝu por ĉiu kolumno, t.e. kiam la formulo estas kopiita al C3, la subĉena referenco ŝanĝiĝos al C$2.
• En la fonta ĉelo referenco, ŝlosu la kolumnon ($A3 ) por ke ĉiuj formuloj kontrolu la valorojn en kolumno A.

La ekrankopio malsupre montras la rezulton:

ISNUMBER FIND - distinga majuskloj. formulo

Ĉar la SERĈA funkcio estas majuskle-maldistinga , la ĉi-supraformulo ne diferencigas majusklajn kaj minusklojn. Se vi serĉas majuskle-distintan formulon, uzu la funkcion TROVU anstataŭ SERĈI.

Por nia ekzempla datumaro , la formulo havus ĉi tiun formon:

=ISNUMBER(FIND(B$2, $A3))

Kiel ĉi tiu formulo funkcias

La logiko de la formulo estas sufiĉe evidenta kaj facile sekvi:

• La funkcio SEARCH / FIND serĉas la subĉenon en la specifita ĉelo. Se la subĉeno estas trovita, la pozicio de la unua signo estas resendita. Se la subĉeno ne estas trovita, la funkcio produktas #VALORO! eraro.
• La funkcio ISNUMBER prenas ĝin de tie kaj prilaboras nombrajn poziciojn. Do, se la subĉeno estas trovita kaj ĝia pozicio estas resendita kiel nombro, ISNUMBER eligas VERA. Se la subĉeno ne estas trovita kaj #VALORO! eraro okazas, ISNUMBER eligas FALSE.

IF ISNUM-formulo

Se vi celas akiri formulon, kiu eligas ion alian ol VERA aŭ FALSA, uzu ISNUMBER kune kun la funkcio SE.

Ekzemplo 1. Ĉelo enhavas kiun tekston

Prenante la antaŭan ekzemplon plu, supozu, ke vi volas marki la koloron de ĉiu ero per "x" kiel montrite en la suba tabelo.

Por fari tion, simple envolvu la formulon ISNUMBER SEARCH en la deklaron IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Se ISNUMBER donas VERA, la IF-funkcio eligas "x" (aŭ ajnan alian valoron al kiu vi liveras). la valoro_se_vera argumento). Se ISNUMBER liveras FALSE, la SE-funkcio eligas malplenan ĉenon ("").

Ekzemplo 2. Unua signo en ĉelo estas nombro aŭ teksto

Imagu, ke vi laboras kun listo de alfanombraj ĉenoj kaj vi volas scii ĉu la unua signo de ĉeno estas nombro aŭ litero.

Por konstrui tian formulon, ni bezonos 4 malsamajn funkciojn:

• La funkcio LEFT ĉerpas la unuan signon de la komenco de ĉeno, ekzemple en ĉelo A2:

  LEFT(A2, 1)

• Ĉar LEFT apartenas al la kategorio de Tekstaj funkcioj, ĝia rezulto estas ĉiam teksta ĉeno, eĉ se ĝi enhavas nur nombrojn. Sekve, antaŭ kontroli la eltirita karakteron, ni devas provi konverti ĝin al nombro. Por tio, uzu aŭ la VALOR-funkcion aŭ duoblan unaran operatoron:

  VALUE(LEFT(A2, 1)) aŭ (--LEFT(A2, 1))

• La ISNUM-funkcio determinas ĉu la eltirita signo estas nombra aŭ ne:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Surbaze de la rezulto ISNUMBER (VERA aŭ FALSA), la SE-funkcio liveras "Nombro" aŭ "Letero", respektive.

Supoze, ke ni testas ĉenon en A2, la kompleta formulo. prenas ĉi tiun formon:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

aŭ

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

La funkcio ISNUM ankaŭ utilas por ĉerpi nombrojn el ĉeno. Jen ekzemplo: Akiru numeron el iu ajn pozicio en ŝnuro.

Kontrolu ĉu valoro ne estas nombro

Kvankam Microsoft Excel havas specialan funkcion, ISNONTEXT, por determiniĉu la valoro de ĉelo ne estas teksto, mankas analoga funkcio por nombroj.

Fabla solvo estas uzi ISNUMERO en kombinaĵo kun NOT kiu redonas la malon de logika valoro. Alivorte, kiam ISNUMBER donas VERA, NE konvertas ĝin al FALSO, kaj inverse.

Por vidi ĝin en ago, bonvolu observi la rezultojn de la sekva formulo:

=NOT(ISNUMBER(A2))

Alia aliro uzas la funkciojn SE kaj ISNUMBER kune:

=IF(ISNUMBER(A2), "", "Not number")

Se A2 estas nombra, la formulo donas nenion (malplena ŝnuro). Se A2 ne estas nombra, la formulo diras ĝin antaŭe: "Ne nombro".

Se vi ŝatus fari kelkajn kalkulojn per nombroj, tiam metu ekvacion aŭ alian. formulo en la argumento valoro_se_vera anstataŭ malplena ĉeno. Ekzemple, la suba formulo multigos nombrojn per 10 kaj donos "Ne nombron" por ne-nombraj valoroj:

=IF(ISNUMBER(A2), A2*10, "Not number")

Kontrolu ĉu intervalo enhavas iun nombron

En situacio kiam vi volas testi la tutan gamon por nombroj, uzu la funkcion ISNUM en kombinaĵo kun SUMPRODUKTO jene:

Ekzemple, por ekscii ĉu la intervalo A2:A5 enhavas iun numeran valoron, la formuloj iru jene:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Se vi ŝatus eligi "Jes" kaj "Ne" anstataŭ VERA kaj FALSA, uzu la IF-diron kiel"envolvaĵo" por la supraj formuloj. Ekzemple:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Kiel ĉi tiu formulo funkcias

En la kerno de la formulo, la funkcio ISNUMBER taksas ĉiun ĉelon de la specifita intervalo, diru B2:B5, kaj liveras VERA por nombroj, FALSE por io alia. Ĉar la intervalo enhavas 4 ĉelojn, la tabelo havas 4 elementojn:

{TRUE;FALSE;FALSE;FALSE}

La multiplika operacio aŭ la duobla unara (--) devigas VERA kaj FALSE en 1-ojn kaj 0-ojn, respektive:

{1;0;0;0}

La funkcio SUMPRODUCT aldonas la elementojn de la tabelo. Se la rezulto estas pli granda ol nulo, tio signifas, ke ekzistas almenaŭ unu nombro la gamo. Do, vi uzas ">0" por akiri finan rezulton de VERA aŭ FALSA.

ISNUMBER en kondiĉa formatado por reliefigi ĉelojn, kiuj enhavas certan tekston

Se vi serĉas reliefigi ĉelojn aŭ tutaj vicoj, kiuj enhavas specifan tekston, kreu kondiĉan formatregulon bazitan sur la formulo ISNUMBER SEARCH (malsentema) aŭ ISNUMBER FIND (majusklekzemple).

Por ĉi tiu ekzemplo, ni reliefigos vicojn bazitajn sur la valoron en kolumno A. Pli precize ni reliefigos la erojn, kiuj enhavas la vorton "ruĝa". Jen kiel:

1. Elektu ĉiujn datumvicojn (A2:C6 en ĉi tiu ekzemplo) aŭ nur la kolumnon en kiu vi volas reliefigi ĉelojn.
2. Sur la Hejmo langeto, en la grupo Stiloj , alklaku Nova Regulo > Uzu formulon por determini kiujn ĉelojn formati .
3. Enla Formati valorojn kie ĉi tiu formulo estas vera , enigu la suban formulon (bonvolu rimarki, ke la kolumna koordinato estas ŝlosita per la $-signo):

   =ISNUMBER(SEARCH("red", $A2))

4. Alklaku la Formati kaj elektu la formaton, kiun vi volas.
5. Alklaku OK dufoje.

Se vi havas malmulte da sperto pri Excel-kondiĉa formatado, vi povas trovi la detalajn paŝojn. kun ekrankopioj en ĉi tiu lernilo: Kiel krei formul-bazitan kondiĉan formatregulon.

Kiel rezulto, ĉiuj eroj de la ruĝa koloro estas reliefigitaj:

Anstataŭ "malmola kodigo" la koloron en la kondiĉa formata regulo, vi povas tajpi ĝin en antaŭdifinita ĉelo, diru E2, kaj referenci al tiu ĉelo en via formulo (bonvolu atenti la absolutan ĉelan referencon $E$2). Aldone, vi devas kontroli ĉu la eniga ĉelo ne estas malplena:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Kiel rezulto, vi ricevos pli flekseblan regulon, kiu reliefigas vicojn laŭ via enigo en E2:

Jen kiel uzi la funkcion ISNUMBER en Excel. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Haveblaj elŝutoj

Excel ISNUMBER-formulekzemploj