Заавар нь Excel-ийн ISNUMBER гэж юу болохыг тайлбарлаж, үндсэн болон дэвшилтэт хэрэглээний жишээнүүдийг өгдөг.

Excel-ийн ISNUMBER функцийн тухай ойлголт нь маш энгийн - энэ нь зөвхөн өгөгдсөн эсэхийг шалгадаг. утга нь тоо юм уу үгүй. Энд нэг чухал зүйл бол функцийн практик хэрэглээ нь түүний үндсэн ойлголтоос хол давсан, ялангуяа том томьёо доторх бусад функцуудтай хослуулсан байдаг.

Excel ISNUMBER функц

Excel-ийн ISNUMBER функц нь нүдэнд тоон утгатай эсэхийг шалгадаг. Энэ нь IS функцүүдийн бүлэгт хамаарна.

Функц нь Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 болон түүнээс доош хувилбаруудад зориулагдсан Excel-ийн бүх хувилбарт боломжтой.

ISNUMBER синтакс нь зөвхөн нэг аргумент шаарддаг:

=ISNUMBER(value)

Энд утга нь таны шалгахыг хүсэж буй утга юм. Энэ нь ихэвчлэн нүдний лавлагаагаар илэрхийлэгддэг боловч та үр дүнг шалгахын тулд бодит утгыг өгөх эсвэл өөр функцийг ISNUMBER дотор оруулах боломжтой.

Хэрэв утга тоон бол функц ҮНЭНийг буцаана. . Бусад бүх зүйлийн хувьд (текстийн утга, алдаа, хоосон зай) ISNUMBER нь ХУДАЛ-г буцаана.

Жишээ нь, A2-аас A6 хүртэлх нүднүүдийн утгыг шалгаад эхний 3 утга нь тоонууд, сүүлийн хоёр нь тоо гэдгийг олж мэдэх болно. текст байна:

Excel дээрх ISNUMBER функцийн талаар таны мэдэх ёстой 2 зүйл

Энд анхаарах хэд хэдэн сонирхолтой зүйл байна:

• ДExcel-ийн дотоод дүрслэл, огноо ба цагийн нь тоон утгууд тул ISNUMBER томьёо нь ҮНЭНийг буцаана (дээрх дэлгэцийн агшинд B3 ба B4-ийг харна уу).
• Текст хэлбэрээр хадгалагдсан тоонуудыг ISNUMBER функц нь ХУДАЛ буцаана (энэ жишээг харна уу).

Excel ISNUMBER томьёоны жишээ

Доорх жишээнүүд нь цөөн хэдэн нийтлэг болон энгийн бус хэрэглээг харуулж байна. Excel-ийн ISNUMBER-н.

Утга нь тоо эсэхийг шалгаарай

Та ажлын хуудсандаа олон тооны утгууд байгаа бөгөөд аль нь тоо болохыг мэдэхийг хүсвэл ISNUMBER нь ашиглахад тохиромжтой функц юм. .

Энэ жишээнд эхний утга нь A2-д байгаа тул бид доорх томьёог ашиглан шалгаж, шаардлагатай бол олон нүд рүү чирнэ:

=ISNUMBER(A2)

Хэдийгээр бүх утгууд нь тоо шиг харагдаж байгаа ч ISNUMBER томьёо нь A4, A5 нүднүүдэд ХУДАЛ гэж буцсан тул эдгээр утгууд нь тоон мөр гэсэн үг гэдгийг анхаарна уу. , өөрөөр хэлбэл текст хэлбэрээр форматлагдсан тоонууд. Үүнд янз бүрийн шалтгаан байж болно, жишээлбэл, эхний тэг, апострофын өмнөх тэмдэг гэх мэт. Ямар ч шалтгаанаар Excel нь тоо гэх мэт утгыг хүлээн зөвшөөрдөггүй. Тиймээс хэрэв таны утгыг зөв тооцоолоогүй бол хамгийн түрүүнд Excel-ийн хувьд үнэхээр тоо мөн эсэхийг шалгаж, шаардлагатай бол текстийг тоо болгон хөрвүүлэх хэрэгтэй.

Excel ISNUMBER SEARCH томъёо

