I den här handledningen får du lära dig hur du automatiskt markerar dubbletter i Excel när något har skrivits. Vi kommer att titta närmare på hur du kan skugga dubbletter av celler, hela rader eller på varandra följande dubbletter med hjälp av villkorlig formatering och ett specialverktyg.

Förra veckan undersökte vi olika sätt att identifiera dubbletter i Excel med hjälp av formler. Dessa lösningar är utan tvekan mycket användbara, men att markera dubbletter i en viss färg kan göra dataanalysen ännu enklare.

Det snabbaste sättet att hitta och markera dubbletter i Excel är att använda villkorlig formatering. Den största fördelen med den här metoden är att den inte bara visar dubbletter i befintlig data utan också automatiskt kontrollerar ny data för dubbletter direkt när du matar in den i ett arbetsblad.

Dessa tekniker fungerar i alla versioner av Excel 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 och lägre.

Hur man markerar dubbletter i Excel

I alla Excel-versioner finns det en fördefinierad regel för att markera dubbla celler. Om du vill tillämpa den här regeln på dina kalkylblad utför du följande steg:

1. Välj de data som du vill kontrollera om det finns dubbletter, vilket kan vara en kolumn, en rad eller ett antal celler.
2. På den Hem på fliken Stilar grupp, klicka på Villkorlig formatering > Markera celler Regler > Dubbla värden...

   

3. Dubbla värden öppnas med formatet Ljusröd fyllning och Mörkröd text som standard. För att tillämpa standardformatet klickar du helt enkelt på OK .

Förutom den röda fyllningen och textformateringen finns en handfull andra fördefinierade format tillgängliga i rullgardinslistan. Om du vill skugga dubbletter med en annan färg klickar du på Anpassat format... (den sista punkten i rullgardinsmenyn) och välj den fyllnads- och/eller typsnittsfärg som du vill ha.

Tips. Om du vill markera unika värden väljer du Unik i den vänstra rutan.

Med hjälp av den inbyggda regeln kan du markera dubbletter i en kolumn eller i flera kolumner som visas i följande skärmdump:

Observera: När du tillämpar den inbyggda duplikatregeln på två eller flera kolumner jämför Excel inte värdena i dessa kolumner, utan markerar bara alla dubbletter i intervallet. Om du vill hitta och markera matchningar och skillnader mellan två kolumner följer du exemplen i den ovan länkade handledningen.

När du använder Excels inbyggda regel för att markera dubbla värden ska du tänka på följande två saker:

• Det fungerar bara för enskilda celler. till markera dubbla rader Om du vill skapa egna regler måste du skapa egna regler som antingen baseras på värden i en specifik kolumn eller genom att jämföra värden i flera kolumner.
• Den skuggar dubbla celler inklusive deras första förekomst. Om du vill markera alla dubbletter utom de första instanserna skapa en regel för villkorlig formatering baserad på en formel som förklaras i nästa exempel.

Hur man markerar dubbletter utan 1:a förekomst

Om du vill markera andra och alla efterföljande dubbletter markerar du cellerna du vill färglägga och skapar en formelbaserad regel på det här sättet:

1. På den Hem på fliken Stilar grupp, klicka på Villkorlig formatering > Ny regel> Använd en formel för att bestämma vilka celler som ska formateras .
2. I Formatera värden där denna formel är sann ange en formel som liknar den här:

=COUNTIF($A$2:$A2,$A2)>1

Där A2 är den översta cellen i det valda intervallet.

Om du inte har så mycket erfarenhet av villkorlig formatering i Excel hittar du detaljerade steg för att skapa en formelbaserad regel i följande handledning: Villkorlig formatering i Excel baserat på ett annat cellvärde.

Resultatet blir att de dubbletter som inte ingår i de första instanserna kommer att markeras med den färg du väljer:

Hur man visar 3:e, 4:e och alla efterföljande duplikatposter

Om du vill visa dubbletter som börjar med den N:e förekomsten skapar du en regel för villkorlig formatering baserad på formeln som i det föregående exemplet, med den enda skillnaden att du ersätter>1 i slutet av formeln med det önskade numret. Till exempel:

Om du vill markera 3:e och alla efterföljande dubbletter skapar du en regel för villkorlig formatering baserad på den här formeln:

=COUNTIF($A$2:$A2,$A2)>=3

För att skugga den fjärde och alla efterföljande dubblettposter använder du denna formel:

=COUNTIF($A$2:$A2,$A2)>=4

Om du bara vill markera specifika förekomster använder du är lika med Om du till exempel vill markera endast andra instanser, skulle du använda följande formel:

=COUNTIF($A$2:$A2,$A2)=2

Hur man markerar dubbletter i ett intervall (flera kolumner)

När du vill kontrollera om det finns dubbletter i flera kolumner, inte genom att jämföra kolumnerna med varandra, utan genom att hitta alla förekomster av samma objekt i alla kolumner, använder du en av följande lösningar.

Markera dubbletter i flera kolumner inklusive första förekomsten

Om det första exemplet av ett objekt som förekommer mer än en gång i datamängden anses vara en dubblett är det lättaste sättet att använda Excels inbyggda regel för dubbletter.

Du kan också skapa en regel för villkorlig formatering med den här formeln:

Om du till exempel vill markera dubbletter i intervallet A2:C8 går formeln till på följande sätt:

=COUNTIF($A$2:$C$8, A2)>1

Observera att du använder absoluta cellreferenser för intervallet ($A$2:$C$8) och relativa referenser för den översta cellen (A2).

Markera dubbletter i flera kolumner utom 1:a förekomsten

Lösningen för detta scenario är mycket svårare, inte undra på att Excel inte har någon inbyggd regel för detta :)

För att markera dubbla poster i flera kolumner och ignorera de första förekomsterna måste du skapa två regler med följande formler:

Regel 1. Gäller för den första kolumnen

Här använder du exakt samma formel som vi använde för att markera dubbletter utan 1:a förekomst i en kolumn (de detaljerade stegen finns här).

I det här exemplet skapar vi en regel för A2:A8 med den här formeln:

=COUNTIF($A$2:$A2,$A2)>1

Resultatet är att de dubbletter som inte har första förekomsten markeras i den vänstra kolumnen i intervallet (i vårt fall finns det bara en sådan post):

Regel 2. Gäller för alla efterföljande kolumner.

Om du vill markera dubbletter i de återstående kolumnerna (B2:C8) använder du den här formeln:

=COUNTIF(A$2:$A$8,B2)+COUNTIF(B$2:B2,B2)>1

I formeln ovan räknar den första COUNTIF-funktionen förekomsterna av ett visst objekt i den första kolumnen, och den andra COUNTIF-funktionen gör detsamma för alla efterföljande kolumner. Sedan adderar du dessa siffror och kontrollerar om summan är större än 1.

Resultatet är att alla duplicerade objekt utom deras första förekomst hittas och markeras:

Markera dubbletter i alla kolumner med en enda regel

En annan möjlig lösning är att lägga till en tom kolumn till vänster om datasetet och kombinera ovanstående formler till en enda formel, till exempel så här:

=IF(COLUMNS($B2:B2)>1,COUNTIF(A$2:$B$8,B2),0) + COUNTIF(B$2:B2,B2)>1

Där B2 är den översta cellen med data i den andra kolumnen i målområdet.

För att bättre förstå formeln kan vi dela upp den i två huvuddelar:

• För den första kolumnen (B) uppfylls aldrig IF-villkoret, så endast den andra COUNTIF-funktionen beräknas (vi har använt den här formeln för att hitta dubbletter utom första förekomsten i en kolumn).
• För alla efterföljande kolumner (C2:D8) är den viktigaste punkten den smarta användningen av absoluta och relativa referenser i de två COUNTIF-funktionerna. För att göra det lättare att förstå har jag kopierat den till kolumn G, så att du kan se hur formeln ändras när den tillämpas på andra celler:

Eftersom IF-villkoret alltid är sant för alla kolumner utom den första (antalet kolumner är större än 1), fortsätter formeln på detta sätt:

• Räknar antalet förekomster av ett visst objekt (D5 i skärmbilden ovan) i alla kolumner till vänster om den aktuella kolumnen: COUNTIF(B$2:$C$8,D5)
• Räknar antalet förekomster av ett visst objekt i objektets kolumn, upp till objektets cell: COUNTIF(D$2:D5,D5)
• Slutligen adderar formeln resultaten av de båda COUNTIF-funktionerna. Om det totala antalet är större än 1, dvs. om det finns mer än en förekomst av objektet, tillämpas regeln och objektet markeras.

Markera hela rader baserat på dubbla värden i en kolumn

Om din tabell innehåller flera kolumner kan du vilja markera hela rader baserat på dubbletter i en specifik kolumn.

Som du redan vet fungerar Excels inbyggda regel för dubbletter endast på cellnivå. Men en anpassad formelbaserad regel har inga problem med att skugga rader. Det viktigaste är att välja hela rader och skapa sedan en regel med en av följande formler:

• Markera dubbla rader utom första förekomsten :

=COUNTIF($A$2:$A2, $A2)>1

=COUNTIF($A$2:$A$15, $A2)>1

Där A2 är den första cellen och A15 är den senast använda cellen i den kolumn som du vill kontrollera om det finns dubbletter. Som du ser är det den smarta användningen av absoluta och relativa cellreferenser som gör skillnad.

Följande skärmdump visar hur båda reglerna fungerar:

Hur man markerar dubbla rader i Excel

I det föregående exemplet har vi visat hur du kan färglägga hela rader baserat på dubbla värden i en specifik kolumn. Men vad händer om du vill visa rader som har identiska värden i flera kolumner? Eller hur markerar du absoluta dubblettrader, de som har helt lika värden i alla kolumner?

Använd COUNTIFS-funktionen som gör det möjligt att jämföra celler med hjälp av flera kriterier. Om du till exempel vill lyfta fram dubbla rader som har identiska värden i kolumnerna A och B kan du använda en av följande formler:

• Markera dubbla rader utom vid första förekomsten :

=COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)>1

=COUNTIFS($A$2:$A$15, $A2, $B$2:$B$15, $B2)>1

Följande skärmdump visar resultatet:

Som du förstår är exemplet ovan endast i demonstrationssyfte. När du markerar dubbla rader i dina riktiga ark är du naturligtvis inte begränsad till att jämföra värden i två kolumner, utan COUNTIFS-funktionen kan behandla upp till 127 intervall/kriteriepar.

Markera på varandra följande dubblettceller i Excel

Ibland behöver du kanske inte markera alla dubbletter i en kolumn utan bara visa på varandra följande dubblettceller, dvs. de som ligger bredvid varandra. För att göra detta markerar du cellerna med data (exklusive kolumnrubriken) och skapar en regel för villkorlig formatering med en av följande formler:

• Markera på varandra följande dubbletter utan 1:a förekomst :

=$A1=$A2

=OR($A1=$A2, $A2=$A3)

Följande skärmdump visar hur du markerar på varandra följande dubbla texter, men dessa regler fungerar även för på varandra följande dubbla nummer och datum:

Om ditt Excel-ark kan ha tomma rader och du inte vill att de tomma cellerna i följd ska markeras, gör följande förbättringar i formlerna:

• Markera på varandra följande dubblettceller utan 1:a förekomst och ignorera tomma celler :

=AND($A2"", $A1=$A2)

=AND($A2"", OR($A1=$A2, $A2=$A3))

Som du ser är det ingen stor sak att markera dubbletter i Excel med hjälp av villkorlig formatering. Det finns dock ett snabbare och enklare sätt att göra det på. För att ta reda på det, läs nästa avsnitt i den här handledningen.

Hur man markerar dubbletter i Excel med Duplicate Remover

