O'quv qo'llanma Excelda ISNUMBER nima ekanligini tushuntirib beradi va asosiy va qo'shimcha foydalanish misollarini beradi.

Excel'dagi ISNUMBER funksiyasi tushunchasi juda oddiy - u shunchaki berilgan yoki yo'qligini tekshiradi. qiymat raqam yoki yo'q. Bu erda muhim jihat shundaki, funktsiyaning amaliy qo'llanilishi uning asosiy tushunchasidan ancha uzoqroq, ayniqsa kattaroq formulalar doirasidagi boshqa funktsiyalar bilan birlashtirilganda.

Excel ISNUMBER funktsiyasi

Exceldagi ISNUMBER funktsiyasi hujayrada raqamli qiymat bor yoki yo'qligini tekshiradi. U IS funktsiyalari guruhiga kiradi.

Funktsiya Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 va undan pastroq versiyalar uchun Excelning barcha versiyalarida mavjud.

ISNUMBER sintaksisi faqat bitta argumentni talab qiladi:

=ISNUMBER(value)

Bu erda qiymat siz tekshirmoqchi bo'lgan qiymatdir. Odatda, u yacheyka havolasi bilan ifodalanadi, lekin natijani tekshirish uchun siz haqiqiy qiymatni ham berishingiz yoki boshqa funksiyani ISNUMBER ichiga joylashtirishingiz mumkin.

Agar qiymat raqamli bo'lsa, funktsiya TRUE qiymatini qaytaradi. . Boshqa har qanday narsa (matn qiymatlari, xatolar, bo'sh joylar) uchun ISNUMBER FALSE qiymatini qaytaradi.

Misol sifatida, keling, A2 dan A6 gacha bo'lgan kataklardagi qiymatlarni sinab ko'raylik va biz birinchi 3 ta qiymat raqamlar va oxirgi ikkitasi ekanligini bilib olamiz. bu matn:

Excel'dagi ISNUMBER funksiyasi haqida bilishingiz kerak bo'lgan 2 ta narsa

Bu erda bir nechta qiziqarli fikrlar mavjud:

• Inichki Excel ko'rinishi, sanalar va vaqt raqamli qiymatlar, shuning uchun ISNUMBER formulasi ular uchun TRUE qiymatini qaytaradi (yuqoridagi skrinshotda B3 va B4 ga qarang).
• uchun matn sifatida saqlangan raqamlar, ISNUMBER funksiyasi FALSE qaytaradi (ushbu misolga qarang).

Excel ISNUMBER formula misollari

Quyidagi misollar bir nechta umumiy va bir nechta ahamiyatsiz foydalanishni ko'rsatadi. Excelda ISNUMBERning soni.

Qiymat raqam ekanligini tekshiring

Ish varaqingizda bir nechta qiymatlar mavjud boʻlsa va ularning qaysi biri raqamlar ekanligini bilmoqchi boʻlsangiz, ISNUMBER toʻgʻri funksiya hisoblanadi. .

Ushbu misolda birinchi qiymat A2 formatida, shuning uchun uni tekshirish uchun quyidagi formuladan foydalanamiz, so'ngra formulani kerak bo'lganda shuncha katakka tortamiz:

=ISNUMBER(A2)

E'tibor bering, barcha qiymatlar raqamlarga o'xshasa-da, ISNUMBER formulasi A4 va A5 kataklari uchun FALSE qiymatini qaytardi, ya'ni bu qiymatlar raqamli satrlar , ya'ni matn sifatida formatlangan raqamlar. Buning turli sabablari bo'lishi mumkin, masalan, bosh nol, apostrofdan oldingi va hokazo. Nima bo'lishidan qat'iy nazar, Excel raqamlar kabi qiymatlarni tanimaydi. Shunday qilib, agar sizning qiymatlaringiz to'g'ri hisoblanmasa, birinchi navbatda ular Excel nuqtai nazaridan raqamlar yoki yo'qligini tekshirib ko'rishingiz va kerak bo'lsa matnni raqamga aylantirishingiz kerak.

