Talaan ng nilalaman
Alam mo ba kung paano magsama ng mga numero sa isang partikular na column kapag ang isang halaga sa isa pang column ay nakakatugon sa alinman sa mga tinukoy na kundisyon? Sa artikulong ito, matututo ka ng 3 iba't ibang paraan upang gawin ang SUMIF gamit ang maramihang pamantayan at OR logic.
May espesyal na function ang Microsoft Excel upang isama ang mga cell na may maraming kundisyon - ang function na SUMIFS. Ang function na ito ay idinisenyo upang gumana sa AND logic - ang isang cell ay idaragdag lamang kapag ang lahat ng tinukoy na pamantayan ay TAMA para sa cell na iyon. Sa ilang sitwasyon, gayunpaman, maaaring kailanganin mong magsama ng maramihang OR pamantayan, ibig sabihin, magdagdag ng cell kapag ang alinman sa mga kundisyon ay TOTOO. At ito ay kapag ang SUMIF function ay madaling gamitin.
SUMIF + SUMIF upang magsama ng mga cell na katumbas nito o iyon
Kapag naghahanap ka ng mga numero sa isang column kapag ang isa pang column ay katumbas ng alinman sa A o B, ang pinaka-halatang solusyon ay ang hawakan ang bawat kundisyon nang isa-isa, at pagkatapos ay idagdag ang mga resulta nang sama-sama:
SUMIF(range, criteria1, sum_range) + SUMIF(range , criteria2, sum_range)Sa talahanayan sa ibaba, ipagpalagay na gusto mong magdagdag ng mga benta para sa dalawang magkaibang produkto, sabihin ang Mansanas at Lemons . Para dito, maaari mong direktang ibigay ang mga item ng interes sa criteria na mga argumento ng 2 magkaibang SUMIF function:
=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)
O maaari mong ilagay ang pamantayan sa magkahiwalay na mga cell, at sumangguni sa mga cell na iyon:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Kung saan ang A2:A10 ay ang listahan ng mga item ( range ), B2:B10ay ang mga numerong susumahin ( sum_rage ), E1 at E2 ang mga target na item ( pamantayan ):
Paano gumagana ang formula na ito:
Ang unang function ng SUMIF ay nagdaragdag ng mga benta ng Mansanas , ang pangalawang SUMIF ay nagsusuma ng Mga Lemon na benta. Ang pagdaragdag na operasyon ay nagdaragdag ng mga sub-kabuuan nang sama-sama at naglalabas ng kabuuan.
SUMIF na may array constant - compact formula na may maraming pamantayan
Ang SUMIF + SUMIF na diskarte ay gumagana nang maayos para sa 2 kundisyon. Kung kailangan mong sumama ng 3 o higit pang pamantayan, ang formula ay magiging masyadong malaki at mahirap basahin. Upang makamit ang parehong resulta sa isang mas compact na formula, ibigay ang iyong pamantayan sa isang array constant:
SUM(SUMIF(range, { crireria1, crireria2, crireria3<. item, ang formula ay: =SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
Sa screenshot sa itaas, ang mga kundisyon ay naka-hardcode sa isang array, ibig sabihin, kailangan mong i-update ang formula gamit ang bawat pagbabago sa pamantayan. Upang maiwasan ito, maaari mong ipasok ang pamantayan sa mga paunang natukoy na mga cell at ibigay sa isang formula bilang reference ng hanay (E1:E3 sa halimbawang ito).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
Sa Excel 365 na sumusuporta sa mga dynamic na array , ito ay gumagana bilang isang regular na formula na nakumpleto gamit ang Enter key. Sa mga pre-dynamic na bersyon ng Excel 2019, Excel 2016, Excel2013 at mas maaga, dapat itong ilagay bilang array formula gamit ang Ctrl + Shift + Enter shortcut:
Paano gumagana ang formula na ito:
Pinipilit ng array constant na nakasaksak sa pamantayan ng SUMIF na magbalik ng maraming resulta sa anyo ng array. Sa aming kaso, ito ay 3 magkaibang halaga: para sa Mansanas , Lemons at Mga dalandan :
{425;425;565}
Upang makuha ang Sa kabuuan, ginagamit namin ang function na SUM at ibinalot ito sa formula ng SUMIF.
SUMPRODUCT at SUMIF upang isama ang mga cell na may maramihang O kundisyon
Hindi gusto ang mga array at naghahanap ng isang normal na formula na papayagan ka bang magsama ng maraming pamantayan sa iba't ibang mga cell? Walang problema. Sa halip na SUM, gamitin ang SUMPRODUCT function na pinangangasiwaan ang mga arrays nang native:
SUMPRODUCT(SUMIF(range, crireria_range , sum_range))
Ipagpalagay na ang mga kundisyon ay nasa mga cell E1, E2 at E3, ganito ang hugis ng formula:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Paano gumagana ang formula na ito:
Gaya sa nakaraang halimbawa, ang SUMIF function ay nagbabalik ng hanay ng mga numero, na kumakatawan sa mga kabuuan para sa bawat indibidwal na kundisyon. Idinaragdag ng SUMPRODUCT ang mga numerong ito nang magkakasama at naglalabas ng panghuling kabuuan. Hindi tulad ng SUM function, ang SUMPRODUCT ay idinisenyo upang magproseso ng mga array, kaya ito ay gumagana bilang isang regular na formula nang hindi mo kailangang pindutin ang Ctrl + Shift + Enter .
SUMIF na gumagamit ng maraming pamantayan na may mga wildcard
Mula noong Sinusuportahan ng Excel SUMIF function ang mga wildcard, magagawa moisama ang mga ito sa maraming pamantayan kung kinakailangan.
Halimbawa, para sa kabuuan ng mga benta para sa lahat ng uri ng Mansanas at Mga Saging , ang formula ay:
=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))
Kung dapat ipasok ang iyong mga kundisyon sa mga indibidwal na cell, maaari kang direktang mag-type ng mga wildcard sa mga cell na iyon at magbigay ng sanggunian sa hanay bilang pamantayan para sa formula ng SUMPRODUCT SUMIF:
Sa halimbawang ito, naglalagay kami ng wildcard na character (*) bago ang mga pangalan ng item upang tumugma sa anumang naunang sequence ng mga character gaya ng Green apples at Goldfinger bananas . Upang makakuha ng kabuuan para sa mga item na naglalaman ng partikular na text saanman sa isang cell, maglagay ng asterisk sa magkabilang panig, hal. "*apple*".
Ganyan gamitin ang SUMIF sa Excel na may maraming kundisyon. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!
Magsanay ng workbook para sa pag-download
SUMIF maraming pamantayan (.xlsx file)
