Opplæringen viser noen få raske og enkle måter å trimme Excel-mellomrom. Lær hvordan du fjerner innledende, etterfølgende og ekstra mellomrom mellom ord, hvorfor Excel TRIM-funksjonen ikke fungerer og hvordan du fikser det.

Sammenligner du to kolonner for duplikater som du vet er der, men finner ikke formlene dine en enkelt duplikatoppføring? Eller legger du sammen to kolonner med tall, men får bare nuller? Og hvorfor i all verden returnerer din åpenbart korrekte Vlookup-formel bare en haug med N/A-feil? Dette er bare noen få eksempler på problemer som du kanskje søker svar på. Og alle er forårsaket av at ekstra mellomrom skjuler seg før, etter eller mellom numeriske og tekstverdier i cellene dine.

Microsoft Excel tilbyr noen forskjellige måter å fjerne mellomrom og rydde opp i dataene dine. I denne opplæringen skal vi undersøke mulighetene til TRIM-funksjonen som den raskeste og enkleste måten å slette mellomrom i Excel.

TRIM-funksjon - fjern ekstra mellomrom i Excel

Du bruker TRIM-funksjonen i Excel fjerner ekstra mellomrom fra tekst. Den sletter alle innledende, etterfølgende og mellomrom bortsett fra et enkelt mellomrom -tegn mellom ordene.

Syntaksen til TRIM-funksjonen er den enkleste man kan forestille seg:

TRIM( tekst)

Hvor tekst er en celle du vil fjerne overflødige mellomrom fra.

For å fjerne mellomrom i celle A1, bruker du for eksempel denneformel:

=TRIM(A1)

Og følgende skjermbilde viser resultatet:

Ja, så enkelt er det!

Vær oppmerksom på at TRIM-funksjonen ble designet for å fjerne bare mellomromstegnet, som har verdi 32 i 7-bits ASCII-kodesystemet. Hvis dataene dine i tillegg til ekstra mellomrom inneholder linjeskift og tegn som ikke skrives ut, bruk TRIM-funksjonen i kombinasjon med CLEAN for å slette de første 32 tegnene som ikke skrives ut i ASCII-systemet.

For å f.eks. fjern mellomrom, linjeskift og andre uønskede tegn fra celle A1, bruk denne formelen:

=TRIM(CLEAN(A1))

For mer informasjon, se Hvordan fjerne tegn som ikke skrives ut i Excel

For å kvitte seg med ikke-brytende mellomrom (html-tegn ), som har verdi 160, bruk TRIM sammen med SUBSTITUTE- og CHAR-funksjoner:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

For fullstendige detaljer, vennligst se Hvordan slette ikke-brytende mellomrom i Excel

Hvordan bruke TRIM-funksjonen i Excel - formeleksempler

Nå som du vet det grunnleggende, la oss diskutere noen spesifikke bruksområder for TRIM i Excel, fallgruver du kan møte og fungerende løsninger.

Hvordan trimme mellomrom i en hel kolonne med data

Forutsatt at du har en kolonne med navn som også har mellomrom før og etter teksten som mer enn ett mellomrom mellom ordene. Så, hvordan fjerner du alle innledende, etterfølgende og overflødige mellomrom i alle celler om gangen? Ved å kopiere en ExcelTRIM formel over kolonnen, og erstatter deretter formler med verdiene deres. De detaljerte trinnene følger nedenfor.

1. Skriv en TRIM-formel for den øverste cellen, A2 i vårt eksempel:

   =TRIM(A2)

2. Plasser markøren til nedre høyre hjørne av formelcellen (B2 i dette eksemplet), og så snart markøren blir til plusstegnet, dobbeltklikker du den for å kopiere formelen nedover i kolonnen, opp til den siste cellen med data. Som et resultat vil du ha 2 kolonner - originale navn med mellomrom og formeldrevne trimmede navn.

Til slutt erstatter du verdiene i den opprinnelige kolonnen med trimmet data. Men vær forsiktig! Bare å kopiere den trimmede kolonnen over den originale kolonnen ville ødelegge formlene dine. For å forhindre at dette skjer, må du bare kopiere verdier, ikke formler. Slik gjør du:

• Velg alle celler med Trim-formler (B2:B8 i dette eksemplet), og trykk Ctrl+C for å kopiere dem.
• Velg alle celler med originaldata (A2:A8) ), og trykk Ctrl+Alt+V og deretter V . Det er snarveien for lim inn verdier som bruker Lim inn spesielle > verdier
• Trykk på Enter-tasten. Ferdig!

