يشرح البرنامج التعليمي ما هو ISNUMBER في Excel ويقدم أمثلة للاستخدامات الأساسية والمتقدمة.

مفهوم وظيفة ISNUMBER في Excel بسيط للغاية - إنه يتحقق فقط مما إذا كان القيمة هي رقم أم لا. نقطة مهمة هنا هي أن الاستخدامات العملية للدالة تتجاوز مفهومها الأساسي ، خاصة عند دمجها مع وظائف أخرى ضمن صيغ أكبر.

وظيفة رقم ISNUMBER في Excel

تتحقق الدالة ISNUMBER في Excel مما إذا كانت الخلية تحتوي على قيمة عددية أم لا. إنها تنتمي إلى مجموعة وظائف IS.

تتوفر الوظيفة في جميع إصدارات Excel لـ Office 365 و Excel 2019 و Excel 2016 و Excel 2013 و Excel 2010 و Excel 2007 والإصدارات الأقل.

يتطلب بناء جملة ISNUMBER وسيطة واحدة فقط:

=ISNUMBER(value)

حيث القيمة هي القيمة التي تريد اختبارها. عادةً ما يتم تمثيله بمرجع خلية ، ولكن يمكنك أيضًا توفير قيمة حقيقية أو تداخل دالة أخرى داخل ISNUMBER للتحقق من النتيجة.

إذا كانت القيمة رقمية ، فإن الدالة ترجع TRUE . لأي شيء آخر (قيم نصية ، أخطاء ، فراغات) يُرجع ISNUMBER FALSE.

كمثال ، دعنا نختبر القيم في الخلايا من A2 إلى A6 ، وسنكتشف أن أول 3 قيم هي أرقام وآخر اثنين عبارة عن نص:

شيئان يجب أن تعرفهما عن وظيفة ISNUMBER في Excel

هناك بضع نقاط مثيرة للاهتمام يجب ملاحظتها هنا:

• فيتمثيل Excel الداخلي ، التواريخ و مرة هي قيم رقمية ، لذا فإن صيغة ISNUMBER ترجع TRUE لها (يرجى الاطلاع على B3 و B4 في لقطة الشاشة أعلاه).
• للحصول على الأرقام المخزنة كنص ، ترجع الدالة ISNUMBER FALSE (انظر هذا المثال).

أمثلة صيغة Excel ISNUMBER

توضح الأمثلة أدناه بعض الاستخدامات الشائعة واثنين من الاستخدامات غير التافهة من ISNUMBER في Excel.

تحقق مما إذا كانت القيمة هي رقم

عندما يكون لديك مجموعة من القيم في ورقة العمل وتريد معرفة أي منها أرقام ، فإن ISNUMBER هي الوظيفة الصحيحة لاستخدامها .

في هذا المثال ، تكون القيمة الأولى في A2 ، لذلك نستخدم الصيغة أدناه للتحقق منها ، ثم اسحب الصيغة لأسفل إلى أي عدد من الخلايا حسب الحاجة:

=ISNUMBER(A2)

يُرجى الانتباه إلى أنه على الرغم من أن جميع القيم تبدو كأرقام ، فإن صيغة ISNUMBER قد أرجع FALSE للخلايا A4 و A5 ، مما يعني أن هذه القيم هي سلاسل رقمية ، أي الأرقام المنسقة كنص. قد تكون هناك أسباب مختلفة لذلك ، على سبيل المثال الأصفار البادئة ، والفاصلة العليا السابقة ، وما إلى ذلك. مهما كان السبب ، لا يتعرف Excel على هذه القيم مثل الأرقام. لذلك ، إذا لم يتم حساب القيم الخاصة بك بشكل صحيح ، فإن أول شيء عليك التحقق منه هو ما إذا كانت بالفعل أرقامًا من حيث Excel ، ثم تحويل النص إلى رقم إذا لزم الأمر.

بصرف النظر عن تحديد الأرقام ، فإن ملف Excelيمكن للدالة ISNUMBER أيضًا التحقق مما إذا كانت الخلية تحتوي على نص معين كجزء من المحتوى. لهذا ، استخدم ISNUMBER مع وظيفة SEARCH.

في النموذج العام ، تبدو الصيغة كما يلي:

حيث السلسلة الفرعية هي النص الذي تريد البحث عنه.

كمثال ، دعنا نتحقق مما إذا كانت السلسلة في A3 تحتوي على لون معين ، على سبيل المثال الأحمر:

=ISNUMBER(SEARCH("red", A3))

تعمل هذه الصيغة بشكل جيد لخلية واحدة. ولكن نظرًا لأن جدول العينات الخاص بنا (من فضلك انظر أدناه) يحتوي على ثلاثة ألوان مختلفة ، فإن كتابة صيغة منفصلة لكل منها سيكون مضيعة للوقت. بدلاً من ذلك ، سوف نشير إلى الخلية التي تحتوي على لون الاهتمام (B2).

=ISNUMBER(SEARCH(B$2, $A3))

لكي تنسخ الصيغة بشكل صحيح وإلى اليمين ، تأكد من قفل الإحداثيات التالية باستخدام علامة $:

