La lernilo montras kelkajn rapidajn kaj facilajn manierojn tranĉi Excel-spacojn. Lernu kiel forigi antaŭajn, malantaŭajn kaj kromajn spacojn inter vortoj, kial Excel TRIM-funkcio ne funkcias kaj kiel ripari ĝin.

Ĉu vi komparas du kolumnojn por duplikatoj, kiujn vi scias, ke ekzistas, sed viaj formuloj ne povas trovi unu duplikatan eniron? Aŭ ĉu vi aldonas du kolumnojn da nombroj, sed daŭre ricevas nur nulojn? Kaj kial via evidente ĝusta Vlookup-formulo resendas nur amason da N/A-eraroj? Ĉi tiuj estas nur kelkaj ekzemploj de problemoj, al kiuj vi eble serĉas respondojn. Kaj ĉiuj estas kaŭzitaj de aldonaj spacoj kaŝiĝantaj antaŭ, post aŭ inter nombraj kaj tekstaj valoroj en viaj ĉeloj.

Microsoft Excel proponas kelkajn malsamajn manierojn forigi spacojn kaj purigu viajn datumojn. En ĉi tiu lernilo, ni esploros la kapablojn de la TRIM-funkcio kiel la plej rapida kaj facila maniero forigi spacojn en Excel.

TRIM-funkcio - forigu kromajn spacojn en Excel

Vi uzas la TRIM-funkcion en Excel forigas kromajn spacojn de teksto. Ĝi forigas ĉiujn antaŭajn, postajn kaj interspacojn krom unu sola spaco signo inter vortoj.

La sintakso de la funkcio TRIM estas la plej facila, kiun oni povus imagi:

Kie teksto estas ĉelo el kiu vi volas forigi troajn spacojn.

Ekzemple, por forigi spacojn en ĉelo A1, vi uzas ĉi tion.formulo:

=TRIM(A1)

Kaj la sekva ekrankopio montras la rezulton:

Jes, estas tiel simpla!

Bonvolu noti tion la TRIM-funkcio estis dizajnita por forigi nur la spacan signon, kiu havas valoron 32 en la 7-bita ASCII-kodsistemo. Se krom kromaj spacoj, viaj datumoj enhavas liniorompojn kaj nepreseblajn signojn, uzu la TRIM-funkcion kombine kun CLEAN por forigi la unuajn 32 nepreseblajn signojn en la ASCII-sistemo.

Ekzemple por forigu spacojn, liniojn kaj aliajn nedeziratajn signojn de ĉelo A1, uzu ĉi tiun formulon:

=TRIM(CLEAN(A1))

Por pliaj informoj, bonvolu vidi Kiel forigi nepresantajn signojn en Excel

Por forigi nerompeblajn spacojn (html-signo ), kiu havas valoron 160, uzu TRIM kune kun SUBSTITUTE kaj CHAR-funkcioj:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Por plenaj detaloj, bv. vidu Kiel forigi nerompeblajn spacojn en Excel

Kiel uzi TRIM-funkcion en Excel - formulekzemploj

Nun kiam vi konas la bazojn, ni diskutu kelkajn specifajn uzojn de TRIM en Excel, malfacilaĵoj kiujn vi povas renkonti kaj laborsolvoj.

Kiel tranĉi spacojn en tuta kolumno de datumoj

Supozi vi havas kolumnon de nomoj kiuj havas iom da blankspaco antaŭ kaj post la teksto, ankaŭ kiel pli ol unu spacoj inter la vortoj. Do, kiel vi forigas ĉiujn ĉefajn, malantaŭajn kaj troajn interspacojn en ĉiuj ĉeloj samtempe? Kopiante ExcelTRIM-formulon tra la kolumno, kaj poste anstataŭigante formulojn per iliaj valoroj. La detalaj paŝoj sekvas sube.

1. Skribu TRIM-formulon por la plej supra ĉelo, A2 en nia ekzemplo:

   =TRIM(A2)

2. Metu la kursoron al la malsupra dekstra angulo de la formulĉelo (B2 en ĉi tiu ekzemplo), kaj tuj kiam la kursoro turniĝas al la plus-signo, duoble alklaku ĝin por kopii la formulon laŭ la kolumno, ĝis la lasta ĉelo kun datumoj. Kiel rezulto, vi havos 2 kolumnojn - originalajn nomojn kun spacoj kaj formul-kondukitaj tajlitaj nomoj.

• Elektu ĉiujn ĉelojn kun Trimformuloj (B2:B8 en ĉi tiu ekzemplo), kaj premu Ctrl+C por kopii ilin.
• Elektu ĉiujn ĉelojn kun la originaj datumoj (A2:A8). ), kaj premu Ctrl+Alt+V , tiam V . Estas la ŝparvojo alglui valorojn, kiu aplikas la Alglui Specialan > Valorojn
• Premu la Enigu klavon. Farita!

Kiel forigi gvidajn spacojn en nombra kolumno