Tillägget Duplicate Remover är en allt-i-ett-lösning för att hantera dubbla poster i Excel. Det kan hitta, markera, välja, kopiera eller flytta dubbla celler eller hela dubbla rader.

Trots sitt namn kan tillägget snabbt och enkelt markera dubbletter i olika färger utan att radera dem.

Duplicate Remover lägger till 3 nya funktioner i Excel-bandet:

• Dedupe-tabell - för att omedelbart hitta och markera dubbletter i en tabell.
• Duplicate Remover - Steg-för-steg-guiden med avancerade alternativ för att identifiera och markera dubbletter eller unika värden i en tabell.
• Jämför 2 tabeller - hitta och markera dubbletter genom att jämföra två kolumner eller två separata tabeller.

När du har installerat Ultimate Suite for Excel hittar du dessa verktyg i Uppgifter om Ablebits på fliken Dedupe grupp:

Markera dubbletter i Excel med några få klick

I det här exemplet har jag skapat följande tabell med några hundra rader, och vårt mål är att markera dubbla rader som har samma värden i alla tre kolumnerna:

Tro det eller ej, du kan få önskat resultat med bara 2 musklick :)

1. När du har markerat en cell i tabellen klickar du på Dedupe-tabell knappen, så tar det smarta tillägget upp hela tabellen.
2. Dedupe-tabell öppnas med alla kolumnerna valda automatiskt, och Färgdubbletter är valt som standard. Så allt du behöver göra är att klicka på OK :) Klart!

Tips: Om du vill upptäcka dubbletter av en eller flera kolumner avmarkerar du alla irrelevanta kolumner och låter endast nyckelkolumnen/kolumnerna vara markerade.

Resultatet skulle se ut ungefär så här:

Som du ser i bilden ovan har verktyget Dupe Table markerat dubbla rader. utan att först ha varit i ett fall. .

Om du vill markera dubbletter inklusive de första förekomsterna , eller om du vill färglägga unika poster snarare än dubbletter, eller om du inte gillar den röda standardfärgen, använd då Duplicate Remover-guiden som har alla dessa funktioner och många fler.

Markera dubbletter i Excel med hjälp av en avancerad steg-för-steg-guide

Jämfört med swift Dedupe-tabell verktyget, den Duplicate Remover wizard kräver några fler klick, men det kompenseras med ett antal ytterligare alternativ. Låt mig visa dig hur det fungerar:

1. Markera en cell i tabellen där du vill markera dubbletter och klicka på Duplicate Remover på bandet. Guiden körs och hela tabellen väljs. Tillägget föreslår också att du skapar en säkerhetskopia av tabellen, för säkerhets skull. Om du inte behöver det, avmarkera den rutan.

   Kontrollera att tabellen har valts korrekt och klicka på Nästa .

   

2. Välj en av följande datatyper som du vill hitta:
   • Duplikat utom första förekomsten
   • Duplikat med 1:a förekomst
   • Unika värden
   • Unika värden och 1:a dubbla förekomster

   För detta exempel kan vi hitta följande Duplikat + 1:a förekomst :

   

3. Välj nu de kolumner som ska kontrolleras för dubbletter. Eftersom vi vill markera fullständiga dubblettrader har jag valt alla tre kolumnerna.

Dessutom kan du ange om tabellen har rubriker och om du vill hoppa över tomma celler. Båda alternativen är valda som standard.

Sedan i dag utforskar vi olika sätt att markera dubbletter i Excel, är vårt val uppenbart :) Så, välj Fyll med färg och välj en av standardfärgerna, eller klicka på Fler färger... och välj en anpassad RGB- eller HSL-färg.

Klicka på Slutförande knappen och njut av resultatet :)

Så här markerar du dubbletter i Excel med hjälp av vårt tillägg Duplicate Remover. Om du är nyfiken på att prova det här verktyget på dina egna kalkylblad är du välkommen att ladda ner en fullt fungerande testversion av Ultimate Suite som innehåller alla våra tidsbesparande verktyg för Excel. Och din feedback i kommentarerna kommer att vara mycket uppskattad!