I den här artikeln får du lära dig olika sätt att sammanfoga textsträngar, siffror och datum i Excel med hjälp av CONCATENATE-funktionen och "&"-operatorn. Vi kommer också att diskutera formler för att kombinera enskilda celler, kolumner och intervall.

I dina Excel-arbetsböcker är data inte alltid strukturerade enligt dina behov. Ofta vill du dela upp innehållet i en cell i enskilda celler eller göra tvärtom - kombinera data från två eller flera kolumner till en enda kolumn. Vanliga exempel är att sammanfoga namn och adressdelar, kombinera text med ett formeldrivet värde, visa datum och tidpunkter i önskat format, för att nämna några exempel.

I den här handledningen kommer vi att utforska olika tekniker för Excel-strängförlängning, så att du kan välja den metod som passar bäst för dina kalkylblad.

Vad är "concatenate" i Excel?

Det finns två sätt att kombinera data i Excel-kalkylblad:

• Sammanslagning av celler
• Samkörning av cellvärden

När du sammanfoga celler sammanfogar du "fysiskt" två eller flera celler till en enda cell. Resultatet är en större cell som visas på flera rader och/eller kolumner.

När du sammanfoga celler i Excel, kombinerar du bara de innehåll med andra ord är concatenation i Excel en process för att sammanfoga två eller flera värden. Denna metod används ofta för att kombinera några textstycken som finns i olika celler (tekniskt sett kallas dessa för textsträngar eller helt enkelt strängar ) eller infoga ett formelberäknat värde mitt i en text.

Följande skärmdump visar skillnaden mellan dessa två metoder:

Att slå ihop celler i Excel är ämnet för en separat artikel, och i den här handledningen diskuterar vi de två viktigaste sätten att sammanfoga strängar i Excel - genom att använda funktionen CONCATENATE och sammanfogningsoperatorn (&).

Excel CONCATENATE-funktionen

Funktionen CONCATENATE i Excel används för att sammanfoga olika textstycken eller kombinera värden från flera celler i en cell.

Syntaxen för Excel CONCATENATE är följande:

Var text är en textsträng, en cellreferens eller ett formeldrivet värde.

Funktionen CONCATENATE stöds i alla versioner av Excel 365 - 2007.

Om du till exempel vill sammanfoga värdena B6 och C6 med ett kommatecken är formeln följande:

=CONCATENATE(B6, ",", C6)

Fler exempel visas i bilden nedan:

Observera: I Excel 365 - Excel 2019 finns också funktionen CONCAT, som är en modern efterföljare till CONCATENATE med exakt samma syntax. Även om CONCATENATE-funktionen behålls för bakåtkompatibilitet lovar Microsoft inte att den kommer att stödjas i framtida versioner av Excel.

Användning av CONCATENATE i Excel - saker att komma ihåg

För att se till att dina CONCATENATE-formler alltid ger rätt resultat ska du komma ihåg följande enkla regler:

• Excel CONCATENATE-funktionen kräver minst ett argument "text" för att fungera.
• I en formel kan du sammanfoga upp till 255 strängar, totalt 8 192 tecken.
• Resultatet av funktionen CONCATENATE är alltid en textsträng, även om alla källvärden är siffror.
• Till skillnad från CONCAT-funktionen känner Excel CONCATENATE inte igen matriser. Varje cellreferens måste listas separat. Du bör till exempel använda CONCATENATE(A1, A2, A3) och inte CONCATENATE(A1:A3).
• Om något av argumenten är ogiltigt returnerar CONCATENATE-funktionen ett #VALUE!-fel.

Operatören "&" för att sammanfoga strängar i Excel

I Microsoft Excel är ampersandtecknet (&) ett annat sätt att sammanfoga celler. Den här metoden är mycket praktisk i många situationer eftersom det går mycket snabbare att skriva ett ampersand än att skriva ordet "sammanfoga" :)

Om du till exempel vill sammanfoga två cellvärden med ett mellanslag emellan är formeln:

=A2&" "&B2

Hur man sammanfogar i Excel - exempel på formler

Nedan hittar du några exempel på hur du kan använda funktionen CONCATENATE i Excel.

Sammanfoga två eller flera celler utan separator

För att kombinera värdena för två celler till en, använder du concatenationsformeln i sin enklaste form:

=CONCATENATE(A2, B2)

Eller

=A2&B2

Observera att värdena kommer att sammanfogas utan någon avgränsare som i skärmdumpen nedan.

För att sammanfoga flera celler måste du ange varje cellreferens individuellt, även om du kombinerar sammanhängande celler:

