Tutorial nunjukkeun sababaraha cara gancang jeung gampang pikeun motong spasi Excel. Diajar kumaha carana miceun spasi hareup, labuh, jeung spasi tambahan antara kecap, naha fungsi Excel TRIM teu jalan jeung kumaha carana ngalereskeun eta.

Naha anjeun ngabandingkeun dua kolom pikeun duplikat nu anjeun terang aya, tapi rumus anjeun teu bisa manggihan hiji entri duplikat tunggal? Atanapi, anjeun nambihan dua kolom angka, tapi tetep ngan ukur nol? Jeung naha di bumi rumus Vlookup anjeun écés bener balik ngan sakumpulan N / A kasalahan? Ieu ngan ukur sababaraha conto masalah anu anjeun tiasa milarian jawaban. Sareng sadayana disababkeun ku spasi tambahan nyumput sateuacan, saatos atanapi antara nilai numerik sareng téks dina sél anjeun.

Microsoft Excel nawiskeun sababaraha cara pikeun ngahapus rohangan sareng ngabersihan data anjeun. Dina tutorial ieu, urang bakal nalungtik kamampuan pungsi TRIM salaku cara panggancangna sareng panggampangna pikeun mupus spasi dina Excel.

Fungsi TRIM - miceun spasi tambahan dina Excel

Anjeun nganggo fungsi TRIM dina Excel ngaleungitkeun spasi tambahan tina téks. Ieu mupus sadaya spasi ngarah, labuh jeung di-antara iwal spasi tunggal karakter antara kecap.

Sintaksis fungsi TRIM paling gampang bisa dibayangkeun:

Dimana text mangrupa sél nu rék miceun kaleuwihan spasi.

Contona, pikeun miceun spasi dina sél A1, anjeun ngagunakeun ieurumus:

=TRIM(A1)

Jeung screenshot di handap nembongkeun hasilna:

Leres, éta basajan pisan!

Punten dicatet yén fungsi TRIM dirancang pikeun miceun ukur karakter spasi, nu boga nilai 32 dina sistem kode ASCII 7-bit. Lamun salian spasi tambahan, data anjeun ngandung garis putus jeung karakter non-nyitak, pake fungsi TRIM digabungkeun jeung BERSIH pikeun mupus 32 karakter non-nyitak munggaran dina sistem ASCII.

Contona, pikeun hapus spasi, garis putus jeung karakter nu teu dihoyongkeun sejenna tina sél A1, make rumus ieu:

=TRIM(CLEAN(A1))

Pikeun inpo nu leuwih lengkep, mangga tingali Kumaha miceun karakter non-printing dina Excel

Pikeun ngaleungitkeun spasi nonbreaking (karakter html ), nu boga nilai 160, make TRIM babarengan jeung fungsi SUBSTITUTE jeung CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Pikeun detil lengkep, mangga tingali Kumaha mupus spasi non-breaking dina Excel

Kumaha ngagunakeun fungsi TRIM dina Excel - conto rumus

Ayeuna anjeun terang dasarna, hayu urang bahas sababaraha kagunaan husus tina TRIM dina Excel, pitfalls anu anjeun tiasa nyanghareupan sareng solusi anu tiasa dianggo.

Kumaha cara motong rohangan dina sakabéh kolom data

Anggap anjeun gaduh kolom nami anu ngagaduhan sababaraha spasi bodas sateuacan sareng saatos téks, ogé sakumaha langkung ti hiji spasi antara kecap. Ku kituna, kumaha anjeun miceun kabeh ngarah, labuh jeung kaleuwihan di-antara spasi dina sakabéh sél dina hiji waktu? Ku nyalin hiji ExcelRumus TRIM sakuliah kolom, lajeng ngaganti rumus jeung nilai maranéhanana. Léngkah-léngkahna di handap ieu.

1. Tulis rumus TRIM pikeun sél anu paling luhur, A2 dina conto urang:

   =TRIM(A2)

2. Posisikeun kursor ka pojok katuhu handap. tina sél rumus (B2 dina conto ieu), jeung pas kursor robah jadi tanda tambah, ganda-klik eta pikeun nyalin rumus handap kolom, nepi ka sél panungtungan kalawan data. Hasilna, anjeun bakal boga 2 kolom - ngaran aslina kalawan spasi jeung rumus-driven ngaran dipangkas.

• Pilih sadaya sél anu nganggo rumus Trim (B2:B8 dina conto ieu), teras pencét Ctrl+C pikeun nyalinna.
• Pilih sadaya sél anu gaduh data asli (A2:A8 ), terus pencét Ctrl+Alt+V , terus V . Ieu mangrupikeun potong kompas nilai témpél anu nerapkeun Tempelkeun Khusus > Nilai
• Pencét kenop Enter. Réngsé!

Kumaha carana miceun spasi ngarah dina kolom numerik

Sakumaha nu geus katempo, fungsi Excel TRIM ngaleungitkeun sakabeh spasi tambahan tina kolom data téks tanpa hiji halangan. Tapi kumaha lamun data anjeun angka, lain téks?