Excel ISNUMBER QIDIRISh formulasi

Raqamlarni aniqlashdan tashqari, ExcelISNUMBER funksiyasi hujayrada kontentning bir qismi sifatida aniq matn mavjudligini ham tekshirishi mumkin. Buning uchun ISNUMBER dan QIDIRUV funksiyasi bilan birga foydalaning.

Umumiy shaklda formula quyidagicha ko'rinadi:

Bu yerda substring siz topmoqchi boʻlgan matn.

Misol sifatida, A3 formatidagi satrda maʼlum bir rang bor yoki yoʻqligini tekshirib koʻraylik, deylik qizil:

=ISNUMBER(SEARCH("red", A3))

Ushbu formula bitta hujayra uchun yaxshi ishlaydi. Ammo bizning namunaviy jadvalimiz (pastga qarang) uch xil rangni o'z ichiga olganligi sababli, har biri uchun alohida formula yozish vaqtni behuda sarflash bo'ladi. Buning o'rniga biz qiziqqan rangni (B2) o'z ichiga olgan katakka murojaat qilamiz.

=ISNUMBER(SEARCH(B$2, $A3))

Formuladan pastga va o'ngga to'g'ri nusxa ko'chirish uchun quyidagi koordinatalarni blokirovka qilishni unutmang. $ belgisi:

• pastki satr havolasida nusxalangan formulalar har doim 2-qatordagi pastki qatorlarni tanlashi uchun qatorni (B$2) qulflang. Ustun havolasi nisbiy, chunki biz uni har bir ustun uchun sozlashni xohlasangiz, ya'ni formula C3 ga ko'chirilganda, pastki qatorga havola C$2 ga o'zgaradi.
• manba katak havolasida ustunni ($A3) qulflang ) shunday qilib, barcha formulalar A ustunidagi qiymatlarni tekshiradi.

Quyidagi skrinshotda natija ko'rsatilgan:

ISNUMBER FIND - katta-kichik harf sezgir formula

QIDIRISh funksiyasi katta harflarni sezmaydi bo'lgani uchun yuqoridagiformula katta va kichik harflarni farqlamaydi. Agar siz katta-kichik harflarga sezgir formula izlayotgan bo‘lsangiz, QIDIRISH o‘rniga TIP funksiyasidan foydalaning.

Bizning namunaviy ma’lumotlar to‘plamimiz uchun , formula quyidagi shaklda bo'ladi:

=ISNUMBER(FIND(B$2, $A3))

Ushbu formula qanday ishlaydi

Formula mantig'i juda aniq va unga amal qilish oson:

• SEARCH / FIND funksiyasi belgilangan katakdagi pastki qatorni qidiradi. Agar pastki qator topilsa, birinchi belgining pozitsiyasi qaytariladi. Agar pastki qator topilmasa, funksiya #VALUE! xato.
• ISNUMBER funksiyasi uni u yerdan oladi va raqamli pozitsiyalarni qayta ishlaydi. Shunday qilib, agar pastki qator topilsa va uning pozitsiyasi raqam sifatida qaytarilsa, ISNUMBER TRUE chiqaradi. Agar pastki qator topilmasa va #VALUE! xato yuz berganda, ISNUMBER FALSE chiqaradi.

IF ISNUMBER formulasi

Agar siz TRUE yoki FALSEdan boshqa narsani chiqaradigan formulani olishni maqsad qilsangiz, ISNUMBER-dan IF funktsiyasi bilan birga foydalaning.

Misol 1. Hujayra qaysi matnni o'z ichiga oladi

Avvalgi misolni ko'rib chiqsak, har bir elementning rangini quyidagi jadvalda ko'rsatilganidek "x" bilan belgilamoqchisiz deylik.

