El tutorial mostra algunes maneres ràpides i senzilles de retallar els espais d'Excel. Obteniu informació sobre com eliminar els espais inicials, finals i addicionals entre les paraules, per què la funció TRIM d'Excel no funciona i com solucionar-ho.

Esteu comparant dues columnes per a duplicats que sabeu que hi ha, però les vostres fórmules no poden trobar una sola entrada duplicada? O, estàs sumant dues columnes de nombres, però segueix obtenint només zeros? I per què la teva fórmula de Vlookup, òbviament correcta, només retorna un munt d'errors N/A? Aquests són només uns quants exemples de problemes als quals potser busqueu respostes. I tots són causats per espais addicionals que s'amaguen abans, després o entre els valors numèrics i de text de les vostres cel·les.

Microsoft Excel ofereix algunes maneres diferents d'eliminar espais i neteja les teves dades. En aquest tutorial, investigarem les capacitats de la funció TRIM com la forma més ràpida i senzilla d'eliminar espais a Excel.

Funció TRIM: elimina els espais addicionals a Excel

Utilitzeu la funció TRIM a Excel elimina els espais addicionals del text. Elimina tots els espais inicials, finals i intermedis excepte un únic espai entre paraules.

La sintaxi de la funció TRIM és la més fàcil que es pugui imaginar:

On text és una cel·la de la qual voleu eliminar els espais en excés.

Per exemple, per eliminar espais a la cel·la A1, feu servir aquestfórmula:

=TRIM(A1)

I la següent captura de pantalla mostra el resultat:

Sí, així de senzill!

Tingues en compte que la funció TRIM va ser dissenyada per eliminar només el caràcter d'espai, que té el valor 32 al sistema de codi ASCII de 7 bits. Si a més d'espais addicionals, les vostres dades contenen salts de línia i caràcters no imprimibles, utilitzeu la funció TRIM en combinació amb CLEAN per eliminar els primers 32 caràcters no imprimibles del sistema ASCII.

Per exemple, per elimineu espais, salts de línia i altres caràcters no desitjats de la cel·la A1, utilitzeu aquesta fórmula:

=TRIM(CLEAN(A1))

Per obtenir més informació, vegeu Com eliminar caràcters que no s'imprimeixen a Excel

Per desfer-se dels espais ininterromputs (caràcter html ), que té el valor 160, utilitzeu TRIM juntament amb les funcions SUBSTITUTE i CHAR:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Per a tots els detalls, si us plau vegeu Com esborrar espais que no es trenquin a Excel

Com utilitzar la funció TRIM a Excel - exemples de fórmules

Ara que ja coneixeu els conceptes bàsics, parlem d'alguns usos específics de TRIM a Excel, inconvenients als quals us podeu enfrontar i solucions de treball.

Com retallar espais en una columna sencera de dades

Suposant que teniu una columna de noms que també tenen espais en blanc abans i després del text. com més més d'un espai entre les paraules. Aleshores, com elimineu tots els espais intermedis inicials, posteriors i en excés de totes les cel·les alhora? En copiar un ExcelTRIM la fórmula a la columna i, a continuació, substituïu les fórmules pels seus valors. A continuació es mostren els passos detallats.

1. Escriu una fórmula TRIM per a la cel·la superior, A2 al nostre exemple:

   =TRIM(A2)

2. Coloqui el cursor a l'extrem inferior dret de la cel·la de la fórmula (B2 en aquest exemple) i tan bon punt el cursor es converteixi en el signe més, feu-hi doble clic per copiar la fórmula a la columna, fins a l'última cel·la amb dades. Com a resultat, tindreu 2 columnes: noms originals amb espais i noms retallats basats en fórmules.

• Seleccioneu totes les cel·les amb fórmules de retall (B2:B8 en aquest exemple) i premeu Ctrl+C per copiar-les.
• Seleccioneu totes les cel·les amb les dades originals (A2:A8). ) i premeu Ctrl+Alt+V i després V. És la drecera per enganxar valors que aplica el Enganxa especial > Valors
• Premeu la tecla Intro. Fet!

Com eliminar els espais inicials d'una columna numèrica

Com acabeu de veure, la funció EXCEL TRIM va eliminar tots els espais addicionals d'una columna de dades de text sense un enganxament. Però, què passa si les teves dades són números, no text?