Saheulaanan, sigana mahFungsi TRIM parantos ngalaksanakeun tugasna. Nalika ditingali langkung caket, anjeun bakal aya bewara yén nilai anu dipangkas henteu kalakuanana sapertos angka. Ieu ngan sababaraha indikasi abnormalitas:

• Boh kolom aslina kalawan spasi ngarah jeung angka dipangkas baris kénca-blok sanajan anjeun nerapkeun format Nomer ka sél, sedengkeun angka normal di-align katuhu. sacara standar.
• Lamun dua atawa leuwih sél nu nomerna dipangkas dipilih, Excel ngan mintonkeun COUNT dina bar status. Pikeun nomer, éta ogé kedah nunjukkeun SUM sareng AVERAGE.
• Rumus SUM anu diterapkeun kana sél anu dipangkas ngahasilkeun nol.

Ti sadaya penampilan, nilai anu dipangkas. nyaéta string téks , sedengkeun urang hoyong angka. Pikeun ngalereskeun ieu, anjeun tiasa ngalikeun nilai-nilai anu dipangkas ku 1 (pikeun ngalikeun sadaya nilai dina hiji swoop, nganggo pilihan Paste Special > Multiply).

Solusi anu langkung elegan nyaéta ngalampirkeun fungsi TRIM dina VALUE , siga kieu:

=VALUE(TRIM(A2))

Rumus di luhur mupus sakabeh spasi hareup jeung labuh, lamun aya, sarta ngarobah nilai hasilna kana angka, sakumaha ditémbongkeun dina screenshot handap:

Kumaha carana miceun spasi ngarah wungkul dina Excel (Pangkas Kénca)

Dina sababaraha kaayaan, anjeun bisa ngetik spasi duplikat komo triplicated antara kecap sangkan data anjeun leuwih hadé dibaca. Nanging, anjeun hoyong nyingkirkeun rohangan utama, sapertos kieu:

Sapertos anjeun terang, fungsi TRIMngaleungitkeun spasi tambahan di tengah string téks, nu teu naon urang hayang. Pikeun ngajaga sakabéh spasi dina-antara gembleng, urang bakal ngagunakeun rumus saeutik leuwih kompleks:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

Dina rumus di luhur, kombinasi FIND, MID jeung TRIM ngitung posisi karakter téks munggaran dina string. Teras, anjeun nyayogikeun nomer éta ka fungsi MID anu sanés supados éta ngabalikeun sadayana senar téks (panjang senar diitung ku LEN) dimimitian dina posisi karakter téks anu munggaran.

Potret layar di handap ieu nunjukkeun yén sadayana spasi ngarah leungit, bari sababaraha spasi antara kecap masih aya:

Salaku finish touch, ngaganti téks aslina ku nilai dipangkas, sakumaha ditémbongkeun dina lengkah 3 tina conto rumus Trim , sareng anjeun badé angkat!

Tip. Upami anjeun ogé hoyong ngahapus rohangan dina tungtung sél, paké alat Potong Spasi. Teu aya rumus Excel anu atra pikeun ngahapus spasi ngarah sareng labuh ngajaga sababaraha spasi antara kecap gembleng.

Kumaha cara ngitung spasi tambahan dina sél

Sok, samemeh miceun spasi dina lambar Excel, Anjeun meureun hoyong terang sabaraha kaleuwihan spasi sabenerna aya.

Pikeun meunangkeun nomer tina spasi tambahan dina sél, panggihan total panjang téks maké fungsi LEN, teras hitung panjang string tanpa spasi tambahan, tur kurangkeun panungtungan ti urut:

=LEN(A2)-LEN(TRIM(A2))

Di handap ieuscreenshot nembongkeun rumus di luhur dina aksi:

Catetan. Rumusna mulangkeun jumlah spasi tambahan dina sél, nyaéta ngarah, labuh, sareng langkung ti hiji spasi padeukeut antara kecap, tapi henteu ngitung spasi tunggal di tengah téks. Upami anjeun hoyong kéngingkeun jumlah total rohangan dina sél, paké rumus Ganti ieu.

Kumaha cara nyorot sél anu langkung seueur rohangan

Nalika damel sareng inpormasi anu sénsitip atanapi penting, anjeun tiasa ragu pikeun ngahapus naon waé tanpa ningali naon anu anjeun hapus. Dina hal ieu, anjeun tiasa nyorot sél anu ngandung rohangan tambahan heula, teras ngaleungitkeun rohangan éta kalayan aman.

Pikeun ieu, jieun aturan pormat kondisional nganggo rumus ieu:

=LEN($A2)>LEN(TRIM($A2))

Dimana A2 nyaéta sél paling luhur kalayan data anu anjeun hoyong disorot.

Rumusna maréntahkeun Excel pikeun nyorot sél anu panjangna stringna langkung ageung tibatan panjang téks anu dipangkas.