=CONCATENATE(A2, B2, C2)

Eller

=A2&B2&C2

Formlerna fungerar för både text och siffror. När det gäller siffror ska du komma ihåg att resultatet är en textsträng. Om du vill konvertera den till en siffra multiplicerar du bara CONCATENATEs resultat med 1 eller lägger till 0. Till exempel:

=CONCATENATE(A2, B2)*1

Tips: I Excel 2019 och senare kan du använda funktionen CONCAT för att snabbt sammanfoga flera celler med hjälp av en eller flera intervallreferenser.

Sammanfoga celler med ett mellanslag, ett kommatecken eller en annan avgränsare.

I dina kalkylblad kan du ofta behöva sammanfoga värden på ett sätt som inkluderar kommatecken, mellanslag, olika skiljetecken eller andra tecken som bindestreck eller snedstreck. För att göra detta sätter du helt enkelt in det önskade tecknet i din sammanfogningsformel. Kom ihåg att sätta tecknet inom citationstecken, vilket visas i följande exempel.

Sammanfoga två celler med en utrymme :

=CONCATENATE(A2, " ", B2)

eller .

=A2 & " " & B2

Sammanfoga två celler med en kommatecken :

=CONCATENATE(A2, ", ", B2)

eller .

=A2 & ", " & B2

Sammanfoga två celler med en bindestreck :

=CONCATENATE(A2, "-", B2)

eller .

=A2 & "-" & B2

Följande skärmdump visar hur resultaten kan se ut:

Tips: I Excel 2019 och senare kan du använda TEXTJOIN-funktionen för att sammanfoga strängar från flera celler med valfri avgränsare som du anger.

Sammanfoga textsträng och cellvärde

Det finns ingen anledning till att Excel-funktionen CONCATENATE bara är begränsad till att sammanfoga cellvärden. Du kan också använda den för att kombinera textsträngar för att göra resultatet mer meningsfullt. Till exempel:

=CONCATENATE(A2, " ", B2, " avslutad")

Formeln ovan informerar användaren om att ett visst projekt är avslutat, som i rad 2 i skärmdumpen nedan. Observera att vi lägger till ett mellanslag före ordet "avslutat" för att skilja de sammanlänkade textsträngarna åt. Ett mellanslag (" ") läggs också in mellan de sammanlänkade värdena, så att resultatet visas som "Projekt 1" i stället för "Projekt1".

Med hjälp av concatenation-operatorn kan formeln skrivas på följande sätt:

=A2 & " " & B2 & " avslutad"

På samma sätt kan du lägga till en textsträng i början eller i mitten av din sammanlänkningsformel, till exempel:

=CONCATENATE("Se ", A2, " " ", B2)

="Se " & A2 & " " " & B2

Sammanfoga textsträng och en annan formel

Om du vill göra resultatet som returneras av en formel mer begripligt för användarna kan du sammanfoga det med en textsträng som förklarar vad värdet egentligen är.

Du kan till exempel använda följande formel för att få tillbaka det aktuella datumet i önskat format och ange vilken typ av datum det är:

=CONCATENATE("Idag är det ",TEXT(TODAY(), "mmmm d, yyyy"))

="Idag är det " & TEXT(TODAY(), "dd-mmm-yy")

Tips: Om du vill ta bort källdata utan att påverka de resulterande textsträngarna kan du använda alternativet "Klistra in special - endast värden" för att konvertera formlerna till deras värden.

Sammanfoga textsträngar med radbrytningar

Oftast separerar du de resulterande textsträngarna med skiljetecken och mellanslag, som i det föregående exemplet. I vissa fall kan det dock vara nödvändigt att separera värdena med en radbrytning eller en vändtecken. Ett vanligt exempel är att slå samman postadresser från uppgifter i separata kolumner.

Ett problem är att du inte bara kan skriva in ett radbrytande tecken i formeln som ett vanligt tecken, utan du måste använda CHAR-funktionen för att ange motsvarande ASCII-kod i formeln för sammanlänkning:

• I Windows använder du CHAR(10) där 10 är teckenkoden för Linjedragning .
• På Mac använder du CHAR(13) där 13 är teckenkoden för Vändtecken .

I det här exemplet har vi adressdelarna i kolumnerna A till F, och vi sammanfogar dem i kolumn G med hjälp av sammanfogningsoperatorn "&". De sammanfogade värdena separeras med ett kommatecken (", "), ett mellanslag (" ") och ett radbrytningstecken CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

CONCATENATE-funktionen skulle se ut på följande sätt:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", ", E2, " ", F2)

