Eğitim, Excel'de ISNUMBER'ın ne olduğunu açıklar ve temel ve gelişmiş kullanım örnekleri sunar.

Excel'deki ISNUMBER fonksiyonunun konsepti çok basittir - sadece verilen bir değerin sayı olup olmadığını kontrol eder. Burada önemli bir nokta, fonksiyonun pratik kullanımlarının, özellikle daha büyük formüller içinde diğer fonksiyonlarla birleştirildiğinde, temel konseptinin çok ötesine geçmesidir.

Excel ISNUMBER işlevi

Excel'deki ISNUMBER işlevi, bir hücrenin sayısal bir değer içerip içermediğini kontrol eder. IS işlevleri grubuna aittir.

İşlev, Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 ve daha düşük sürümler için Excel'in tüm sürümlerinde kullanılabilir.

ISNUMBER sözdizimi yalnızca bir bağımsız değişken gerektirir:

=ISNUMBER(değer)

Nerede değer Genellikle bir hücre referansı ile temsil edilir, ancak sonucu kontrol etmek için gerçek bir değer de sağlayabilir veya ISNUMBER içine başka bir işlev yerleştirebilirsiniz.

Eğer değer sayısal ise, fonksiyon DOĞRU döndürür. Başka herhangi bir şey için (metin değerleri, hatalar, boşluklar) ISNUMBER YANLIŞ döndürür.

Örnek olarak, A2 ile A6 arasındaki hücrelerdeki değerleri test edelim ve ilk 3 değerin sayı, son ikisinin ise metin olduğunu görelim:

Excel'de ISNUMBER işlevi hakkında bilmeniz gereken 2 şey

Burada dikkat edilmesi gereken birkaç ilginç nokta var:

