Ang tutorial ay nagpapaliwanag kung ano ang ISNUMBER sa Excel at nagbibigay ng mga halimbawa ng mga basic at advanced na paggamit.

Ang konsepto ng ISNUMBER function sa Excel ay napakasimple - sinusuri lamang nito kung ang isang ibinigay ang halaga ay isang numero o hindi. Ang isang mahalagang punto dito ay ang mga praktikal na paggamit ng function na higit pa sa pangunahing konsepto nito, lalo na kapag pinagsama sa iba pang mga function sa loob ng mas malalaking formula.

Excel ISNUMBER function

Ang ISNUMBER function sa Excel ay nagsusuri kung ang isang cell ay naglalaman ng isang numerical na halaga o hindi. Nabibilang ito sa pangkat ng mga function ng IS.

Available ang function sa lahat ng bersyon ng Excel para sa Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 at mas mababa.

Ang ISNUMBER syntax ay nangangailangan lamang ng isang argument:

=ISNUMBER(value)

Kung saan ang value ay ang value na gusto mong subukan. Kadalasan, ito ay kinakatawan ng isang cell reference, ngunit maaari ka ring magbigay ng isang tunay na halaga o maglagay ng isa pang function sa loob ng ISNUMBER upang suriin ang resulta.

Kung ang value ay numeric, ang function ay nagbabalik ng TRUE . Para sa anumang bagay (mga text value, error, blanks) ISNUMBER ay nagbabalik ng FALSE.

Bilang halimbawa, subukan natin ang mga value sa mga cell A2 hanggang A6, at malalaman natin na ang unang 3 value ay mga numero at ang huling dalawa ay text:

2 bagay na dapat mong malaman tungkol sa ISNUMBER function sa Excel

May ilang mga kawili-wiling punto na dapat tandaan dito:

• SaAng panloob na representasyon ng Excel, mga petsa at beses ay mga numeric na halaga, kaya ang ISNUMBER formula ay nagbabalik ng TRUE para sa kanila (pakitingnan ang B3 at B4 sa screenshot sa itaas).
• Para sa mga numerong nakaimbak bilang text, ang ISNUMBER function ay nagbabalik ng FALSE (tingnan ang halimbawang ito).

Excel ISNUMBER na mga halimbawa ng formula

Ang mga halimbawa sa ibaba ay nagpapakita ng ilang karaniwan at ilang di-trivial na paggamit ng ISNUMBER sa Excel.

Tingnan kung numero ang isang value

Kapag mayroon kang isang grupo ng mga value sa iyong worksheet at gusto mong malaman kung alin ang mga numero, ISNUMBER ang tamang function na gagamitin .

Sa halimbawang ito, ang unang value ay nasa A2, kaya ginagamit namin ang formula sa ibaba upang suriin ito, at pagkatapos ay i-drag pababa ang formula sa pinakamaraming cell kung kinakailangan:

=ISNUMBER(A2)

Mangyaring bigyang-pansin na kahit na ang lahat ng mga halaga ay mukhang mga numero, ang ISNUMBER formula ay nagbalik ng FALSE para sa mga cell A4 at A5, na nangangahulugang ang mga halagang iyon ay numeric string , ibig sabihin, mga numerong naka-format bilang text. Maaaring may iba't ibang dahilan para dito, halimbawa nangunguna sa mga zero, naunang apostrophe, atbp. Anuman ang dahilan, hindi kinikilala ng Excel ang mga halaga bilang mga numero. Kaya, kung hindi tama ang pagkalkula ng iyong mga halaga, ang unang bagay na dapat mong suriin ay kung talagang mga numero ang mga ito sa mga tuntunin ng Excel, at pagkatapos ay i-convert ang text sa numero kung kinakailangan.

Formula ng Excel ISNUMBER SEARCH

Bukod sa pagtukoy ng mga numero, ang ExcelAng ISNUMBER function ay maaari ding suriin kung ang isang cell ay naglalaman ng partikular na teksto bilang bahagi ng nilalaman. Para dito, gamitin ang ISNUMBER kasama ang SEARCH function.

Sa generic na anyo, ang formula ay ganito ang hitsura:

Kung saan substring ang text na gusto mong hanapin.

Bilang halimbawa, tingnan natin kung ang string sa A3 ay naglalaman ng isang partikular na kulay, sabihin ang pula:

=ISNUMBER(SEARCH("red", A3))

