Tutoriali shpjegon se çfarë është ISNUMBER në Excel dhe ofron shembuj të përdorimeve bazë dhe të avancuara.

Koncepti i funksionit ISNUMBER në Excel është shumë i thjeshtë - ai thjesht kontrollon nëse një vlera është një numër apo jo. Një pikë e rëndësishme këtu është se përdorimet praktike të funksionit shkojnë shumë përtej konceptit të tij bazë, veçanërisht kur kombinohen me funksione të tjera brenda formulave më të mëdha.

Funksioni ISNUMBER Excel

Funksioni ISNUMBER në Excel kontrollon nëse një qelizë përmban një vlerë numerike apo jo. Ai i përket grupit të funksioneve IS.

Funksioni është i disponueshëm në të gjitha versionet e Excel për Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007 dhe më poshtë.

Sintaksa ISNUMBER kërkon vetëm një argument:

=ISNUMBER(value)

Ku vlera është vlera që dëshironi të testoni. Zakonisht, ajo përfaqësohet nga një referencë qelize, por mund të jepni gjithashtu një vlerë reale ose të vendosni një funksion tjetër brenda ISNUMBER për të kontrolluar rezultatin.

Nëse vlera është numerike, funksioni kthen TRUE . Për çdo gjë tjetër (vlerat e tekstit, gabimet, boshllëqet) ISNUMBER kthen FALSE.

Si shembull, le të testojmë vlerat në qelizat A2 deri në A6 dhe do të zbulojmë se 3 vlerat e para janë numra dhe dy të fundit janë teksti:

2 gjëra që duhet të dini rreth funksionit ISNUMBER në Excel

Ka disa pika interesante për t'u theksuar këtu:

• Nëpërfaqësimi i brendshëm i Excel-it, datat dhe herët janë vlera numerike, kështu që formula ISNUMBER kthen TË VËRTETË për to (ju lutemi shihni B3 dhe B4 në pamjen e mësipërme).
• Për numrat e ruajtur si tekst, funksioni ISNUMBER kthen FALSE (shih këtë shembull).

Shembuj të formulës ISNUMBER Excel

Shembujt e mëposhtëm demonstrojnë disa përdorime të zakonshme dhe jo të parëndësishme e ISNUMBER në Excel.

Kontrolloni nëse një vlerë është numër

Kur keni një grup vlerash në fletën tuaj të punës dhe dëshironi të dini se cilat janë numra, ISNUMBER është funksioni i duhur për t'u përdorur .

Në këtë shembull, vlera e parë është në A2, kështu që ne përdorim formulën e mëposhtme për ta kontrolluar atë, dhe më pas zvarriteni formulën në aq qeliza sa nevojitet:

=ISNUMBER(A2)

Ju lutemi kushtoni vëmendje se megjithëse të gjitha vlerat duken si numra, formula ISNUMBER ka kthyer FALSE për qelizat A4 dhe A5, që do të thotë se ato vlera janë vargje numerike , pra numra të formatuar si tekst. Mund të ketë arsye të ndryshme për këtë, për shembull zero kryesore, apostrof paraprak, etj. Cilado qoftë arsyeja, Excel nuk i njeh vlera të tilla si numra. Pra, nëse vlerat tuaja nuk llogariten saktë, gjëja e parë që duhet të kontrolloni është nëse ato janë me të vërtetë numra për sa i përket Excel-it, dhe më pas konvertoni tekstin në numër nëse është e nevojshme.

Formula Excel ISNUMBER SEARCH

Përveç identifikimit të numrave, ExcelFunksioni ISNUMBER gjithashtu mund të kontrollojë nëse një qelizë përmban tekst specifik si pjesë e përmbajtjes. Për këtë, përdorni ISNUMBER së bashku me funksionin SEARCH.

Në formën e përgjithshme, formula duket si më poshtë:

Ku nënvargu është teksti që dëshironi të gjeni.

Si shembull, le të kontrollojmë nëse vargu në A3 përmban një ngjyrë specifike, thuaj të kuqe:

=ISNUMBER(SEARCH("red", A3))

Kjo formulë funksionon mirë për një qelizë të vetme. Por për shkak se tabela jonë e mostrës (shih më poshtë) përmban tre ngjyra të ndryshme, shkrimi i një formule të veçantë për secilën do të ishte humbje kohe. Në vend të kësaj, ne do t'i referohemi qelizës që përmban ngjyrën e interesit (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Që formula të kopjohet saktë poshtë dhe djathtas, sigurohuni që të kyçni koordinatat e mëposhtme me shenja $:

