Tutorial menerangkan tentang ISNUMBER dalam Excel dan menyediakan contoh penggunaan asas dan lanjutan.

Konsep fungsi ISNUMBER dalam Excel adalah sangat mudah - ia hanya menyemak sama ada sesuatu yang diberikan nilai ialah nombor atau tidak. Perkara penting di sini ialah penggunaan praktikal fungsi itu jauh melebihi konsep asasnya, terutamanya apabila digabungkan dengan fungsi lain dalam formula yang lebih besar.

Fungsi ISNUMBER Excel

Fungsi ISNUMBER dalam Excel menyemak sama ada sel mengandungi nilai berangka atau tidak. Ia tergolong dalam kumpulan fungsi IS.

Fungsi ini tersedia dalam semua versi Excel untuk Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 dan lebih rendah.

Sintaks ISNUMBER memerlukan hanya satu hujah:

=ISNUMBER(value)

Di mana nilai ialah nilai yang ingin anda uji. Biasanya, ia diwakili oleh rujukan sel, tetapi anda juga boleh membekalkan nilai sebenar atau menyarangkan fungsi lain di dalam ISNUMBER untuk menyemak hasilnya.

Jika nilai ialah angka, fungsi itu mengembalikan TRUE . Untuk perkara lain (nilai teks, ralat, kosong) ISNUMBER mengembalikan FALSE.

Sebagai contoh, mari kita uji nilai dalam sel A2 hingga A6 dan kita akan mengetahui bahawa 3 nilai pertama ialah nombor dan dua yang terakhir ialah teks:

2 perkara yang perlu anda ketahui tentang fungsi ISNUMBER dalam Excel

Terdapat beberapa perkara menarik untuk diperhatikan di sini:

• Dalamperwakilan Excel dalaman, tarikh dan masa ialah nilai angka, jadi formula ISNUMBER mengembalikan TRUE untuknya (sila lihat B3 dan B4 dalam tangkapan skrin di atas).
• Untuk nombor yang disimpan sebagai teks, fungsi ISNUMBER mengembalikan FALSE (lihat contoh ini).

Contoh formula Excel ISNUMBER

Contoh di bawah menunjukkan beberapa kegunaan biasa dan bukan remeh. daripada ISNUMBER dalam Excel.

Semak sama ada nilai ialah nombor

Apabila anda mempunyai sekumpulan nilai dalam lembaran kerja anda dan anda ingin tahu yang mana satu nombor, ISNUMBER ialah fungsi yang sesuai untuk digunakan .

Dalam contoh ini, nilai pertama adalah dalam A2, jadi kami menggunakan formula di bawah untuk menyemaknya dan kemudian seret ke bawah formula kepada seberapa banyak sel yang diperlukan:

=ISNUMBER(A2)

Sila ambil perhatian bahawa walaupun semua nilai kelihatan seperti nombor, formula ISNUMBER telah mengembalikan FALSE untuk sel A4 dan A5, yang bermaksud nilai tersebut ialah rentetan angka , iaitu nombor yang diformatkan sebagai teks. Mungkin terdapat sebab yang berbeza untuk ini, contohnya sifar pendahuluan, tanda kutip sebelumnya, dsb. Walau apa pun sebabnya, Excel tidak mengenali nilai tersebut sebagai nombor. Jadi, jika nilai anda tidak dikira dengan betul, perkara pertama yang perlu anda semak ialah sama ada ia benar-benar nombor dari segi Excel, dan kemudian tukar teks kepada nombor jika perlu.

Formula CARIAN ISNUMBER Excel

Selain daripada mengenal pasti nombor, ExcelFungsi ISNUMBER juga boleh menyemak sama ada sel mengandungi teks tertentu sebagai sebahagian daripada kandungan. Untuk ini, gunakan ISNUMBER bersama-sama dengan fungsi SEARCH.

Dalam bentuk generik, formula kelihatan seperti berikut:

Di mana subrentetan ialah teks yang anda ingin cari.

Sebagai contoh, mari kita semak sama ada rentetan dalam A3 mengandungi warna tertentu, katakan merah:

=ISNUMBER(SEARCH("red", A3))