Тоонуудыг тодорхойлохоос гадна ExcelISNUMBER функц нь тухайн нүд нь агуулгын хэсэг болгон тодорхой текст агуулсан эсэхийг шалгах боломжтой. Үүний тулд ISNUMBER-г SEARCH функцтэй хамт ашиглана уу.

Ерөнхий хэлбэрт томъёо дараах байдлаар харагдана:

Энд дэд мөр нь таны олохыг хүсэж буй текст юм.

Жишээ нь, A3 дээрх мөр тодорхой өнгө агуулсан эсэхийг шалгая, улаан гэж хэлээрэй:

=ISNUMBER(SEARCH("red", A3))

Энэ томьёо нь нэг нүдэнд сайн ажилладаг. Гэхдээ бидний жишээ хүснэгт (доороос харна уу) гурван өөр өнгө агуулсан тул тус тусад нь томьёо бичих нь цаг хугацаа алдах болно. Үүний оронд бид сонирхсон өнгө (B2) агуулсан нүдийг заана.

=ISNUMBER(SEARCH(B$2, $A3))

Томьёог доош болон баруун тийш зөв хуулахын тулд дараах координатуудыг түгжихээ мартуузай. $ тэмдэг:

• дэд мөр лавлагаанд хуулсан томьёо 2-р эгнээний дэд мөрүүдийг сонгохын тулд мөрийг (B$2) түгж. багана тус бүрд тохируулахыг хүсэж байна, өөрөөр хэлбэл томьёог C3 руу хуулах үед дэд мөрийн лавлагаа C$2 болж өөрчлөгдөнө.
• эх нүд лавлагаанд баганыг түгжих ($A3) ) ингэснээр бүх томьёо А баганын утгуудыг шалгана.

Доорх дэлгэцийн агшинд үр дүнг харуулав:

ISNUMBER FIND - том жижиг жижиг жижиг томьёо

SEARCH функц нь цэг жижиг үсэг мэдрэгдэггүй тул дээрхТомьёо нь том, жижиг үсгийг ялгадаггүй. Хэрэв та жижиг жижиг томьёо хайж байгаа бол SEARCH биш харин FIND функцийг ашиглаарай. , томъёо нь дараах хэлбэртэй байна:

=ISNUMBER(FIND(B$2, $A3))

Энэ томьёо хэрхэн ажилладаг вэ

Томьёоны логик нь маш ойлгомжтой бөгөөд дагахад хялбар:

• SEARCH / FIND функц нь заасан нүдн дэх дэд мөрийг хайдаг. Хэрэв дэд мөр олдвол эхний тэмдэгтийн байрлалыг буцаана. Хэрэв дэд мөр олдохгүй бол функц нь #VALUE! алдаа.
• ISNUMBER функц нь үүнийг тэндээс авч, тоон байрлалыг боловсруулдаг. Тэгэхээр, хэрэв дэд мөр олдож, байрлалыг нь тоо болгон буцаавал ISNUMBER нь ҮНЭН гэсэн гаралт болно. Хэрэв дэд мөр олдоогүй бол #VALUE! алдаа гарвал ISNUMBER нь ХУДАЛ гарна.

IF ISNUMBER томьёо

Хэрэв та ҮНЭН эсвэл ХУДАЛ-аас өөр зүйлийг гаргах томьёог авахыг зорьсон бол ISNUMBER-г IF функцтэй хамт ашиглаарай.

Жишээ 1. Нүдэнд ямар текст агуулагдаж байна

Өмнөх жишээг цааш нь авч үзвэл, доорх хүснэгтэд үзүүлсэн шиг зүйл бүрийн өнгийг "x"-ээр тэмдэглэхийг хүсэж байна гэж бодъё.

Үүнийг хийхийн тулд ISNUMBER ХАЙЛТЫН томьёог IF команд руу оруулахад л хангалттай:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Хэрэв ISNUMBER нь ҮНЭН гэж буцвал IF функц нь "x" (эсвэл таны өгсөн бусад утгыг) гаргана. үнэн_хэрэв_үнэн аргумент). Хэрэв ISNUMBER нь ХУДАЛ гэж буцаавал IF функц нь хоосон мөр ("") гаргана.