• Në referencën nënstring , kyçni rreshtin (B$2) në mënyrë që formulat e kopjuara të zgjedhin gjithmonë nënvargjet në rreshtin 2. Referenca e kolonës është relative sepse ne dëshironi që ajo të rregullohet për secilën kolonë, d.m.th. kur formula kopjohet në C3, referenca e nënvargut do të ndryshojë në C$2.
• Në referencën qeliza burimore , kyçni kolonën ($A3 ) në mënyrë që të gjitha formulat të kontrollojnë vlerat në kolonën A.

Pamja e ekranit më poshtë tregon rezultatin:

GJENI I NUMRIT FIND - i ndjeshëm ndaj shkronjave të vogla formula

Meqë funksioni SEARCH është i pandjeshëm ndaj shkronjave të vogla , sa më sipërformula nuk dallon shkronjat e mëdha dhe të vogla. Nëse jeni duke kërkuar për një formulë të ndjeshme ndaj shkronjave, përdorni funksionin FIND në vend të SEARCH.

Për grupin tonë të të dhënave të mostrës , formula do të kishte këtë formë:

=ISNUMBER(FIND(B$2, $A3))

Si funksionon kjo formulë

Logjika e formulës është mjaft e qartë dhe e lehtë për t'u ndjekur:

• Funksioni SEARCH / FIND kërkon nënvargun në qelizën e specifikuar. Nëse gjendet nënvargu, pozicioni i karakterit të parë kthehet. Nëse nënvargu nuk gjendet, funksioni prodhon një #VALUE! gabim.
• Funksioni ISNUMBER e merr prej andej dhe përpunon pozicionet numerike. Pra, nëse gjendet nënvargu dhe pozicioni i tij kthehet si numër, ISNUMBER nxjerr TRUE. Nëse nënvargu nuk gjendet dhe një #VALUE! ndodh gabimi, ISNUMBER nxjerr FALSE.

NËSE formula ISNUMBER

Nëse synoni të merrni një formulë që nxjerr diçka tjetër përveç TRUE ose FALSE, përdorni ISNUMBER së bashku me funksionin IF.

Shembulli 1. Celi përmban cilin tekst

Duke marrë më tej shembullin e mëparshëm, supozoni se dëshironi të shënoni ngjyrën e secilit artikull me "x" siç tregohet në tabelën më poshtë.

Për ta bërë këtë, thjesht mbështillni formulën ISNUMBER SEARCH në deklaratën IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Nëse ISNUMBER kthen TRUE, funksioni IF nxjerr "x" (ose çdo vlerë tjetër që i jepni vlera_nëse_e vërtetë argument). Nëse ISNUMBER kthen FALSE, funksioni IF nxjerr një varg bosh ("").

Shembull 2. Karakteri i parë në një qelizë është numri ose teksti

Imagjinoni që jeni duke punuar me një listë vargjesh alfanumerike dhe dëshironi të dini nëse karakteri i parë i vargut është një numër apo shkronjë.

Për të ndërtuar një formulë të tillë, do të na duhen 4 funksione të ndryshme:

• Funksioni LEFT nxjerr karakterin e parë nga fillimi i një vargu, le të themi në qelizën A2:

  LEFT(A2, 1)

• Për shkak se LEFT i përket kategorisë së funksioneve të tekstit, ai rezultati është gjithmonë një varg teksti, edhe nëse përmban vetëm numra. Prandaj, përpara se të kontrollojmë karakterin e nxjerrë, duhet të përpiqemi ta konvertojmë atë në një numër. Për këtë, përdorni ose funksionin VALUE ose operatorin e dyfishtë unar:

  VALUE(LEFT(A2, 1)) ose (--LEFT(A2, 1))

  Shiko gjithashtu: Si të shtoni linjën e trendit në grafikun Excel
• Funksioni ISNUMBER përcakton nëse karakteri i nxjerrë është numerik ose jo:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Bazuar në rezultatin ISNUMBER (TRUE ose FALSE), funksioni IF kthen përkatësisht "Number" ose "Letter".

Duke supozuar se po testojmë një varg në A2, formula e plotë merr këtë formë:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Number", "Letter")

ose

=IF(ISNUMBER(--LEFT(A2, 1)), "Number", "Letter")

Funksioni ISNUMBER është gjithashtu i dobishëm për nxjerrja e numrave nga një varg. Ja një shembull: Merr një numër nga çdo pozicion në një varg.

Kontrollo nëse një vlerë nuk është numër

Megjithëse Microsoft Excel ka një funksion të veçantë, ISNONTEXT, për të përcaktuarnëse vlera e një qelize nuk është tekst, mungon një funksion analog për numrat.

Një zgjidhje e lehtë është përdorimi i ISNUMBER në kombinim me NOT që kthen të kundërtën e një vlere logjike. Me fjalë të tjera, kur ISNUMBER kthen TRUE, NOT e konverton në FALSE, dhe anasjelltas.

