Упатството објаснува што е ISNUMBER во Excel и дава примери за основна и напредна употреба.

Концептот на функцијата ISNUMBER во Excel е многу едноставен - само проверува дали даденото вредноста е број или не. Важна точка овде е тоа што практичната употреба на функцијата оди многу подалеку од нејзиниот основен концепт, особено кога се комбинира со други функции во поголеми формули.

Функција ISNUMBER Excel

Функцијата ISNUMBER во Excel проверува дали ќелијата содржи нумеричка вредност или не. Спаѓа во групата на IS функции.

Функцијата е достапна во сите верзии на Excel за Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 и пониски.

Синтаксата ISNUMBER бара само еден аргумент:

=ISNUMBER(value)

Каде што вредност е вредноста што сакате да ја тестирате. Вообичаено, таа е претставена со референца на ќелијата, но исто така можете да наведете вистинска вредност или да вметнете друга функција во ISNUMBER за да го проверите резултатот.

Ако вредноста е нумеричка, функцијата враќа TRUE . За било што друго (текстуални вредности, грешки, празни места) ISNUMBER враќа FALSE.

Како пример, да ги тестираме вредностите во ќелиите A2 до A6 и ќе дознаеме дека првите 3 вредности се броеви, а последните две се текст:

2 работи што треба да ги знаете за функцијата ISNUMBER во Excel

Овде треба да се забележат неколку интересни точки:

• Вовнатрешното претставување на Excel, датумите и времето се нумерички вредности, така што формулата ISNUMBER враќа ТОЧНО за нив (видете ги B3 и B4 на сликата од екранот погоре).
• За броеви зачувани како текст, функцијата ISNUMBER враќа FALSE (видете го овој пример).

Примери на формулата на Excel ISNUMBER

Примерите подолу покажуваат неколку вообичаени и неколку нетривијални употреби од ISNUMBER во Excel.

Проверете дали вредноста е број

Кога имате куп вредности во вашиот работен лист и сакате да знаете кои се броеви, ISNUMBER е вистинската функција за користење .

Во овој пример, првата вредност е во A2, затоа ја користиме формулата подолу за да ја провериме, а потоа ја влечеме формулата на онолку ќелии колку што е потребно:

=ISNUMBER(A2)

Внимавајте, иако сите вредности изгледаат како бројки, формулата ISNUMBER врати FALSE за ќелиите A4 и A5, што значи дека тие вредности се нумерички низи , т.е. броеви форматирани како текст. Може да има различни причини за ова, на пример водечки нули, претходен апостроф итн. Без оглед на причината, Excel не ги препознава таквите вредности како бројки. Значи, ако вашите вредности не се пресметуваат правилно, првото нешто што треба да проверите е дали тие се навистина бројки во однос на Excel, а потоа претворете го текстот во број доколку е потребно.

Формула за ПРЕБАРУВАЊЕ НА ISNUMBER Excel

Покрај идентификацијата на броевите, ExcelФункцијата ISNUMBER исто така може да провери дали ќелијата содржи специфичен текст како дел од содржината. За ова, користете ISNUMBER заедно со функцијата SEARCH.

Во генеричката форма, формулата изгледа вака:

Каде што подстринг е текстот што сакате да го најдете.

Како пример, да провериме дали низата во А3 содржи одредена боја, да речеме црвена:

=ISNUMBER(SEARCH("red", A3))

Оваа формула работи убаво за една ќелија. Но, бидејќи нашата табела за примероци (видете подолу) содржи три различни бои, пишувањето посебна формула за секоја од нив би било губење време. Наместо тоа, ќе се повикаме на ќелијата што ја содржи бојата на интерес (B2).

=ISNUMBER(SEARCH(B$2, $A3))

За формулата правилно да се копира надолу и надесно, задолжително заклучете ги следните координати со знакот $:

• Во референцата substring , заклучете го редот (B$2) така што копираните формули секогаш ги избираат поднизите во редот 2. Референцата на колоната е релативна бидејќи ние сакате да се приспособи за секоја колона, т.е. кога формулата ќе се копира во C3, референцата на поднизата ќе се смени во C$2.
• Во референцата изворната ќелија , заклучете ја колоната ($A3 ) така што сите формули ги проверуваат вредностите во колоната А.

Сликата од екранот подолу го покажува резултатот:

ПРОНАЈДЕТЕ ГИ БРОЈ НА ИЗ - чувствителна на букви формула

Бидејќи функцијата SEARCH е неосетлива на букви , горенаведенотоформулата не разликува големи и мали знаци. Ако барате формула чувствителна на големи букви, користете ја функцијата FIND наместо SEARCH.

За нашата база на податоци , формулата би ја имала оваа форма:

=ISNUMBER(FIND(B$2, $A3))

Како функционира оваа формула

Логиката на формулата е сосема очигледна и лесна за следење:

• Функцијата SEARCH / FIND ја бара поднизата во наведената ќелија. Ако се најде поднизата, се враќа позицијата на првиот знак. Ако поднизата не е пронајдена, функцијата произведува #VALUE! грешка.
• Функцијата ISNUMBER ја зема од таму и обработува нумерички позиции. Значи, ако поднизата се најде и нејзината позиција се врати како број, ISNUMBER дава ТОЧНО. Ако поднизата не е пронајдена и има #VALUE! се појавува грешка, ISNUMBER излегува НЕТОЧНО.

АКО формулата ISNUMBER

Ако сакате да добиете формула што дава нешто друго освен TRUE или FALSE, користете ISNUMBER заедно со функцијата IF.

Пример 1. Кој текст го содржи ќелијата

Да го земеме претходниот пример понатаму, да претпоставиме дека сакате да ја означите бојата на секоја ставка со „x“ како што е прикажано во табелата подолу.

За да го направите ова, едноставно завиткајте ја формулата ISNUMBER SEARCH во изјавата IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Ако ISNUMBER врати TRUE, функцијата IF дава „x“ (или која било друга вредност што ја давате на value_if_true аргумент). Ако ISNUMBER врати FALSE, функцијата IF дава празна низа ("").

Пример 2. Првиот знак во ќелијата е број или текст

Замислете дека работите со листа на алфанумерички стрингови и сакате да знаете дали првиот знак на низата е број или буква.

За да изградите таква формула, ќе ви требаат 4 различни функции:

• Функцијата LEFT го извлекува првиот знак од почетокот на низата, да речеме во ќелијата A2:

  LEFT(A2, 1)

• Бидејќи LEFT припаѓа на категоријата на текстуални функции, резултатот е секогаш текстуална низа, дури и ако содржи само броеви. Затоа, пред да го провериме извлечениот знак, треба да се обидеме да го претвориме во број. За ова, користете ја функцијата VALUE или двоен унарен оператор:

  VALUE(LEFT(A2, 1)) или (--LEFT(A2, 1))

• Функцијата ISNUMBER одредува дали извлечениот знак е нумерички или не:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Врз основа на резултатот ISNUMBER (TRUE или FALSE), функцијата IF враќа „Number“ или „Letter“, соодветно.

Претпоставувајќи дека тестираме низа во A2, целосната формула ја има оваа форма:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

или

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Функцијата ISNUMBER исто така е корисна за извлекување броеви од низа. Еве еден пример: Земете број од која било позиција во низата.

Проверете дали вредноста не е број

Иако Microsoft Excel има посебна функција, ISNONTEXT, за да одредибез разлика дали вредноста на ќелијата не е текст, недостасува аналогна функција за броеви.

Лесно решение е да се користи ISNUMBER во комбинација со NOT што ја враќа спротивното од логичката вредност. Со други зборови, кога ISNUMBER враќа TRUE, NOT го претвора во FALSE, и обратно.