Buni amalga oshirish uchun ISNUMBER SEARCH formulasini IF iborasiga oʻrash kifoya:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Agar ISNUMBER TRUE qiymatini qaytarsa, IF funksiyasi “x” (yoki siz bergan boshqa qiymat) chiqaradi. haqiqat_agar_qiymat dalil). Agar ISNUMBER FALSE qiymatini qaytarsa, IF funktsiyasi bo'sh qatorni ("") chiqaradi.

Misol 2. Yacheykadagi birinchi belgi raqam yoki matn

Tasavvur qiling-a, siz alfanumerik satrlar ro'yxati bilan ishlayapsiz va satrning birinchi belgisi raqam yoki harf ekanligini bilmoqchisiz.

Bunday formulani yaratish uchun sizga 4 xil funksiya kerak bo'ladi:

• CHAP funksiyasi satr boshidan birinchi belgini ajratib oladi, deylik A2 katakchada:

  LEFT(A2, 1)

• Chunki LEFT Matn funksiyalari toifasiga kiradi, uning natija faqat raqamlardan iborat bo'lsa ham, har doim matn qatoridir. Shuning uchun, chiqarilgan belgini tekshirishdan oldin, biz uni raqamga aylantirishga harakat qilishimiz kerak. Buning uchun VALUE funksiyasidan yoki ikkilik birlik operatoridan foydalaning:

  VALUE(LEFT(A2, 1)) yoki (--LEFT(A2, 1))

• ISNUMBER funksiyasi chiqarilgan belgi sonli yoki raqamli emasligini aniqlaydi:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• ISNUMBER natijasiga (TRUE yoki FALSE) asoslanib, IF funksiyasi mos ravishda "Raqam" yoki "Harf" ni qaytaradi.

Agar biz A2 formatidagi satrni sinab ko'rayotgan bo'lsak, to'liq formula bu shaklni oladi:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

yoki

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER funktsiyasi <12 uchun ham qo'l keladi>satrdan raqamlarni chiqarish. Mana bir misol: Satrning istalgan pozitsiyasidan raqam oling.

Qiymat raqam emasligini tekshiring

Microsoft Excelda ISNONTEXT maxsus funksiyasi borligini aniqlang.yacheykaning qiymati matn bo'lishidan qat'i nazar, raqamlar uchun o'xshash funktsiya yo'q.

Oson yechim bu mantiqiy qiymatning teskarisini qaytaradigan ISNUMBER-ni NOT bilan birgalikda ishlatishdir. Boshqacha qilib aytganda, ISNUMBER TRUE qiymatini qaytarsa, EMAS uni FALSE ga oʻzgartiradi va aksincha.

Uni amalda koʻrish uchun quyidagi formula natijalariga rioya qiling:

=NOT(ISNUMBER(A2))

Boshqa yondashuv IF va ISNUMBER funksiyalaridan birgalikda foydalanishdir:

=IF(ISNUMBER(A2), "", "Not number")

Agar A2 raqamli bo'lsa, formula hech narsa qaytarmaydi (bo'sh string). Agar A2 raqamli bo'lmasa, formulada buni oldindan aytadi: "Raqam emas".

Agar siz raqamlar bilan ba'zi hisob-kitoblarni amalga oshirmoqchi bo'lsangiz, tenglama yoki boshqasini qo'ying. formula bo'sh qator o'rniga agar_haqiqat_qiymat argumentida. Misol uchun, quyidagi formula raqamlarni 10 ga ko'paytiradi va raqamli bo'lmagan qiymatlar uchun "Raqam emas" ni beradi:

=IF(ISNUMBER(A2), A2*10, "Not number")

Diapazonda biron bir raqam mavjudligini tekshiring

In Agar siz raqamlar uchun butun diapazonni sinab ko'rmoqchi bo'lsangiz, ISNUMBER funksiyasidan SUMPRODUCT bilan birgalikda quyidagi tarzda foydalaning:

Masalan, A2:A5 diapazonida har qanday raqamli qiymat mavjudligini bilish uchun formulalar quyidagicha bo'ladi:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Agar siz TRUE va FALSE o'rniga "Ha" va "Yo'q" ni chiqarishni istasangiz, IF iborasidan foydalaning.Yuqoridagi formulalar uchun "o'rash". Masalan:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Ushbu formula qanday ishlaydi

Formula markazida ISNUMBER funktsiyasi har bir katakchani baholaydi. belgilangan diapazon, B2:B5 deb ayting va raqamlar uchun TRUE, boshqa narsalar uchun FALSE qaytaradi. Diapazon 4 yacheykadan iborat bo‘lgani uchun massiv 4 ta elementga ega:

{TRUE;FALSE;FALSE;FALSE}

Ko‘paytirish amali yoki qo‘sh birlik (--) TRUE va FALSE ni mos ravishda 1 va 0 ga majburlaydi:

{1;0;0;0}

SUMPRODUCT funktsiyasi massiv elementlarini qo'shadi. Agar natija noldan katta bo'lsa, bu diapazonda kamida bitta raqam borligini anglatadi. Yakuniy natijani TRUE yoki FALSE olish uchun ">0" dan foydalanasiz.

ISNUMBER shartli formatlashda ma'lum matnni o'z ichiga olgan katakchalarni ajratib ko'rsatish uchun

Agar siz katakchalarni ajratib ko'rsatmoqchi bo'lsangiz yoki Muayyan matnni o'z ichiga olgan butun qatorlar uchun ISNUMBER SEARCH (katta-katta harflarni sezmaydi) yoki ISNUMBER FIND (katta-katta harflarni sezgir) formulalari asosida shartli formatlash qoidasini yarating.

Ushbu misol uchun biz quyidagiga asoslangan qatorlarni ajratib ko'rsatamiz. ustundagi qiymat A. Aniqrog'i, biz "qizil" so'zini o'z ichiga olgan narsalarni ajratib ko'rsatamiz. Mana shunday:

1. Barcha ma'lumotlar qatorlarini (ushbu misolda A2:C6) yoki faqat katakchalarni ajratib ko'rsatmoqchi bo'lgan ustunni tanlang.
2. Uy sahifasida yorlig'i, Uslublar guruhida, Yangi qoida > Qaysi katakchalarni formatlashni aniqlash uchun formuladan foydalaning .
3. In Ushbu formula to'g'ri bo'lgan qiymatlarni formatlash maydoniga quyidagi formulani kiriting (ustun koordinatasi $ belgisi bilan qulflanganligiga e'tibor bering):

   =ISNUMBER(SEARCH("red", $A2))

4. Buni bosing. Format tugmasini bosing va kerakli formatni tanlang.
5. OK tugmasini ikki marta bosing.

Agar Excelni shartli formatlashda tajribangiz kam boʻlsa, batafsil qadamlarni topishingiz mumkin. Ushbu qo'llanmada skrinshotlar bilan: Formulaga asoslangan shartli formatlash qoidasini qanday yaratish mumkin.

Natijada qizil rangning barcha elementlari ajratib ko'rsatiladi:

Shartli formatlash qoidasida rangni "qattiq kodlash" o'rniga, uni oldindan belgilangan katakka kiritishingiz mumkin, masalan, E2 va formulangizdagi o'sha katakka murojaat qiling (iltimos, $E$2 mutlaq hujayra havolasiga e'tibor bering). Bundan tashqari, siz kiritish katakchasi bo'sh emasligini tekshirishingiz kerak:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Natijada siz E2 dagi kiritishingiz asosida qatorlarni ajratib ko'rsatadigan yanada moslashuvchan qoidaga ega bo'lasiz:

Excelda ISNUMBER funksiyasidan shunday foydalanish mumkin. O'qiganingiz uchun rahmat va keyingi haftada blogimizda ko'rishga umid qilaman!

Mavjud yuklab olishlar

Excel ISNUMBER formula misollari