A primera vista, pot semblar que elLa funció TRIM ha fet la seva feina. En una ullada més de prop, però, notareu que els valors retallats no es comporten com números. Aquí només hi ha alguns indicis d'anormalitat:

• Tant la columna original amb espais inicials com els números retallats estan alineats a l'esquerra encara que apliqueu el format de nombre a les cel·les, mentre que els números normals estan alineats a la dreta. per defecte.
• Quan se seleccionen dues o més cel·les amb números retallats, l'Excel només mostra COUNT a la barra d'estat. Per als números, també hauria de mostrar SUMA i MITJANA.
• Una fórmula de SUMA aplicada a les cel·les retallades retorna zero.

Des de totes les aparences, els valors retallats. són cadenes de text , mentre que volem números. Per solucionar-ho, podeu multiplicar els valors retallats per 1 (per multiplicar tots els valors d'un sol cop, utilitzeu l'opció Enganxa especial > Multiplica).

Una solució més elegant és incloure la funció TRIM a VALOR. , així:

=VALUE(TRIM(A2))

La fórmula anterior elimina tots els espais inicials i finals, si n'hi ha, i converteix el valor resultant en un nombre, tal com es mostra a la captura de pantalla següent:

Com eliminar només els espais inicials a Excel (recort esquerre)

En algunes situacions, podeu escriure espais duplicats i fins i tot triplicats entre paraules per fer que les vostres dades siguin més llegibles. Tanmateix, voleu desfer-vos dels espais principals, com aquest:

Com ja sabeu, la funció TRIMelimina espais addicionals al mig de les cadenes de text, que no és el que volem. Per mantenir intactes tots els espais intermedis, utilitzarem una fórmula una mica més complexa:

=MID(A2,FIND(MID(TRIM(A2),1,1),A2),LEN(A2))

A la fórmula anterior, la combinació de FIND, MID i TRIM calcula la posició de el primer caràcter de text d'una cadena. A continuació, proporcioneu aquest número a una altra funció MID perquè retorni tota la cadena de text (la longitud de la cadena es calcula mitjançant LEN) començant a la posició del primer caràcter de text.

La captura de pantalla següent mostra que tots els espais inicials desapareixen, mentre que encara hi ha diversos espais entre paraules:

Com a toc final, substituïu el text original amb els valors retallats, tal com es mostra al pas 3 de l'exemple de fórmula Retalla. , i ja estàs a punt!

Consell. Si també voleu eliminar espais del final de les cel·les, feu servir l'eina Retalla espais. No hi ha una fórmula d'Excel òbvia per eliminar els espais inicials i finals mantenint intactes diversos espais entre paraules.

Com comptar espais addicionals en una cel·la

De vegades, abans d'eliminar espais del vostre full d'Excel, és possible que vulgueu saber quants espais en excés hi ha realment.

Per obtenir el número d'espais addicionals en una cel·la, esbrineu la longitud total del text utilitzant la funció LEN, després calculeu la longitud de la cadena sense espais addicionals i resteu la segona de la primera:

=LEN(A2)-LEN(TRIM(A2))

El següentLa captura de pantalla mostra la fórmula anterior en acció:

Nota. La fórmula retorna el recompte d' espais addicionals en una cel·la, és a dir, espais inicials, finals i més d'un espai consecutiu entre paraules, però no compta els espais únics al mig del text. Si voleu obtenir el nombre total d'espais d'una cel·la, utilitzeu aquesta fórmula de substitució.

Com ressaltar les cel·les amb excés d'espais

Quan treballeu amb informació sensible o important, és possible que dubtis a suprimir qualsevol cosa sense veure què esteu suprimint exactament. En aquest cas, primer podeu ressaltar les cel·les que continguin espais addicionals i després eliminar-los amb seguretat.

Per a això, creeu una regla de format condicional amb la fórmula següent:

=LEN($A2)>LEN(TRIM($A2))

On A2 és la cel·la superior amb les dades que voleu ressaltar.

La fórmula indica a Excel que ressalti les cel·les en què la longitud total de la cadena sigui superior a la del text retallat.

Per crear una regla de format condicional, seleccioneu totes les cel·les (files) que vulgueu ressaltar sense capçaleres de columna, aneu a la pestanya Inici > Estils i feu clic a Format condicional > Nova regla > Utilitzeu una fórmula per determinar quines cel·les voleu formatar .

