Pamokoje paaiškinama, kas yra ISNUMBER programoje "Excel", ir pateikiami pagrindinio ir išplėstinio naudojimo pavyzdžiai.

"Excel" funkcijos ISNUMBER koncepcija labai paprasta - ji tiesiog tikrina, ar tam tikra reikšmė yra skaičius, ar ne. Svarbu tai, kad praktinis funkcijos naudojimas gerokai pranoksta jos pagrindinę koncepciją, ypač kai ji derinama su kitomis funkcijomis didesnėse formulėse.

"Excel" ISNUMBER funkcija

"Excel" funkcija ISNUMBER tikrina, ar ląstelėje yra skaitinė reikšmė, ar ne. Ji priklauso IS funkcijų grupei.

Ši funkcija yra visose "Office 365", "Excel 2019", "Excel 2019", "Excel 2016", "Excel 2013", "Excel 2010", "Excel 2007" ir žemesnėse "Excel" versijose.

ISNUMBER sintaksei reikia tik vieno argumento:

=ISNUMBER(value)

Kur vertė paprastai tai būna ląstelės nuoroda, tačiau taip pat galite pateikti realią vertę arba ISNUMBER viduje įterpti kitą funkciją, kad patikrintumėte rezultatą.

Jei vertė jei reikšmė yra skaitinė, funkcija grąžina TRUE. Jei reikšmė yra kitokia (teksto reikšmės, klaidos, tušti langeliai), funkcija ISNUMBER grąžina FALSE.

Pavyzdžiui, patikrinkime A2-A6 langelių reikšmes ir pamatysime, kad pirmosios 3 reikšmės yra skaičiai, o paskutinės dvi - tekstas:

2 dalykai, kuriuos turėtumėte žinoti apie "Excel" funkciją ISNUMBER

Čia reikia atkreipti dėmesį į keletą įdomių dalykų:

• Vidiniame "Excel" atvaizdavime, datos ir kartus yra skaitinės reikšmės, todėl formulė ISNUMBER joms grąžina TRUE (žr. B3 ir B4 paveikslėlyje aukščiau).
• Jei skaičiai saugomi kaip tekstas, funkcija ISNUMBER grąžina FALSE (žr. šį pavyzdį).

"Excel" ISNUMBER formulės pavyzdžiai

Toliau pateiktuose pavyzdžiuose parodyta keletas įprastų ir keletas netrivialių ISNUMBER naudojimo būdų programoje "Excel".

Patikrinkite, ar reikšmė yra skaičius

Kai darbalapyje turite daugybę reikšmių ir norite sužinoti, kurios iš jų yra skaičiai, reikia naudoti funkciją ISNUMBER.

Šiame pavyzdyje pirmoji reikšmė yra A2 langelyje, todėl, norėdami ją patikrinti, naudojame toliau pateiktą formulę, o tada formulę vilkite žemyn į tiek langelių, kiek reikia:

=ISNUMBER(A2)

Atkreipkite dėmesį, kad nors visos reikšmės atrodo kaip skaičiai, formulė ISNUMBER ląstelėms A4 ir A5 grąžino FALSE, o tai reiškia, kad šios reikšmės yra skaitinės eilutės t. y. skaičiai, suformatuoti kaip tekstas. To priežastys gali būti įvairios, pavyzdžiui, pradiniai nuliai, prieš juos esantis apostrofas ir t. t. Kad ir kokia būtų priežastis, "Excel" tokių reikšmių neatpažįsta kaip skaičių. Taigi, jei jūsų reikšmės apskaičiuojamos neteisingai, pirmiausia turite patikrinti, ar jos tikrai yra skaičiai "Excel" požiūriu, ir tada, jei reikia, konvertuoti tekstą į skaičių.

"Excel" ISNUMBER SEARCH formulė

Be skaičių nustatymo, "Excel" funkcija ISNUMBER taip pat galima patikrinti, ar ląstelės turinyje yra konkretaus teksto. Šiuo tikslu naudokite funkciją ISNUMBER kartu su funkcija SEARCH.

Bendroji formulė atrodo taip:

Kur poaibis yra tekstas, kurį norite rasti.

Pavyzdžiui, patikrinkime, ar eilutėje A3 yra tam tikra spalva, tarkime, raudona:

=ISNUMBER(SEARCH("red", A3))

Ši formulė puikiai tinka vienai ląstelei. Tačiau kadangi mūsų pavyzdinėje lentelėje (žr. toliau) yra trys skirtingos spalvos, rašyti atskirą formulę kiekvienai iš jų būtų laiko švaistymas. Vietoj to nurodysime ląstelę, kurioje yra dominanti spalva (B2).

=ISNUMBER(SEARCH(B$2, $A3))

Kad formulė būtų teisingai nukopijuota į apačią ir į dešinę, būtinai užblokuokite šias koordinates ženklu $:

• Svetainėje poaibis nuorodą, užfiksuokite eilutę (B$2), kad nukopijuotos formulės visada rinktųsi 2 eilutės posričius. Stulpelio nuoroda yra santykinė, nes norime, kad ji būtų pritaikyta kiekvienam stulpeliui, t. y. kai formulė nukopijuojama į C3, posričio nuoroda pasikeis į C$2.
• Į šaltinio ląstelė nuorodą, užrakinkite stulpelį ($A3), kad visos formulės tikrintų A stulpelio reikšmes.

Toliau pateiktoje ekrano nuotraukoje matomas rezultatas:

ISNUMBER FIND - formulė, kurioje didžiosios raidės yra jautrios

Kadangi funkcija SEARCH yra Atskirų raidžių , pirmiau pateiktoje formulėje neskiriamos didžiosios ir mažosios raidės. Jei ieškote formulės, kurioje būtų skiriamos didžiosios ir mažosios raidės, naudokite funkciją FIND, o ne SEARCH.

Mūsų pavyzdinio duomenų rinkinio atveju formulė būtų tokia:

=ISNUMBER(FIND(B$2, $A3))

Kaip veikia ši formulė

Formulės logika yra gana akivaizdi ir lengvai suprantama:

• Funkcija SEARCH / FIND ieško poaibio nurodytoje ląstelėje. Jei poaibis randamas, grąžinama pirmojo simbolio pozicija. Jei poaibis nerandamas, funkcija pateikia #VALUE! klaidą.
• Funkcija ISNUMBER ją perima ir apdoroja skaitines pozicijas. Taigi, jei eilutė randama ir jos pozicija grąžinama kaip skaičius, ISNUMBER pateikia TRUE. Jei eilutė nerandama ir įvyksta klaida #VALUE!, ISNUMBER pateikia FALSE.

IF ISNUMBER formulė

Jei norite gauti formulę, kurios rezultatas būtų kitoks nei TRUE arba FALSE, naudokite ISNUMBER kartu su funkcija IF.

1 pavyzdys. Kokiame ląstelės langelyje yra koks tekstas

Tęsiant ankstesnį pavyzdį, įsivaizduokime, kad kiekvieno elemento spalvą norite pažymėti ženklu "x", kaip parodyta toliau pateiktoje lentelėje.

Norėdami tai padaryti, tiesiog įtraukite formulę ISNUMBER SEARCH į teiginį IF:

=IF(ISNUMBER(SEARCH(B$2, $A3)), "x", "")

