අන්තර්ගත වගුව
Excel හි ISNUMBER යනු කුමක්දැයි නිබන්ධනය පැහැදිලි කරන අතර මූලික සහ උසස් භාවිතයන් සඳහා උදාහරණ සපයයි.
Excel හි ISNUMBER ශ්‍රිතයේ සංකල්පය ඉතා සරලයි - එය ලබා දී ඇත්දැයි පරීක්ෂා කරයි. අගය අංකයක් හෝ නැත. මෙහි වැදගත් කරුණක් නම්, ශ්‍රිතයේ ප්‍රායෝගික භාවිතයන් එහි මූලික සංකල්පයෙන් ඔබ්බට ගොස් තිබීමයි, විශේෂයෙන්ම විශාල සූත්‍ර තුළ ඇති අනෙකුත් ශ්‍රිත සමඟ සංකලනය වූ විට.
Excel ISNUMBER ශ්‍රිතය
Excel හි ISNUMBER ශ්‍රිතය සෛලයක සංඛ්‍යාත්මක අගයක් තිබේද නැද්ද යන්න පරීක්ෂා කරයි. එය IS ශ්‍රිත සමූහයට අයත් වේ.
Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 සහ පහළ සඳහා Excel හි සියලුම අනුවාද වල ශ්‍රිතය පවතී.
ISNUMBER වාක්‍ය ඛණ්ඩයට අවශ්‍ය වන්නේ එක් තර්කයක් පමණි:
=ISNUMBER(value)
අගය යනු ඔබට පරීක්ෂා කිරීමට අවශ්‍ය අගයයි. සාමාන්‍යයෙන්, එය සෛල යොමුවකින් නිරූපනය වේ, නමුත් ප්‍රතිඵලය පරීක්ෂා කිරීමට ඔබට සැබෑ අගයක් සැපයිය හැකිය, නැතහොත් ISNUMBER තුළ වෙනත් ශ්‍රිතයක් කැදලිගත හැක.
අගය සංඛ්‍යාත්මක නම්, ශ්‍රිතය සත්‍ය වේ . වෙනත් ඕනෑම දෙයක් සඳහා (පෙළ අගයන්, දෝෂ, හිස් තැන්) ISNUMBER FALSE ලබා දෙයි.
උදාහරණයක් ලෙස, A2 සිට A6 දක්වා සෛලවල අගයන් පරීක්ෂා කරමු, එවිට පළමු අගයන් 3 ඉලක්කම් සහ අවසාන දෙක බව අපි සොයා ගනිමු. පෙළ වේ:
Excel හි ISNUMBER ශ්‍රිතය ගැන ඔබ දැනගත යුතු කරුණු 2ක්
මෙහි සටහන් කළ යුතු රසවත් කරුණු කිහිපයක් තිබේ:
- තුළඅභ්‍යන්තර Excel නියෝජනය, දින සහ වේලා සංඛ්‍යාත්මක අගයන් වේ, එබැවින් ISNUMBER සූත්‍රය ඒවා සඳහා සත්‍ය ලබා දෙයි (කරුණාකර ඉහත තිර රුවෙහි B3 සහ B4 බලන්න).
- සඳහා පෙළ ලෙස ගබඩා කර ඇති සංඛ්‍යා, ISNUMBER ශ්‍රිතය අසත්‍ය ලබා දෙයි (මෙම උදාහරණය බලන්න).
Excel ISNUMBER සූත්‍ර උදාහරණ
පහත උදාහරණ මගින් පොදු සහ සුළු නොවන භාවිතයන් කිහිපයක් පෙන්නුම් කරයි Excel හි ISNUMBER හි.
අගය අංකයක් දැයි පරීක්ෂා කරන්න
ඔබේ වැඩ පත්‍රිකාවේ අගයන් පොකුරක් ඇති විට සහ ඔබට අංක මොනවාදැයි දැන ගැනීමට අවශ්‍ය වූ විට, ISNUMBER භාවිතා කිරීමට නිවැරදි කාර්යය වේ. .
මෙම උදාහරණයේ, පළමු අගය A2 හි ඇත, එබැවින් අපි එය පරීක්ෂා කිරීමට පහත සූත්‍රය භාවිතා කරමු, ඉන්පසු අවශ්‍ය තරම් සෛල ගණනකට සූත්‍රය පහළට ඇද දමන්න:
=ISNUMBER(A2)
සියලු අගයන් සංඛ්‍යා ලෙස පෙනුනද, ISNUMBER සූත්‍රය A4 සහ A5 කොටු සඳහා FALSE ලබා දී ඇති බව කරුණාවෙන් සලකන්න, එනම් එම අගයන් සංඛ්‍යාත්මක තන්තු , එනම් පෙළ ලෙස සංයුති කර ඇති අංක. මේ සඳහා විවිධ හේතු තිබිය හැක, උදාහරණයක් ලෙස ප්‍රමුඛ ශුන්‍ය, පෙර අපෝස්ට්‍රොෆි යනාදිය. හේතුව කුමක් වුවත්, Excel එවැනි අගයන් සංඛ්‍යා ලෙස හඳුනා නොගනී. එබැවින්, ඔබේ අගයන් නිවැරදිව ගණනය නොකරන්නේ නම්, ඔබ විසින් පරීක්ෂා කළ යුතු පළමු දෙය නම්, ඒවා සැබවින්ම Excel අනුව සංඛ්‍යාද යන්නයි, පසුව අවශ්‍ය නම් පෙළ අංකයට පරිවර්තනය කරන්න.
Excel ISNUMBER සෙවුම් සූත්‍රය
අංක හඳුනාගැනීමට අමතරව, ExcelISNUMBER ශ්‍රිතයට කොටුවක අන්තර්ගතයේ කොටසක් ලෙස නිශ්චිත පෙළ තිබේදැයි පරීක්ෂා කළ හැක. මේ සඳහා, සෙවුම් ශ්‍රිතය සමඟ එක්ව ISNUMBER භාවිතා කරන්න.
සාමාන්‍ය ආකෘතියේ, සූත්‍රය පහත පරිදි දිස්වේ:
ISNUMBER(SEARCH( substring, cell))substring යනු ඔබට සොයා ගැනීමට අවශ්‍ය පෙළ වේ.
උදාහරණයක් ලෙස, A3 හි ඇති තන්තුවෙහි නිශ්චිත වර්ණයක් තිබේදැයි පරීක්ෂා කර බලමු, රතු යැයි කියන්න:
=ISNUMBER(SEARCH("red", A3))
මෙම සූත්‍රය තනි සෛලයක් සඳහා හොඳින් ක්‍රියා කරයි. නමුත් අපගේ නියැදි වගුව (කරුණාකර පහත බලන්න) විවිධ වර්ණ තුනක් අඩංගු වන නිසා, එක් එක් සඳහා වෙනම සූත්‍රයක් ලිවීම කාලය නාස්තියක් වනු ඇත. ඒ වෙනුවට, අපි උනන්දුව දක්වන වර්ණය (B2) අඩංගු කොටුව වෙත යොමු කරන්නෙමු.
=ISNUMBER(SEARCH(B$2, $A3))
සූත්‍රය නිවැරදිව පහළට සහ දකුණට පිටපත් කිරීමට, පහත ඛණ්ඩාංක සමඟ අගුලු දැමීමට වග බලා ගන්න. $ ලකුණ:
- substring යොමුවෙහි, පේළිය (B$2) අගුළු දමන්න එවිට පිටපත් කරන ලද සූත්‍ර සෑම විටම පේළියේ 2 හි ඇති උපසිරැසි තෝරා ගනී. තීරු යොමුව සාපේක්ෂ වන නිසා අපි එය එක් එක් තීරුව සඳහා සීරුමාරු කිරීමට අවශ්‍ය වේ, එනම් සූත්‍රය C3 වෙත පිටපත් කළ විට, උපසිරැසි යොමුව C$2 වෙත වෙනස් වනු ඇත.
- මූලාශ්‍ර කොටුව යොමුවෙහි, තීරුව අගුළු දමන්න ($A3 ) එවිට සියලුම සූත්‍ර A තීරුවේ ඇති අගයන් පරීක්ෂා කරයි.
පහත තිර රුවක් ප්‍රතිඵලය පෙන්වයි:
ISNUMBER FIND - case-sensitive සූත්‍රය
සෙවුම් ශ්‍රිතය අවස්ථාව සංවේදී නොවන බැවින්, ඉහතසූත්‍රය විශාල අකුරු සහ කුඩා අකුරු වෙන්කර හඳුනා නොගනී. ඔබ සිද්ධි සංවේදී සූත්‍රයක් සොයන්නේ නම්, සෙවීමට වඩා FIND ශ්‍රිතය භාවිතා කරන්න.
ISNUMBER(FIND( substring, cell))අපගේ නියැදි දත්ත කට්ටලය සඳහා , සූත්‍රය මෙම පෝරමය ගනු ඇත:
=ISNUMBER(FIND(B$2, $A3))
මෙම සූත්‍රය ක්‍රියා කරන ආකාරය
සූත්‍රයේ තර්කනය ඉතා පැහැදිලි වන අතර අනුගමනය කිරීමට පහසුය:
- SEARCH / FIND ශ්‍රිතය නිශ්චිත කොටුවේ ඇති උපස්ථරය සොයයි. උපස්ථරය සොයාගතහොත්, පළමු අක්ෂරයේ පිහිටීම ආපසු ලබා දෙනු ලැබේ. උපස්ථරය සොයාගත නොහැකි නම්, ශ්‍රිතය #VALUE එකක් නිපදවයි! දෝෂය.
- ISNUMBER ශ්‍රිතය එය එතැනින් ගෙන සංඛ්‍යාත්මක ස්ථාන සකසයි. එබැවින්, උපස්ථරය සොයාගෙන එහි පිහිටීම අංකයක් ලෙස ආපසු ලබා දෙන්නේ නම්, ISNUMBER ප්‍රතිදානය සත්‍ය වේ. උපසිරසිය සොයාගත නොහැකි නම් සහ #VALUE! දෝෂයක් සිදුවේ, ISNUMBER ප්‍රතිදානය අසත්‍ය වේ.
ISNUMBER සූත්‍රය නම්
ඔබ සත්‍ය හෝ අසත්‍ය ප්‍රතිදානය කරන සූත්‍රයක් ලබා ගැනීමට ඉලක්ක කරන්නේ නම්, IF ශ්‍රිතය සමඟ එක්ව ISNUMBER භාවිතා කරන්න.
උදාහරණ 1. කොටුවේ කුමන පෙළ අඩංගු වේ
පෙර උදාහරණය තවදුරටත් ගෙන, පහත වගුවේ පෙන්වා ඇති පරිදි එක් එක් අයිතමයේ වර්ණය "x" වලින් සලකුණු කිරීමට ඔබට අවශ්‍ය යැයි සිතන්න.
මෙය සිදු කිරීම සඳහා, ISNUMBER සෙවුම් සූත්‍රය IF ප්‍රකාශය තුළට ඔතා:
=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")
ISNUMBER සත්‍ය ලෙස ලබා දෙන්නේ නම්, IF ශ්‍රිතය "x" (හෝ ඔබ සපයන වෙනත් අගයක්) ප්‍රතිදානය කරයි. value_if_true තර්කය). ISNUMBER FALSE ලබා දෙන්නේ නම්, IF ශ්‍රිතය හිස් තන්තුවක් ("") ප්‍රතිදානය කරයි.
උදාහරණ 2. කොටුවක පළමු අක්ෂරය අංකය හෝ පෙළ
ඔබ අක්ෂරාංක අනුලකුණු ලැයිස්තුවක් සමඟ වැඩ කරන බව සිතන්න සහ ඔබට තන්තුවක පළමු අක්ෂරය අංකයක් හෝ අකුරක් දැයි දැන ගැනීමට අවශ්‍ය වේ.
එවැනි සූත්‍රයක් තැනීමට, අපට ඔබට විවිධ ශ්‍රිත 4ක් අවශ්‍ය වනු ඇත:
- LEFT ශ්‍රිතය තන්තුවක ආරම්භයේ සිට පළමු අක්ෂරය උපුටා ගනී, A2 කොටුවේ කියන්න:
LEFT(A2, 1) - LEFT Text functions ගණයට අයත් වන නිසා, එහි එහි සංඛ්‍යා පමණක් අඩංගු වුවද, ප්‍රතිඵලය සැමවිටම පෙළ තන්තුවකි. එමනිසා, උපුටා ගත් අක්ෂරය පරීක්ෂා කිරීමට පෙර, අපි එය අංකයකට පරිවර්තනය කිරීමට උත්සාහ කළ යුතුය. මේ සඳහා, VALUE ශ්‍රිතය හෝ ද්විත්ව ඒකීය ක්‍රියාකරු භාවිතා කරන්න:
VALUE(LEFT(A2, 1))හෝ(--LEFT(A2, 1)) - ISNUMBER ශ්‍රිතය උපුටා ගත් අක්ෂරය සංඛ්‍යාත්මකද නැද්ද යන්න තීරණය කරයි:
ISNUMBER(VALUE(LEFT(A2, 1))) - ISNUMBER ප්‍රතිඵලය (සත්‍ය හෝ අසත්‍ය) මත පදනම්ව, IF ශ්‍රිතය පිළිවෙළින් "අංකය" හෝ "අකුරු" ලබා දෙයි.
අපි සම්පූර්ණ සූත්‍රය වන A2 හි තන්තුවක් පරීක්ෂා කරන්නේ යැයි උපකල්පනය කරයි. මෙම හැඩය ගනී:
=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")
හෝ
=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")
ISNUMBER ශ්‍රිතය <12 සඳහාද ප්‍රයෝජනවත් වේ තන්තුවකින් අංක උපුටා ගැනීම. මෙන්න උදාහරණයක්: තන්තුවක ඕනෑම ස්ථානයක සිට අංකයක් ලබා ගන්න.
අගය අංකයක් නොවේදැයි පරීක්ෂා කරන්න
Microsoft Excel විශේෂ කාර්යයක් ඇතත්, ISNONTEXT, තීරණය කිරීමටකොටුවක අගය අකුරු නොවේද, සංඛ්‍යා සඳහා ප්‍රතිසම ශ්‍රිතයක් නොමැත.
පහසු විසඳුමක් වන්නේ තාර්කික අගයක ප්‍රතිවිරුද්ධය ලබා දෙන NOT සමඟ සංයෝජනයක් ලෙස ISNUMBER භාවිතා කිරීමයි. වෙනත් වචන වලින් කිවහොත්, ISNUMBER TRUE වෙත ආපසු එන විට, එය FALSE බවට පරිවර්තනය නොකරන අතර, අනෙක් අතට එය පරිවර්තනය කරයි.
එය ක්‍රියාවෙන් බැලීමට, කරුණාකර පහත සූත්‍රයේ ප්‍රතිඵල නිරීක්ෂණය කරන්න:
=NOT(ISNUMBER(A2))
තවත් ප්‍රවේශයක් වන්නේ IF සහ ISNUMBER ශ්‍රිත එකට භාවිතා කිරීමයි:
=IF(ISNUMBER(A2), "", "Not number")
A2 සංඛ්‍යාත්මක නම්, සූත්‍රය කිසිවක් ලබා නොදේ (හිස් එකක් තන්තුව). A2 සංඛ්‍යාත්මක නොවේ නම්, සූත්‍රය එය කලින් කියයි: "සංඛ්‍යා නොවේ" හිස් තන්තුවක් වෙනුවට value_if_true තර්කයේ සූත්‍රය. උදාහරණයක් ලෙස, පහත සූත්‍රය සංඛ්‍යා 10 න් ගුණ කර සංඛ්‍යාත්මක නොවන අගයන් සඳහා "අංක නොවේ" ලබා දෙනු ඇත:
=IF(ISNUMBER(A2), A2*10, "Not number")
පරාසයක කිසියම් සංඛ්‍යාවක් තිබේදැයි පරීක්ෂා කරන්න
දී ඔබට සංඛ්‍යා සඳහා සම්පූර්ණ පරාසය පරීක්ෂා කිරීමට අවශ්‍ය වූ විට, SUMPRODUCT සමඟ ඒකාබද්ධව ISNUMBER ශ්‍රිතය භාවිතා කරන්න:
SUMPRODUCT(--ISNUMBER( range))>0 SUMPRODUCT(ISNUMBER( පරාසය)*1)>0උදාහරණයක් ලෙස, A2:A5 පරාසයේ කිසියම් සංඛ්‍යාත්මක අගයක් තිබේදැයි සොයා ගැනීමට, සූත්‍ර පහත පරිදි යයි:
=SUMPRODUCT(--ISNUMBER(A2:A5))>0
=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0
ඔබ සත්‍ය සහ අසත්‍ය වෙනුවට "ඔව්" සහ "නැත" ප්‍රතිදානය කිරීමට කැමති නම්, IF ප්‍රකාශය භාවිතා කරන්නඉහත සූත්‍ර සඳහා "දවුම්". උදාහරණයක් ලෙස:
=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")
මෙම සූත්‍රය ක්‍රියා කරන ආකාරය
සූත්‍රයේ හදවතේ, ISNUMBER ශ්‍රිතය මඟින් එක් එක් සෛලය ඇගයීමට ලක් කරයි. නිශ්චිත පරාසය, B2:B5 කියන්න, සහ අංක සඳහා TRUE, වෙනත් ඕනෑම දෙයක් සඳහා FALSE ලබා දෙයි. පරාසයේ කොටු 4ක් අඩංගු වන බැවින්, අරාවට මූලද්‍රව්‍ය 4ක් ඇත:
{TRUE;FALSE;FALSE;FALSE}
ගුණ කිරීමේ ක්‍රියාව හෝ ද්විත්ව ඒකීය (--) පිළිවෙළින් 1 සහ 0 වලට TRUE සහ FALSE බල කරයි:
{1;0;0;0}
SUMPRODUCT ශ්‍රිතය අරාවේ මූලද්‍රව්‍ය එකතු කරයි. ප්‍රතිඵලය ශුන්‍යයට වඩා වැඩි නම්, එයින් අදහස් වන්නේ පරාසයේ අවම වශයෙන් එක් අංකයක්වත් ඇති බවයි. එබැවින්, ඔබ සත්‍ය හෝ අසත්‍යයේ අවසාන ප්‍රතිඵලයක් ලබා ගැනීමට ">0" භාවිතා කරයි.
නිශ්චිත පෙළ අඩංගු කොටු උද්දීපනය කිරීමට කොන්දේසි සහිත හැඩතල ගැන්වීමේ ISNUMBER
ඔබ සෛල උද්දීපනය කිරීමට බලාපොරොත්තු වන්නේ නම් හෝ නිශ්චිත පෙළ අඩංගු සම්පූර්ණ පේළි, ISNUMBER SEARCH (case-inensitive) හෝ ISNUMBER FIND (case-sensitive) සූත්‍රය මත පදනම්ව කොන්දේසි සහිත හැඩතල ගැන්වීමේ රීතියක් සාදන්න.
මෙම උදාහරණය සඳහා, අපි පේළි ඉස්මතු කිරීමට යන්නේ A තීරුවේ අගය. වඩාත් නිවැරදිව, අපි "රතු" යන වචනය අඩංගු අයිතම ඉස්මතු කරමු. මෙන්න මෙහෙමයි:
- සියලු දත්ත පේළි තෝරන්න (මෙම උදාහරණයේ A2:C6) හෝ ඔබට කොටු උද්දීපනය කිරීමට අවශ්‍ය තීරුව පමණක් තෝරන්න.
- මුල් පිටුවේ ටැබය, විලාස සමූහයේ, නව රීතිය > ආකෘතිකරණය කළ යුතු සෛල තීරණය කිරීමට සූත්‍රයක් භාවිතා කරන්න .
- දී මෙම සූත්‍රය සත්‍ය වන ආකෘති අගයන් කොටුව, පහත සූත්‍රය ඇතුළු කරන්න (තීරු ඛණ්ඩාංකය $ ලකුණ සමඟ අගුලු දමා ඇති බව කරුණාවෙන් සලකන්න):
=ISNUMBER(SEARCH("red", $A2)) - ක්ලික් කරන්න Format බොත්තම සහ ඔබට අවශ්‍ය ආකෘතිය තෝරන්න.
- දෙවරක් OK ක්ලික් කරන්න.
ඔබට Excel කොන්දේසි සහිත හැඩතල ගැන්වීම පිළිබඳ අඩු අත්දැකීමක් තිබේ නම්, ඔබට සවිස්තරාත්මක පියවර සොයා ගත හැක. මෙම නිබන්ධනයේ තිරපිටපත් සමඟ: සූත්‍රය මත පදනම් වූ කොන්දේසි සහිත හැඩතල ගැන්වීමේ රීතියක් සාදා ගන්නේ කෙසේද.
ප්‍රතිඵලයක් ලෙස, රතු පැහැයේ සියලුම අයිතම උද්දීපනය කෙරේ:
=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")
ප්‍රතිඵලයක් ලෙස, E2:<3 හි ඔබගේ ආදානය මත පදනම්ව පේළි ඉස්මතු කරන වඩාත් නම්‍යශීලී රීතියක් ඔබට ලැබෙනු ඇත>
එක්සෙල් හි ISNUMBER ශ්‍රිතය භාවිතා කරන්නේ කෙසේද යන්නයි. කියවීම සඳහා මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ අපගේ බ්ලොගයේ ඔබව දැකීමට බලාපොරොත්තු වෙමි!
ලබාගත හැකි බාගැනීම්
Excel ISNUMBER සූත්‍ර උදාහරණ