Pikeun nyieun aturan pormat kondisional, pilih sadaya sél (baris) nu Anjeun hoyong sorot tanpa lulugu kolom, buka grup Home > Styles , teras klik Format kondisional > Aturan Anyar > Paké rumus pikeun nangtukeun sél mana nu rék diformat .

Mun anjeun can wawuh jeung pormat kondisional Excel. , anjeun bakal manggihan léngkah lengkep di dieu: Kumaha carana nyieun aturan pormat kondisional dumasar kanarumusna.

Sakumaha anu dipidangkeun dina screenshot di handap, hasilna saluyu sareng jumlah spasi tambahan anu kami peroleh dina conto samemehna:

Sakumaha nu katingali, pamakéan tina fungsi TRIM dina Excel gampang tur lugas. Nanging, upami aya anu hoyong ningal langkung caket kana rumus anu dibahas dina tutorial ieu, anjeun tiasa ngaunduh Buku Gawé Spasi Trim Excel.

Excel TRIM henteu jalan

Fungsi TRIM ngan ngaleungitkeun. karakter spasi diwakilan ku nilai kode 32 dina set karakter ASCII 7-bit. Dina set karakter Unicode, aya hiji deui karakter spasi disebut non-breaking spasi, nu ilahar dipaké dina kaca web salaku karakter html . Spasi nonbreaking boga nilai desimal 160, sarta fungsi TRIM teu bisa dihapus ku sorangan.

Jadi, lamun set data anjeun ngandung hiji atawa leuwih spasi bodas nu fungsi TRIM teu dipiceun, gunakeun fungsi SUBSTITUTE. pikeun ngarobah spasi non-megatkeun kana spasi biasa lajeng motong aranjeunna. Upami téksna aya dina A1, rumusna kieu:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Salaku pancegahan tambahan, anjeun tiasa nyelapkeun pungsi BERSIH pikeun ngabersihan sél tina karakter anu teu tiasa dicitak:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

Potret layar di handap ieu nembongkeun bédana:

Upami rumus di luhur ogé henteu dianggo pikeun anjeun, kamungkinan yén data anjeun ngandung sababaraha nonprinting khusus. aksarakalawan nilai kode lian ti 32 jeung 160. Dina hal ieu, make salah sahiji rumus di handap pikeun manggihan kodeu karakter, dimana A1 mangrupakeun sél masalah:

Rohang anjog: =CODE(LEFT(A1,1))

Trailing spasi: =CODE(RIGHT(A1,1))

Di-antara spasi (dimana n mangrupa posisi karakter masalah dina string téks):

=CODE(MID(A1, n , 1)))

Terus , asupkeun kodeu karakter anu dipulangkeun kana rumus TRIM(SUBSTITUTE()) anu dibahas di luhur.

Contona, upami fungsi CODE mulihkeun 9, nyaéta karakter Tab Horizontal, anjeun nganggo rumus ieu pikeun ngaleungitkeunana:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Pangkas Spasi pikeun Excel - miceun spasi tambahan dina hiji klik

Naha ideu diajar sakeupeul rumus anu béda pikeun nganyahokeun tugas sepele disada konyol? Teras anjeun tiasa resep téknik hiji-klik ieu pikeun ngaleungitkeun rohangan dina Excel. Hayu atuh ngenalkeun anjeun kana Text Toolkit anu kalebet dina Suite Ultimate kami. Diantara hal séjén sapertos ngarobah kasus, ngabagi téks sareng ngabersihan pormat, éta nawiskeun pilihan Trim Spasi .

Kalayan Ultimate Suite dipasang dina Excel anjeun, ngahapus rohangan dina Excel sasederhana ieu. :

1. Pilih sél dimana anjeun hoyong mupus spasi.
2. Klik tombol Pangkas Spasi dina pita.
3. Pilih salah sahiji atawa sakabéh pilihan ieu:
   • Motong ngarah jeung labuh spasi
   • Motong tambahan spasi antara kecap, iwal hiji tunggalspasi
   • Motong teu putus spasi ( )
4. Klik Motong .

Sakitu wae! Kabéh spasi tambahan dihapus dina sakedap.

Dina conto ieu, urang ngan miceun spasi hareup jeung labuh, ngajaga sababaraha spasi antara kecap gembleng pikeun kabacaan hadé - tugas nu rumus Excel teu bisa diungkulan dilaksanakeun ku a klik beurit!

Mun anjeun kabetot pikeun nyobaan Trim Spasi dina lambaran anjeun, anjeun tiasa ngaunduh vérsi évaluasi dina tungtung tulisan ieu.

Abdi hatur nuhun tos maca sareng ngarepkeun pendak sareng anjeun minggu payun. Dina tutorial salajengna urang, urang bakal ngabahas cara séjén pikeun motong spasi dina Excel, mangga tetep katala!

Sadia undeuran

Trim Excel Spasi - conto rumus (.xlsx file)

Ultimate Suite - versi percobaan (file .exe)