Kennslan útskýrir hvað ISNUMBER í Excel er og gefur dæmi um grunn- og háþróaða notkun.

Hugmyndin um ISNUMBER fallið í Excel er mjög einföld - það athugar bara hvort tiltekið gildi er tala eða ekki. Mikilvægur punktur hér er að hagnýt notkun fallsins er langt út fyrir grunnhugmynd þess, sérstaklega þegar hún er sameinuð öðrum föllum innan stærri formúla.

Excel ISNUMBER fall

ISNUMBER aðgerðin í Excel athugar hvort reit inniheldur tölugildi eða ekki. Það tilheyrir hópi IS-aðgerða.

Hugsunin er fáanleg í öllum útgáfum af Excel fyrir Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 og lægri.

ISNUMBER setningafræðin krefst aðeins einnar röksemdar:

=ISNUMBER(value)

Þar sem gildi er gildið sem þú vilt prófa. Venjulega er það táknað með frumutilvísun, en þú getur líka gefið upp raunverulegt gildi eða hreiður annað fall inni í ISNUMBER til að athuga niðurstöðuna.

Ef gildi er tölulegt, skilar fallið TRUE . Fyrir allt annað (textagildi, villur, eyður) skilar ISNUMBER FALSE.

Sem dæmi skulum við prófa gildi í hólfum A2 til A6 og við munum komast að því að fyrstu 3 gildin eru tölur og síðustu tvö eru texti:

2 hlutir sem þú ættir að vita um ISNUMBER aðgerðina í Excel

Það eru nokkrir áhugaverðir punktar sem þarf að hafa í huga hér:

• Íinnri Excel framsetning, dagsetningar og tímar eru tölugildi, þannig að ISNUMBER formúlan skilar TRUE fyrir þau (vinsamlegast sjá B3 og B4 á skjámyndinni hér að ofan).
• Fyrir því tölur sem eru geymdar sem texti, ISNUMBER fallið skilar FALSE (sjá þetta dæmi).

Excel ISNUMBER formúludæmi

Dæmin hér að neðan sýna nokkrar algengar og nokkrar óléttar notkunaraðferðir af ISNUMBER í Excel.

Athugaðu hvort gildi sé tala

Þegar þú ert með fullt af gildum í vinnublaðinu þínu og vilt vita hverjir eru tölur, þá er ISNUMBER rétta aðgerðin til að nota .

Í þessu dæmi er fyrsta gildið í A2, þannig að við notum formúluna hér að neðan til að athuga það og drögum svo formúluna niður í eins marga reiti og þarf:

=ISNUMBER(A2)

Vinsamlegast athugaðu að þó öll gildin líti út eins og tölur hefur ISNUMBER formúlan skilað FALSE fyrir reiti A4 og A5, sem þýðir að þessi gildi eru tölustrengir , þ.e. tölur sem eru sniðnar sem texti. Það geta verið mismunandi ástæður fyrir þessu, td núll í fremstu röð, undanfarandi fráfall osfrv. Hver sem ástæðan er, þá þekkir Excel ekki gildi eins og tölur. Þannig að ef gildin þín reiknast ekki rétt, þá er það fyrsta sem þú þarft að athuga hvort þau séu raunverulega tölur miðað við Excel og umbreyta síðan texta í tölu ef þörf krefur.

Excel ISNUMBER LEIT formúla

Fyrir utan að auðkenna tölur, ExcelISNUMBER aðgerðin getur einnig athugað hvort hólf inniheldur ákveðinn texta sem hluta af innihaldinu. Til þess skaltu nota ISNUMBER ásamt SEARCH fallinu.

Í almennu formi lítur formúlan svona út:

Þar sem undirstrengur er textinn sem þú vilt finna.

Sem dæmi skulum við athuga hvort strengurinn í A3 inniheldur ákveðinn lit, segjum rauðan:

=ISNUMBER(SEARCH("red", A3))

Þessi formúla virkar vel fyrir eina frumu. En vegna þess að sýnistafla okkar (vinsamlegast sjáðu hér að neðan) inniheldur þrjá mismunandi liti, þá væri tímasóun að skrifa sérstaka formúlu fyrir hvern og einn. Þess í stað munum við vísa til reitsins sem inniheldur litinn sem vekur áhuga (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Til að formúlan afriti rétt niður og til hægri, vertu viss um að læsa eftirfarandi hnit með $ táknið:

• Í undirstreng tilvísun, læstu röðinni (B$2) þannig að afrituðu formúlurnar velji alltaf undirstrengina í línu 2. Dálktilvísunin er afstæð vegna þess að við viltu að það sé stillt fyrir hvern dálk, þ.e. þegar formúlan er afrituð yfir í C3, breytist undirstrengstilvísunin í C$2.
• Í upprunahólfinu tilvísun, læstu dálknum ($A3) ) þannig að allar formúlurnar athuga gildin í dálki A.