Жишээ 2. Нүдний эхний тэмдэгт нь тоо эсвэл текст

Та үсэг, тоон мөрүүдийн жагсаалттай ажиллаж байгаа бөгөөд мөрийн эхний тэмдэгт нь тоо эсвэл үсэг мөн эсэхийг мэдэхийг хүсч байна гэж төсөөлөөд үз дээ.

Ийм томъёог бүтээхийн тулд танд 4 өөр функц хэрэгтэй болно:

• ЗҮҮН функц нь мөрийн эхнээс эхний тэмдэгтийг гаргаж авдаг, тухайлбал A2 нүдэнд:

  LEFT(A2, 1)

• ЗҮҮН функц нь Текст функцүүдийн ангилалд хамаарах тул түүний Үр дүн нь зөвхөн тоо агуулсан байсан ч үргэлж текстийн мөр байдаг. Тиймээс, задалсан тэмдэгтийг шалгахын өмнө бид үүнийг тоо болгон хувиргах хэрэгтэй. Үүний тулд VALUE функц эсвэл давхар нэгдмэл операторыг ашиглана уу:

  VALUE(LEFT(A2, 1)) эсвэл (--LEFT(A2, 1))

• ISNUMBER функц нь задалсан тэмдэгт тоон эсэхийг тодорхойлно:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• ISNUMBER үр дүнд (ҮНЭН эсвэл ХУДАЛ) үндэслэн IF функц нь "Тоо" эсвэл "Үсэг"-ийг буцаана.

Бид A2 дахь мөрийг шалгаж байна гэж үзвэл томьёо бүрэн хийгдэнэ. энэ хэлбэрийг авдаг:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

эсвэл

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER функц нь <12-д бас тохиромжтой>мөрөөс тоо гаргаж авах . Жишээ нь: Мөр дэх дурын байрлалаас дугаар авах.

Утга нь тоо биш эсэхийг шалгах

Хэдийгээр Microsoft Excel нь ISNONTEXT гэсэн тусгай функцтэй байдаг.Нүдний утга нь текст биш эсэхээс үл хамааран тоонуудын ижил төстэй функц байхгүй байна.

Хялбар шийдэл бол логик утгын эсрэг утгатай ISNUMBER-г NOT-той хослуулан ашиглах явдал юм. Өөрөөр хэлбэл, ISNUMBER нь ҮНЭНийг буцаавал БИШ, үүнийг ХУДАЛ болгож хувиргана.

Үүнийг хэрхэн ажиллаж байгааг харахын тулд дараах томъёоны үр дүнг ажиглана уу:

=NOT(ISNUMBER(A2))

Өөр нэг арга бол IF болон ISNUMBER функцийг хамтад нь ашиглах явдал юм:

=IF(ISNUMBER(A2), "", "Not number")

Хэрэв A2 нь тоон бол томъёо нь юу ч буцаадаггүй (хоосон мөр). Хэрэв A2 нь тоо биш бол томьёо нь үүнийг "Тоо биш" гэж урьдчилж бичнэ.

Хэрэв та тоонуудын тусламжтайгаар зарим тооцоолол хийхийг хүсвэл тэгшитгэл эсвэл өөр томъёог оруулна уу. томъёог үнэн_хэрэв_үнэн аргумент дахь хоосон мөрийн оронд оруулна. Жишээлбэл, доорх томьёо нь тоонуудыг 10-аар үржүүлж, тоон бус утгуудын хувьд "Тоо биш" гэсэн утгыг гаргана:

=IF(ISNUMBER(A2), A2*10, "Not number")

Мужид ямар нэгэн тоо байгаа эсэхийг шалгах

Хэрэв та бүх мужийг тоогоор шалгахыг хүсвэл ISNUMBER функцийг SUMPRODUCT-тай хослуулан дараах байдлаар ашиглаарай:

Жишээ нь, A2:A5 мужид ямар нэгэн тоон утга агуулагдаж байгаа эсэхийг мэдэхийн тулд томъёонууд дараах байдлаар явагдана:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Хэрэв та ҮНЭН ба ХУДАЛ-ын оронд "Тийм", "Үгүй" гэж гаргахыг хүсвэл IF мэдэгдлийг ашиглана уу.Дээрх томьёоны "боодол". Жишээ нь:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Энэ томъёо хэрхэн ажилладаг вэ

Томъёоны гол хэсэгт ISNUMBER функц нь нүд бүрийг үнэлдэг. заасан мужийг B2:B5 гэж хэлэх ба тоонуудын хувьд ҮНЭН, бусад зүйлд ХУДАЛ буцаана. Муж нь 4 нүдтэй тул массив нь 4 элементтэй байна:

{TRUE;FALSE;FALSE;FALSE}

Үржүүлэх үйлдэл эсвэл давхар нэгдэл (--) нь ҮНЭН ба ХУДАЛ-ыг 1 ба 0 болгон шахдаг:

{1;0;0;0}

SUMPRODUCT функц нь массивын элементүүдийг нэмдэг. Хэрэв үр дүн тэгээс их бол энэ нь мужид дор хаяж нэг тоо байна гэсэн үг юм. Тиймээс, та ">0"-г ашиглан ҮНЭН эсвэл ХУДАЛ гэсэн эцсийн үр дүнг гаргана.

Нөхцөлт форматаар ISNUMBER тодорхой текст агуулсан нүднүүдийг тодруулахын тулд

Хэрэв та нүдийг тодруулах гэж байгаа бол эсвэл тодорхой текст агуулсан мөрүүдийг бүхэлд нь ISNUMBER SEARCH (үсийн том жижиг жижиг) эсвэл ISNUMBER FIND (үсийн жижиг үсэг мэдрэгчтэй) томъёонд үндэслэн нөхцөлт форматлах дүрмийг үүсгэнэ үү.

Энэ жишээнд бид мөрүүдийг дараах байдлаар тодруулах болно. А баганын утга. Илүү нарийвчлалтайгаар бид "улаан" гэсэн үгийг агуулсан зүйлсийг тодруулах болно. Үүнд:

1. Бүх өгөгдлийн мөрүүдийг (энэ жишээнд A2:C6) эсвэл зөвхөн нүднүүдийг тодруулахыг хүссэн баганыг сонгоно уу.
2. Нүүр хуудас табын Загвар бүлгийн Шинэ дүрэм > Аль нүдийг форматлахыг томьёо ашиглана -г товшино уу.
3. Д Энэ томьёо үнэн бол утгыг форматлах талбарт доорх томьёог оруулна уу (баганын координат $ тэмдгээр түгжигдсэнийг анхаарна уу):

   =ISNUMBER(SEARCH("red", $A2))

4. Формат товчийг дарж хүссэн форматаа сонгоно уу.
5. ОК дээр хоёр удаа товшино уу.

Хэрэв танд Excel-ийн нөхцөлт форматын талаар бага туршлага байгаа бол дэлгэрэнгүй алхмуудыг олох боломжтой. Энэ гарын авлагын дэлгэцийн агшинтай: Томьёонд суурилсан нөхцөлт форматын дүрмийг хэрхэн үүсгэх талаар.

Үүний үр дүнд улаан өнгийн бүх зүйлийг тодруулсан болно:

Нөхцөлт форматын дүрмийн өнгийг "хатуу кодлох"-ын оронд та үүнийг урьдчилан тодорхойлсон нүдэнд бичиж, E2 гэж хэлээд томьёоныхоо тэр нүдийг лавлаж болно ($E$2 гэсэн үнэмлэхүй нүдний лавлагааг анхаарна уу). Нэмж хэлэхэд, та оролтын нүд хоосон биш эсэхийг шалгах хэрэгтэй:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Үүний үр дүнд та E2-д оруулсан оруулсан зүйлдээ тулгуурлан мөрүүдийг тодруулдаг илүү уян хатан дүрмийг авах болно:

Excel дээр ISNUMBER функцийг ингэж ашиглах юм. Уншиж байгаад баярлалаа, дараа долоо хоногт манай блог дээр уулзана гэж найдаж байна!

Татаж авах боломжтой

Excel ISNUMBER томъёоны жишээ