Ուսուցումը բացատրում է, թե ինչ է ISNUMBER Excel-ում և ներկայացնում է հիմնական և առաջադեմ օգտագործման օրինակներ:

ISNUMBER ֆունկցիայի հայեցակարգը Excel-ում շատ պարզ է. այն պարզապես ստուգում է, թե արդյոք տվյալ արժեքը թիվ է, թե ոչ: Այստեղ կարևոր կետն այն է, որ ֆունկցիայի գործնական կիրառումը շատ ավելին է, քան իր հիմնական հայեցակարգը, հատկապես, երբ զուգակցվում է այլ գործառույթների հետ ավելի մեծ բանաձևերում:

Excel ISNUMBER ֆունկցիան

Excel-ում ISNUMBER ֆունկցիան ստուգում է՝ արդյոք բջիջը պարունակում է թվային արժեք, թե ոչ: Այն պատկանում է IS գործառույթների խմբին:

Ֆունկցիան հասանելի է Excel-ի բոլոր տարբերակներում Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 և ավելի ցածր տարբերակների համար:

ISNUMBER շարահյուսությունը պահանջում է ընդամենը մեկ արգումենտ.

=ISNUMBER(value)

Որտեղ արժեքը այն արժեքն է, որը ցանկանում եք ստուգել: Սովորաբար այն ներկայացված է բջջային հղումով, բայց դուք կարող եք նաև իրական արժեք տրամադրել կամ ISNUMBER-ի ներսում տեղադրել մեկ այլ ֆունկցիա՝ արդյունքը ստուգելու համար:

Եթե արժեքը թվային է, ֆունկցիան վերադարձնում է TRUE: . Մնացած ամեն ինչի համար (տեքստային արժեքներ, սխալներ, դատարկ նյութեր) ISNUMBER-ը վերադարձնում է FALSE:

Որպես օրինակ, եկեք փորձարկենք արժեքները A2-ից A6 բջիջներում և պարզենք, որ առաջին 3 արժեքները թվեր են, իսկ վերջին երկուսը: տեքստ են.

2 բան, որ դուք պետք է իմանաք Excel-ում ISNUMBER ֆունկցիայի մասին

Այստեղ պետք է նշել մի քանի հետաքրքիր կետ.

• ՄեջExcel-ի ներքին ներկայացումը, ամսաթվերը և ժամանակները թվային արժեքներ են, ուստի ISNUMBER բանաձևը դրանց համար վերադարձնում է TRUE (տես B3 և B4 վերևի սքրինշոթում):
• թվեր, որոնք պահվում են որպես տեքստ, ISNUMBER ֆունկցիան վերադարձնում է FALSE (տես այս օրինակը):

Excel ISNUMBER բանաձևի օրինակներ

Ստորև բերված օրինակները ցույց են տալիս մի քանի ընդհանուր և մի քանի ոչ աննշան կիրառումներ ISNUMBER-ից Excel-ում:

Ստուգեք, արդյոք արժեքը համար է

Երբ ձեր աշխատաթերթում ունեք մի շարք արժեքներ և ցանկանում եք իմանալ, թե որոնք են թվերը, ISNUMBER-ը ճիշտ գործառույթն է, որը պետք է օգտագործել: .

Այս օրինակում առաջին արժեքը A2-ում է, ուստի մենք օգտագործում ենք ստորև բերված բանաձևը՝ այն ստուգելու համար, այնուհետև քաշում ենք բանաձևը այնքան բջիջ, որքան անհրաժեշտ է.

=ISNUMBER(A2)

Խնդրում ենք ուշադրություն դարձնել, որ թեև բոլոր արժեքները թվերի տեսք ունեն, ISNUMBER բանաձևը վերադարձրել է FALSE A4 և A5 բջիջների համար, ինչը նշանակում է, որ այդ արժեքները թվային տողեր են , այսինքն՝ տեքստային ձևաչափված թվեր։ Դրա համար կարող են լինել տարբեր պատճառներ, օրինակ՝ առաջատար զրոներ, նախորդող ապաստրոֆ և այլն: Ինչ էլ որ լինի պատճառը, Excel-ը չի ճանաչում այդպիսի արժեքները որպես թվեր: Այսպիսով, եթե ձեր արժեքները ճիշտ չեն հաշվարկվում, առաջին բանը, որ դուք պետք է ստուգեք, այն է, թե արդյոք դրանք իսկապես թվեր են Excel-ի առումով, և անհրաժեշտության դեպքում տեքստը վերածեք թվի:

Excel ISNUMBER SEARCH բանաձև

Բացի թվերի նույնականացումից, Excel-ըISNUMBER ֆունկցիան կարող է նաև ստուգել, ​​թե արդյոք բջիջը պարունակում է որոշակի տեքստ որպես բովանդակության մաս: Դրա համար օգտագործեք ISNUMBER SEARCH ֆունկցիայի հետ միասին:

Ընդհանուր ձևով բանաձևն ունի հետևյալ տեսքը.

Որտեղ ենթատողը այն տեքստն է, որը ցանկանում եք գտնել:

Որպես օրինակ, եկեք ստուգենք, արդյոք A3-ի տողը որոշակի գույն է պարունակում, ասենք կարմիր.

=ISNUMBER(SEARCH("red", A3))

Այս բանաձևը լավ է աշխատում մեկ բջիջի համար: Բայց քանի որ մեր ընտրանքային աղյուսակը (տես ստորև) պարունակում է երեք տարբեր գույներ, յուրաքանչյուրի համար առանձին բանաձև գրելը ժամանակի կորուստ կլինի: Փոխարենը, մենք կանդրադառնանք հետաքրքրության գույնը պարունակող բջիջին (B2):

=ISNUMBER(SEARCH(B$2, $A3))

Որպեսզի բանաձևը ճիշտ պատճենի ներքև և աջ, համոզվեք, որ կողպեք հետևյալ կոորդինատները $ նշանը.

• ենթատողի հղումում կողպեք տողը (B$2), որպեսզի պատճենված բանաձևերը միշտ ընտրեն 2-րդ շարքի ենթատողերը: Սյունակի հղումը հարաբերական է, քանի որ մենք ուզում եմ, որ այն հարմարվի յուրաքանչյուր սյունակի համար, այսինքն, երբ բանաձևը պատճենվում է C3-ին, ենթալարի հղումը կփոխվի C$2-ի:
• աղբյուրի բջիջի հղումում կողպեք սյունակը ($A3): ) այնպես, որ բոլոր բանաձևերը ստուգեն A սյունակի արժեքները:

Սքրինշոթը ստորև ցույց է տալիս արդյունքը.

ISNUMBER FIND - մեծատառերի զգայուն բանաձև

Քանի որ SEARCH ֆունկցիան գործունեության զգայուն չէ , վերը նշվածըբանաձևը չի տարբերում մեծատառ և փոքրատառ նիշերը: Եթե ​​փնտրում եք մեծատառերի զգայուն բանաձև, օգտագործեք FIND ֆունկցիան, այլ ոչ թե SEARCH:

Մեր նմուշային տվյալների հավաքածուի համար , բանաձևը կունենա հետևյալ ձևը.

=ISNUMBER(FIND(B$2, $A3))

Ինչպես է աշխատում այս բանաձևը

Բանաձևի տրամաբանությունը բավականին ակնհայտ է և հեշտ է հետևել.

• SEARCH / FIND ֆունկցիան փնտրում է ենթատողը նշված բջիջում: Եթե ​​ենթատողը գտնվի, առաջին նիշի դիրքը վերադարձվում է: Եթե ​​ենթատողը չի գտնվել, ֆունկցիան արտադրում է #VALUE! սխալ:
• ISNUMBER ֆունկցիան այն վերցնում է այնտեղից և մշակում թվային դիրքերը: Այսպիսով, եթե ենթատողը գտնվի և նրա դիրքը վերադարձվի որպես թիվ, ISNUMBER-ը դուրս է բերում TRUE: Եթե ​​ենթատողը չի գտնվել և #VALUE! սխալ է տեղի ունենում, ISNUMBER-ը ցույց է տալիս FALSE:

IF ISNUMBER բանաձև

Եթե ցանկանում եք ստանալ բանաձև, որը դուրս է բերում այլ բան, քան TRUE կամ FALSE, օգտագործեք ISNUMBER-ը IF ֆունկցիայի հետ միասին:

Օրինակ 1. Բջիջը պարունակում է որ տեքստը

Վերցնելով նախորդ օրինակը, ենթադրենք, որ ցանկանում եք նշել յուրաքանչյուր տարրի գույնը «x»-ով, ինչպես ցույց է տրված ստորև աղյուսակում:

Դա անելու համար պարզապես փաթեթավորեք ISNUMBER SEARCH բանաձևը IF հայտարարության մեջ.

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Եթե ISNUMBER-ը վերադարձնում է TRUE, IF ֆունկցիան դուրս է բերում «x» (կամ ցանկացած այլ արժեք, որը դուք տրամադրում եք): the value_if_true փաստարկ): Եթե ​​ISNUMBER-ը վերադարձնում է FALSE, IF ֆունկցիան թողարկում է դատարկ տող (""):