Formula ini berfungsi dengan baik untuk satu sel. Tetapi kerana jadual sampel kami (sila lihat di bawah) mengandungi tiga warna berbeza, menulis formula berasingan untuk setiap satu akan membuang masa. Sebaliknya, kami akan merujuk kepada sel yang mengandungi warna minat (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Untuk formula menyalin ke bawah dan ke kanan dengan betul, pastikan anda mengunci koordinat berikut dengan tanda $:

• Dalam rujukan subrentetan , kunci baris (B$2) supaya formula yang disalin sentiasa memilih subrentetan dalam baris 2. Rujukan lajur adalah relatif kerana kita mahu ia melaraskan untuk setiap lajur, iaitu apabila formula disalin ke C3, rujukan subrentetan akan berubah kepada C$2.
• Dalam rujukan sel sumber , kunci lajur ($A3 ) supaya semua formula menyemak nilai dalam lajur A.

Tangkapan skrin di bawah menunjukkan keputusan:

ISNUMBER FIND - sensitif huruf besar-besaran formula

Memandangkan fungsi SEARCH adalah tidak peka huruf besar-kecil , perkara di atasformula tidak membezakan aksara besar dan huruf kecil. Jika anda sedang mencari formula sensitif huruf besar-besaran, gunakan fungsi FIND dan bukannya CARI.

Untuk sampel set data kami , formula akan mengambil bentuk ini:

=ISNUMBER(FIND(B$2, $A3))

Cara formula ini berfungsi

Logik formula agak jelas dan mudah diikuti:

• Fungsi SEARCH / FIND mencari subrentetan dalam sel yang ditentukan. Jika subrentetan ditemui, kedudukan aksara pertama dikembalikan. Jika subrentetan tidak ditemui, fungsi menghasilkan #VALUE! ralat.
• Fungsi ISNUMBER mengambilnya dari sana dan memproses kedudukan berangka. Jadi, jika subrentetan ditemui dan kedudukannya dikembalikan sebagai nombor, ISNUMBER mengeluarkan TRUE. Jika subrentetan tidak ditemui dan #VALUE! ralat berlaku, ISNUMBER mengeluarkan FALSE.

JIKA formula ISNUMBER

Jika anda menyasarkan untuk mendapatkan formula yang menghasilkan sesuatu selain TRUE atau FALSE, gunakan ISNUMBER bersama-sama dengan fungsi IF.

Contoh 1. Sel mengandungi teks yang mana

Mengambil contoh sebelumnya dengan lebih lanjut, katakan anda ingin menandakan warna setiap item dengan "x" seperti yang ditunjukkan dalam jadual di bawah.

Untuk melakukan ini, hanya bungkus formula ISNUMBER SEARCH ke dalam pernyataan IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Jika ISNUMBER mengembalikan TRUE, fungsi IF mengeluarkan "x" (atau mana-mana nilai lain yang anda bekalkan kepada nilai_jika_benar hujah). Jika ISNUMBER mengembalikan FALSE, fungsi IF mengeluarkan rentetan kosong ("").

Contoh 2. Aksara pertama dalam sel ialah nombor atau teks

Bayangkan anda sedang bekerja dengan senarai rentetan alfanumerik dan anda ingin mengetahui sama ada aksara pertama rentetan ialah nombor atau huruf.

Untuk membina formula sedemikian, kami memerlukan 4 fungsi berbeza:

• Fungsi LEFT mengekstrak aksara pertama dari permulaan rentetan, katakan dalam sel A2:

  LEFT(A2, 1)

• Oleh kerana LEFT tergolong dalam kategori fungsi Teks, fungsinya keputusan sentiasa rentetan teks, walaupun ia hanya mengandungi nombor. Oleh itu, sebelum menyemak aksara yang diekstrak, kita perlu cuba menukarnya kepada nombor. Untuk ini, gunakan sama ada fungsi VALUE atau pengendali dua unari:

  VALUE(LEFT(A2, 1)) atau (--LEFT(A2, 1))

• Fungsi ISNUMBER menentukan sama ada aksara yang diekstrak ialah angka atau tidak:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Berdasarkan hasil ISNUMBER (TRUE atau FALSE), fungsi IF masing-masing mengembalikan "Nombor" atau "Huruf".

Dengan mengandaikan kami sedang menguji rentetan dalam A2, formula lengkap mengambil bentuk ini:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

atau

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Fungsi ISNUMBER juga berguna untuk mengekstrak nombor daripada rentetan. Berikut ialah contoh: Dapatkan nombor dari mana-mana kedudukan dalam rentetan.

Semak sama ada nilai bukan nombor

Walaupun Microsoft Excel mempunyai fungsi khas, ISNONTEXT, untuk menentukansama ada nilai sel bukan teks, fungsi analog untuk nombor tiada.

Penyelesaian mudah ialah menggunakan ISNUMBER dalam kombinasi dengan NOT yang mengembalikan nilai yang bertentangan dengan nilai logik. Dalam erti kata lain, apabila ISNUMBER mengembalikan TRUE, NOT menukarnya kepada FALSE dan sebaliknya.

Untuk melihatnya dalam tindakan, sila amati keputusan formula berikut:

=NOT(ISNUMBER(A2))

Pendekatan lain menggunakan fungsi IF dan ISNUMBER bersama-sama:

=IF(ISNUMBER(A2), "", "Not number")

Jika A2 ialah angka, formula tidak mengembalikan apa-apa (kosong tali). Jika A2 bukan angka, formula menyatakannya di hadapan: "Bukan nombor".

Jika anda ingin melakukan beberapa pengiraan dengan nombor, kemudian letakkan persamaan atau yang lain formula dalam argumen value_if_true dan bukannya rentetan kosong. Sebagai contoh, formula di bawah akan mendarab nombor dengan 10 dan menghasilkan "Bukan nombor" untuk nilai bukan angka:

=IF(ISNUMBER(A2), A2*10, "Not number")

Semak sama ada julat mengandungi sebarang nombor

In situasi apabila anda ingin menguji keseluruhan julat untuk nombor, gunakan fungsi ISNUMBER dalam kombinasi dengan SUMPRODUCT seperti ini:

Sebagai contoh, untuk mengetahui sama ada julat A2:A5 mengandungi sebarang nilai berangka, formula akan pergi seperti berikut:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Jika anda ingin mengeluarkan "Ya" dan "Tidak" dan bukannya BENAR dan SALAH, gunakan pernyataan IF sebagai"pembungkus" untuk formula di atas. Contohnya:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Cara formula ini berfungsi

Di tengah-tengah formula, fungsi ISNUMBER menilai setiap sel bagi julat yang ditentukan, sebut B2:B5, dan mengembalikan TRUE untuk nombor, FALSE untuk apa-apa lagi. Memandangkan julat mengandungi 4 sel, tatasusunan mempunyai 4 elemen:

{TRUE;FALSE;FALSE;FALSE}

Operasi pendaraban atau double unary (--) memaksa TRUE dan FALSE menjadi 1 dan 0, masing-masing:

{1;0;0;0}

Fungsi SUMPRODUCT menambah elemen tatasusunan. Jika keputusan lebih besar daripada sifar, ini bermakna terdapat sekurang-kurangnya satu nombor julat. Jadi, anda menggunakan ">0" untuk mendapatkan hasil akhir TRUE atau FALSE.

ISNUMBER dalam pemformatan bersyarat untuk menyerlahkan sel yang mengandungi teks tertentu

Jika anda ingin menyerlahkan sel atau keseluruhan baris yang mengandungi teks tertentu, buat peraturan pemformatan bersyarat berdasarkan formula ISNUMBER CARI (tidak peka huruf besar-kecil) atau ISNUMBER FIND (sensitif huruf besar-kecil).

Untuk contoh ini, kami akan menyerlahkan baris berdasarkan nilai dalam lajur A. Lebih tepat lagi, kami akan menyerlahkan item yang mengandungi perkataan "merah". Begini caranya:

1. Pilih semua baris data (A2:C6 dalam contoh ini) atau hanya lajur yang anda ingin serlahkan sel.
2. Pada Laman Utama , dalam kumpulan Gaya , klik Peraturan Baharu > Gunakan formula untuk menentukan sel yang hendak diformatkan .
3. Dalamdalam kotak Formatkan nilai formula ini , masukkan formula di bawah (sila ambil perhatian bahawa koordinat lajur dikunci dengan tanda $):

   =ISNUMBER(SEARCH("red", $A2))

4. Klik Butang Format dan pilih format yang anda mahu.
5. Klik OK dua kali.

Jika anda mempunyai sedikit pengalaman dengan pemformatan bersyarat Excel, anda boleh mendapatkan langkah terperinci dengan tangkapan skrin dalam tutorial ini: Cara membuat peraturan pemformatan bersyarat berasaskan formula.

Hasilnya, semua item warna merah diserlahkan:

Daripada "mengekod keras" warna dalam peraturan pemformatan bersyarat, anda boleh menaipnya dalam sel yang dipratentukan, sebut E2 dan merujuk kepada sel tersebut dalam formula anda (sila ambil perhatian rujukan sel mutlak $E$2). Selain itu, anda perlu menyemak sama ada sel input tidak kosong:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Hasilnya, anda akan mendapat peraturan yang lebih fleksibel yang menyerlahkan baris berdasarkan input anda dalam E2:

Begitulah cara menggunakan fungsi ISNUMBER dalam Excel. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Muat turun yang tersedia

Contoh formula Excel ISNUMBER