Падручнік тлумачыць, што такое ISNUMBER у Excel, і дае прыклады базавага і пашыранага выкарыстання.

Канцэпцыя функцыі ISNUMBER у Excel вельмі простая - яна проста правярае, ці зададзены значэнне з'яўляецца лікам ці не. Важным момантам з'яўляецца тое, што практычнае прымяненне функцыі выходзіць далёка за межы яе асноўнай канцэпцыі, асабліва ў спалучэнні з іншымі функцыямі ў вялікіх формулах.

Функцыя Excel ISNUMBER

Функцыя ISNUMBER у Excel правярае, змяшчае ячэйка лікавае значэнне ці не. Яна належыць да групы функцый IS.

Функцыя даступная ва ўсіх версіях Excel для Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 і ніжэй.

Сінтаксіс ISNUMBER патрабуе толькі аднаго аргумента:

=ISNUMBER(value)

Дзе значэнне гэта значэнне, якое вы хочаце праверыць. Звычайна ён прадстаўлены спасылкай на ячэйку, але вы таксама можаце падаць рэальнае значэнне або ўкласці іншую функцыю ў ISNUMBER, каб праверыць вынік.

Калі значэнне з'яўляецца лікавым, функцыя вяртае TRUE . Для ўсяго іншага (тэкставыя значэнні, памылкі, прабелы) ISNUMBER вяртае ХЛУСНІ.

У якасці прыкладу, давайце праверым значэнні ў ячэйках ад A2 да A6, і мы даведаемся, што першыя 3 значэнні з'яўляюцца лічбамі, а апошнія два гэта тэкст:

2 рэчы, якія вы павінны ведаць пра функцыю ISNUMBER у Excel

Тут ёсць некалькі цікавых момантаў, якія варта адзначыць:

• Уунутранае прадстаўленне Excel, даты і час з'яўляюцца лікавымі значэннямі, таму формула ISNUMBER вяртае TRUE для іх (калі ласка, глядзіце B3 і B4 на скрыншоце вышэй).
• Для лікаў, якія захоўваюцца ў выглядзе тэксту, функцыя ISNUMBER вяртае FALSE (гл. гэты прыклад).

Прыклады формул Excel ISNUMBER

У прыведзеных ніжэй прыкладах дэманструецца некалькі распаўсюджаных і некалькі нетрывіяльных ужыванняў ISNUMBER у Excel.

Праверце, ці з'яўляецца значэнне лікам

Калі ў вашым аркушы ёсць куча значэнняў і вы хочаце ведаць, якія з іх з'яўляюцца лічбамі, ISNUMBER - гэта правільная функцыя для выкарыстання .

У гэтым прыкладзе першае значэнне знаходзіцца ў A2, таму мы выкарыстоўваем прыведзеную ніжэй формулу, каб праверыць яго, а потым перацягваем формулу ўніз у столькі ячэек, колькі неабходна:

=ISNUMBER(A2)

Калі ласка, звярніце ўвагу, што, хоць усе значэнні выглядаюць як лічбы, формула ISNUMBER вярнула ХЛУСНІ для ячэек A4 і A5, што азначае, што гэтыя значэнні з'яўляюцца лікавымі радкамі , гэта значыць лікі, адфарматаваныя ў тэкст. Гэтаму могуць быць розныя прычыны, напрыклад, нулі ў пачатку, апостраф перад ім і г. д. Незалежна ад прычыны, Excel не распазнае такія значэнні як лічбы. Такім чынам, калі вашы значэнні не разлічваюцца правільна, першае, што вам трэба праверыць, ці сапраўды яны з'яўляюцца лічбамі з пункту гледжання Excel, а затым пераўтварыць тэкст у лік, калі гэта неабходна.

Формула ПОШУКУ ISНУМРА ў Excel

Акрамя ідэнтыфікацыі лічбаў, ExcelФункцыя ISNUMBER таксама можа праверыць, ці змяшчае ячэйка пэўны тэкст як частку змесціва. Для гэтага выкарыстоўвайце ISNUMBER разам з функцыяй ПОШУК.

У агульным выглядзе формула выглядае наступным чынам:

Дзе падрадок - гэта тэкст, які вы хочаце знайсці.

У якасці прыкладу давайце праверым, ці змяшчае радок у A3 пэўны колер, скажам, чырвоны:

=ISNUMBER(SEARCH("red", A3))