Օրինակ 2. Բջջի առաջին նիշը համարն է կամ տեքստը

Պատկերացրեք, որ դուք աշխատում եք այբբենական թվային տողերի ցուցակի հետ և ցանկանում եք իմանալ, թե տողի առաջին նիշը թիվ է, թե տառ:

Նման բանաձև ստեղծելու համար մեզ անհրաժեշտ են 4 տարբեր գործառույթներ.

• LEFT ֆունկցիան հանում է առաջին նիշը տողի սկզբից, ասենք A2 բջիջում.

  LEFT(A2, 1)

• Քանի որ LEFT-ը պատկանում է Տեքստային ֆունկցիաների կատեգորիային, դրա արդյունքը միշտ տեքստային տող է, նույնիսկ եթե այն պարունակում է միայն թվեր: Հետեւաբար, մինչ արդյունահանված նիշը ստուգելը, մենք պետք է փորձենք այն վերածել թվի։ Դրա համար օգտագործեք կամ VALUE ֆունկցիան կամ կրկնակի միանվագ օպերատորը՝

  VALUE(LEFT(A2, 1)) կամ (--LEFT(A2, 1))

• ISNUMBER ֆունկցիան որոշում է՝ արդյունահանված նիշը թվային է, թե ոչ՝

  ISNUMBER(VALUE(LEFT(A2, 1)))

  <14:>