Skjámyndin hér að neðan sýnir niðurstöðuna:

ISNUMBER FIND - hástafaviðkvæmur formúla

Þar sem SEARCH fallið er óháð hástöfum er ofangreintformúla gerir ekki greinarmun á hástöfum og lágstöfum. Ef þú ert að leita að stafrænni formúlu, notaðu FIND aðgerðina frekar en SEARCH.

Fyrir sýnishorn gagnasafns okkar , formúlan myndi hafa þessa mynd:

=ISNUMBER(FIND(B$2, $A3))

Hvernig þessi formúla virkar

Rökfræði formúlunnar er nokkuð augljós og auðvelt að fylgja eftir:

• SEARCH / FIND aðgerðin leitar að undirstrengnum í tilgreindum reit. Ef undirstrengurinn finnst er staðsetning fyrsta stafsins skilað. Ef undirstrengurinn finnst ekki framleiðir aðgerðin #VALUE! villa.
• ISNUMBER fallið tekur það þaðan og vinnur tölulegar stöður. Þannig að ef undirstrengurinn finnst og staðsetning hans er skilað sem tala, gefur ISNUMBER út TRUE. Ef undirstrengurinn finnst ekki og #VALUE! villa kemur upp, ISNUMBER gefur út FALSE.

IF ISNUMBER formúla

Ef þú stefnir að því að fá formúlu sem gefur út eitthvað annað en TRUE eða FALSE, notaðu ISNUMBER ásamt EF fallinu.

Dæmi 1. Hólf inniheldur hvaða texta

Ef þú tekur fyrra dæmið lengra, segjum að þú viljir merkja lit hvers atriðis með "x" eins og sýnt er í töflunni hér að neðan.

Til að gera þetta skaltu einfaldlega setja ISNUMBER SEARCH formúluna inn í IF setninguna:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Ef ISNUMBER skilar TRUE, gefur IF fallið út "x" (eða önnur gildi sem þú gefur til gildið_ef_satt rök). Ef ISNUMBER skilar FALSE gefur IF fallið út tóman streng ("").

Dæmi 2. Fyrsti stafurinn í reit er tala eða texti

Ímyndaðu þér að þú sért að vinna með lista yfir alfanumeríska strengi og þú vilt vita hvort fyrsti stafur strengs er tala eða bókstafur.

Til að búa til slíka formúlu þarftu 4 mismunandi aðgerðir:

• LEFT aðgerðin dregur út fyrsta stafinn úr byrjun strengs, segjum í reit A2:

  LEFT(A2, 1)

• Þar sem LEFT tilheyrir flokki Textaaðgerða, niðurstaða er alltaf textastrengur, jafnvel þótt hann innihaldi aðeins tölur. Þess vegna þurfum við að reyna að breyta því í tölu áður en þú athugar útdráttarstafinn. Notaðu annaðhvort VALUE fallið eða tvöfaldan einhæfan rekstraraðila:

  VALUE(LEFT(A2, 1)) eða (--LEFT(A2, 1))

• ISNUMBER fallið ákvarðar hvort útdreginn stafurinn sé tölulegur eða ekki:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Byggt á ISNUMBER niðurstöðunni (TRUE eða FALSE), skilar IF fallið "Number" eða "Letter", í sömu röð.

Svo sem sagt að við séum að prófa streng í A2, heildarformúluna tekur þessa lögun:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

eða

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

ISNUMBER aðgerðin kemur líka að góðum notum fyrir taka tölur úr streng. Hér er dæmi: Fáðu tölu úr hvaða stöðu sem er í streng.

Athugaðu hvort gildi sé ekki tala

Þó að Microsoft Excel hafi sérstaka aðgerð, ISNONTEXT, til að ákvarðahvort gildi hólfs sé ekki texti, þá vantar hliðstæða fall fyrir tölur.

Auðveld lausn er að nota ISNUMBER ásamt NOT sem skilar andstæðu röklegu gildis. Með öðrum orðum, þegar ISNUMBER skilar TRUE, EKKI breytir því í FALSE, og öfugt.