Jei ISNUMBER grąžina TRUE, funkcija IF išveda "x" (arba bet kurią kitą reikšmę, kurią pateikiate funkcijai value_if_true Jei ISNUMBER grąžina FALSE, funkcija IF išveda tuščią eilutę ("").

2 pavyzdys. Pirmasis ląstelės simbolis yra skaičius arba tekstas

Įsivaizduokite, kad dirbate su raidinių-skaitmeninių eilučių sąrašu ir norite sužinoti, ar eilutės pirmasis simbolis yra skaičius, ar raidė.

Norint sukurti tokią formulę, reikės 4 skirtingų funkcijų:

• Funkcija LEFT iš eilutės, pavyzdžiui, esančios A2 ląstelėje, pradžios ištraukia pirmąjį simbolį:

  LEFT(A2, 1)

• Kadangi funkcija LEFT priklauso funkcijų kategorijai Text, jos rezultatas visada yra teksto eilutė, net jei joje yra tik skaičiai. Todėl prieš tikrindami išskirtą simbolį turime pabandyti jį paversti skaičiumi. Tam naudokite funkciją VALUE arba dvigubą vienaženklį operatorių:

  VERTĖ(LEFT(A2, 1)) arba (--LEFT(A2, 1))

• Funkcija ISNUMBER nustato, ar išskirtas simbolis yra skaitinis, ar ne:

  ISNUMBER(VALUE(LEFT(A2, 1)))

• Pagal ISNUMBER rezultatą (TRUE arba FALSE) funkcija IF grąžina atitinkamai "Skaičius" arba "Raidė".

Darant prielaidą, kad testuojame eilutę A2, visa formulė įgauna tokią formą:

=IF(ISNUMBER(VALUE(LEFT(A2, 1))), "Skaičius", "Raidė")

arba

=IF(ISNUMBER(--LEFT(A2, 1)), "Skaičius", "Raidė")

Funkcija ISNUMBER taip pat praverčia skaičių išskyrimas iš eilutės. Štai pavyzdys: Gauti skaičių iš bet kurios eilutės pozicijos.

Patikrinkite, ar reikšmė nėra skaičius

Nors "Microsoft Excel" turi specialią funkciją ISNONTEXT, skirtą nustatyti, ar ląstelės reikšmė nėra tekstas, analogiškos funkcijos, skirtos skaičiams, nėra.

Paprastas sprendimas - naudoti ISNUMBER kartu su NOT, kuris grąžina priešingą loginę reikšmę. Kitaip tariant, kai ISNUMBER grąžina TRUE, NOT ją paverčia FALSE, ir atvirkščiai.

Norėdami įsitikinti, kaip tai veikia, stebėkite šios formulės rezultatus:

=NOT(ISNUMBER(A2))

Kitas būdas - naudoti funkcijas IF ir ISNUMBER kartu:

=IF(ISNUMBER(A2), "", "Ne skaičius")

Jei A2 yra skaitmuo, formulė negrąžina nieko (tuščią eilutę). Jei A2 nėra skaitmuo, formulė tai nurodo iš anksto: "Ne skaitmuo".

Jei norite atlikti tam tikrus skaičiavimus su skaičiais, į langelį įrašykite lygtį arba kitą formulę. value_if_true argumentas, o ne tuščia eilutė. Pavyzdžiui, toliau pateikta formulė padaugins skaičius iš 10, o neskaitmeninėms reikšmėms gaus "Ne skaičius":

=IF(ISNUMBER(A2), A2*10, "Ne skaičius")

Patikrinkite, ar diapazone yra koks nors skaičius

Jei norite patikrinti visą skaičių intervalą, naudokite funkciją ISNUMBER kartu su SUMPRODUCT taip:

Pavyzdžiui, norėdami sužinoti, ar diapazone A2:A5 yra kokia nors skaitinė reikšmė, formulės būtų tokios:

=SUMPRODUCT(--ISNUMBER(A2:A5))>0

=SUMPRODUCT(ISNUMBER(A2:A5)*1)>0

Jei vietoj TRUE ir FALSE norite išvesti "Yes" ir "No", naudokite IF teiginį kaip pirmiau pateiktų formulių apvalkalą. Pavyzdžiui:

=IF(SUMPRODUCT(--ISNUMBER(A2:A5))>0, "Taip", "Ne")

Kaip veikia ši formulė

Formulės esmė - funkcija ISNUMBER įvertina kiekvieną nurodyto intervalo, tarkime, B2:B5, langelį ir grąžina TRUE, jei tai yra skaičiai, ir FALSE, jei tai yra kas nors kita. Kadangi intervalą sudaro 4 langeliai, masyvą sudaro 4 elementai:

{TRUE;FALSE;FALSE;FALSE;FALSE}

Daugybos operacija arba dviguba vienaskaita (--) verčia TRUE ir FALSE atitinkamai į 1 ir 0:

{1;0;0;0}

Funkcija SUMPRODUCT sudeda masyvo elementus. Jei rezultatas yra didesnis už nulį, vadinasi, diapazone yra bent vienas skaičius. Taigi, norėdami gauti galutinį rezultatą TRUE arba FALSE, naudokite ">0".

ISNUMBER sąlyginiame formatavime, kad paryškintumėte ląsteles, kuriose yra tam tikras tekstas

Jei norite paryškinti langelius arba ištisas eilutes, kuriose yra tam tikras tekstas, sukurkite sąlyginio formatavimo taisyklę pagal formulę ISNUMBER SEARCH (nereikšminga didžiosioms raidėms) arba ISNUMBER FIND (nereikšminga didžiosioms raidėms).

Šiame pavyzdyje paryškinsime eilutes pagal A stulpelio reikšmę. Tiksliau, paryškinsime elementus, kuriuose yra žodis "raudona". Štai kaip:

1. Pasirinkite visas duomenų eilutes (šiame pavyzdyje A2:C6) arba tik tą stulpelį, kuriame norite paryškinti ląsteles.
2. Dėl Pagrindinis skirtuke Stiliai grupę, spustelėkite Nauja taisyklė > Naudokite formulę, kad nustatytumėte, kurias ląsteles formatuoti .
3. Į Formuoti reikšmes, kai ši formulė yra teisinga įveskite toliau pateiktą formulę (atkreipkite dėmesį, kad stulpelio koordinatė užrakinta su $ ženklu):

   =ISNUMBER(SEARCH("red", $A2))

4. Spustelėkite Formatas mygtuką ir pasirinkite norimą formatą.
5. Du kartus spustelėkite OK.

Jei turite nedaug "Excel" sąlyginio formatavimo patirties, išsamius veiksmus su ekrano nuotraukomis rasite šioje pamokoje: Kaip sukurti formule pagrįstą sąlyginio formatavimo taisyklę.

Todėl visi raudonos spalvos elementai yra paryškinti:

Užuot "užkodavę" spalvą sąlyginio formatavimo taisyklėje, galite ją įvesti iš anksto nustatytoje ląstelėje, tarkime, E2, ir nurodyti tą ląstelę formulėje (nepamirškite absoliučios ląstelės nuorodos $E$2). Be to, reikia patikrinti, ar įvesties ląstelė nėra tuščia:

=AND(ISNUMBER(SEARCH($E$2, $A2)), $E$2"")

Todėl gausite lankstesnę taisyklę, kuri išryškins eilutes pagal jūsų įvestus duomenis E2:

Štai kaip "Excel" programoje naudoti funkciją ISNUMBER. Dėkoju, kad perskaitėte, ir tikiuosi, kad kitą savaitę susitiksime mūsų tinklaraštyje!

Galimi atsisiuntimai

"Excel" ISNUMBER formulės pavyzdžiai