Resultatet blir i vilket fall som helst en textsträng på tre rader: Observera: När du använder radbrytningar för att separera de kombinerade värdena måste du ha Wrap text aktiverat för att resultatet ska visas korrekt. För att göra detta trycker du på Ctrl + 1 för att öppna Formatera celler dialogrutan, växla till den Anpassning och kontrollerar Omslag av text box.

På samma sätt kan du separera slutsträngar med andra tecken, t.ex:

• Dubbla citationstecken (") - CHAR(34)
• Skråstreck (/) - CHAR(47)
• Asterisk (*) - CHAR (42)
• Den fullständiga förteckningen över ASCII-koder finns här.

Hur man sammanfogar kolumner i Excel

Om du vill sammanfoga två eller flera kolumner skriver du bara in din sammanfogningsformel i den första cellen och kopierar den sedan ner till andra celler genom att dra i fyllningshandtaget (den lilla fyrkanten som visas i det nedre högra hörnet av den valda cellen).

Om du till exempel vill kombinera två kolumner (kolumn A och B) och avgränsa värdena med ett mellanslag, är formeln i C2 kopierad ner:

=CONCATENATE(A2, " ", B2)

Eller

= A2 & " " & B2 Tips: Ett snabbt sätt att kopiera formeln ner i kolumnen är att markera cellen med formeln och dubbelklicka på fyllningshandtaget.

För mer information, se Hur du slår ihop två kolumner i Excel utan att förlora data.

Kombinera text och siffror genom att behålla formateringen

När du sammanfogar en textsträng med ett tal, en procentsats eller ett datum kan det hända att du vill behålla den ursprungliga formateringen av ett numeriskt värde eller visa det på ett annat sätt. Detta kan du göra genom att ange formatkoden i TEXT-funktionen, som du bäddar in i en sammanfogningsformel.

I början av den här handledningen har vi redan diskuterat en formel som sammanfogar text och datum.

Och här är ytterligare några exempel på formler som kombinerar text och nummer :

Tal med 2 decimaler och $-tecknet:

=A2 & " " & TEXT(B2, "$#,#0.00")

Tal utan obetydliga nollor och $-tecknet:

=A2 & " " & TEXT(B2, "0.#")

Bråttal:

=A2 & " " & TEXT(B2, "# ?/????")

För att sammanfoga text och procentsatser är formlerna:

Procent med två decimaler:

=A12 & " " & TEXT(B12, "0,00%")

Avrundad hel procent:

=A12 & " " & TEXT(B12, "0%")

Hur man sammanfogar ett antal celler i Excel

Att kombinera värden från flera celler kan kräva en viss ansträngning eftersom Excel-funktionen CONCATENATE inte accepterar matriser.

Om du vill sammanfoga flera celler, till exempel A1 till A4, måste du använda en av följande formler:

=CONCATENATE(A1, A2, A3, A4)

eller .

=A1 & A2 & A3 & A4

När du kombinerar en ganska liten grupp av celler är det ingen stor grej att skriva in alla referenser. Ett stort intervall skulle vara tråkigt att tillhandahålla, genom att skriva in varje enskild referens manuellt. Nedan hittar du tre metoder för snabb sammankoppling av intervall i Excel.

Metod 1. Tryck på CTRL för att välja flera celler.

Om du snabbt vill markera flera celler kan du hålla ned Ctrl-tangenten medan du klickar på varje cell som du vill inkludera i formeln. Här är de detaljerade stegen:

1. Välj en cell där du vill skriva in formeln.
2. Skriv =CONCATENATE( i den cellen eller i formellfältet.
3. Håll ned Ctrl och klicka på varje cell som du vill sammanfoga.
4. Släpp Ctrl-knappen, skriv den avslutande parentesen och tryck på Enter .

Metod 2. Använd TRANSPOSE-funktionen för att få fram alla cellvärden.

När ett intervall består av tiotals eller hundratals celler kanske den tidigare metoden inte är tillräckligt snabb eftersom den kräver att du klickar på varje cell. I det här fallet kan du använda funktionen TRANSPOSE för att returnera en matris av värden och sedan slå ihop dem i ett enda svep.

1. I den cell där du vill att resultatet ska visas anger du formeln TRANSPOSE, till exempel:

   =TRANSPOSE(A1:A10)

2. Tryck på F9 i formellfältet för att ersätta formeln med beräknade värden. Resultatet blir en matris med värden som ska sammanfogas.
3. Ta bort de parenteser som omger matrisen.
4. Skriv =CONCATENATE( före det första värdet, skriv sedan den avslutande parentesen efter det sista värdet och tryck på Enter .

Observera: Resultatet av denna formel är statisk eftersom den sammanfogar värdena, inte cellreferenser. Om källdata ändras måste du upprepa processen.

Metod 3. Använd CONCAT-funktionen

I Excel 365 och Excel 2021 kan den här enkla formeln sammanfoga ett antal celler på ett ögonblick:

=CONCAT(A1:A10)

Metod 4. Använd tilläggsmodulen Slå samman celler

Ett snabbt och formelfritt sätt att sammanfoga alla intervall i Excel är att använda tillägget Merge Cells med tillägget " Slå ihop alla områden i urvalet "är avstängd, vilket visas i Kombinera värden från flera celler i en cell.

Excel-operatorn "&" vs. CONCATENATE-funktionen

Många användare undrar vilket sätt som är effektivast för att sammanfoga strängar i Excel - CONCATENATE-funktionen eller "&"-operatorn.

Den enda verkliga skillnaden är att CONCATENATE-funktionen har en begränsning på 255 strängar och att det inte finns någon sådan begränsning när du använder ampersand. I övrigt finns det ingen skillnad mellan de två metoderna, och det finns inte heller någon hastighetsskillnad mellan CONCATENATE- och "&"-formlerna.

Eftersom 255 är ett riktigt stort tal och du knappast behöver kombinera så många strängar i ditt arbete, handlar skillnaden om komfort och användarvänlighet. Vissa användare tycker att CONCATENATE-formlerna är lättare att läsa, men jag föredrar att använda "&"-metoden. Så håll dig till den teknik som du känner dig mest bekväm med.

Motsatsen till CONCATENATE i Excel (dela celler)

Motsatsen till concatenate i Excel är att dela upp innehållet i en cell i flera celler. Detta kan göras på några olika sätt:

• Funktion för text till kolumner
• Alternativet Flash Fill i Excel 2013 och senare
• Funktionen TEXTSPLIT i Excel 365
• Anpassade formler för att dela upp celler (MID, RIGHT, LEFT, etc.)

Du kan också hitta användbar information i den här artikeln: Hur du tar bort sammanfogning av celler i Excel.

Sammanfoga i Excel med tilläggsmodulen Merge Cells

Med tillägget Merge Cells i Ultimate Suite for Excel kan du effektivt göra båda sakerna:

• Slå ihop flera celler till en utan att förlora data.
• Sammanfoga värdena från flera celler i en enda cell och separera dem med valfri avgränsare.

Verktyget Merge Cells fungerar med alla Excel-versioner från 2016 till 365 och kan kombinera alla datatyper, inklusive textsträngar, siffror, datum och specialsymboler. De två viktigaste fördelarna är enkelhet och snabbhet - alla sammanfogningar görs med ett par klick.

Kombinera värden från flera celler i en cell

Om du vill kombinera innehållet i flera celler väljer du det område som ska sammanfogas och konfigurerar följande inställningar:

• Under Vad ska man slå ihop? , välj Celler till en enda .
• Under Kombinera med , skriv in avgränsare (i vårt fall ett kommatecken och ett mellanslag).
• Välj var du vill placera resultatet.
• Viktigast av allt är att avmarkera krysset Slå ihop alla områden i urvalet Det är detta alternativ som styr om cellerna ska slås ihop eller om deras värden ska sammanfogas.

Kombinera kolumner rad för rad

Om du vill sammanfoga två eller flera kolumner konfigurerar du inställningarna för Sammanfoga celler på liknande sätt, men väljer att sammanfoga kolumner till en kolumn och placera resultaten i den vänstra kolumnen.

Sammanfoga rader kolumn för kolumn

Om du vill kombinera data i varje enskild rad, kolumn för kolumn, väljer du:

• Slå ihop rader till en enda .
• Använd en radbrytning för avgränsaren.
• Placera resultaten i översta raden .

Resultatet kan se ut ungefär så här:

För att kontrollera hur tillägget Merge Cells klarar av dina datamängder kan du ladda ner en fullt fungerande testversion av vår Ultimate Suite for Excel nedan.

Så här gör du för att sammanfoga i Excel. Tack för att du läste och hoppas att vi ses på vår blogg nästa vecka!

Tillgängliga nedladdningar

Exempel på formler för sammanlänkning (.xlsx-fil)

Ultimate Suite 14-dagars testversion (.exe-fil)