За да го видите во акција, ве молиме погледнете ги резултатите од следнава формула:

=NOT(ISNUMBER(A2))

Друг пристап е користење на функциите IF и ISNUMBER заедно:

=IF(ISNUMBER(A2), "", "Not number")

Ако A2 е нумерички, формулата не враќа ништо (празна низа). Ако A2 не е нумерички, формулата однапред вели: „Не е број“.

Ако сакате да извршите некои пресметки со бројки, тогаш ставете равенка или друга формула во аргументот value_if_true наместо празна низа. На пример, формулата подолу ќе ги помножи броевите со 10 и ќе даде „Не број“ за ненумерички вредности:

=IF(ISNUMBER(A2), A2*10, "Not number")

Проверете дали опсегот содржи кој било број

Во ситуација кога сакате да го тестирате целиот опсег за броеви, користете ја функцијата ISNUMBER во комбинација со SUMPRODUCT вака:

На пример, за да дознаете дали опсегот A2:A5 содржи некоја нумеричка вредност, формулите ќе одат на следниов начин:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Ако сакате да излезете „Да“ и „Не“ наместо ТОЧНО и НЕТОЧНО, искористете ја изјавата IF како„обвивка“ за горенаведените формули. На пример:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Како функционира оваа формула

Во срцето на формулата, функцијата ISNUMBER ја проценува секоја ќелија од одреден опсег, да речеме B2:B5, и враќа ТОЧНО за броеви, НЕТОЧНО за било што друго. Бидејќи опсегот содржи 4 ќелии, низата има 4 елементи:

{TRUE;FALSE;FALSE;FALSE}

Операцијата за множење или двојната унарна (--) ги принудува TRUE и FALSE во 1 и 0, соодветно:

{1;0;0;0}

Функцијата SUMPRODUCT ги собира елементите на низата. Ако резултатот е поголем од нула, тоа значи дека има барем еден број во опсегот. Значи, користите „>0“ за да добиете конечен резултат од TRUE или FALSE.

ISNUMBER во условно форматирање за да ги означите ќелиите што содржат одреден текст

Ако сакате да означите ќелии или цели редови што содржат специфичен текст, креирајте правило за условно форматирање засновано на формулата ISNUMBER SEARCH (неосетливи на букви) или ISNUMBER FIND (чувствителни на големи букви).

За овој пример, ќе ги истакнеме редовите засновани на вредноста во колоната A. Поточно ќе ги истакнеме ставките што го содржат зборот „црвено“. Еве како:

1. Изберете ги сите редови со податоци (A2:C6 во овој пример) или само колоната во која сакате да ги означите ќелиите.
2. На Дома картичката, во групата Стилови , кликнете Ново правило > Користете формула за да одредите кои ќелии да се форматираат .
3. Вополето Форматирајте ги вредностите каде оваа формула е вистинита , внесете ја формулата подолу (забележете дека координатата на колоната е заклучена со знакот $):

   =ISNUMBER(SEARCH("red", $A2))

4. Кликнете на Копче Формат и изберете го форматот што го сакате.
5. Кликнете на ОК двапати.

Ако имате мало искуство со условно форматирање на Excel, можете да ги најдете деталните чекори со слики од екранот во ова упатство: Како да креирате правило за условно форматирање засновано на формула.

Како резултат на тоа, сите ставки со црвена боја се означени:

Наместо да ја „хардкодирате“ бојата во правилото за условно форматирање, можете да ја напишете во претходно дефинирана ќелија, на пример E2, и да се повикате на таа ќелија во вашата формула (ве молиме имајте ја апсолутната референца на ќелијата $E$2). Дополнително, треба да проверите дали влезната ќелија не е празна:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Како резултат на тоа, ќе добиете пофлексибилно правило кое ги истакнува редовите врз основа на вашиот внес во E2:

Така се користи функцијата ISNUMBER во Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Достапни преземања

Примери на формулата на Excel ISNUMBER