Hvordan fjerne innledende mellomrom i en numerisk kolonne

Som du nettopp har sett, fjernet Excel TRIM-funksjonen alle ekstra mellomrom fra en kolonne med tekstdata uten et stikk. Men hva om dataene dine er tall, ikke tekst?

Ved første øyekast kan det virke som omTRIM-funksjonen har gjort jobben sin. Ved en nærmere titt vil du imidlertid legge merke til at de trimmede verdiene ikke oppfører seg som tall. Her er bare noen få indikasjoner på unormalitet:

• Både den opprinnelige kolonnen med innledende mellomrom og trimmede tall er venstrejustert selv om du bruker tallformatet på cellene, mens normale tall er høyrejustert som standard.
• Når to eller flere celler med trimmede tall er valgt, viser Excel kun COUNT i statuslinjen. For tall skal den også vise SUM og GJENNOMSNITT.
• En SUM-formel brukt på de trimmede cellene returnerer null.

Fra alle visninger, de trimmede verdiene er tekststrenger , mens vi vil ha tall. For å fikse dette, kan du multiplisere de trimmede verdiene med 1 (for å multiplisere alle verdiene med ett slag, bruk alternativet Paste Special> Multiply).

En mer elegant løsning er å omslutte TRIM-funksjonen i VALUE , som dette:

=VALUE(TRIM(A2))

Formelen ovenfor fjerner alle innledende og etterfølgende mellomrom, hvis noen, og gjør den resulterende verdien til et tall, som vist på skjermbildet nedenfor:

Hvordan fjerne kun innledende mellomrom i Excel (Venstre trim)

I noen situasjoner kan du skrive dupliserte og til og med tredoblede mellomrom mellom ord for å gjøre dataene dine bedre lesbare. Du ønsker imidlertid å bli kvitt ledende mellomrom, som dette:

Som du allerede vet, TRIM-funksjoneneliminerer ekstra mellomrom i midten av tekststrenger, noe som ikke er det vi ønsker. For å holde alle mellomrom intakte, bruker vi en litt mer kompleks formel:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

I formelen ovenfor beregner kombinasjonen FIND, MID og TRIM posisjonen til det første teksttegnet i en streng. Og så oppgir du det tallet til en annen MID-funksjon slik at den returnerer hele tekststrengen (strenglengden beregnes av LEN) fra posisjonen til det første teksttegnet.

Følgende skjermbilde viser at alle innledende mellomrom er borte, mens flere mellomrom mellom ord fortsatt er der:

Som en prikken over i-en, erstatt den opprinnelige teksten med de trimmede verdiene, som vist i trinn 3 i Trim-formeleksemplet , og du er klar!

Tips. Hvis du også vil fjerne mellomrom fra slutten av cellene, bruk Trim Spaces-verktøyet. Det er ingen åpenbar Excel-formel for å fjerne innledende og etterfølgende mellomrom og holde flere mellomrom mellom ordene intakte.

Hvordan telle ekstra mellomrom i en celle

Noen ganger, før du fjerner mellomrom i Excel-arket, vil du kanskje vite hvor mange overflødige mellomrom som faktisk er der.

For å få tallet av ekstra mellomrom i en celle, finn ut den totale tekstlengden ved hjelp av LEN-funksjonen, beregn deretter strenglengden uten ekstra mellomrom, og trekk sistnevnte fra førstnevnte:

=LEN(A2)-LEN(TRIM(A2))

Følgendeskjermbilde viser formelen ovenfor i aksjon:

Merk. Formelen returnerer antallet ekstra mellomrom i en celle, dvs. innledende, etterfølgende, og mer enn ett påfølgende mellomrom mellom ord, men den teller ikke enkeltrom i midten av teksten. Hvis du ønsker å få det totale antallet mellomrom i en celle, bruk denne erstatningsformelen.

Hvordan markere celler med overflødig mellomrom

Når du arbeider med sensitiv eller viktig informasjon, kan du være nølende med å slette noe uten å se nøyaktig hva du sletter. I dette tilfellet kan du først utheve celler som inneholder ekstra mellomrom, og deretter trygt eliminere disse mellomrommene.

For å gjøre dette, lag en betinget formateringsregel med følgende formel:

=LEN($A2)>LEN(TRIM($A2))

Hvor A2 er den øverste cellen med data du vil markere.

Formelen instruerer Excel til å utheve celler der den totale strenglengden er større enn lengden på den trimmede teksten.