Ang formula na ito ay mahusay na gumagana para sa isang cell. Ngunit dahil ang aming sample na talahanayan (pakitingnan sa ibaba) ay naglalaman ng tatlong magkakaibang kulay, ang pagsusulat ng isang hiwalay na formula para sa bawat isa ay isang pag-aaksaya ng oras. Sa halip, sasangguni kami sa cell na naglalaman ng kulay ng interes (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Para makopya nang tama ang formula pababa at pakanan, tiyaking i-lock ang mga sumusunod na coordinate gamit ang ang $ sign:

• Sa substring reference, i-lock ang row (B$2) para palaging piliin ng mga kinopyang formula ang mga substring sa row 2. Relative ang column reference dahil tayo nais nitong ayusin para sa bawat column, ibig sabihin, kapag ang formula ay kinopya sa C3, ang substring reference ay magiging C$2.
• Sa source cell reference, i-lock ang column ($A3 ) para suriin ng lahat ng formula ang mga value sa column A.

Ipinapakita ng screenshot sa ibaba ang resulta:

ISNUMBER FIND - case-sensitive formula

Dahil ang SEARCH function ay case-insensitive , ang nasa itaashindi pinag-iiba ng formula ang uppercase at lowercase na character. Kung naghahanap ka ng case-sensitive na formula, gamitin ang FIND function sa halip na SEARCH.

Para sa aming sample na dataset , ang formula ay kukuha ng ganitong form:

=ISNUMBER(FIND(B$2, $A3))

Paano gumagana ang formula na ito

Ang lohika ng formula ay medyo halata at madaling sundin:

• Hinahanap ng function na SEARCH / FIND ang substring sa tinukoy na cell. Kung natagpuan ang substring, ibabalik ang posisyon ng unang character. Kung hindi matagpuan ang substring, bubuo ang function ng #VALUE! error.
• Ang ISNUMBER function ay kinukuha ito mula doon at nagpoproseso ng mga numeric na posisyon. Kaya, kung ang substring ay natagpuan at ang posisyon nito ay ibinalik bilang isang numero, ang ISNUMBER ay maglalabas ng TRUE. Kung hindi mahanap ang substring at isang #VALUE! nagkakaroon ng error, ang ISNUMBER ay naglalabas ng FALSE.

IF ISNUMBER formula

Kung nilalayon mong makakuha ng formula na naglalabas ng ibang bagay maliban sa TRUE o FALSE, gamitin ang ISNUMBER kasama ng IF function.

Halimbawa>Upang magawa ito, i-wrap lang ang ISNUMBER SEARCH formula sa IF statement:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Kung ang ISNUMBER ay nagbabalik ng TRUE, ang IF function ay naglalabas ng "x" (o anumang iba pang value na ibibigay mo sa ang value_if_true argumento). Kung ang ISNUMBER ay nagbabalik ng FALSE, ang IF function ay naglalabas ng walang laman na string ("").

Halimbawa 2. Ang unang character sa isang cell ay numero o text

Isipin na nagtatrabaho ka sa isang listahan ng mga alphanumeric na string at gusto mong malaman kung numero o titik ang unang character ng string.

Upang bumuo ng ganoong formula, kakailanganin namin ng 4 na magkakaibang function:

• Kinukuha ng LEFT function ang unang character mula sa simula ng isang string, sabihin sa cell A2:

  LEFT(A2, 1)

• Dahil ang LEFT ay kabilang sa kategorya ng mga Text function, ang ang resulta ay palaging isang text string, kahit na naglalaman lamang ito ng mga numero. Samakatuwid, bago suriin ang nakuha na character, kailangan nating subukang i-convert ito sa isang numero. Para dito, gamitin ang alinman sa VALUE function o double unary operator:

  VALUE(LEFT(A2, 1)) o (--LEFT(A2, 1))

• Tinutukoy ng ISNUMBER function kung numeric o hindi ang na-extract na character:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Batay sa resulta ng ISNUMBER (TRUE o FALSE), ang IF function ay nagbabalik ng "Number" o "Letter", ayon sa pagkakabanggit.

Ipagpalagay na sinusubukan namin ang isang string sa A2, ang kumpletong formula ganito ang hugis:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

o

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Ang ISNUMBER function ay magagamit din para sa pag-extract ng mga numero mula sa isang string. Narito ang isang halimbawa: Kumuha ng numero mula sa anumang posisyon sa isang string.

Tingnan kung ang isang halaga ay hindi numero

Kahit na ang Microsoft Excel ay may espesyal na function, ISNONTEXT, upang matukoykung ang value ng cell ay hindi text, nawawala ang isang analogous function para sa mga numero.

Ang isang madaling solusyon ay ang paggamit ng ISNUMBER kasama ng NOT na nagbabalik ng kabaligtaran ng isang logical value. Sa madaling salita, kapag ang ISNUMBER ay nagbalik ng TRUE, HINDI ito iko-convert sa FALSE, at sa kabilang banda.

Upang makita ito sa pagkilos, mangyaring obserbahan ang mga resulta ng sumusunod na formula:

=NOT(ISNUMBER(A2))

Ang isa pang diskarte ay ang paggamit ng IF at ISNUMBER function nang magkasama:

=IF(ISNUMBER(A2), "", "Not number")

Kung ang A2 ay numeric, ang formula ay walang ibinabalik (isang walang laman string). Kung ang A2 ay hindi numeric, ang formula ay nagsasabi nito sa harapan: "Hindi numero".

Kung gusto mong magsagawa ng ilang mga kalkulasyon na may mga numero, pagkatapos ay maglagay ng equation o iba pa. formula sa value_if_true argument sa halip na isang walang laman na string. Halimbawa, ang formula sa ibaba ay magpaparami ng mga numero sa 10 at magbubunga ng "Hindi numero" para sa mga hindi numeric na halaga:

=IF(ISNUMBER(A2), A2*10, "Not number")

Tingnan kung ang isang hanay ay naglalaman ng anumang numero

Sa sitwasyon kapag gusto mong subukan ang buong hanay para sa mga numero, gamitin ang ISNUMBER function na kasama ng SUMPRODUCT tulad nito:

Halimbawa, upang malaman kung ang hanay na A2:A5 ay naglalaman ng anumang numeric na halaga, ang mga formula ay pupunta sa sumusunod:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Kung gusto mong i-output ang "Oo" at "Hindi" sa halip na TRUE at FALSE, gamitin ang IF statement bilang isang"wrapper" para sa mga formula sa itaas. Halimbawa:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Paano gumagana ang formula na ito

Sa gitna ng formula, sinusuri ng ISNUMBER function ang bawat cell ng tinukoy na hanay, sabihin ang B2:B5, at nagbabalik ng TRUE para sa mga numero, FALSE para sa anumang bagay. Dahil ang range ay naglalaman ng 4 na cell, ang array ay may 4 na elemento:

{TRUE;FALSE;FALSE;FALSE}

Ang multiplication operation o ang double unary (--) ay pinipilit ang TRUE at FALSE sa 1's at 0's, ayon sa pagkakabanggit:

{1;0;0;0}

Ang SUMPRODUCT function ay nagdaragdag ng mga elemento ng array. Kung ang resulta ay mas malaki kaysa sa zero, nangangahulugan iyon na mayroong kahit isang numero ang hanay. Kaya, ginagamit mo ang ">0" upang makakuha ng huling resulta ng TRUE o FALSE.

ISNUMBER sa conditional formatting upang i-highlight ang mga cell na naglalaman ng ilang partikular na text

Kung naghahanap ka upang i-highlight ang mga cell o buong row na naglalaman ng partikular na text, gumawa ng conditional formatting rule batay sa ISNUMBER SEARCH (case-insensitive) o ISNUMBER FIND (case-sensitive) na formula.

Para sa halimbawang ito, iha-highlight namin ang mga row batay sa ang halaga sa column A. Mas tiyak, iha-highlight namin ang mga item na naglalaman ng salitang "pula". Ganito:

1. Piliin ang lahat ng row ng data (A2:C6 sa halimbawang ito) o ang column lang kung saan mo gustong i-highlight ang mga cell.
2. Sa Home tab, sa grupong Mga Estilo , i-click ang Bagong Panuntunan > Gumamit ng formula upang matukoy kung aling mga cell ang ipo-format .
3. Saang Format values ​​kung saan totoo ang formula na ito , ilagay ang formula sa ibaba (pakipansin na ang column coordinate ay naka-lock na may $ sign):

   =ISNUMBER(SEARCH("red", $A2))

4. I-click ang Button na Format at piliin ang format na gusto mo.
5. I-click ang OK nang dalawang beses.

Kung wala kang karanasan sa Excel conditional formatting, makikita mo ang mga detalyadong hakbang na may mga screenshot sa tutorial na ito: Paano gumawa ng nakabatay sa formula na tuntunin sa conditional formatting.

Bilang resulta, ang lahat ng mga item ng pulang kulay ay naka-highlight:

Sa halip na "hardcoding" ang kulay sa conditional formatting rule, maaari mo itong i-type sa isang paunang natukoy na cell, sabihin ang E2, at sumangguni sa cell na iyon sa iyong formula (mangyaring isipin ang absolute cell reference $E$2). Bukod pa rito, kailangan mong suriin kung walang laman ang input cell:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Bilang resulta, makakakuha ka ng mas flexible na panuntunan na nagha-highlight ng mga row batay sa iyong input sa E2:

Ganyan gamitin ang function na ISNUMBER sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Mga available na download

Excel ISNUMBER na mga halimbawa ng formula