• في مرجع سلسلة فرعية ، قم بإغلاق الصف (B $ 2) بحيث تختار الصيغ المنسوخة السلاسل الفرعية في الصف 2. دائمًا ما يكون مرجع العمود نسبيًا لأننا تريد ضبطه لكل عمود ، أي عند نسخ الصيغة إلى C3 ، سيتغير مرجع السلسلة الفرعية إلى C $ 2.
• في مرجع الخلية المصدر ، قم بإغلاق العمود ($ A3 ) بحيث تتحقق جميع الصيغ من القيم الموجودة في العمود A.

توضح لقطة الشاشة أدناه النتيجة:

ISNUMBER FIND - حساسة لحالة الأحرف الصيغة

نظرًا لأن وظيفة البحث غير حساسة لحالة الأحرف ، فإن ما ورد أعلاهالصيغة لا تفرق بين الأحرف الكبيرة والصغيرة. إذا كنت تبحث عن صيغة حساسة لحالة الأحرف ، فاستخدم الدالة FIND بدلاً من البحث.

لمجموعة البيانات النموذجية الخاصة بنا ، ستتخذ الصيغة هذا الشكل:

=ISNUMBER(FIND(B$2, $A3))

كيف تعمل هذه الصيغة

منطق الصيغة واضح تمامًا ويسهل اتباعه:

• تبحث الدالة SEARCH / FIND عن السلسلة الفرعية في الخلية المحددة. إذا تم العثور على السلسلة الفرعية ، يتم إرجاع موضع الحرف الأول. إذا لم يتم العثور على السلسلة الفرعية ، فإن الدالة تنتج الخطأ #VALUE! خطأ.
• تأخذها الدالة ISNUMBER من هناك وتعالج المواضع الرقمية. لذلك ، إذا تم العثور على السلسلة الفرعية وتم إرجاع موضعها كرقم ، فإن ISNUMBER تنتج TRUE. إذا لم يتم العثور على السلسلة الفرعية وكان الخطأ #VALUE! حدث خطأ ، ينتج عن ISNUMBER FALSE.

إذا كانت صيغة ISNUMBER

إذا كنت تهدف إلى الحصول على صيغة تنتج شيئًا آخر غير TRUE أو FALSE ، فاستخدم ISNUMBER مع الدالة IF.

مثال 1. الخلية تحتوي على النص

إذا أخذنا المثال السابق إلى أبعد من ذلك ، افترض أنك تريد تمييز لون كل عنصر بـ "x" كما هو موضح في الجدول أدناه.

للقيام بذلك ، قم ببساطة بلف صيغة ISNUMBER SEARCH في عبارة IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

إذا كان ISNUMBER يُرجع TRUE ، فإن دالة IF تُخرج "x" (أو أي قيمة أخرى توفرها لـ value_if_true جدال). إذا قام ISNUMBER بإرجاع FALSE ، فإن الدالة IF تُخرج سلسلة فارغة ("").

مثال 2. الحرف الأول في الخلية هو الرقم أو النص

تخيل أنك تعمل بقائمة من السلاسل الأبجدية الرقمية وتريد معرفة ما إذا كان الحرف الأول في السلسلة هو رقم أم حرف.

لإنشاء مثل هذه الصيغة ، سنحتاج إلى 4 وظائف مختلفة:

• تستخرج الدالة LEFT الحرف الأول من بداية سلسلة ، على سبيل المثال في الخلية A2:

  LEFT(A2, 1)

• نظرًا لأن LEFT ينتمي إلى فئة وظائف النص ، النتيجة دائمًا عبارة عن سلسلة نصية ، حتى لو كانت تحتوي على أرقام فقط. لذلك ، قبل التحقق من الحرف المستخرج ، نحتاج إلى محاولة تحويله إلى رقم. لهذا ، استخدم إما دالة VALUE أو عامل تشغيل أحادي مزدوج:

  VALUE(LEFT(A2, 1)) أو (--LEFT(A2, 1))

• تحدد الدالة ISNUMBER ما إذا كان الحرف المستخرج رقميًا أم لا:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• استنادًا إلى نتيجة ISNUMBER (TRUE أو FALSE) ، ترجع الدالة IF "Number" أو "Letter" ، على التوالي.

بافتراض أننا نختبر سلسلة في A2 ، الصيغة الكاملة يأخذ هذا الشكل:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

أو

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

تكون وظيفة ISNUMBER مفيدة أيضًا لـ استخراج الأرقام من سلسلة. إليك مثال: احصل على رقم من أي موضع في سلسلة.

تحقق مما إذا كانت القيمة ليست رقمًا

على الرغم من أن Microsoft Excel لديه وظيفة خاصة ، ISNONTEXT ، لتحديدسواء كانت قيمة الخلية ليست نصية ، فإن الدالة المماثلة للأرقام مفقودة.

الحل السهل هو استخدام ISNUMBER مع NOT الذي يُرجع عكس القيمة المنطقية. بمعنى آخر ، عندما يقوم ISNUMBER بإرجاع TRUE ، لا يحولها NOT إلى FALSE ، والعكس صحيح.