Til að sjá það í aðgerð skaltu fylgjast með niðurstöðum eftirfarandi formúlu:

=NOT(ISNUMBER(A2))

Önnur aðferð er að nota IF og ISNUMBER föllin saman:

=IF(ISNUMBER(A2), "", "Not number")

Ef A2 er tölustafur skilar formúlan engu (tómt strengur). Ef A2 er ekki tölustafur segir formúlan það fyrirfram: "Ekki tala".

Ef þú vilt framkvæma einhverja útreikninga með tölum skaltu setja jöfnu eða aðra jöfnu. formúlu í gildi_ef_sannur röksemdinni í stað tóms strengs. Til dæmis mun formúlan hér að neðan margfalda tölur með 10 og gefa „Ekki tala“ fyrir ótalnagildi:

=IF(ISNUMBER(A2), A2*10, "Not number")

Athugaðu hvort svið inniheldur einhverja tölu

Í aðstæður þegar þú vilt prófa allt bilið fyrir tölur, notaðu ISNUMBER aðgerðina ásamt SUMPRODUCT svona:

Til dæmis, til að komast að því hvort bilið A2:A5 inniheldur eitthvert tölugildi, myndu formúlurnar vera sem hér segir:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Ef þú vilt gefa út „Já“ og „Nei“ í stað TRUE og FALSE, notaðu IF-yfirlýsinguna sem"umbúðir" fyrir ofangreindar formúlur. Til dæmis:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Hvernig þessi formúla virkar

Í hjarta formúlunnar metur ISNUMBER fallið hverja reit í tilgreint svið, segjum B2:B5, og skilar TRUE fyrir tölur, FALSE fyrir allt annað. Þar sem sviðið inniheldur 4 frumur, hefur fylkið 4 þætti:

{TRUE;FALSE;FALSE;FALSE}

Margföldunaraðgerðin eða tvöfaldur einflokkurinn (--) þvingar TRUE og FALSE í 1 og 0, í sömu röð:

{1;0;0;0}

SUMPRODUCT aðgerðin leggur saman þætti fylkisins. Ef niðurstaðan er meiri en núll þýðir það að það er að minnsta kosti ein tala á bilinu. Þannig að þú notar ">0" til að fá lokaniðurstöðuna TRUE eða FALSE.

ISNUMBER í skilyrtu sniði til að auðkenna hólf sem innihalda ákveðinn texta

Ef þú ert að leita að auðkenna hólf eða heilar línur sem innihalda ákveðinn texta, búðu til skilyrta sniðsreglu sem byggir á ISNUMBER SEARCH (há- og hástöfum) eða ISNUMBER FIND (case-sensitive) formúlunni.

Í þessu dæmi ætlum við að auðkenna línur út frá gildið í dálki A. Nánar tiltekið munum við auðkenna hlutina sem innihalda orðið „rautt“. Svona er það:

1. Veldu allar gagnalínurnar (A2:C6 í þessu dæmi) eða aðeins dálkinn sem þú vilt auðkenna frumur í.
2. Á Heimasvæði flipann, í hópnum Stílar , smelltu á Ný regla > Notaðu formúlu til að ákvarða hvaða frumur á að forsníða .
3. Í Sniðgildi þar sem þessi formúla er sönn skaltu slá inn formúluna hér að neðan (vinsamlegast athugið að dálkhnitið er læst með $ tákninu):

   =ISNUMBER(SEARCH("red", $A2))

4. Smelltu á Format hnappinn og veldu sniðið sem þú vilt.
5. Smelltu tvisvar á OK.

Ef þú hefur litla reynslu af Excel skilyrtu sniði geturðu fundið ítarleg skref með skjámyndum í þessari kennslu: Hvernig á að búa til formúlubundna skilyrta sniðsreglu.

Sem afleiðing eru öll atriði rauða litarins auðkennd:

Í stað þess að "harðkóða" litinn í skilyrtu sniðreglunni geturðu slegið hann inn í fyrirfram skilgreindan reit, segjum E2, og vísað til þess hólfs í formúlunni þinni (vinsamlegast hafðu í huga algeru frumutilvísunina $E$2). Auk þess þarftu að athuga hvort inntaksreiturinn sé ekki tómur:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Þar af leiðinni færðu sveigjanlegri reglu sem undirstrikar línur byggðar á inntakinu þínu í E2:

Svona á að nota ISNUMBER aðgerðina í Excel. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Lagt niðurhal

Excel ISNUMBER formúludæmi