Гэта формула добра працуе для адной ячэйкі. Але паколькі наша ўзорная табліца (гл. ніжэй) змяшчае тры розныя колеры, напісанне асобнай формулы для кожнага з іх было б марнаваннем часу. Замест гэтага мы будзем спасылацца на ячэйку, якая змяшчае цікавы колер (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Каб формула правільна скапіявалася ўніз і направа, не забудзьцеся зафіксаваць наступныя каардынаты з дапамогай знак $:

• У спасылцы на падрадок заблакіруйце радок (B$2), каб скапіраваныя формулы заўсёды выбіралі падрадкі ў радку 2. Спасылка на слупок адносная, бо мы хочаце, каб ён наладжваўся для кожнага слупка, г. зн., калі формула капіюецца ў C3, спасылка на падрадок зменіцца на C$2.
• У спасылцы на крынічную ячэйку заблакіруйце слупок ($A3 ), каб усе формулы правяралі значэнні ў слупку A.

На скрыншоце ніжэй паказаны вынік:

ISNUMBER FIND - з улікам рэгістра формула

Паколькі функцыя ПОШУК неадчувальная да рэгістра , вышэйформула не адрознівае вялікія і малыя літары. Калі вы шукаеце формулу з улікам рэгістра, выкарыстоўвайце функцыю FIND, а не SEARCH.

Для нашага ўзору набору даных , формула прыме наступны выгляд:

=ISNUMBER(FIND(B$2, $A3))

Як працуе гэтая формула

Логіка формулы цалкам відавочная і лёгка прытрымлівацца:

• Функцыя SEARCH / FIND шукае падрадок у вызначанай ячэйцы. Калі падрадок знойдзены, вяртаецца пазіцыя першага сімвала. Калі падрадок не знойдзены, функцыя выдае #VALUE! памылка.
• Функцыя ISNUMBER бярэ яго адтуль і апрацоўвае лікавыя пазіцыі. Такім чынам, калі падрадок знойдзены і яго пазіцыя вяртаецца як лік, ISNUMBER выводзіць TRUE. Калі падрадок не знойдзены і #VALUE! адбываецца памылка, ISNUMBER выводзіць ХЛУСНІ.

КАЛІ формула ISNUMBER

Калі вы хочаце атрымаць формулу, якая выводзіць нешта іншае, чым TRUE або FALSE, выкарыстоўвайце ISNUMBER разам з функцыяй IF.

Прыклад 1. Ячэйка змяшчае тэкст

Працягваючы папярэдні прыклад, выкажам здагадку, што вы хочаце пазначыць колер кожнага элемента знакам "x", як паказана ў табліцы ніжэй.

Каб зрабіць гэта, проста абгарніце формулу ISNUMBER SEARCH у аператар IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Калі ISNUMBER вяртае TRUE, функцыя IF выводзіць "x" (ці любое іншае значэнне, якое вы падаеце ў значэнне_калі_праўда аргумент). Калі ISNUMBER вяртае ХЛУСНІ, функцыя КАЛІ выводзіць пусты радок ("").

Прыклад 2. Першы сімвал у ячэйцы - гэта лік або тэкст

Уявіце, што вы працуеце са спісам літарна-лічбавых радкоў і хочаце ведаць, ці з'яўляецца першы сімвал радка лічбай ці літарай.

Каб пабудаваць такую ​​формулу, вам спатрэбяцца 4 розныя функцыі:

• Функцыя LEFT здабывае першы сімвал з пачатку радка, скажам, у ячэйцы A2:

  LEFT(A2, 1)

• Паколькі LEFT належыць да катэгорыі тэкставых функцый, яе вынік заўсёды з'яўляецца тэкставым радком, нават калі ён змяшчае толькі лічбы. Такім чынам, перш чым правяраць выняты сімвал, нам трэба паспрабаваць пераўтварыць яго ў лік. Для гэтага выкарыстоўвайце функцыю VALUE або двайны ўнарны аператар:

  VALUE(LEFT(A2, 1)) або (--LEFT(A2, 1))

• Функцыя ISNUMBER вызначае, ці з'яўляецца выняты сімвал лічбавым:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Зыходзячы з выніку ISNUMBER (TRUE або FALSE), функцыя КАЛІ вяртае «лічбу» або «літару» адпаведна.

Пры ўмове, што мы тэстуем радок у A2, поўная формула прымае такую ​​форму:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ці

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Функцыя ISNUMBER таксама карысная для выманне лікаў з радка. Вось прыклад: атрымаць лік з любой пазіцыі ў радку.

Праверце, ці не з'яўляецца значэнне лікам

Хоць Microsoft Excel мае спецыяльную функцыю ISNONTEXT для вызначэннякалі значэнне ячэйкі не з'яўляецца тэкстам, аналагічная функцыя для лікаў адсутнічае.

Лёгкім рашэннем з'яўляецца выкарыстанне ISNUMBER у спалучэнні з NOT, якое вяртае супрацьлеглае лагічнае значэнне. Іншымі словамі, калі ISNUMBER вяртае TRUE, НЕ пераўтварае яго ў FALSE, і наадварот.

Каб убачыць гэта ў дзеянні, паглядзіце вынікі наступнай формулы:

=NOT(ISNUMBER(A2))

Іншы падыход заключаецца ў выкарыстанні функцый IF і ISNUMBER разам:

=IF(ISNUMBER(A2), "", "Not number")

Калі A2 з'яўляецца лікам, формула нічога не вяртае (пусты радок). Калі A2 не з'яўляецца лікам, у формуле гэта сказана загадзя: "Не лік".

Калі вы жадаеце выканаць некаторыя вылічэнні з лікамі, пастаўце ўраўненне ці інш. формулу ў аргуменце value_if_true замест пустога радка. Напрыклад, прыведзеная ніжэй формула будзе памнажаць лікі на 10 і дасць "Не лік" для нелікавых значэнняў:

=IF(ISNUMBER(A2), A2*10, "Not number")

Праверце, ці змяшчае дыяпазон якое-небудзь лік

In сітуацыя, калі вы хочаце праверыць увесь дыяпазон лікаў, выкарыстоўвайце функцыю ISNUMBER у спалучэнні з SUMPRODUCT, як гэта:

Напрыклад, каб даведацца, ці змяшчае дыяпазон A2:A5 якое-небудзь лікавае значэнне, формулы будуць выглядаць наступным чынам:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Калі вы хочаце вывесці "Так" і "Не" замест TRUE і FALSE, выкарыстоўвайце аператар IF як"абгортка" для прыведзеных вышэй формул. Напрыклад:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Як працуе гэтая формула

У аснове формулы функцыя ISNUMBER ацэньвае кожную ячэйку вызначаны дыяпазон, скажам, B2:B5, і вяртае TRUE для лікаў, FALSE для ўсяго астатняга. Паколькі дыяпазон змяшчае 4 ячэйкі, масіў мае 4 элементы:

{TRUE;FALSE;FALSE;FALSE}

Аперацыя множання або двайны унарны (--) ператварае TRUE і FALSE у 1 і 0 адпаведна:

{1;0;0;0}

Функцыя SUMPRODUCT складае элементы масіва. Калі вынік большы за нуль, гэта азначае, што ёсць хаця б адзін лік у дыяпазоне. Такім чынам, вы выкарыстоўваеце ">0", каб атрымаць канчатковы вынік TRUE або FALSE.

ISNUMBER ва ўмоўным фарматаванні, каб вылучыць вочкі, якія змяшчаюць пэўны тэкст

Калі вы хочаце вылучыць вочкі або цэлыя радкі, якія змяшчаюць пэўны тэкст, стварыце правіла ўмоўнага фарматавання на аснове формулы ISNUMBER SEARCH (без уліку рэгістра) або ISNUMBER FIND (з улікам рэгістра).

У гэтым прыкладзе мы збіраемся вылучыць радкі на аснове значэнне ў слупку А. Дакладней, вылучым пункты, у якіх ёсць слова «чырвоны». Вось як:

1. Выберыце ўсе радкі даных (A2:C6 у гэтым прыкладзе) або толькі слупок, у якім вы хочаце вылучыць ячэйкі.
2. На Home на ўкладцы Стылі пстрыкніце Новае правіла > Выкарыстоўвайце формулу, каб вызначыць, якія ячэйкі трэба адфарматаваць .
3. Уу поле Фарматаваць значэнні, дзе гэтая формула праўдзівая , увядзіце наступную формулу (звярніце ўвагу, што каардынаты слупка зафіксаваны знакам $):

   =ISNUMBER(SEARCH("red", $A2))

4. Націсніце Кнопка Фарматаваць і абярыце патрэбны вам фармат.
5. Націсніце ОК двойчы.

Калі ў вас мала вопыту працы з умоўным фарматаваннем Excel, вы можаце знайсці падрабязныя крокі са здымкамі экрана ў гэтым падручніку: Як стварыць правіла ўмоўнага фарматавання на аснове формулы.

У выніку ўсе элементы чырвонага колеру вылучаюцца:

Замест "цвёрдага кадзіравання" колеру ў правіле ўмоўнага фарматавання, вы можаце ўвесці яго ў прадвызначаную ячэйку, скажам, E2, і спасылацца на гэтую ячэйку ў вашай формуле (звярніце ўвагу на абсалютную спасылку на ячэйку $E$2). Акрамя таго, вам трэба праверыць, ці не пустая ячэйка ўводу:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

У выніку вы атрымаеце больш гнуткае правіла, якое вылучае радкі на аснове вашага ўводу ў E2:

Вось як выкарыстоўваць функцыю ISNUMBER у Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Даступныя загрузкі

Прыклады формул Excel ISNUMBER