• Հիմք ընդունելով ISNUMBER արդյունքը (TRUE կամ FALSE), IF ֆունկցիան համապատասխանաբար վերադարձնում է «Թիվ» կամ «Տառ»: ստանում է այս ձևը.

  =IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

  կամ

  =IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

  

  ISNUMBER ֆունկցիան նույնպես հարմար է <12-ի համար>համարների հանում տողից: Ահա մի օրինակ․ Ստացեք համարը տողի ցանկացած դիրքից։

  Ստուգեք՝ արդյոք արժեքը թիվ չէ

  Չնայած Microsoft Excel-ն ունի հատուկ ֆունկցիա՝ ISNONTEXT, որոշելու համար։անկախ նրանից, թե բջիջի արժեքը տեքստ չէ, թվերի անալոգային ֆունկցիան բացակայում է:

  Հեշտ լուծում է ISNUMBER-ի օգտագործումը NOT-ի հետ համատեղ, որը վերադարձնում է տրամաբանական արժեքի հակառակը: Այլ կերպ ասած, երբ ISNUMBER-ը վերադարձնում է TRUE, NOT-ը այն փոխակերպում է FALSE-ի, և հակառակը:

  Այն գործողության մեջ տեսնելու համար խնդրում ենք հետևել հետևյալ բանաձևի արդյունքներին.

  =NOT(ISNUMBER(A2))

  

  Մեկ այլ մոտեցում է IF և ISNUMBER ֆունկցիաները միասին օգտագործելը.

  =IF(ISNUMBER(A2), "", "Not number")

  Եթե A2-ը թվային է, բանաձևը ոչինչ չի վերադարձնում (դատարկ լար): Եթե ​​A2-ը թվային չէ, ապա բանաձևը նախապես ասում է. «Ոչ թիվ»:

  

  Եթե ցանկանում եք կատարել որոշ հաշվարկներ թվերով, ապա դրեք հավասարում կամ այլ հավասարում: բանաձեւը value_if_true արգումենտում դատարկ տողի փոխարեն: Օրինակ, ստորև բերված բանաձևը թվերը կբազմապատկի 10-ով և ոչ թվային արժեքների համար կբերի «Ոչ թիվ».

  =IF(ISNUMBER(A2), A2*10, "Not number")

  Ստուգեք, արդյոք տիրույթը պարունակում է որևէ թիվ

  In Իրավիճակը, երբ ցանկանում եք ստուգել ամբողջ տիրույթը թվերի համար, օգտագործեք ISNUMBER ֆունկցիան SUMPRODUCT-ի հետ հետևյալ կերպ.

  SUMPRODUCT(--ISNUMBER( միջակայք ))>0 SUMPRODUCT(ISNUMBER( միջակայք )*1)>0

  Օրինակ, պարզելու համար, թե արդյոք A2:A5 միջակայքը պարունակում է որևէ թվային արժեք, բանաձևերը կգործեն հետևյալ կերպ.

  =SUMPRODUCT(--ISNUMBER(A2:A5))>0

  =SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

  

  Եթե ցանկանում եք արտաբերել «Այո» և «Ոչ»՝ TRUE-ի և FALSE-ի փոխարեն, օգտագործեք IF հայտարարությունը որպես«փաթաթան» վերը նշված բանաձեւերի համար: Օրինակ՝

  =IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

  

  Ինչպես է աշխատում այս բանաձևը

  Բանաձևի հիմքում ISNUMBER ֆունկցիան գնահատում է յուրաքանչյուր բջիջ նշված միջակայքը, ասենք B2:B5, և թվերի համար վերադարձնում է TRUE, ցանկացած այլ բանի համար FALSE: Քանի որ միջակայքը պարունակում է 4 բջիջ, զանգվածն ունի 4 տարր.

  {TRUE;FALSE;FALSE;FALSE}

  Բազմապատկման գործողությունը կամ կրկնակի միանվագը (--) ստիպում է TRUE-ին և FALSE-ին համապատասխանաբար 1-ի և 0-ի մեջ դնել՝<3:>

  {1;0;0;0}

  SUMPRODUCT ֆունկցիան գումարում է զանգվածի տարրերը: Եթե ​​արդյունքը զրոյից մեծ է, դա նշանակում է, որ միջակայքում կա առնվազն մեկ թիվ: Այսպիսով, դուք օգտագործում եք «>0»՝ TRUE-ի կամ FALSE-ի վերջնական արդյունքը ստանալու համար:

  ISNUMBER-ը պայմանական ձևաչափով՝ ընդգծելու որոշակի տեքստ պարունակող բջիջները

  Եթե ցանկանում եք ընդգծել բջիջները կամ ամբողջ տողերը, որոնք պարունակում են հատուկ տեքստ, ստեղծեք պայմանական ձևաչափման կանոն՝ հիմնված ISNUMBER SEARCH (մեծատառերի նկատմամբ զգայուն) կամ ISNUMBER FIND (տառերի նկատմամբ զգայուն) բանաձևի վրա:

  Այս օրինակի համար մենք պատրաստվում ենք ընդգծել տողերը՝ հիմնված արժեքը A սյունակում: Ավելի ճիշտ, մենք կնշենք «կարմիր» բառը պարունակող տարրերը: Ահա թե ինչպես.

  1. Ընտրեք տվյալների բոլոր տողերը (այս օրինակում A2:C6) կամ միայն այն սյունակը, որում ցանկանում եք ընդգծել բջիջները:
  2. Տան վրա ներդիրում, Ոճեր խմբում սեղմեք Նոր կանոն > Օգտագործեք բանաձև՝ որոշելու համար, թե որ բջիջները պետք է ֆորմատավորել :
  3. Մտքում Ձևաչափեք արժեքները, որտեղ այս բանաձևը ճշմարիտ է վանդակում, մուտքագրեք ստորև բերված բանաձևը (նկատեք, որ սյունակի կոորդինատը կողպված է $ նշանով).

     =ISNUMBER(SEARCH("red", $A2))

  4. Սեղմեք Ձևաչափել կոճակը և ընտրեք ձեր ուզած ձևաչափը:
  5. Կտտացրեք OK երկու անգամ:

  Եթե դուք քիչ փորձ ունեք Excel-ի պայմանական ձևաչափման հետ, կարող եք գտնել մանրամասն քայլերը: Այս ձեռնարկի սքրինշոթներով. Ինչպես ստեղծել բանաձևի վրա հիմնված պայմանական ձևաչափման կանոն:

  Արդյունքում կարմիր գույնի բոլոր տարրերը ընդգծված են.

  

  Գույնը պայմանական ձևաչափման կանոնում «կոշտ կոդավորելու» փոխարեն կարող եք մուտքագրել այն նախապես սահմանված բջիջում, ասենք E2, և հղում կատարել ձեր բանաձևի այդ բջիջին (խնդրում ենք հաշվի առնել $E$2 բջիջի բացարձակ հղումը): Բացի այդ, դուք պետք է ստուգեք, թե արդյոք մուտքային բջիջը դատարկ չէ․>

  

  Այսպես կարելի է օգտագործել ISNUMBER ֆունկցիան Excel-ում: Շնորհակալ եմ կարդալու համար և հուսով եմ, որ հաջորդ շաբաթ կտեսնենք ձեզ մեր բլոգում:

  Հասանելի ներբեռնումներ

  Excel ISNUMBER բանաձևի օրինակներ