Kiel vi ĵus vidis, la Excel TRIM-funkcio forigis ĉiujn kromajn spacojn de kolumno de tekstaj datumoj sen ŝtopilo. Sed kio se viaj datumoj estas ciferoj, ne teksto?

Unuavide, eble ŝajnas, ke laTRIM-funkcio faris sian laboron. Pli detale rigardante, vi tamen rimarkos, ke la tajlitaj valoroj ne kondutas kiel nombroj. Jen nur kelkaj indikoj de anomalio:

• Kaj la originala kolumno kun gvidaj spacoj kaj eltonditaj nombroj estas maldekstre vicigitaj eĉ se vi aplikas la Nombra formaton al la ĉeloj, dum normalaj nombroj estas dekstre vicigitaj. defaŭlte.
• Kiam du aŭ pli da ĉeloj kun tajlitaj nombroj estas elektitaj, Excel montras nur COUNT en la statusbreto. Por nombroj, ĝi ankaŭ montru SUM kaj AVERAGE.
• SUMO-formulo aplikata al la tajlitaj ĉeloj donas nulon.

El ĉiuj aspektoj, la tajlitaj valoroj. estas tekstaj ĉenoj , dum ni volas nombrojn. Por solvi ĉi tion, vi povas multobligi la tajlitajn valorojn per 1 (por multobligi ĉiujn valorojn en unu paŝo, uzu la opcion Alglui Speciala > Multipli).

Pli eleganta solvo estas enmeti la TRIM-funkcion en VALORO. , tiel:

=VALUE(TRIM(A2))

La supra formulo forigas ĉiujn antaŭajn kaj postajn spacojn, se ekzistas, kaj ŝanĝas la rezultan valoron en nombron, kiel montrite en la ekrankopio sube:

Kiel forigi nur ĉefajn spacojn en Excel (Maldekstra Trim)

En iuj situacioj, vi povas tajpi duobligitajn kaj eĉ trioblatajn spacojn inter vortoj por plibonigi viajn datumojn. Tamen, vi volas forigi gvidajn spacojn, kiel ĉi tio:

Kiel vi jam scias, la funkcio TRIMforigas kromajn spacojn en la mezo de tekstaj ĉenoj, kio ne estas tio, kion ni volas. Por konservi ĉiujn interspacojn nerompitaj, ni uzos iom pli kompleksan formulon:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

En la supra formulo, la kombinaĵo de FIND, MID kaj TRIM kalkulas la pozicion de la unua teksta signo en ĉeno. Kaj tiam, vi liveras tiun nombron al alia MID-funkcio tiel ke ĝi resendas la tutan tekstan ĉenon (la ĉenlongon estas kalkulita per LEN) komencante ĉe la pozicio de la unua tekstsigno.

La sekva ekrankopio montras, ke ĉiuj gvidaj spacoj malaperis, dum pluraj spacoj inter vortoj ankoraŭ estas tie:

Kiel finas, anstataŭigu la originan tekston per la tajlitaj valoroj, kiel montrite en la paŝo 3 de la Ekzemplo de Trim-formulo. , kaj vi estas bona por iri!

Konsileto. Se vi ankaŭ volas forigi spacojn de la fino de ĉeloj, uzu la ilon Trim Spaces. Ne ekzistas evidenta Excel-formulo por forigi ĉefajn kaj postajn spacojn konservante plurajn spacojn inter vortoj nerompitaj.

Kiel kalkuli kromajn spacojn en ĉelo

Foje, antaŭ ol forigi spacojn en via Excel-folio, vi eble volas scii kiom da troaj spacoj estas efektive tie.

Por akiri la nombron. de kromaj spacoj en ĉelo, malkovru la totalan tekstolongon uzante la funkcion LEN, poste kalkulu la kordlongon sen kromaj spacoj, kaj subtrahi la lastan de la unua:

=LEN(A2)-LEN(TRIM(A2))

La jenajekrankopio montras la supran formulon en ago:

Noto. La formulo resendas la kalkulon de kromspacoj en ĉelo, t.e. kondukante, malantaŭan, kaj pli ol unu sinsekvajn spacojn inter vortoj, sed ĝi ne kalkulas unuopajn spacojn en la mezo de la teksto. Se vi volas akiri la totalan nombron da spacoj en ĉelo, uzu ĉi tiun Anstataŭan formulon.

Kiel reliefigi ĉelojn kun troaj spacoj

Kiam vi laboras kun sentemaj aŭ gravaj informoj, vi eble hezitas forigi ion ajn sen vidi kion ĝuste vi forigas. En ĉi tiu kazo, vi povas unue reliefigi ĉelojn enhavantajn kromajn spacojn, kaj poste sekure forigi tiujn spacojn.

Por tio, kreu kondiĉan formatregulon kun la jena formulo:

=LEN($A2)>LEN(TRIM($A2))

Kie A2 estas la plej supra ĉelo kun datumoj, kiujn vi volas reliefigi.

La formulo instrukcias Excel reliefigi ĉelojn en kiuj la tuta longo de la ĉeno estas pli granda ol la longo de la tajlita teksto.

