Mục lục
Hướng dẫn này trình bày một số cách nhanh chóng và dễ dàng để cắt khoảng trắng trong Excel. Tìm hiểu cách xóa đầu, cuối và khoảng trắng thừa giữa các từ, tại sao hàm TRIM trong Excel không hoạt động và cách khắc phục.
Bạn đang so sánh hai cột để tìm các cột trùng lặp mà bạn biết là có nhưng công thức của bạn không thể tìm thấy một mục trùng lặp duy nhất? Hoặc, bạn đang cộng hai cột số, nhưng vẫn chỉ nhận được số không? Và tại sao công thức Vlookup rõ ràng là chính xác của bạn lại chỉ trả về một loạt lỗi N/A? Đây chỉ là một vài ví dụ về các vấn đề mà bạn có thể đang tìm kiếm câu trả lời. Và tất cả đều do dấu cách thừa ẩn trước, sau hoặc giữa các giá trị số và văn bản trong các ô của bạn.
Microsoft Excel cung cấp một số cách khác nhau để xóa khoảng trắng và làm sạch dữ liệu của bạn. Trong hướng dẫn này, chúng ta sẽ tìm hiểu các khả năng của hàm TRIM như là cách nhanh nhất và dễ dàng nhất để xóa khoảng trắng trong Excel.
Hàm TRIM - xóa khoảng trắng thừa trong Excel
Bạn sử dụng hàm TRIM trong Excel để loại bỏ khoảng trắng thừa khỏi văn bản. Nó xóa tất cả các khoảng trắng ở đầu, ở cuối và ở giữa ngoại trừ một ký tự khoảng trắng giữa các từ.
Cú pháp của hàm TRIM là cú pháp đơn giản nhất mà người ta có thể hình dung:
TRIM( text)Trong đó text là ô mà bạn muốn xóa khoảng trắng thừa.
Ví dụ: để xóa khoảng trắng trong ô A1, bạn sử dụng cách nàycông thức:
=TRIM(A1)
Và ảnh chụp màn hình sau đây cho thấy kết quả:
Vâng, thật đơn giản!
Xin lưu ý rằng hàm TRIM được thiết kế để chỉ xóa ký tự khoảng trắng có giá trị 32 trong hệ thống mã ASCII 7 bit. Nếu ngoài khoảng trắng thừa, dữ liệu của bạn còn chứa dấu ngắt dòng và ký tự không in được, hãy sử dụng hàm TRIM kết hợp với CLEAN để xóa 32 ký tự không in được đầu tiên trong hệ thống ASCII.
Ví dụ: để xóa khoảng trắng, ngắt dòng và các ký tự không mong muốn khác khỏi ô A1, hãy sử dụng công thức sau:
=TRIM(CLEAN(A1))
Để biết thêm thông tin, vui lòng xem Cách xóa các ký tự không in được trong Excel
Để loại bỏ các khoảng trắng không ngắt (ký tự html ), có giá trị 160, hãy sử dụng TRIM cùng với các hàm SUBSTITUTE và CHAR:
=TRIM(SUBSTITUTE(A1, CHAR(160), " "))
Để biết thêm chi tiết, vui lòng xem Cách xóa khoảng trắng không ngắt trong Excel
Cách sử dụng hàm TRIM trong Excel - ví dụ về công thức
Bây giờ bạn đã biết những điều cơ bản, hãy thảo luận về một vài cách sử dụng cụ thể của hàm TRIM trong Excel, những cạm bẫy mà bạn có thể gặp phải và các giải pháp hiệu quả.
Cách cắt khoảng trắng trong toàn bộ cột dữ liệu
Giả sử bạn có một cột tên cũng có một số khoảng trắng trước và sau văn bản càng nhiều hơn một khoảng cách giữa các từ. Vì vậy, làm thế nào để bạn loại bỏ tất cả các khoảng trắng ở đầu, cuối và dư thừa ở giữa trong tất cả các ô cùng một lúc? Bằng cách sao chép một ExcelTRIM trên cột, sau đó thay thế các công thức bằng các giá trị của chúng. Các bước chi tiết thực hiện theo bên dưới.
- Viết công thức TRIM cho ô trên cùng, A2 trong ví dụ của chúng tôi:
=TRIM(A2) - Định vị con trỏ ở góc dưới bên phải của ô công thức (trong ví dụ này là B2) và ngay khi con trỏ biến thành dấu cộng, hãy bấm đúp vào ô đó để sao chép công thức xuống cột, cho đến ô cuối cùng có dữ liệu. Kết quả là bạn sẽ có 2 cột - tên ban đầu có dấu cách và tên được cắt bớt theo công thức.
- Chọn tất cả các ô có công thức Trim (B2:B8 trong ví dụ này) và nhấn Ctrl+C để sao chép chúng.
- Chọn tất cả các ô có dữ liệu gốc (A2:A8 ) và nhấn Ctrl+Alt+V , sau đó nhấn V . Phím tắt dán giá trị áp dụng Dán đặc biệt > Giá trị
- Nhấn phím Enter. Xong!
Cách xóa dấu cách ở đầu cột số
Như bạn vừa thấy, hàm TRIM của Excel đã xóa tất cả khoảng trắng thừa khỏi cột dữ liệu văn bản mà không cần một quá giang. Nhưng nếu dữ liệu của bạn là số chứ không phải văn bản thì sao?
Thoạt nhìn, có vẻ nhưChức năng TRIM đã hoàn thành công việc của nó. Tuy nhiên, khi xem xét kỹ hơn, bạn sẽ nhận thấy rằng các giá trị được cắt xén không hoạt động giống như các con số. Đây chỉ là một vài dấu hiệu của sự bất thường:
- Cả cột ban đầu có khoảng trắng ở đầu và các số được cắt xén đều được căn trái ngay cả khi bạn áp dụng định dạng Số cho các ô, trong khi các số bình thường được căn phải theo mặc định.
- Khi hai hoặc nhiều ô có số bị cắt bớt được chọn, Excel chỉ hiển thị COUNT trên thanh trạng thái. Đối với các số, ô này cũng sẽ hiển thị TỔNG và TRUNG BÌNH.
- Công thức SUM được áp dụng cho các ô đã cắt sẽ trả về 0.
Từ tất cả các lần xuất hiện, các giá trị đã cắt là chuỗi văn bản , trong khi chúng tôi muốn số. Để khắc phục điều này, bạn có thể nhân các giá trị đã cắt với 1 (để nhân tất cả các giá trị trong một lần thực hiện, hãy sử dụng tùy chọn Paste Special > Multiply).
Một giải pháp tinh tế hơn là đặt hàm TRIM trong VALUE , như sau:
=VALUE(TRIM(A2))
Công thức trên xóa tất cả khoảng trắng ở đầu và cuối, nếu có, đồng thời chuyển giá trị kết quả thành một số, như minh họa trong ảnh chụp màn hình bên dưới:
Cách xóa chỉ các khoảng trắng ở đầu trong Excel (Cắt xén bên trái)
Trong một số trường hợp, bạn có thể nhập các khoảng trắng trùng lặp và thậm chí là ba lần giữa các từ để giúp dữ liệu của bạn dễ đọc hơn. Tuy nhiên, bạn muốn loại bỏ khoảng trắng ở đầu, như sau:
Như bạn đã biết, hàm TRIMloại bỏ khoảng trắng thừa ở giữa các chuỗi văn bản, đây không phải là điều chúng tôi muốn. Để giữ nguyên tất cả các khoảng trống ở giữa, chúng tôi sẽ sử dụng công thức phức tạp hơn một chút:
=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))
Trong công thức trên, sự kết hợp giữa FIND, MID và TRIM sẽ tính toán vị trí của ký tự văn bản đầu tiên trong một chuỗi. Sau đó, bạn cung cấp số đó cho một hàm MID khác để hàm này trả về toàn bộ chuỗi văn bản (độ dài chuỗi được tính bằng LEN) bắt đầu từ vị trí của ký tự văn bản đầu tiên.
Ảnh chụp màn hình sau đây cho thấy tất cả các khoảng trắng ở đầu đã biến mất, trong khi vẫn còn nhiều khoảng trắng giữa các từ:
Để hoàn thiện, hãy thay thế văn bản gốc bằng các giá trị đã cắt bớt, như minh họa trong bước 3 của ví dụ về công thức Cắt bỏ và bạn đã sẵn sàng để bắt đầu!
Mẹo. Nếu bạn cũng muốn xóa khoảng trắng ở cuối ô, hãy sử dụng công cụ Trim Spaces. Không có công thức Excel rõ ràng nào để loại bỏ các khoảng trắng ở đầu và cuối để giữ nguyên nhiều khoảng trắng giữa các từ.
Cách đếm khoảng trắng thừa trong một ô
Đôi khi, trước khi xóa khoảng trắng trong trang tính Excel của mình, bạn có thể muốn biết thực sự có bao nhiêu khoảng trắng thừa.
Để lấy số khoảng trắng thừa trong một ô, hãy tìm tổng độ dài văn bản bằng cách sử dụng hàm LEN, sau đó tính toán độ dài chuỗi không có khoảng trắng thừa và trừ khoảng cách sau khỏi khoảng trắng trước:
=LEN(A2)-LEN(TRIM(A2))
Dưới đâyảnh chụp màn hình hiển thị công thức trên đang hoạt động:
Lưu ý. Công thức trả về số lượng khoảng trắng thừa trong một ô, tức là ở đầu, ở cuối và nhiều hơn một khoảng trắng liên tiếp giữa các từ, nhưng nó không tính các khoảng trắng đơn lẻ ở giữa văn bản. Nếu bạn muốn lấy tổng số khoảng trắng trong một ô, hãy sử dụng công thức Thay thế này.
Cách đánh dấu các ô có khoảng trắng thừa
Khi làm việc với thông tin nhạy cảm hoặc quan trọng, bạn có thể do dự khi xóa bất kỳ thứ gì mà không nhìn thấy chính xác mình đang xóa gì. Trong trường hợp này, trước tiên, bạn có thể đánh dấu các ô chứa khoảng trắng thừa, sau đó loại bỏ các khoảng trắng đó một cách an toàn.
Đối với điều này, hãy tạo quy tắc định dạng có điều kiện bằng công thức sau:
=LEN($A2)>LEN(TRIM($A2))
Trong đó A2 là ô trên cùng có dữ liệu mà bạn muốn đánh dấu.
Công thức hướng dẫn Excel đánh dấu các ô trong đó tổng độ dài chuỗi lớn hơn độ dài của văn bản đã cắt.
Để tạo quy tắc định dạng có điều kiện, hãy chọn tất cả các ô (hàng) mà bạn muốn đánh dấu mà không có tiêu đề cột, chuyển đến tab Trang chủ > nhóm Kiểu dáng và nhấp vào Định dạng có điều kiện > Quy tắc mới > Sử dụng công thức để xác định ô cần định dạng .
Nếu bạn chưa quen với định dạng có điều kiện của Excel , bạn sẽ tìm thấy các bước chi tiết tại đây: Cách tạo quy tắc định dạng có điều kiện dựa trêncông thức.
Như minh họa trong ảnh chụp màn hình bên dưới, kết quả hoàn toàn phù hợp với số lượng khoảng trắng thừa mà chúng ta có trong ví dụ trước:
Như bạn thấy, việc sử dụng của hàm TRIM trong Excel rất dễ dàng và đơn giản. Tuy nhiên, nếu ai đó muốn xem kỹ hơn các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống Sổ làm việc Trim Excel Spaces.
TRIM Excel không hoạt động
Hàm TRIM chỉ loại bỏ ký tự khoảng trắng được biểu thị bằng giá trị mã 32 trong bộ ký tự ASCII 7 bit. Trong bộ ký tự Unicode, có thêm một ký tự khoảng trắng được gọi là khoảng cách không phá vỡ, thường được sử dụng trên các trang web dưới dạng ký tự html . Khoảng trắng không ngắt có giá trị thập phân là 160 và hàm TRIM không thể tự xóa khoảng trắng đó.
Vì vậy, nếu tập dữ liệu của bạn chứa một hoặc nhiều khoảng trắng mà hàm TRIM không xóa được, hãy sử dụng hàm SUBSTITUTE để chuyển đổi không gian không phá vỡ thành không gian thông thường và sau đó cắt chúng. Giả sử văn bản ở dạng A1, công thức sẽ như sau:
=TRIM(SUBSTITUTE(A1, CHAR(160), " "))
Để đề phòng thêm, bạn có thể nhúng hàm CLEAN để xóa ô khỏi mọi ký tự không in được:
=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))
Ảnh chụp màn hình sau đây cho thấy sự khác biệt:
Nếu các công thức trên cũng không hiệu quả với bạn, thì rất có thể dữ liệu của bạn chứa một số lỗi không in được cụ thể nhân vậtvới các giá trị mã khác 32 và 160. Trong trường hợp này, hãy sử dụng một trong các công thức sau để tìm ra mã ký tự, trong đó A1 là ô có vấn đề:
Dấu cách: =CODE(LEFT(A1,1))
Dưới cuối dấu cách: =CODE(RIGHT(A1,1))
Khoảng trắng ở giữa (trong đó n là vị trí của ký tự có vấn đề trong chuỗi văn bản):
=CODE(MID(A1, n , 1)))
Và sau đó , hãy cung cấp mã ký tự được trả về cho công thức TRIM(SUBSTITUTE()) đã thảo luận ở trên.
Ví dụ: nếu hàm CODE trả về 9, là ký tự Tab ngang, thì bạn sử dụng công thức sau để xóa ký tự đó:
=TRIM(SUBSTITUTE(A1, CHAR(9), " "))
Cắt bớt khoảng trắng cho Excel - loại bỏ khoảng trắng thừa chỉ bằng một cú nhấp chuột
Ý tưởng học một số công thức khác nhau để giải quyết một nhiệm vụ tầm thường nghe có nực cười không? Sau đó, bạn có thể thích kỹ thuật một cú nhấp chuột này để loại bỏ khoảng trắng trong Excel. Hãy để tôi giới thiệu với bạn Bộ công cụ văn bản có trong Ultimate Suite của chúng tôi. Trong số những thứ khác như thay đổi kiểu chữ, tách văn bản và xóa định dạng, nó cung cấp tùy chọn Cắt dấu cách .
Với Ultimate Suite được cài đặt trong Excel của bạn, việc xóa dấu cách trong Excel cũng đơn giản như sau :
- Chọn (các) ô mà bạn muốn xóa khoảng trắng.
- Nhấp vào nút Cắt dấu cách trên ruy-băng.
- Chọn một hoặc tất cả các tùy chọn sau:
- Cắt dấu cách đầu và dấu cách
- Cắt dấu cách phụ giữa các từ, ngoại trừ một từ duy nhấtdấu cách
- Cắt không ngắt dấu cách ( )
- Nhấp vào Cắt .
Thats tất cả để có nó! Tất cả khoảng trắng thừa sẽ bị xóa trong nháy mắt.
Trong ví dụ này, chúng tôi chỉ xóa khoảng trắng ở đầu và cuối, giữ nguyên nhiều khoảng trắng giữa các từ để dễ đọc hơn - nhiệm vụ mà các công thức Excel không thể giải quyết được hoàn thành bằng một nhấp chuột!
Nếu bạn muốn thử Cắt dấu cách trong trang tính của mình, bạn có thể tải xuống phiên bản đánh giá ở cuối bài đăng này.
Tôi cảm ơn bạn đã đọc và mong được gặp bạn vào tuần tới. Trong hướng dẫn tiếp theo của chúng tôi, chúng tôi sẽ thảo luận về các cách khác để cắt khoảng trắng trong Excel, hãy chú ý theo dõi!
Các bản tải xuống có sẵn
Cắt khoảng trắng trong Excel - ví dụ về công thức (tệp .xlsx)
Ultimate Suite - phiên bản dùng thử (tệp .exe)