Për ta parë atë në veprim, ju lutemi vëzhgoni rezultatet e formulës së mëposhtme:

=NOT(ISNUMBER(A2))

Një qasje tjetër është përdorimi i funksioneve IF dhe ISNUMBER së bashku:

=IF(ISNUMBER(A2), "", "Not number")

Nëse A2 është numerik, formula nuk kthen asgjë (një bosh varg). Nëse A2 nuk është numerik, formula e thotë përpara: "Jo numër".

Nëse dëshironi të kryeni disa llogaritje me numra, atëherë vendosni një ekuacion ose një tjetër formula në argumentin value_if_true në vend të një vargu bosh. Për shembull, formula e mëposhtme do t'i shumëzojë numrat me 10 dhe do të japë "Jo numër" për vlerat jonumerike:

=IF(ISNUMBER(A2), A2*10, "Not number")

Kontrollo nëse një varg përmban ndonjë numër

Në Situata kur dëshironi të testoni të gjithë gamën për numra, përdorni funksionin ISNUMBER në kombinim me SUMPRODUCT si kjo:

Për shembull, për të zbuluar nëse diapazoni A2:A5 përmban ndonjë vlerë numerike, formulat do të shkonin si më poshtë:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Nëse dëshironi të nxirrni "Po" dhe "Jo" në vend të TRUE dhe FALSE, përdorni deklaratën IF si një"mbështjellës" për formulat e mësipërme. Për shembull:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Yes", "No")

Si funksionon kjo formulë

Në zemër të formulës, funksioni ISNUMBER vlerëson secilën qelizë të intervalin e specifikuar, le të themi B2:B5 dhe kthen TRUE për numrat, FALSE për çdo gjë tjetër. Duke qenë se diapazoni përmban 4 qeliza, grupi ka 4 elemente:

{TRUE;FALSE;FALSE;FALSE}

Operacioni i shumëzimit ose unari i dyfishtë (--) detyron TRUE dhe FALSE në 1 dhe 0, përkatësisht:

{1;0;0;0}

Funksioni SUMPRODUCT mbledh elementet e grupit. Nëse rezultati është më i madh se zero, kjo do të thotë se ka të paktën një numër në interval. Pra, ju përdorni ">0" për të marrë një rezultat përfundimtar të TRUE ose FALSE.

ISNUMBER në formatimin e kushtëzuar për të theksuar qelizat që përmbajnë tekst të caktuar

Nëse po kërkoni të nënvizoni qelizat ose rreshtat e tëra që përmbajnë tekst specifik, krijojnë një rregull të formatimit të kushtëzuar bazuar në formulën ISNUMBER SEARCH (pandjeshme ndaj shkronjave të vogla) ose ISNUMBER FIND (ndjeshme ndaj shkronjave).

Për këtë shembull, ne do të theksojmë rreshtat bazuar në vlera në kolonën A. Më saktë do të veçojmë artikujt që përmbajnë fjalën "e kuqe". Ja se si:

1. Zgjidhni të gjitha rreshtat e të dhënave (A2:C6 në këtë shembull) ose vetëm kolonën në të cilën dëshironi të nënvizoni qelizat.
2. Në Home , në grupin Stilet , kliko Rregull i ri > Përdor një formulë për të përcaktuar se cilat qeliza të formatohen .
3. Nënë kutinë Formatoni vlerat ku kjo formulë është e vërtetë , shkruani formulën e mëposhtme (ju lutem vini re se koordinata e kolonës është e kyçur me shenjën $):

   =ISNUMBER(SEARCH("red", $A2))

4. Klikoni Butoni Format dhe zgjidhni formatin që dëshironi.
5. Klikoni OK dy herë.

Nëse keni pak përvojë me formatimin e kushtëzuar të Excel, mund të gjeni hapat e detajuar me pamjet e ekranit në këtë tutorial: Si të krijoni një rregull të formatimit të kushtëzuar të bazuar në formulë.

Si rezultat, të gjithë elementët e ngjyrës së kuqe theksohen:

Në vend të "kodifikimit të fortë" të ngjyrës në rregullin e formatimit të kushtëzuar, mund ta shtypni atë në një qelizë të paracaktuar, le të themi E2, dhe t'i referoheni asaj qelize në formulën tuaj (ju lutemi mbani parasysh referencën absolute të qelizës $E$2). Për më tepër, duhet të kontrolloni nëse qeliza hyrëse nuk është bosh:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Si rezultat, do të merrni një rregull më fleksibël që thekson rreshtat bazuar në të dhënat tuaja në E2:

Kështu përdoret funksioni ISNUMBER në Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën tjetër!

Shkarkimet e disponueshme

Shembuj të formulave Excel ISNUMBER