Si encara no esteu familiaritzat amb el format condicional d'Excel , trobareu els passos detallats aquí: Com crear una regla de format condicional basada enfórmula.

Com es demostra a la captura de pantalla següent, el resultat corrobora perfectament amb el recompte d'espais addicionals que vam obtenir a l'exemple anterior:

Com veieu, l'ús de la funció TRIM a Excel és fàcil i senzill. No obstant això, si algú vol mirar més de prop les fórmules que es comenten en aquest tutorial, us convidem a descarregar-vos el llibre de treball de Trim Excel Spaces.

Excel TRIM no funciona

La funció TRIM només elimina el caràcter espai representat pel valor de codi 32 al conjunt de caràcters ASCII de 7 bits. Al conjunt de caràcters Unicode, hi ha un caràcter d'espai més anomenat espai ininterromput que s'utilitza habitualment a les pàgines web com a caràcter html . L'espai ininterromput té un valor decimal de 160 i la funció TRIM no el pot eliminar per si mateixa.

Per tant, si el vostre conjunt de dades conté un o més espais en blanc que la funció TRIM no elimina, feu servir la funció SUBSTITUTE. per convertir espais que no es trenquin en espais regulars i després retallar-los. Suposant que el text és a A1, la fórmula és el següent:

=TRIM(SUBSTITUTE(A1, CHAR(160), " "))

Com a precaució addicional, podeu incrustar la funció CLEAN per netejar la cel·la de qualsevol caràcter no imprimible:

=TRIM(CLEAN(SUBSTITUTE(A1, CHAR(160), " ")))

La captura de pantalla següent mostra la diferència:

Si les fórmules anteriors tampoc us funcionen, és probable que les vostres dades continguin alguna cosa específica que no s'imprimeixi. personatgesamb valors de codi diferents de 32 i 160. En aquest cas, utilitzeu una de les fórmules següents per esbrinar el codi de caràcter, on A1 és una cel·la problemàtica:

Espai inicial: =CODE(LEFT(A1,1))

A final espai: =CODE(RIGHT(A1,1))

Espai intermedi (on n és la posició del caràcter problemàtic a la cadena de text):

=CODE(MID(A1, n , 1)))

I després , proporcioneu el codi de caràcter retornat a la fórmula TRIM(SUBSTITUTE()) comentada anteriorment.

Per exemple, si la funció CODI retorna 9, que és el caràcter de tabulació horitzontal, feu servir la fórmula següent per eliminar-lo:

=TRIM(SUBSTITUTE(A1, CHAR(9), " "))

Retalla els espais per a Excel: elimina els espais addicionals amb un clic

La idea d'aprendre un grapat de fórmules diferents per fer front a una tasca trivial sembla ridícula? Aleshores, us pot agradar aquesta tècnica d'un sol clic per desfer-vos dels espais a Excel. Permeteu-me presentar-vos a Text Toolkit inclòs a la nostra Ultimate Suite. Entre altres coses, com ara canviar majúscules i minúscules, dividir el text i esborrar el format, ofereix l'opció Trim Spaces .

Amb Ultimate Suite instal·lat al vostre Excel, eliminar espais a Excel és tan senzill com això. :

1. Seleccioneu les cel·les on voleu suprimir espais.
2. Feu clic al botó Retalla els espais de la cinta.
3. Trieu una o totes de les opcions següents:
   • Retalla espais inicials i finals
   • Retalla espais addicionals entre paraules, excepte una solaespai
   • Retalla espais ininterromputs ( )
4. Feu clic a Retalla .

Això és tot el que hi ha! Tots els espais addicionals s'eliminen en un parpelleig.

En aquest exemple, només estem eliminant els espais inicials i finals, mantenint intactes diversos espais entre paraules per a una millor llegibilitat; la tasca a la qual les fórmules d'Excel no poden fer front s'aconsegueix amb un feu clic al ratolí!

Si esteu interessats a provar Retallar espais als vostres fulls, podeu descarregar-vos una versió d'avaluació al final d'aquesta publicació.

Us agraeixo la lectura i espero veure-us la setmana vinent. Al nostre proper tutorial, parlarem d'altres maneres de retallar espais a Excel, estigueu atents!

Descàrregues disponibles

Retalla espais d'Excel: exemples de fórmules (fitxer .xlsx)

Ultimate Suite - versió de prova (fitxer .exe)