لرؤيتها بشكل عملي ، يرجى ملاحظة نتائج الصيغة التالية:

=NOT(ISNUMBER(A2))

هناك طريقة أخرى تستخدم الدالتين IF و ISNUMBER معًا:

=IF(ISNUMBER(A2), "", "Not number")

إذا كانت A2 رقمية ، فإن الصيغة لا تُرجع شيئًا (فارغة سلسلة). إذا لم تكن A2 رقمية ، فإن الصيغة تقولها مقدمًا: "ليس رقمًا".

إذا كنت ترغب في إجراء بعض العمليات الحسابية باستخدام الأرقام ، فضع معادلة أو أخرى الصيغة في الوسيطة value_if_true بدلاً من سلسلة فارغة. على سبيل المثال ، ستضرب الصيغة أدناه الأرقام في 10 وتنتج "ليس رقمًا" للقيم غير الرقمية:

=IF(ISNUMBER(A2), A2*10, "Not number")

تحقق مما إذا كان النطاق يحتوي على أي رقم

في عندما تريد اختبار النطاق الكامل للأرقام ، استخدم الدالة ISNUMBER جنبًا إلى جنب مع SUMPRODUCT مثل هذا:

على سبيل المثال ، لمعرفة ما إذا كان النطاق A2: A5 يحتوي على أي قيمة رقمية ، ستظهر الصيغ على النحو التالي:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

إذا كنت ترغب في إخراج "نعم" و "لا" بدلاً من TRUE و FALSE ، فاستخدم عبارة IF باعتبارها"المجمع" للصيغ أعلاه. على سبيل المثال:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

كيف تعمل هذه الصيغة

في قلب الصيغة ، تقوم الدالة ISNUMBER بتقييم كل خلية في النطاق المحدد ، على سبيل المثال B2: B5 ، وإرجاع TRUE للأرقام ، FALSE لأي شيء آخر. نظرًا لأن النطاق يحتوي على 4 خلايا ، فإن المصفوفة تحتوي على 4 عناصر:

{TRUE;FALSE;FALSE;FALSE}

عملية الضرب أو الأحادية المزدوجة (-) تقسم TRUE و FALSE إلى 1 و 0 ، على التوالي:

{1;0;0;0}

تضيف الدالة SUMPRODUCT عناصر المصفوفة. إذا كانت النتيجة أكبر من الصفر ، فهذا يعني وجود رقم واحد على الأقل في النطاق. لذلك ، يمكنك استخدام "& gt؛ 0" للحصول على نتيجة نهائية من TRUE أو FALSE.

ISNUMBER في التنسيق الشرطي لتمييز الخلايا التي تحتوي على نص معين

إذا كنت تبحث عن تمييز خلايا أو صفوف كاملة تحتوي على نص معين ، قم بإنشاء قاعدة تنسيق شرطي استنادًا إلى صيغة ISNUMBER SEARCH (غير حساسة لحالة الأحرف) أو صيغة ISNUMBER FIND (حساسة لحالة الأحرف).

في هذا المثال ، سنقوم بتمييز الصفوف بناءً على القيمة الموجودة في العمود A. بتعبير أدق ، سنبرز العناصر التي تحتوي على كلمة "أحمر". وإليك الطريقة:

1. حدد جميع صفوف البيانات (A2: C6 في هذا المثال) أو العمود الذي تريد تمييز الخلايا فيه فقط.
2. في الصفحة الرئيسية ، في المجموعة الأنماط ، انقر فوق قاعدة جديدة & gt ؛ استخدم صيغة لتحديد الخلايا المراد تنسيقها .
3. فيفي المربع تنسيق القيم حيث تكون هذه الصيغة صحيحة ، أدخل الصيغة أدناه (يرجى ملاحظة أن إحداثي العمود مغلق بعلامة $):

   =ISNUMBER(SEARCH("red", $A2))

4. انقر فوق زر التنسيق واختر التنسيق الذي تريده.
5. انقر فوق "موافق" مرتين.

إذا كانت لديك خبرة قليلة في تنسيق Excel الشرطي ، يمكنك العثور على الخطوات التفصيلية مع لقطات الشاشة في هذا البرنامج التعليمي: كيفية إنشاء قاعدة تنسيق شرطي قائمة على الصيغة.

نتيجة لذلك ، يتم تمييز جميع عناصر اللون الأحمر:

بدلاً من "الترميز الثابت" للون في قاعدة التنسيق الشرطي ، يمكنك كتابته في خلية محددة مسبقًا ، على سبيل المثال E2 ، والإشارة إلى تلك الخلية في الصيغة (يرجى مراعاة مرجع الخلية المطلق $ E $ 2). بالإضافة إلى ذلك ، تحتاج إلى التحقق مما إذا كانت خلية الإدخال ليست فارغة:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

ونتيجة لذلك ، ستحصل على قاعدة أكثر مرونة تبرز الصفوف بناءً على إدخالك في E2:

هذه هي كيفية استخدام دالة ISNUMBER في Excel. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

التنزيلات المتاحة

أمثلة صيغة Excel ISNUMBER