Por krei kondiĉan formatregulon, elektu ĉiujn ĉelojn (vicojn), kiujn vi volas reliefigi sen kolumnaj kapoj, iru al la langeto Hejmo > Stiloj , kaj alklaku Kondiĉa formatado > Nova Regulo > Uzu formulon por determini kiujn ĉelojn formati .

Se vi ankoraŭ ne konas Excel-kondiĉan formatadon , vi trovos la detalajn paŝojn ĉi tie: Kiel krei kondiĉan formatregulon bazitan surformulo.

Kiel pruvite en la suba ekrankopio, la rezulto perfekte konfirmas kun la kroma kalkulo de spacoj kiujn ni ricevis en la antaŭa ekzemplo:

Kiel vi vidas, la uzo de la TRIM-funkcio en Excel estas facila kaj simpla. Tamen, se iu volas pli detale rigardi la formulojn diskutitajn en ĉi tiu lernilo, vi bonvenas elŝuti la Laborlibron de Trim Excel Spaces.

Excel TRIM ne funkcias

La TRIM-funkcio nur forigas la spaca signo reprezentita per kodvaloro 32 en la 7-bita ASCII-signaro. En la Unikoda signaro, ekzistas unu plia spaca signo nomata nerompebla spaco, kiu estas kutime uzata en retpaĝoj kiel la html-signo . La nerompebla spaco havas decimalan valoron 160, kaj la TRIM-funkcio ne povas forigi ĝin per si mem.

Do, se via datumaro enhavas unu aŭ plurajn blankajn spacojn, kiujn la TRIM-funkcio ne forigas, uzu la SUBSTITUTE-funkcion. por konverti nerompeblajn spacojn en regulajn spacojn kaj poste tranĉi ilin. Supozante, ke la teksto estas en A1, la formulo iras jene:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Kiel kroma antaŭzorgo, vi povas enigi la funkcion CLEAN por purigi la ĉelon de iuj nepreseblaj signoj:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

La sekva ekrankopio montras la diferencon:

Se la supraj formuloj ankaŭ ne funkcias por vi, verŝajne viaj datumoj enhavas iun specifan neprintadon. karakterojkun kodaj valoroj krom 32 kaj 160. En ĉi tiu kazo, uzu unu el la jenaj formuloj por ekscii la signan kodon, kie A1 estas problema ĉelo:

Ĉefspaco: =CODE(LEFT(A1,1))

Suba spaco: =CODE(RIGHT(A1,1))

Interspaco (kie n estas la pozicio de la problema signo en la teksta ĉeno):

=CODE(MID(A1, n , 1)))

Kaj tiam , liveru la redonitan signan kodon al la formulo TRIM(SUBSTITUTE()) supre diskutita.

Ekzemple, se la CODE-funkcio liveras 9, kiu estas la Horizontala Tab-signo, vi uzas la jenan formulon por forigi ĝin:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Eltondi spacojn por Excel - forigu kromajn spacojn per klako

Ĉu la ideo lerni kelkajn malsamajn formulojn por trakti bagatela tasko sonas ridinde? Tiam vi eble ŝatas ĉi tiun unu-klakan teknikon por forigi spacojn en Excel. Permesu al mi prezenti vin al Teksta Ilaro inkluzivita en nia Finfina Suite. Inter aliaj aferoj kiel ŝanĝado de majuskloj, disigo de teksto kaj forigo de formatado, ĝi ofertas la opcion Trim Spaces .

Kun Ultimate Suite instalita en via Excel, forigi spacojn en Excel estas tiel simpla kiel ĉi tio. :

1. Elektu la ĉelon(j)n, kie vi volas forigi spacojn.
2. Alklaku la butonon Eltondi spacojn sur la rubando.
3. Elektu unu aŭ ĉiujn el la sekvaj opcioj:
   • Tondi ĉefajn kaj malantaŭajn spacojn
   • Tondi kroajn spacojn inter vortoj, krom unuopaspaco
   • Tordi nerompeblaj spacoj ( )
4. Alklaku Trimi .

Tio estas ĉio! Ĉiuj kromaj spacoj estas forigitaj palpebrume.

En ĉi tiu ekzemplo, ni nur forigas antaŭajn kaj postajn spacojn, konservante plurajn spacojn inter vortoj nerompitaj por pli bona legebleco - la tasko, kiun Excel-formuloj ne povas trakti, estas plenumita per musklaku!

Se vi interesiĝas provi Trimi Spacojn en viaj folioj, vi bonvenas elŝuti taksan version fine de ĉi tiu afiŝo.

Mi dankas vin pro legado kaj antaŭĝojas vidi vin venontsemajne. En nia sekva lernilo, ni diskutos aliajn manierojn tranĉi spacojn en Excel, bonvolu resti agordita!

Haveblaj elŝutoj

Trimi Excel-spacojn - ekzemploj de formuloj (.xlsx-dosiero)

Ultimate Suite - prova versio (.exe dosiero)