For å lage en betinget formateringsregel, velg alle cellene (radene) du vil markere uten kolonneoverskrifter, gå til Hjem -fanen > Stiler -gruppen, og klikk Betinget formatering > Ny regel > Bruk en formel for å bestemme hvilke celler som skal formateres .

Hvis du ikke er kjent med Excel betinget formatering ennå , finner du de detaljerte trinnene her: Hvordan lage en betinget formateringsregel basert påformel.

Som vist i skjermbildet nedenfor, samsvarer resultatet perfekt med antallet ekstra mellomrom som vi fikk i forrige eksempel:

Som du ser, er bruken av TRIM-funksjonen i Excel er enkel og grei. Likevel, hvis noen ønsker å se nærmere på formlene som er diskutert i denne opplæringen, er du velkommen til å laste ned Trim Excel Spaces Workbook.

Excel TRIM fungerer ikke

TRIM-funksjonen fjerner bare mellomromstegnet representert av kodeverdi 32 i 7-bit ASCII-tegnsettet. I Unicode-tegnsettet er det enda et mellomromstegn kalt non-breaking space, som vanligvis brukes på nettsider som html-tegnet . Det ubrytende mellomrommet har en desimalverdi på 160, og TRIM-funksjonen kan ikke fjerne det av seg selv.

Så, hvis datasettet ditt inneholder ett eller flere mellomrom som TRIM-funksjonen ikke fjerner, bruk ERSTATT-funksjonen å konvertere ikke-brytende mellomrom til vanlige mellomrom og deretter trimme dem. Forutsatt at teksten er i A1, er formelen som følger:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Som en ekstra forholdsregel kan du bygge inn CLEAN-funksjonen for å rense cellen for alle tegn som ikke kan skrives ut:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Følgende skjermbilde viser forskjellen:

Hvis formlene ovenfor ikke fungerer for deg heller, er sjansen stor for at dataene dine inneholder en spesifikk ikke-utskrift tegnmed andre kodeverdier enn 32 og 160. I dette tilfellet bruker du en av følgende formler for å finne ut tegnkoden, der A1 er en problematisk celle:

Leading space: =CODE(LEFT(A1,1))

Trailing space: =CODE(RIGHT(A1,1))

In-between space (der n er posisjonen til det problematiske tegnet i tekststrengen):

=CODE(MID(A1, n , 1)))

Og så , oppgi den returnerte tegnkoden til TRIM(SUBSTITUTE())-formelen diskutert ovenfor.

For eksempel, hvis CODE-funksjonen returnerer 9, som er Horisontal Tab-tegnet, bruker du følgende formel for å fjerne det:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Trim mellomrom for Excel - fjern ekstra mellomrom med et klikk

Høres ideen om å lære en håndfull forskjellige formler for å håndtere en triviell oppgave latterlig ut? Da vil du kanskje like denne ett-klikks-teknikken for å bli kvitt mellomrom i Excel. La meg introdusere deg til Text Toolkit inkludert i vår Ultimate Suite. Blant annet som å endre store og små bokstaver, dele tekst og slette formatering, tilbyr den alternativet Trim mellomrom .

Med Ultimate Suite installert i Excel, er det så enkelt som dette å fjerne mellomrom i Excel :

1. Velg cellen(e) der du vil slette mellomrom.
2. Klikk Trim mellomrom -knappen på båndet.
3. Velg ett eller alle de følgende alternativene:
   • Trim ledende og etterfølgende mellomrom
   • Trim ekstra mellomrom mellom ord, bortsett fra et enkeltspace
   • Trim ikke-brytende mellomrom ( )
4. Klikk Trim .

Det er alt som skal til! Alle ekstra mellomrom fjernes på et blunk.

I dette eksemplet fjerner vi bare innledende og etterfølgende mellomrom, og holder flere mellomrom mellom ordene intakte for bedre lesbarhet - oppgaven som Excel-formler ikke kan takle, utføres med en museklikk!

Hvis du er interessert i å prøve Trim Spaces i arkene dine, er du velkommen til å laste ned en evalueringsversjon på slutten av dette innlegget.

Jeg takker for at du leser og ser frem til å se deg neste uke. I vår neste veiledning vil vi diskutere andre måter å trimme mellomrom i Excel, følg med!

Tilgjengelige nedlastinger

Trim Excel Spaces - formeleksempler (.xlsx-fil)

Ultimate Suite - prøveversjon (.exe-fil)