• Dahili Excel gösteriminde, tarihler ve zamanlar sayısal değerlerdir, bu nedenle ISNUMBER formülü bunlar için TRUE döndürür (lütfen yukarıdaki ekran görüntüsünde B3 ve B4'e bakın).
• Metin olarak saklanan sayılar için ISNUMBER işlevi FALSE döndürür (bu örneğe bakın).

Excel ISNUMBER formülü örnekleri

Aşağıdaki örnekler, Excel'de ISNUMBER'ın birkaç yaygın ve birkaç önemsiz kullanımını göstermektedir.

Bir değerin sayı olup olmadığını kontrol edin

Çalışma sayfanızda bir grup değer olduğunda ve hangilerinin sayı olduğunu bilmek istediğinizde, ISNUMBER kullanılacak doğru fonksiyondur.

Bu örnekte, ilk değer A2'dedir, bu nedenle onu kontrol etmek için aşağıdaki formülü kullanırız ve ardından formülü gerektiği kadar hücreye sürükleriz:

=ISNUMBER(A2)

Lütfen tüm değerlerin sayı gibi görünmesine rağmen, ISNUMBER formülünün A4 ve A5 hücreleri için YANLIŞ döndürdüğüne dikkat edin, bu da bu değerlerin sayısal dizeler Bunun farklı nedenleri olabilir, örneğin baştaki sıfırlar, öndeki kesme işareti vb. Nedeni ne olursa olsun, Excel bu tür değerleri sayı olarak tanımaz. Dolayısıyla, değerleriniz doğru hesaplanmıyorsa, kontrol etmeniz gereken ilk şey Excel açısından gerçekten sayı olup olmadıklarıdır ve ardından gerekirse metni sayıya dönüştürün.

Excel ISNUMBER ARAMA formülü

Excel ISNUMBER işlevi, sayıları tanımlamanın yanı sıra, bir hücrenin içeriğinin bir parçası olarak belirli bir metin içerip içermediğini de kontrol edebilir. Bunun için ISNUMBER işlevini ARA işlevi ile birlikte kullanın.

Genel formda formül aşağıdaki gibi görünür:

Nerede alt dize bulmak istediğiniz metindir.

Örnek olarak, A3'teki dizenin belirli bir renk, örneğin kırmızı, içerip içermediğini kontrol edelim:

=ISNUMBER(SEARCH("red", A3))

Bu formül tek bir hücre için güzel bir şekilde çalışır. Ancak örnek tablomuz (lütfen aşağıya bakın) üç farklı renk içerdiğinden, her biri için ayrı bir formül yazmak zaman kaybı olacaktır. Bunun yerine, ilgilenilen rengi içeren hücreye (B2) başvuracağız.

=ISNUMBER(SEARCH(B$2, $A3))

Formülün aşağı ve sağa doğru doğru kopyalanması için, aşağıdaki koordinatları $ işaretiyle kilitlediğinizden emin olun:

• İçinde alt dize başvurusu, satırı (B$2) kilitleyin, böylece kopyalanan formüller her zaman satır 2'deki alt dizeleri seçer. Sütun başvurusu görelidir çünkü her sütun için ayarlanmasını istiyoruz, yani formül C3'e kopyalandığında, alt dize başvurusu C$2 olarak değişecektir.
• İçinde kaynak hücre referansını kullanarak sütunu ($A3) kilitleyin, böylece tüm formüller A sütunundaki değerleri kontrol eder.

Aşağıdaki ekran görüntüsü sonucu göstermektedir:

ISNUMBER BUL - büyük/küçük harfe duyarlı formül

ARAMA işlevi olduğu için büyük/küçük harf duyarsız yukarıdaki formül büyük ve küçük harfleri ayırt etmez. Büyük/küçük harfe duyarlı bir formül arıyorsanız, ARA yerine BUL işlevini kullanın.

Örnek veri kümemiz için formül şu şekilde olacaktır:

=ISNUMBER(FIND(B$2, $A3))

Bu formül nasıl çalışır?

Formülün mantığı oldukça açık ve takip etmesi kolay:

• ARA / BUL işlevi, belirtilen hücrede alt dizeyi arar. Alt dize bulunursa, ilk karakterin konumu döndürülür. Alt dize bulunamazsa, işlev bir #DEĞER! hatası üretir.
• ISNUMBER işlevi buradan alır ve sayısal konumları işler. Bu nedenle, alt dize bulunursa ve konumu bir sayı olarak döndürülürse, ISNUMBER TRUE çıktısı verir. Alt dize bulunamazsa ve #VALUE! hatası oluşursa, ISNUMBER FALSE çıktısı verir.

IF ISNUMBER formülü

DOĞRU veya YANLIŞ dışında bir çıktı veren bir formül elde etmeyi amaçlıyorsanız, ISNUMBER öğesini EĞER işleviyle birlikte kullanın.

Örnek 1. Hücre hangi metni içeriyor

Önceki örneği daha da ileri götürerek, aşağıdaki tabloda gösterildiği gibi her bir öğenin rengini "x" ile işaretlemek istediğinizi varsayalım.

Bunu yapmak için, ISNUMBER SEARCH formülünü IF deyiminin içine sarmanız yeterlidir:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

ISNUMBER TRUE değerini döndürürse, IF fonksiyonu "x" çıktısını verir (veya value_if_true argümanı). ISNUMBER FALSE döndürürse, IF işlevi boş bir dize ("") çıktısı verir.

Örnek 2. Hücredeki ilk karakter sayı veya metindir

Alfanümerik dizelerden oluşan bir listeyle çalıştığınızı ve bir dizenin ilk karakterinin sayı mı yoksa harf mi olduğunu bilmek istediğinizi düşünün.

Böyle bir formül oluşturmak için 4 farklı fonksiyona ihtiyacımız olacak:

• LEFT işlevi, örneğin A2 hücresindeki bir dizenin başlangıcından ilk karakteri çıkarır:

  LEFT(A2, 1)

• LEFT, Metin fonksiyonları kategorisine ait olduğundan, sonucu yalnızca sayılar içerse bile her zaman bir metin dizesidir. Bu nedenle, çıkarılan karakteri kontrol etmeden önce, onu bir sayıya dönüştürmeye çalışmamız gerekir. Bunun için VALUE fonksiyonunu veya çift tekli operatörü kullanın:

  DEĞER(SOL(A2, 1)) veya (--LEFT(A2, 1))

• ISNUMBER işlevi, çıkarılan karakterin sayısal olup olmadığını belirler:

  ISNUMBER(VALUE(LEFT(A2, 1))

• ISNUMBER sonucuna (TRUE veya FALSE) bağlı olarak, IF fonksiyonu sırasıyla "Sayı" veya "Harf" döndürür.

A2'de bir dizeyi test ettiğimizi varsayarsak, formülün tamamı bu şekli alır:

=IF(ISNUMBER(VALUE(LEFT(A2, 1)), "Sayı", "Harf")

veya

=IF(ISNUMBER(--LEFT(A2, 1)), "Sayı", "Harf")

ISNUMBER işlevi ayrıca aşağıdakiler için de kullanışlıdır sayıların çıkarılması İşte bir örnek: Bir dizedeki herhangi bir konumdan sayı alın.

Bir değerin sayı olup olmadığını kontrol edin

Microsoft Excel, bir hücrenin değerinin metin olup olmadığını belirlemek için ISNONTEXT adlı özel bir işleve sahip olmasına rağmen, sayılar için benzer bir işlev eksiktir.

Kolay bir çözüm, ISNUMBER'ı mantıksal bir değerin tersini döndüren NOT ile birlikte kullanmaktır. Başka bir deyişle, ISNUMBER TRUE döndürdüğünde, NOT bunu FALSE'a dönüştürür ve bunun tersi de geçerlidir.

Bunu uygulamada görmek için lütfen aşağıdaki formülün sonuçlarını gözlemleyin:

=NOT(ISNUMBER(A2))

Diğer bir yaklaşım ise IF ve ISNUMBER fonksiyonlarını birlikte kullanmaktır:

=IF(ISNUMBER(A2), "", "Not number")

A2 sayısal ise, formül hiçbir şey döndürmez (boş bir dize). A2 sayısal değilse, formül bunu önceden söyler: "Sayı değil".

Rakamlarla bazı hesaplamalar yapmak istiyorsanız, bir denklem veya başka bir formülü value_if_true bağımsız değişkenini boş bir dize yerine kullanır. Örneğin, aşağıdaki formül sayıları 10 ile çarpacak ve sayısal olmayan değerler için "Sayı değil" sonucunu verecektir:

=IF(ISNUMBER(A2), A2*10, "Not number")

Bir aralığın herhangi bir sayı içerip içermediğini kontrol edin

Sayılar için tüm aralığı test etmek istediğinizde, ISNUMBER işlevini SUMPRODUCT ile birlikte aşağıdaki gibi kullanın:

Örneğin, A2:A5 aralığının herhangi bir sayısal değer içerip içermediğini bulmak için formüller aşağıdaki gibi olacaktır:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

DOĞRU ve YANLIŞ yerine "Evet" ve "Hayır" çıktısı almak istiyorsanız, yukarıdaki formüller için "sarmalayıcı" olarak IF deyimini kullanın. Örneğin:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Evet", "Hayır")

Bu formül nasıl çalışır?

Formülün merkezinde yer alan ISNUMBER işlevi, belirtilen aralığın (örneğin B2:B5) her hücresini değerlendirir ve sayılar için DOĞRU, diğer her şey için YANLIŞ döndürür. Aralık 4 hücre içerdiğinden, dizinin 4 öğesi vardır:

{TRUE;FALSE;FALSE;FALSE}

Çarpma işlemi veya çift tekli (--), TRUE ve FALSE değerlerini sırasıyla 1'lere ve 0'lara zorlar:

{1;0;0;0}

SUMPRODUCT işlevi dizinin öğelerini toplar. Sonuç sıfırdan büyükse, aralıkta en az bir sayı olduğu anlamına gelir. Bu nedenle, DOĞRU veya YANLIŞ nihai sonucunu elde etmek için ">0" kullanırsınız.

Belirli metinleri içeren hücreleri vurgulamak için koşullu biçimlendirmede ISNUMBER

Belirli bir metin içeren hücreleri veya tüm satırları vurgulamak istiyorsanız, ISNUMBER SEARCH (büyük/küçük harfe duyarsız) veya ISNUMBER FIND (büyük/küçük harfe duyarlı) formülünü temel alan bir koşullu biçimlendirme kuralı oluşturun.

Bu örnekte, A sütunundaki değere göre satırları vurgulayacağız. Daha doğrusu, "kırmızı" kelimesini içeren öğeleri vurgulayacağız:

1. Tüm veri satırlarını (bu örnekte A2:C6) veya yalnızca hücreleri vurgulamak istediğiniz sütunu seçin.
2. Üzerinde Ev sekmesinde Stiller grubunu seçin, tıklayın Yeni Kural > Hangi hücrelerin biçimlendirileceğini belirlemek için bir formül kullanma .
3. İçinde Bu formülün doğru olduğu değerleri biçimlendirin kutusuna aşağıdaki formülü girin (lütfen sütun koordinatının $ işaretiyle kilitlendiğine dikkat edin):

   =ISNUMBER(SEARCH("red", $A2))

4. Tıklayınız Biçim düğmesine basın ve istediğiniz biçimi seçin.
5. İki kez Tamam'a tıklayın.

Excel koşullu biçimlendirme konusunda çok az deneyiminiz varsa, ekran görüntüleriyle birlikte ayrıntılı adımları şu eğitimde bulabilirsiniz: Formül tabanlı bir koşullu biçimlendirme kuralı nasıl oluşturulur?

Sonuç olarak, kırmızı renkteki tüm öğeler vurgulanır:

Koşullu biçimlendirme kuralında rengi "sabit kodlamak" yerine, önceden tanımlanmış bir hücreye, örneğin E2'ye yazabilir ve formülünüzde bu hücreye başvurabilirsiniz (lütfen mutlak hücre başvurusu $E$2'ye dikkat edin). Ayrıca, giriş hücresinin boş olup olmadığını kontrol etmeniz gerekir:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Sonuç olarak, E2'deki girdinize göre satırları vurgulayan daha esnek bir kural elde edersiniz:

İşte Excel'de ISNUMBER fonksiyonunun kullanımı. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Mevcut indirmeler

Excel ISNUMBER formülü örnekleri